FS/FS/UID.pm

   1 package FS::UID;
   2
   3 use strict;
   4 use vars qw(
   5   @ISA @EXPORT_OK $cgi $dbh $freeside_uid $user
   6   $conf_dir $secrets $datasrc $db_user $db_pass %callback $driver_name
   7   $AutoCommit
   8 );
   9 use subs qw(
  10   getsecrets cgisetotaker
  11 );
  12 use Exporter;
  13 use Carp qw(carp croak cluck);
  14 use DBI;
  15 use FS::Conf;
  16
  17 @ISA = qw(Exporter);
  18 @EXPORT_OK = qw(checkeuid checkruid cgisuidsetup adminsuidsetup forksuidsetup
  19                 getotaker dbh datasrc getsecrets driver_name );
  20
  21 $freeside_uid = scalar(getpwnam('freeside'));
  22
  23 $conf_dir = "/usr/local/etc/freeside/";
  24
  25 $AutoCommit = 1; #ours, not DBI
  26
  27 =head1 NAME
  28
  29 FS::UID - Subroutines for database login and assorted other stuff
  30
  31 =head1 SYNOPSIS
  32
  33   use FS::UID qw(adminsuidsetup cgisuidsetup dbh datasrc getotaker
  34   checkeuid checkruid);
  35
  36   adminsuidsetup $user;
  37
  38   $cgi = new CGI;
  39   $dbh = cgisuidsetup($cgi);
  40
  41   $dbh = dbh;
  42
  43   $datasrc = datasrc;
  44
  45   $driver_name = driver_name;
  46
  47 =head1 DESCRIPTION
  48
  49 Provides a hodgepodge of subroutines.
  50
  51 =head1 SUBROUTINES
  52
  53 =over 4
  54
  55 =item adminsuidsetup USER
  56
  57 Sets the user to USER (see config.html from the base documentation).
  58 Cleans the environment.
  59 Make sure the script is running as freeside, or setuid freeside.
  60 Opens a connection to the database.
  61 Swaps real and effective UIDs.
  62 Runs any defined callbacks (see below).
  63 Returns the DBI database handle (usually you don't need this).
  64
  65 =cut
  66
  67 sub adminsuidsetup {
  68   $dbh->disconnect if $dbh;
  69   &forksuidsetup(@_);
  70 }
  71
  72 sub forksuidsetup {
  73   $user = shift;
  74   croak "fatal: adminsuidsetup called without arguements" unless $user;
  75
  76   $user =~ /^([\w\-\.]+)$/ or croak "fatal: illegal user $user";
  77   $user = $1;
  78
  79   $ENV{'PATH'} ='/usr/local/bin:/usr/bin:/usr/ucb:/bin';
  80   $ENV{'SHELL'} = '/bin/sh';
  81   $ENV{'IFS'} = " \t\n";
  82   $ENV{'CDPATH'} = '';
  83   $ENV{'ENV'} = '';
  84   $ENV{'BASH_ENV'} = '';
  85
  86   croak "Not running uid freeside!" unless checkeuid();
  87   getsecrets;
  88   $dbh = DBI->connect($datasrc,$db_user,$db_pass, {
  89                           'AutoCommit' => 0,
  90                           'ChopBlanks' => 1,
  91   } ) or die "DBI->connect error: $DBI::errstr\n";
  92
  93   foreach ( keys %callback ) {
  94     &{$callback{$_}};
  95     delete $callback{$_}; #run once
  96   }
  97
  98   $dbh;
  99 }
 100
 101 =item cgisuidsetup CGI_object
 102
 103 Takes a single argument, which is a CGI (see L<CGI>) or Apache (see L<Apache>)
 104 object (CGI::Base is depriciated).  Runs cgisetotaker and then adminsuidsetup.
 105
 106 =cut
 107
 108 sub cgisuidsetup {
 109   $cgi=shift;
 110   if ( $cgi->isa('CGI::Base') ) {
 111     carp "Use of CGI::Base is depriciated";
 112   } elsif ( $cgi->isa('Apache') ) {
 113
 114   } elsif ( ! $cgi->isa('CGI') ) {
 115     croak "fatal: unrecognized object $cgi";
 116   }
 117   cgisetotaker;
 118   adminsuidsetup($user);
 119 }
 120
 121 =item cgi
 122
 123 Returns the CGI (see L<CGI>) object.
 124
 125 =cut
 126
 127 sub cgi {
 128   carp "warning: \$FS::UID::cgi isa Apache" if $cgi->isa('Apache');
 129   $cgi;
 130 }
 131
 132 =item dbh
 133
 134 Returns the DBI database handle.
 135
 136 =cut
 137
 138 sub dbh {
 139   $dbh;
 140 }
 141
 142 =item datasrc
 143
 144 Returns the DBI data source.
 145
 146 =cut
 147
 148 sub datasrc {
 149   $datasrc;
 150 }
 151
 152 =item driver_name
 153
 154 Returns just the driver name portion of the DBI data source.
 155
 156 =cut
 157
 158 sub driver_name {
 159   return $driver_name if defined $driver_name;
 160   $driver_name = ( split(':', $datasrc) )[1];
 161 }
 162
 163 sub suidsetup {
 164   croak "suidsetup depriciated";
 165 }
 166
 167 =item getotaker
 168
 169 Returns the current Freeside user.
 170
 171 =cut
 172
 173 sub getotaker {
 174   $user;
 175 }
 176
 177 =item cgisetotaker
 178
 179 Sets and returns the CGI REMOTE_USER.  $cgi should be defined as a CGI.pm
 180 object (see L<CGI>) or an Apache object (see L<Apache>).  Support for CGI::Base
 181 and derived classes is depriciated.
 182
 183 =cut
 184
 185 sub cgisetotaker {
 186   if ( $cgi && $cgi->isa('CGI::Base') && defined $cgi->var('REMOTE_USER')) {
 187     carp "Use of CGI::Base is depriciated";
 188     $user = lc ( $cgi->var('REMOTE_USER') );
 189   } elsif ( $cgi && $cgi->isa('CGI') && defined $cgi->remote_user ) {
 190     $user = lc ( $cgi->remote_user );
 191   } elsif ( $cgi && $cgi->isa('Apache') ) {
 192     $user = lc ( $cgi->connection->user );
 193   } else {
 194     die "fatal: Can't get REMOTE_USER! for cgi $cgi - you need to setup ".
 195         "Apache user authentication as documented in httemplate/docs/install.html";
 196   }
 197   $user;
 198 }
 199
 200 =item checkeuid
 201
 202 Returns true if effective UID is that of the freeside user.
 203
 204 =cut
 205
 206 sub checkeuid {
 207   ( $> == $freeside_uid );
 208 }
 209
 210 =item checkruid
 211
 212 Returns true if the real UID is that of the freeside user.
 213
 214 =cut
 215
 216 sub checkruid {
 217   ( $< == $freeside_uid );
 218 }
 219
 220 =item getsecrets [ USER ]
 221
 222 Sets the user to USER, if supplied.
 223 Sets and returns the DBI datasource, username and password for this user from
 224 the `/usr/local/etc/freeside/mapsecrets' file.
 225
 226 =cut
 227
 228 sub getsecrets {
 229   my($setuser) = shift;
 230   $user = $setuser if $setuser;
 231   die "No user!" unless $user;
 232   my($conf) = new FS::Conf $conf_dir;
 233   my($line) = grep /^\s*$user\s/, $conf->config('mapsecrets');
 234   die "User $user not found in mapsecrets!" unless $line;
 235   $line =~ /^\s*$user\s+(.*)$/;
 236   $secrets = $1;
 237   die "Illegal mapsecrets line for user?!" unless $secrets;
 238   ($datasrc, $db_user, $db_pass) = $conf->config($secrets)
 239     or die "Can't get secrets: $!";
 240   $FS::Conf::default_dir = $conf_dir. "/conf.$datasrc";
 241   undef $driver_name;
 242   ($datasrc, $db_user, $db_pass);
 243 }
 244
 245 =back
 246
 247 =head1 CALLBACKS
 248
 249 Warning: this interface is likely to change in future releases.
 250
 251 A package can install a callback to be run in adminsuidsetup by putting a
 252 coderef into the hash %FS::UID::callback :
 253
 254     $coderef = sub { warn "Hi, I'm returning your call!" };
 255     $FS::UID::callback{'Package::Name'};
 256
 257 =head1 VERSION
 258
 259 $Id: UID.pm,v 1.15 2002-06-14 09:19:33 ivan Exp $
 260
 261 =head1 BUGS
 262
 263 Too many package-global variables.
 264
 265 Not OO.
 266
 267 No capabilities yet.  When mod_perl and Authen::DBI are implemented,
 268 cgisuidsetup will go away as well.
 269
 270 Goes through contortions to support non-OO syntax with multiple datasrc's.
 271
 272 Callbacks are inelegant.
 273
 274 =head1 SEE ALSO
 275
 276 L<FS::Record>, L<CGI>, L<DBI>, config.html from the base documentation.
 277
 278 =cut
 279
 280 1;
 281