FS/FS/Upgrade.pm

   1 package FS::Upgrade;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use File::Slurp;
   8 use FS::UID qw( dbh driver_name );
   9 use FS::Conf;
  10 use FS::Record qw(qsearchs qsearch str2time_sql);
  11 use FS::queue;
  12 use FS::upgrade_journal;
  13 use FS::Setup qw( enable_banned_pay_pad );
  14
  15 use FS::svc_domain;
  16 $FS::svc_domain::whois_hack = 1;
  17
  18 @ISA = qw( Exporter );
  19 @EXPORT_OK = qw( upgrade_schema upgrade_config upgrade upgrade_sqlradius );
  20
  21 $DEBUG = 1;
  22
  23 =head1 NAME
  24
  25 FS::Upgrade - Database upgrade routines
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Upgrade;
  30
  31 =head1 DESCRIPTION
  32
  33 Currently this module simply provides a place to store common subroutines for
  34 database upgrades.
  35
  36 =head1 SUBROUTINES
  37
  38 =over 4
  39
  40 =item upgrade_config
  41
  42 =cut
  43
  44 #config upgrades
  45 sub upgrade_config {
  46   my %opt = @_;
  47
  48   my $conf = new FS::Conf;
  49
  50   # to simplify tokenization upgrades
  51   die "Conf selfservice-payment_gateway no longer supported"
  52     if $conf->config('selfservice-payment_gateway');
  53
  54   $conf->touch('payment_receipt')
  55     if $conf->exists('payment_receipt_email')
  56     || $conf->config('payment_receipt_msgnum');
  57
  58   $conf->touch('geocode-require_nw_coordinates')
  59     if $conf->exists('svc_broadband-require-nw-coordinates');
  60
  61   unless ( $conf->config('echeck-country') ) {
  62     if ( $conf->exists('cust_main-require-bank-branch') ) {
  63       $conf->set('echeck-country', 'CA');
  64     } elsif ( $conf->exists('echeck-nonus') ) {
  65       $conf->set('echeck-country', 'XX');
  66     } else {
  67       $conf->set('echeck-country', 'US');
  68     }
  69   }
  70
  71   my @agents = qsearch('agent', {});
  72
  73   upgrade_overlimit_groups($conf);
  74   map { upgrade_overlimit_groups($conf,$_->agentnum) } @agents;
  75
  76   upgrade_invoice_from($conf);
  77   foreach my $agent (@agents) {
  78     upgrade_invoice_from($conf,$agent->agentnum,1);
  79   }
  80
  81   my $DIST_CONF = '/usr/local/etc/freeside/default_conf/';#DIST_CONF in Makefile
  82   $conf->set($_, scalar(read_file( "$DIST_CONF/$_" )) )
  83     foreach grep { ! $conf->exists($_) && -s "$DIST_CONF/$_" }
  84       qw( quotation_html quotation_latex quotation_latexnotes );
  85
  86   # change 'fslongtable' to 'longtable'
  87   # in invoice and quotation main templates, and also in all secondary
  88   # invoice templates
  89   my @latex_confs =
  90     qsearch('conf', { 'name' => {op=>'LIKE', value=>'%latex%'} });
  91
  92   foreach my $c (@latex_confs) {
  93     my $value = $c->value;
  94     if (length($value) and $value =~ /fslongtable/) {
  95       $value =~ s/fslongtable/longtable/g;
  96       $conf->set($c->name, $value, $c->agentnum);
  97     }
  98   }
  99
 100   # if there's a USPS tools login, assume that's the standardization method
 101   # you want to use
 102   $conf->set('address_standardize_method', 'usps')
 103     if $conf->exists('usps_webtools-userid')
 104     && length($conf->config('usps_webtools-userid')) > 0
 105     && ! $conf->exists('address_standardize_method');
 106
 107   # this option has been renamed/expanded
 108   if ( $conf->exists('cust_main-enable_spouse_birthdate') ) {
 109     $conf->touch('cust_main-enable_spouse');
 110     $conf->delete('cust_main-enable_spouse_birthdate');
 111   }
 112
 113   # renamed/repurposed
 114   if ( $conf->exists('cust_pkg-show_fcc_voice_grade_equivalent') ) {
 115     $conf->touch('part_pkg-show_fcc_options');
 116     $conf->delete('cust_pkg-show_fcc_voice_grade_equivalent');
 117     warn "
 118 You have FCC Form 477 package options enabled.
 119
 120 Starting with the October 2014 filing date, the FCC has redesigned
 121 Form 477 and introduced new service categories.  See bin/convert-477-options
 122 to update your package configuration for the new report.
 123
 124 If you need to continue using the old Form 477 report, turn on the
 125 'old_fcc_report' configuration option.
 126 ";
 127   }
 128
 129   # boolean invoice_sections_by_location option is now
 130   # invoice_sections_method = 'location'
 131   my @invoice_sections_confs =
 132     qsearch('conf', { 'name' => { op=>'LIKE', value=>'%sections_by_location' } });
 133   foreach my $c (@invoice_sections_confs) {
 134     $c->name =~ /^(\w+)sections_by_location$/;
 135     $conf->delete($c->name);
 136     my $newname = $1.'sections_method';
 137     $conf->set($newname, 'location');
 138   }
 139
 140   # boolean enable_taxproducts is now tax_data_vendor = 'cch'
 141   if ( $conf->exists('enable_taxproducts') ) {
 142
 143     $conf->delete('enable_taxproducts');
 144     $conf->set('tax_data_vendor', 'cch');
 145
 146   }
 147
 148   # boolean tax-cust_exempt-groups-require_individual_nums is now -num_req all
 149   if ( $conf->exists('tax-cust_exempt-groups-require_individual_nums') ) {
 150     $conf->set('tax-cust_exempt-groups-num_req', 'all');
 151     $conf->delete('tax-cust_exempt-groups-require_individual_nums');
 152   }
 153
 154   # boolean+text previous_balance-exclude_from_total is now two separate options
 155   my $total_new_charges = $conf->config('previous_balance-exclude_from_total');
 156   if (length($total_new_charges) > 0) {
 157     $conf->set('previous_balance-text-total_new_charges', $total_new_charges);
 158     $conf->set('previous_balance-exclude_from_total', '');
 159   }
 160
 161   # switch from specifying an email address to boolean check
 162   if ( $conf->exists('batch-errors_to') ) {
 163     $conf->touch('batch-errors_not_fatal');
 164     $conf->delete('batch-errors_to');
 165   }
 166
 167   if ( $conf->exists('voip-cust_email_csv_cdr') ) {
 168     $conf->set('voip_cdr_email_attach', 'csv');
 169     $conf->delete('voip-cust_email_csv_cdr') ;
 170   }
 171
 172   if ($conf->exists('unsuspendauto') && !$conf->config('unsuspend_balance')) {
 173     $conf->set('unsuspend_balance','Zero');
 174     $conf->delete('unsuspendauto');
 175   }
 176
 177   if ($conf->config('cust-fields') =~ / \| Payment Type/) {
 178     my $cust_fields = $conf->config('cust-fields');
 179     # so we can potentially use 'Payment Types' or somesuch in the future
 180     $cust_fields =~ s/ \| Payment Type( \|)/$1/;
 181     $cust_fields =~ s/ \| Payment Type$//;
 182     $conf->set('cust-fields',$cust_fields);
 183   }
 184
 185   enable_banned_pay_pad() unless length($conf->config('banned_pay-pad'));
 186
 187   # if translate-auto-insert is enabled for a locale, ensure that invoice
 188   # terms are in the msgcat (is there a better place for this?)
 189   if (my $auto_locale = $conf->config('translate-auto-insert')) {
 190     my $lh = FS::L10N->get_handle($auto_locale);
 191     foreach (@FS::Conf::invoice_terms) {
 192       $lh->maketext($_) if length($_);
 193     }
 194   }
 195
 196   unless ( FS::upgrade_journal->is_done('deprecate_unmask_ss') ) {
 197     if ( $conf->config_bool( 'unmask_ss' )) {
 198       warn "'unmask_ssn' deprecated from global configuration\n";
 199       for my $access_group ( qsearch( access_group => {} )) {
 200         $access_group->grant_access_right( 'Unmask customer SSN' );
 201         warn " - 'Unmask customer SSN' access right granted to '" .
 202              $access_group->groupname . "' employee group\n";
 203       }
 204     }
 205     FS::upgrade_journal->set_done('deprecate_unmask_ss');
 206   }
 207
 208 }
 209
 210 sub upgrade_overlimit_groups {
 211     my $conf = shift;
 212     my $agentnum = shift;
 213     my @groups = $conf->config('overlimit_groups',$agentnum);
 214     if(scalar(@groups)) {
 215         my $groups = join(',',@groups);
 216         my @groupnums;
 217         my $error = '';
 218         if ( $groups !~ /^[\d,]+$/ ) {
 219             foreach my $groupname ( @groups ) {
 220                 my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 221                 unless ( $g ) {
 222                     $g = new FS::radius_group {
 223                                     'groupname' => $groupname,
 224                                     'description' => $groupname,
 225                                     };
 226                     $error = $g->insert;
 227                     die $error if $error;
 228                 }
 229                 push @groupnums, $g->groupnum;
 230             }
 231             $conf->set('overlimit_groups',join("\n",@groupnums),$agentnum);
 232         }
 233     }
 234 }
 235
 236 sub upgrade_invoice_from {
 237   my ($conf, $agentnum, $agentonly) = @_;
 238   if (
 239           ! $conf->exists('invoice_from_name',$agentnum,$agentonly)
 240        && $conf->exists('invoice_from',$agentnum,$agentonly)
 241        && $conf->config('invoice_from',$agentnum,$agentonly) =~ /\<(.*)\>/
 242   ) {
 243     my $realemail = $1;
 244     $realemail =~ s/^\s*//; # remove leading spaces
 245     $realemail =~ s/\s*$//; # remove trailing spaces
 246     my $realname = $conf->config('invoice_from',$agentnum);
 247     $realname =~ s/\<.*\>//; # remove email address
 248     $realname =~ s/^\s*//; # remove leading spaces
 249     $realname =~ s/\s*$//; # remove trailing spaces
 250     # properly quote names that contain punctuation
 251     if (($realname =~ /[^[:alnum:][:space:]]/) && ($realname !~ /^\".*\"$/)) {
 252       $realname = '"' . $realname . '"';
 253     }
 254     $conf->set('invoice_from_name', $realname, $agentnum);
 255     $conf->set('invoice_from', $realemail, $agentnum);
 256   }
 257 }
 258
 259 =item upgrade
 260
 261 =cut
 262
 263 sub upgrade {
 264   my %opt = @_;
 265
 266   my $data = upgrade_data(%opt);
 267
 268   my $oldAutoCommit = $FS::UID::AutoCommit;
 269   local $FS::UID::AutoCommit = 0;
 270   local $FS::UID::AutoCommit = 0;
 271
 272   local $FS::cust_pkg::upgrade = 1; #go away after setup+start dates cleaned up for old customers
 273
 274
 275   foreach my $table ( keys %$data ) {
 276
 277     my $class = "FS::$table";
 278     eval "use $class;";
 279     die $@ if $@;
 280
 281     if ( $class->can('_upgrade_data') ) {
 282       warn "Upgrading $table...\n";
 283
 284       my $start = time;
 285
 286       $class->_upgrade_data(%opt);
 287
 288       # New interface for async upgrades: a class can declare a
 289       # "queueable_upgrade" method, which will run as part of the normal
 290       # upgrade, but if the -j option is passed, will instead be run from
 291       # the job queue.
 292       if ( $class->can('queueable_upgrade') ) {
 293         my $jobname = $class . '::queueable_upgrade';
 294         my $num_jobs = FS::queue->count("job = '$jobname' and status != 'failed'");
 295         if ($num_jobs > 0) {
 296           warn "$class upgrade already scheduled.\n";
 297         } else {
 298           if ( $opt{'queue'} ) {
 299             warn "Scheduling $class upgrade.\n";
 300             my $job = FS::queue->new({ job => $jobname });
 301             $job->insert($class, %opt);
 302           } else {
 303             $class->queueable_upgrade(%opt);
 304           }
 305         } #$num_jobs == 0
 306       }
 307
 308       if ( $oldAutoCommit ) {
 309         warn "  committing\n";
 310         dbh->commit or die dbh->errstr;
 311       }
 312
 313       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 314       warn "  done in ". (time-$start). " seconds\n";
 315
 316     } else {
 317       warn "WARNING: asked for upgrade of $table,".
 318            " but FS::$table has no _upgrade_data method\n";
 319     }
 320
 321 #    my @records = @{ $data->{$table} };
 322 #
 323 #    foreach my $record ( @records ) {
 324 #      my $args = delete($record->{'_upgrade_args'}) || [];
 325 #      my $object = $class->new( $record );
 326 #      my $error = $object->insert( @$args );
 327 #      die "error inserting record into $table: $error\n"
 328 #        if $error;
 329 #    }
 330
 331   }
 332
 333   local($FS::cust_main::ignore_expired_card) = 1;
 334   #this is long-gone... would need to set an equivalent in cust_location #local($FS::cust_main::ignore_illegal_zip) = 1;
 335   local($FS::cust_main::ignore_banned_card) = 1;
 336   local($FS::cust_main::skip_fuzzyfiles) = 1;
 337
 338   local($FS::cust_payby::ignore_expired_card) = 1;
 339   local($FS::cust_payby::ignore_banned_card) = 1;
 340
 341   # decrypt inadvertantly-encrypted payinfo where payby != CARD,DCRD,CHEK,DCHK
 342   # kind of a weird spot for this, but it's better than duplicating
 343   # all this code in each class...
 344   my @decrypt_tables = qw( cust_payby cust_pay_void cust_pay cust_refund cust_pay_pending );
 345   foreach my $table ( @decrypt_tables ) {
 346       my @objects = qsearch({
 347         'table'     => $table,
 348         'hashref'   => {},
 349         'extra_sql' => "WHERE payby NOT IN ( 'CARD', 'DCRD', 'CHEK', 'DCHK' ) ".
 350                        " AND LENGTH(payinfo) > 100",
 351       });
 352       foreach my $object ( @objects ) {
 353           my $payinfo = $object->decrypt($object->payinfo);
 354           if ( $payinfo eq $object->payinfo ) {
 355             warn "error decrypting payinfo for $table: $payinfo\n";
 356             next;
 357           }
 358           $object->payinfo($payinfo);
 359           my $error = $object->replace;
 360           die $error if $error;
 361       }
 362   }
 363
 364 }
 365
 366 =item upgrade_data
 367
 368 =cut
 369
 370 sub upgrade_data {
 371   my %opt = @_;
 372
 373   tie my %hash, 'Tie::IxHash',
 374
 375     #remap log levels
 376         'log' => [],
 377
 378     #fix whitespace - before cust_main
 379     'cust_location' => [],
 380
 381     # need before cust_main tokenization upgrade,
 382     # blocks tokenization upgrade if deprecated features still in use
 383     'agent_payment_gateway' => [],
 384
 385     #cust_main (tokenizes cards, remove paycvv from history, locations, cust_payby, etc)
 386     # (handles payinfo encryption/tokenization across all relevant tables)
 387     'cust_main' => [],
 388
 389     #contact -> cust_contact / prospect_contact
 390     'contact' => [],
 391
 392     #msgcat
 393     'msgcat' => [],
 394
 395     #reason type and reasons
 396     'reason_type'     => [],
 397     'cust_pkg_reason' => [],
 398
 399     #need part_pkg before cust_credit...
 400     'part_pkg' => [],
 401
 402     #customer credits
 403     'cust_credit' => [],
 404
 405     # reason / void_reason migration to reasonnum / void_reasonnum
 406     'cust_credit_void' => [],
 407     'cust_bill_void' => [],
 408     # also fix some tax allocation records
 409     'cust_bill_pkg_void' => [],
 410
 411     #duplicate history records
 412     'h_cust_svc'  => [],
 413
 414     #populate cust_pay.otaker
 415     'cust_pay'    => [],
 416
 417     #populate part_pkg_taxclass for starters
 418     'part_pkg_taxclass' => [],
 419
 420     #remove bad pending records
 421     'cust_pay_pending' => [],
 422
 423     #replace invnum and pkgnum with billpkgnum
 424     'cust_bill_pkg_detail' => [],
 425
 426     #usage_classes if we have none
 427     'usage_class' => [],
 428
 429     #phone_type if we have none
 430     'phone_type' => [],
 431
 432     #fixup access rights
 433     'access_right' => [],
 434
 435     #change recur_flat and enable_prorate
 436     'part_pkg_option' => [],
 437
 438     #add weights to pkg_category
 439     'pkg_category' => [],
 440
 441     #cdrbatch fixes
 442     'cdr' => [],
 443
 444     #otaker->usernum
 445     'cust_attachment' => [],
 446     #'cust_credit' => [],
 447     #'cust_main' => [],
 448     'cust_main_note' => [],
 449     #'cust_pay' => [],
 450     'cust_pay_void' => [],
 451     'cust_pkg' => [],
 452     #'cust_pkg_reason' => [],
 453     'cust_pkg_discount' => [],
 454     'cust_refund' => [],
 455     'banned_pay' => [],
 456
 457     #paycardtype
 458     'cust_payby' => [],
 459
 460     #default namespace
 461     'payment_gateway' => [],
 462
 463     #migrate to templates
 464     'msg_template' => [],
 465
 466     #return unprovisioned numbers to availability
 467     'phone_avail' => [],
 468
 469     #insert scripcondition
 470     'TicketSystem' => [],
 471
 472     #insert LATA data if not already present
 473     'lata' => [],
 474
 475     #insert MSA data if not already present
 476     'msa' => [],
 477
 478     # migrate to radius_group and groupnum instead of groupname
 479     'radius_usergroup' => [],
 480     'part_svc'         => [],
 481     'part_export'      => [],
 482
 483     #insert default tower_sector if not present
 484     'tower' => [],
 485
 486     #repair improperly deleted services
 487     'cust_svc' => [],
 488
 489     #routernum/blocknum
 490     'svc_broadband' => [],
 491
 492     #set up payment gateways if needed
 493     'pay_batch' => [],
 494
 495     #flag monthly tax exemptions
 496     'cust_tax_exempt_pkg' => [],
 497
 498     #kick off tax location history upgrade
 499     'cust_bill_pkg' => [],
 500
 501     #fix taxable line item links
 502     'cust_bill_pkg_tax_location' => [],
 503
 504     #populate state FIPS codes if not already done
 505     'state' => [],
 506
 507     #set default locations on quoted packages
 508     'quotation_pkg' => [],
 509
 510     #populate tax statuses
 511     'tax_status' => [],
 512
 513     #mark certain taxes as system-maintained,
 514     # and fix whitespace
 515     'cust_main_county' => [],
 516
 517     #'compliance solutions' -> 'compliance_solutions'
 518     'tax_rate' => [],
 519     'tax_rate_location' => [],
 520
 521     #upgrade part_event_condition_option agentnum to a multiple hash value
 522     'part_event_condition_option' =>[],
 523
 524     #fix ip format
 525     'svc_circuit' => [],
 526
 527     #fix ip format
 528     'svc_hardware' => [],
 529
 530     #fix ip format
 531     'svc_pbx' => [],
 532
 533     #fix ip format
 534     'tower_sector' => [],
 535
 536
 537   ;
 538
 539   \%hash;
 540
 541 }
 542
 543 =item upgrade_schema
 544
 545 =cut
 546
 547 sub upgrade_schema {
 548   my %opt = @_;
 549
 550   my $data = upgrade_schema_data(%opt);
 551
 552   my $oldAutoCommit = $FS::UID::AutoCommit;
 553   local $FS::UID::AutoCommit = 0;
 554   local $FS::UID::AutoCommit = 0;
 555
 556   foreach my $table ( keys %$data ) {
 557
 558     my $class = "FS::$table";
 559     eval "use $class;";
 560     die $@ if $@;
 561
 562     if ( $class->can('_upgrade_schema') ) {
 563       warn "Upgrading $table schema...\n";
 564
 565       my $start = time;
 566
 567       $class->_upgrade_schema(%opt);
 568
 569       if ( $oldAutoCommit ) {
 570         warn "  committing\n";
 571         dbh->commit or die dbh->errstr;
 572       }
 573
 574       #warn "\e[1K\rUpgrading $table... done in ". (time-$start). " seconds\n";
 575       warn "  done in ". (time-$start). " seconds\n";
 576
 577     } else {
 578       warn "WARNING: asked for schema upgrade of $table,".
 579            " but FS::$table has no _upgrade_schema method\n";
 580     }
 581
 582   }
 583
 584 }
 585
 586 =item upgrade_schema_data
 587
 588 =cut
 589
 590 sub upgrade_schema_data {
 591   my %opt = @_;
 592
 593   #auto-find tables/classes with an _update_schema method?
 594
 595   tie my %hash, 'Tie::IxHash',
 596
 597     #fix classnum character(1)
 598     'cust_bill_pkg_detail' => [],
 599     #add necessary columns to RT schema
 600     'TicketSystem' => [],
 601     #remove h_access_user_log if it exists (since our regular auto schema
 602     # upgrade doesn't have the drop tables flag turned on)
 603     'access_user_log' => [],
 604     #remove possible dangling records
 605     'password_history' => [],
 606     'cust_pay_pending' => [],
 607     #remove records referencing removed things with their FKs
 608     'pkg_referral' => [],
 609     'cust_bill_pkg_discount' => [],
 610     'cust_msg' => [],
 611     'cust_bill_pay_batch' => [],
 612     'cust_event_fee' => [],
 613     'radius_attr' => [],
 614     'queue_depend' => [],
 615     'cust_main_invoice' => [],
 616     #update records referencing removed things with their FKs
 617     'cust_pkg' => [],
 618   ;
 619
 620   \%hash;
 621
 622 }
 623
 624 sub upgrade_sqlradius {
 625   #my %opt = @_;
 626
 627   my $conf = new FS::Conf;
 628
 629   my @part_export = FS::part_export::sqlradius->all_sqlradius_withaccounting();
 630
 631   foreach my $part_export ( @part_export ) {
 632
 633     my $errmsg = 'Error adding FreesideStatus to '.
 634                  $part_export->option('datasrc'). ': ';
 635
 636     my $dbh = DBI->connect(
 637       ( map $part_export->option($_), qw ( datasrc username password ) ),
 638       { PrintError => 0, PrintWarn => 0 }
 639     ) or do {
 640       warn $errmsg.$DBI::errstr;
 641       next;
 642     };
 643
 644     my $str2time = str2time_sql( $dbh->{Driver}->{Name} );
 645     my $group = "UserName";
 646     $group .= ",Realm"
 647       if ref($part_export) =~ /withdomain/
 648       || $dbh->{Driver}->{Name} =~ /^Pg/; #hmm
 649
 650     my $sth_alter = $dbh->prepare(
 651       "ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL"
 652     );
 653     if ( $sth_alter ) {
 654       if ( $sth_alter->execute ) {
 655         my $sth_update = $dbh->prepare(
 656          "UPDATE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL"
 657         ) or die $errmsg.$dbh->errstr;
 658         $sth_update->execute or die $errmsg.$sth_update->errstr;
 659       } else {
 660         my $error = $sth_alter->errstr;
 661         warn $errmsg.$error
 662           unless $error =~ /Duplicate column name/i  #mysql
 663               || $error =~ /already exists/i;        #Pg
 664 ;
 665       }
 666     } else {
 667       my $error = $dbh->errstr;
 668       warn $errmsg.$error; #unless $error =~ /exists/i;
 669     }
 670
 671     my $sth_index = $dbh->prepare(
 672       "CREATE INDEX FreesideStatus ON radacct ( FreesideStatus )"
 673     );
 674     if ( $sth_index ) {
 675       unless ( $sth_index->execute ) {
 676         my $error = $sth_index->errstr;
 677         warn $errmsg.$error
 678           unless $error =~ /Duplicate key name/i #mysql
 679               || $error =~ /already exists/i;    #Pg
 680       }
 681     } else {
 682       my $error = $dbh->errstr;
 683       warn $errmsg.$error. ' (preparing statement)';#unless $error =~ /exists/i;
 684     }
 685
 686     my $times = ($dbh->{Driver}->{Name} =~ /^mysql/)
 687       ? ' AcctStartTime != 0 AND AcctStopTime != 0 '
 688       : ' AcctStartTime IS NOT NULL AND AcctStopTime IS NOT NULL ';
 689
 690     my $sth = $dbh->prepare("SELECT UserName,
 691                                     Realm,
 692                                     $str2time max(AcctStartTime)),
 693                                     $str2time max(AcctStopTime))
 694                               FROM radacct
 695                               WHERE FreesideStatus = 'done'
 696                                 AND $times
 697                               GROUP BY $group
 698                             ")
 699       or die $errmsg.$dbh->errstr;
 700     $sth->execute() or die $errmsg.$sth->errstr;
 701
 702     while (my $row = $sth->fetchrow_arrayref ) {
 703       my ($username, $realm, $start, $stop) = @$row;
 704
 705       $username = lc($username) unless $conf->exists('username-uppercase');
 706
 707       my $exportnum = $part_export->exportnum;
 708       my $extra_sql = " AND exportnum = $exportnum ".
 709                       " AND exportsvcnum IS NOT NULL ";
 710
 711       if ( ref($part_export) =~ /withdomain/ ) {
 712         $extra_sql = " AND '$realm' = ( SELECT domain FROM svc_domain
 713                          WHERE svc_domain.svcnum = svc_acct.domsvc ) ";
 714       }
 715
 716       my $svc_acct = qsearchs({
 717         'select'    => 'svc_acct.*',
 718         'table'     => 'svc_acct',
 719         'addl_from' => 'LEFT JOIN cust_svc   USING ( svcnum )'.
 720                        'LEFT JOIN export_svc USING ( svcpart )',
 721         'hashref'   => { 'username' => $username },
 722         'extra_sql' => $extra_sql,
 723       });
 724
 725       if ($svc_acct) {
 726         $svc_acct->last_login($start)
 727           if $start && (!$svc_acct->last_login || $start > $svc_acct->last_login);
 728         $svc_acct->last_logout($stop)
 729           if $stop && (!$svc_acct->last_logout || $stop > $svc_acct->last_logout);
 730       }
 731     }
 732   }
 733
 734 }
 735
 736 =back
 737
 738 =head1 BUGS
 739
 740 Sure.
 741
 742 =head1 SEE ALSO
 743
 744 =cut
 745
 746 1;