FS/FS/UI/Web.pm

   1 package FS::UI::Web;
   2
   3 use vars qw($DEBUG);
   4 use FS::Conf;
   5 use FS::Record qw(dbdef);
   6
   7 #use vars qw(@ISA);
   8 #use FS::UI
   9 #@ISA = qw( FS::UI );
  10
  11 use Date::Parse;
  12 sub parse_beginning_ending {
  13   my($cgi) = @_;
  14
  15   my $beginning = 0;
  16   if ( $cgi->param('begin') =~ /^(\d+)$/ ) {
  17     $beginning = $1;
  18   } elsif ( $cgi->param('beginning') =~ /^([ 0-9\-\/]{1,64})$/ ) {
  19     $beginning = str2time($1) || 0;
  20   }
  21
  22   my $ending = 4294967295; #2^32-1
  23   if ( $cgi->param('end') =~ /^(\d+)$/ ) {
  24     $ending = $1 - 1;
  25   } elsif ( $cgi->param('ending') =~ /^([ 0-9\-\/]{1,64})$/ ) {
  26     #probably need an option to turn off the + 86399
  27     $ending = str2time($1) + 86399;
  28   }
  29
  30   ( $beginning, $ending );
  31 }
  32
  33 ###
  34 # cust_main report methods
  35 ###
  36
  37 =item cust_header
  38
  39 Returns an array of customer information headers according to the
  40 B<cust-fields> configuration setting.
  41
  42 =cut
  43
  44 use vars qw( @cust_fields );
  45
  46 sub cust_sql_fields {
  47   my @fields = qw( last first company );
  48   push @fields, map "ship_$_", @fields
  49     if dbdef->table('cust_main')->column('ship_last');
  50   map "cust_main.$_", @fields;
  51 }
  52
  53 sub cust_header {
  54
  55   warn "FS::svc_Common::cust_header called"
  56     if $DEBUG;
  57
  58   my $conf = new FS::Conf;
  59
  60   my %header2method = (
  61     'Customer'           => 'name',
  62     'Cust#'              => 'custnum',
  63     'Name'               => 'contact',
  64     'Company'            => 'company',
  65     '(bill) Customer'    => 'name',
  66     '(service) Customer' => 'ship_name',
  67     '(bill) Name'        => 'contact',
  68     '(service) Name'     => 'ship_contact',
  69     '(bill) Company'     => 'company',
  70     '(service) Company'  => 'ship_company',
  71   );
  72
  73   my @cust_header;
  74   if (    $conf->exists('cust-fields')
  75        && $conf->config('cust-fields') =~ /^([\w \|\#\(\)]+):/
  76      )
  77   {
  78     warn "  found cust-fields configuration value"
  79       if $DEBUG;
  80
  81     my $cust_fields = $1;
  82      @cust_header = split(/ \| /, $cust_fields);
  83      @cust_fields = map { $header2method{$_} } @cust_header;
  84   } else {
  85     warn "  no cust-fields configuration value found; using default 'Customer'"
  86       if $DEBUG;
  87     @cust_header = ( 'Customer' );
  88     @cust_fields = ( 'name' );
  89   }
  90
  91   #my $svc_x = shift;
  92   @cust_header;
  93 }
  94
  95 =item cust_fields
  96
  97 Given a svc_ object that contains fields from cust_main (say, from a
  98 JOINed search.  See httemplate/search/svc_* for examples), returns an array
  99 of customer information according to the <B>cust-fields</B> configuration
 100 setting, or "(unlinked)" if this service is not linked to a customer.
 101
 102 =cut
 103
 104 sub cust_fields {
 105   my $svc_x = shift;
 106   warn "FS::svc_Common::cust_fields called for $svc_x ".
 107        "(cust_fields: @cust_fields)"
 108     if $DEBUG > 1;
 109
 110   cust_header() unless @cust_fields;
 111
 112   my $seen_unlinked = 0;
 113   map {
 114     if ( $svc_x->custnum ) {
 115       warn "  $svc_x -> $_"
 116         if $DEBUG > 1;
 117       $svc_x->$_(@_);
 118     } else {
 119       warn "  ($svc_x unlinked)"
 120         if $DEBUG > 1;
 121       $seen_unlinked++ ? '' : '(unlinked)';
 122     }
 123   } @cust_fields;
 124 }
 125
 126 ###
 127 # begin JSRPC code...
 128 ###
 129
 130 package FS::UI::Web::JSRPC;
 131
 132 use strict;
 133 use vars qw(@ISA $DEBUG);
 134 use Storable qw(nfreeze);
 135 use MIME::Base64;
 136 use JavaScript::RPC::Server::CGI;
 137 use FS::UID;
 138 use FS::Record qw(qsearchs);
 139 use FS::queue;
 140
 141 @ISA = qw( JavaScript::RPC::Server::CGI );
 142 $DEBUG = 0;
 143
 144 sub new {
 145         my $class = shift;
 146         my $self  = {
 147                 env => {},
 148                 job => shift,
 149         };
 150
 151         bless $self, $class;
 152
 153         return $self;
 154 }
 155
 156 sub start_job {
 157   my $self = shift;
 158
 159   warn "FS::UI::Web::start_job: ". join(', ', @_) if $DEBUG;
 160 #  my %param = @_;
 161   my %param = ();
 162   while ( @_ ) {
 163     my( $field, $value ) = splice(@_, 0, 2);
 164     unless ( exists( $param{$field} ) ) {
 165       $param{$field} = $value;
 166     } elsif ( ! ref($param{$field}) ) {
 167       $param{$field} = [ $param{$field}, $value ];
 168     } else {
 169       push @{$param{$field}}, $value;
 170     }
 171   }
 172   warn "FS::UI::Web::start_job\n".
 173        join('', map {
 174                       if ( ref($param{$_}) ) {
 175                         "  $_ => [ ". join(', ', @{$param{$_}}). " ]\n";
 176                       } else {
 177                         "  $_ => $param{$_}\n";
 178                       }
 179                     } keys %param )
 180     if $DEBUG;
 181
 182   #first get the CGI params shipped off to a job ASAP so an id can be returned
 183   #to the caller
 184
 185   my $job = new FS::queue { 'job' => $self->{'job'} };
 186
 187   #too slow to insert all the cgi params as individual args..,?
 188   #my $error = $queue->insert('_JOB', $cgi->Vars);
 189
 190   #warn 'froze string of size '. length(nfreeze(\%param)). " for job args\n"
 191   #  if $DEBUG;
 192
 193   my $error = $job->insert( '_JOB', encode_base64(nfreeze(\%param)) );
 194
 195   if ( $error ) {
 196     $error;
 197   } else {
 198     $job->jobnum;
 199   }
 200
 201 }
 202
 203 sub job_status {
 204   my( $self, $jobnum ) = @_; #$url ???
 205
 206   sleep 5; #could use something better...
 207
 208   my $job;
 209   if ( $jobnum =~ /^(\d+)$/ ) {
 210     $job = qsearchs('queue', { 'jobnum' => $jobnum } );
 211   } else {
 212     die "FS::UI::Web::job_status: illegal jobnum $jobnum\n";
 213   }
 214
 215   my @return;
 216   if ( $job && $job->status ne 'failed' ) {
 217     @return = ( 'progress', $job->statustext );
 218   } elsif ( !$job ) { #handle job gone case : job sucessful
 219                       # so close popup, redirect parent window...
 220     @return = ( 'complete' );
 221   } else {
 222     @return = ( 'error', $job ? $job->statustext : $jobnum );
 223   }
 224
 225   join("\n",@return);
 226
 227 }
 228
 229 sub get_new_query {
 230   FS::UID::cgi();
 231 }
 232
 233 1;
 234