FS/FS/access_right.pm

   1 package FS::access_right;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 use FS::Record qw( qsearch qsearchs );
   6
   7 @ISA = qw(FS::Record);
   8
   9 =head1 NAME
  10
  11 FS::access_right - Object methods for access_right records
  12
  13 =head1 SYNOPSIS
  14
  15   use FS::access_right;
  16
  17   $record = new FS::access_right \%hash;
  18   $record = new FS::access_right { 'column' => 'value' };
  19
  20   $error = $record->insert;
  21
  22   $error = $new_record->replace($old_record);
  23
  24   $error = $record->delete;
  25
  26   $error = $record->check;
  27
  28 =head1 DESCRIPTION
  29
  30 An FS::access_right object represents a granted access right.  FS::access_right
  31 inherits from FS::Record.  The following fields are currently supported:
  32
  33 =over 4
  34
  35 =item rightnum - primary key
  36
  37 =item righttype -
  38
  39 =item rightobjnum -
  40
  41 =item rightname -
  42
  43
  44 =back
  45
  46 =head1 METHODS
  47
  48 =over 4
  49
  50 =item new HASHREF
  51
  52 Creates a new right.  To add the right to the database, see L<"insert">.
  53
  54 Note that this stores the hash reference, not a distinct copy of the hash it
  55 points to.  You can ask the object for a copy with the I<hash> method.
  56
  57 =cut
  58
  59 # the new method can be inherited from FS::Record, if a table method is defined
  60
  61 sub table { 'access_right'; }
  62
  63 =item insert
  64
  65 Adds this record to the database.  If there is an error, returns the error,
  66 otherwise returns false.
  67
  68 =cut
  69
  70 # the insert method can be inherited from FS::Record
  71
  72 =item delete
  73
  74 Delete this record from the database.
  75
  76 =cut
  77
  78 # the delete method can be inherited from FS::Record
  79
  80 =item replace OLD_RECORD
  81
  82 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  83 returns the error, otherwise returns false.
  84
  85 =cut
  86
  87 # the replace method can be inherited from FS::Record
  88
  89 =item check
  90
  91 Checks all fields to make sure this is a valid right.  If there is
  92 an error, returns the error, otherwise returns false.  Called by the insert
  93 and replace methods.
  94
  95 =cut
  96
  97 # the check method should currently be supplied - FS::Record contains some
  98 # data checking routines
  99
 100 sub check {
 101   my $self = shift;
 102
 103   my $error =
 104     $self->ut_numbern('rightnum')
 105     || $self->ut_text('righttype')
 106     || $self->ut_text('rightobjnum')
 107     || $self->ut_text('rightname')
 108   ;
 109   return $error if $error;
 110
 111   $self->SUPER::check;
 112 }
 113
 114 # _upgrade_data
 115 #
 116 # Used by FS::Upgrade to migrate to a new database.
 117
 118 sub _upgrade_data { # class method
 119   my ($class, %opts) = @_;
 120
 121   my @unmigrated = ( qsearch( 'access_right',
 122                               { 'righttype'=>'FS::access_group',
 123                                 'rightname'=>'Engineering configuration',
 124                               }
 125                             ),
 126                      qsearch( 'access_right',
 127                               { 'righttype'=>'FS::access_group',
 128                                 'rightname'=>'Engineering global configuration',
 129                               }
 130                             )
 131                    );
 132   foreach ( @unmigrated ) {
 133     my $rightname = $_->rightname;
 134     $rightname =~ s/Engineering/Dialup/;
 135     $_->rightname($rightname);
 136     my $error = $_->replace;
 137     die "Failed to update access right: $error"
 138       if $error;
 139     my $broadband = new FS::access_right { $_->hash };
 140     $rightname =~ s/Dialup/Broadband/;
 141     $broadband->rightnum('');
 142     $broadband->rightname($rightname);
 143     $error = $broadband->insert;
 144     die "Failed to insert access right: $error"
 145       if $error;
 146   }
 147
 148   my %migrate = (
 149     'Post payment'    => [ 'Post check payment', 'Post cash payment' ],
 150     'Process payment' => [ 'Process credit card payment', 'Process Echeck payment' ],
 151     'Post refund'     => [ 'Post check refund', 'Post cash refund' ],
 152     'Refund payment'  => [ 'Refund credit card payment', 'Refund Echeck payment' ],
 153   );
 154
 155   foreach my $oldright (keys %migrate) {
 156     my @old = qsearch('access_right', { 'righttype'=>'FS::access_group',
 157                                         'rightname'=>$oldright,
 158                                       }
 159                      );
 160
 161     foreach my $old ( @old ) {
 162
 163       foreach my $newright ( @{ $migrate{$oldright} } ) {
 164         my %hash = (
 165           'righttype'   => 'FS::access_group',
 166           'rightobjnum' => $old->rightobjnum,
 167           'rightname'   => $newright,
 168         );
 169         next if qsearchs('access_right', \%hash);
 170         my $access_right = new FS::access_right \%hash;
 171         my $error = $access_right->insert;
 172         die $error if $error;
 173       }
 174
 175       #after the WEST stuff is sorted, etc.
 176       #my $error = $old->delete;
 177       #die $error if $error;
 178
 179     }
 180
 181   }
 182
 183   my @all_groups = qsearch('access_group', {});
 184
 185   my %onetime = (
 186     'List customers'   => 'List all customers',
 187     'List packages'    => 'Summarize packages',
 188     'Post payment'     => 'Backdate payment',
 189     'List services'    => [ 'Services: Accounts',
 190                             'Services: Domains',
 191                             'Services: Certificates',
 192                             'Services: Mail forwards',
 193                             'Services: Virtual hosting services',
 194                             'Services: Wireless broadband services',
 195                             'Services: DSLs',
 196                             'Services: Dish services',
 197                             'Services: Hardware',
 198                             'Services: Phone numbers',
 199                             'Services: PBXs',
 200                             'Services: Ports',
 201                             'Services: Mailing lists',
 202                             'Services: External services',
 203                           ],
 204     'List rating data' => [ 'Usage: RADIUS sessions',
 205                             'Usage: Call Detail Records (CDRs)',
 206                             'Usage: Unrateable CDRs',
 207                           ],
 208     'Cancel customer package immediately' => 'Un-cancel customer package',
 209   );
 210
 211   foreach my $old_acl ( keys %onetime ) {
 212
 213     my @new_acl = ref($onetime{$old_acl})
 214                     ? @{ $onetime{$old_acl} }
 215                     :  ( $onetime{$old_acl} );
 216
 217     foreach my $new_acl ( @new_acl ) {
 218
 219       ( my $journal = 'ACL_'.lc($new_acl) ) =~ s/\W/_/g;
 220       next if FS::upgrade_journal->is_done($journal);
 221
 222       # grant $new_acl to all groups who have $old_acl
 223       for my $group (@all_groups) {
 224         next unless $group->access_right($old_acl);
 225         next if     $group->access_right($new_acl);
 226         my $access_right = FS::access_right->new( {
 227             'righttype'   => 'FS::access_group',
 228             'rightobjnum' => $group->groupnum,
 229             'rightname'   => $new_acl,
 230         } );
 231         my $error = $access_right->insert;
 232         die $error if $error;
 233       }
 234
 235       FS::upgrade_journal->set_done($journal);
 236
 237     }
 238
 239   }
 240
 241   ### ACL_download_report_data
 242   if ( !FS::upgrade_journal->is_done('ACL_download_report_data') ) {
 243
 244     # grant to everyone
 245     for my $group (@all_groups) {
 246       my $access_right = FS::access_right->new( {
 247           'righttype'   => 'FS::access_group',
 248           'rightobjnum' => $group->groupnum,
 249           'rightname'   => 'Download report data',
 250       } );
 251       my $error = $access_right->insert;
 252       die $error if $error;
 253     }
 254
 255     FS::upgrade_journal->set_done('ACL_download_report_data');
 256   }
 257
 258   '';
 259
 260 }
 261
 262 =back
 263
 264 =head1 BUGS
 265
 266 =head1 SEE ALSO
 267
 268 L<FS::Record>, schema.html from the base documentation.
 269
 270 =cut
 271
 272 1;
 273