FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum);
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 320     unless $cust_main->payname
 321         && $cust_main->payby !~ /^(CARD|DCRD|CHEK|DCHK)$/;
 322
 323   my $locale = $params{'locale'} || $cust_main->locale;
 324
 325   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 326                      'html'     => [ '<%=', '%>' ],
 327                      'template' => [ '{', '}' ],
 328                    );
 329
 330   warn "$me print_generic creating template\n"
 331     if $DEBUG > 1;
 332
 333   # set the notice name here, and nowhere else.
 334   my $notice_name =  $params{notice_name}
 335                   || $conf->config('notice_name')
 336                   || $self->notice_name;
 337
 338   #create the template
 339   my $template = $params{template} ? $params{template} : $self->_agent_template;
 340   my $templatefile = $self->template_conf. $format;
 341   $templatefile .= "_$template"
 342     if length($template) && $conf->exists($templatefile."_$template");
 343
 344   # the base template
 345   my @invoice_template = map "$_\n", $conf->config($templatefile)
 346     or die "cannot load config data $templatefile";
 347
 348   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 349     #change this to a die when the old code is removed
 350     # it's been almost ten years, changing it to a die
 351     die "old-style invoice template $templatefile; ".
 352          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 353          #$old_latex = 'true';
 354          #@invoice_template = _translate_old_latex_format(@invoice_template);
 355   }
 356
 357   warn "$me print_generic creating T:T object\n"
 358     if $DEBUG > 1;
 359
 360   my $text_template = new Text::Template(
 361     TYPE => 'ARRAY',
 362     SOURCE => \@invoice_template,
 363     DELIMITERS => $delimiters{$format},
 364   );
 365
 366   warn "$me print_generic compiling T:T object\n"
 367     if $DEBUG > 1;
 368
 369   $text_template->compile()
 370     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 371
 372
 373   # additional substitution could possibly cause breakage in existing templates
 374   my %convert_maps = (
 375     'latex' => {
 376                  'notes'         => sub { map "$_", @_ },
 377                  'footer'        => sub { map "$_", @_ },
 378                  'smallfooter'   => sub { map "$_", @_ },
 379                  'returnaddress' => sub { map "$_", @_ },
 380                  'coupon'        => sub { map "$_", @_ },
 381                  'summary'       => sub { map "$_", @_ },
 382                },
 383     'html'  => {
 384                  'notes' =>
 385                    sub {
 386                      map {
 387                        s/%%(.*)$/<!-- $1 -->/g;
 388                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 389                        s/\\begin\{enumerate\}/<ol>/g;
 390                        s/\\item /  <li>/g;
 391                        s/\\end\{enumerate\}/<\/ol>/g;
 392                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 393                        s/\\\\\*/<br>/g;
 394                        s/\\dollar ?/\$/g;
 395                        s/\\#/#/g;
 396                        s/~/&nbsp;/g;
 397                        $_;
 398                      }  @_
 399                    },
 400                  'footer' =>
 401                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 402                  'smallfooter' =>
 403                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 404                  'returnaddress' =>
 405                    sub {
 406                      map {
 407                        s/~/&nbsp;/g;
 408                        s/\\\\\*?\s*$/<BR>/;
 409                        s/\\hyphenation\{[\w\s\-]+}//;
 410                        s/\\([&])/$1/g;
 411                        $_;
 412                      }  @_
 413                    },
 414                  'coupon'        => sub { "" },
 415                  'summary'       => sub { "" },
 416                },
 417     'template' => {
 418                  'notes' =>
 419                    sub {
 420                      map {
 421                        s/%%.*$//g;
 422                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 423                        s/\\begin\{enumerate\}//g;
 424                        s/\\item /  * /g;
 425                        s/\\end\{enumerate\}//g;
 426                        s/\\textbf\{(.*)\}/$1/g;
 427                        s/\\\\\*/ /;
 428                        s/\\dollar ?/\$/g;
 429                        $_;
 430                      }  @_
 431                    },
 432                  'footer' =>
 433                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 434                  'smallfooter' =>
 435                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 436                  'returnaddress' =>
 437                    sub {
 438                      map {
 439                        s/~/ /g;
 440                        s/\\\\\*?\s*$/\n/;             # dubious
 441                        s/\\hyphenation\{[\w\s\-]+}//;
 442                        $_;
 443                      }  @_
 444                    },
 445                  'coupon'        => sub { "" },
 446                  'summary'       => sub { "" },
 447                },
 448   );
 449
 450
 451   # hashes for differing output formats
 452   my %nbsps = ( 'latex'    => '~',
 453                 'html'     => '',    # '&nbps;' would be nice
 454                 'template' => '',    # not used
 455               );
 456   my $nbsp = $nbsps{$format};
 457
 458   my %escape_functions = ( 'latex'    => \&_latex_escape,
 459                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 460                            'template' => sub { shift },
 461                          );
 462   my $escape_function = $escape_functions{$format};
 463   my $escape_function_nonbsp = ($format eq 'html')
 464                                  ? \&_html_escape : $escape_function;
 465
 466   my %newline_tokens = (  'latex'     => '\\\\',
 467                           'html'      => '<br>',
 468                           'template'  => "\n",
 469                         );
 470   my $newline_token = $newline_tokens{$format};
 471
 472   warn "$me generating template variables\n"
 473     if $DEBUG > 1;
 474
 475   # generate template variables
 476   my $returnaddress;
 477
 478   if (
 479          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 480                                         $template
 481                                       )
 482                 )
 483        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 484                                         $template
 485                                       )
 486                 )
 487   ) {
 488
 489     $returnaddress = join("\n",
 490       $conf->config_orbase("invoice_${format}returnaddress", $template)
 491     );
 492
 493   } elsif ( grep /\S/,
 494             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 495
 496     my $convert_map = $convert_maps{$format}{'returnaddress'};
 497     $returnaddress =
 498       join( "\n",
 499             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 500                                                  $template
 501                                                )
 502                          )
 503           );
 504   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 505
 506     my $convert_map = $convert_maps{$format}{'returnaddress'};
 507     $returnaddress = join( "\n", &$convert_map(
 508                                    map { s/( {2,})/'~' x length($1)/eg;
 509                                          s/$/\\\\\*/;
 510                                          $_
 511                                        }
 512                                      ( $conf->config('company_name', $cust_main->agentnum),
 513                                        $conf->config('company_address', $cust_main->agentnum),
 514                                      )
 515                                  )
 516                      );
 517
 518   } else {
 519
 520     my $warning = "Couldn't find a return address; ".
 521                   "do you need to set the company_address configuration value?";
 522     warn "$warning\n";
 523     $returnaddress = $nbsp;
 524     #$returnaddress = $warning;
 525
 526   }
 527
 528   warn "$me generating invoice data\n"
 529     if $DEBUG > 1;
 530
 531   my $agentnum = $cust_main->agentnum;
 532
 533   my %invoice_data = (
 534
 535     #invoice from info
 536     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 537     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 538     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 539     'returnaddress'   => $returnaddress,
 540     'agent'           => &$escape_function($cust_main->agent->agent),
 541
 542     #invoice/quotation info
 543     'no_number'       => $params{'no_number'},
 544     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 545     'quotationnum'    => $self->quotationnum,
 546     'no_date'         => $params{'no_date'},
 547     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 548       # workaround for inconsistent behavior in the early plain text
 549       # templates; see RT#28271
 550     'date'            => ( $params{'no_date'}
 551                              ? ''
 552                              : ($format eq 'template'
 553                                ? $self->_date
 554                                : $self->time2str_local('long', $self->_date, $format)
 555                                )
 556                          ),
 557     'today'           => $self->time2str_local('long', $today, $format),
 558     'terms'           => $self->terms,
 559     'template'        => $template, #params{'template'},
 560     'notice_name'     => $notice_name, # escape?
 561     'current_charges' => sprintf("%.2f", $self->charged),
 562     'duedate'         => $self->due_date2str('rdate'), #date_format?
 563
 564     #customer info
 565     'custnum'         => $cust_main->display_custnum,
 566     'prospectnum'     => $cust_main->prospectnum,
 567     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 568     ( map { $_ => &$escape_function($cust_main->$_()) } qw(
 569       payname company address1 address2 city state zip fax
 570     )),
 571
 572     #global config
 573     'ship_enable'     => $conf->exists('invoice-ship_address'),
 574     'unitprices'      => $conf->exists('invoice-unitprice'),
 575     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 576     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 577     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 578
 579     #layout info -- would be fancy to calc some of this and bury the template
 580     #               here in the code
 581     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 582     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 583     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 584     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 585     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 586     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 587     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 588     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 589     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 590     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 591
 592     # better hang on to conf_dir for a while (for old templates)
 593     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 594
 595     #these are only used when doing paged plaintext
 596     'page'            => 1,
 597     'total_pages'     => 1,
 598
 599   );
 600
 601   #localization
 602   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 603   # prototype here to silence warnings
 604   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 605
 606   my $min_sdate = 999999999999;
 607   my $max_edate = 0;
 608   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 609     next unless $cust_bill_pkg->pkgnum > 0;
 610     $min_sdate = $cust_bill_pkg->sdate
 611       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 612     $max_edate = $cust_bill_pkg->edate
 613       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 614   }
 615
 616   $invoice_data{'bill_period'} = '';
 617   $invoice_data{'bill_period'} =
 618       $self->time2str_local('%e %h', $min_sdate, $format)
 619       . " to " .
 620       $self->time2str_local('%e %h', $max_edate, $format)
 621     if ($max_edate != 0 && $min_sdate != 999999999999);
 622
 623   $invoice_data{finance_section} = '';
 624   if ( $conf->config('finance_pkgclass') ) {
 625     my $pkg_class =
 626       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 627     $invoice_data{finance_section} = $pkg_class->categoryname;
 628   }
 629   $invoice_data{finance_amount} = '0.00';
 630   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 631
 632   my $countrydefault = $conf->config('countrydefault') || 'US';
 633   foreach ( qw( address1 address2 city state zip country fax) ){
 634     my $method = 'ship_'.$_;
 635     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 636   }
 637   if ( length($cust_main->ship_company) ) {
 638     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 639   } else {
 640     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 641   }
 642   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 643   $invoice_data{'ship_country'} = ''
 644     if ( $invoice_data{'ship_country'} eq $countrydefault );
 645
 646   $invoice_data{'cid'} = $params{'cid'}
 647     if $params{'cid'};
 648
 649   if ( $cust_main->country eq $countrydefault ) {
 650     $invoice_data{'country'} = '';
 651   } else {
 652     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 653   }
 654
 655   my @address = ();
 656   $invoice_data{'address'} = \@address;
 657   push @address,
 658     $cust_main->payname.
 659       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 660         ? " (P.O. #". $cust_main->payinfo. ")"
 661         : ''
 662       )
 663   ;
 664   push @address, $cust_main->company
 665     if $cust_main->company;
 666   push @address, $cust_main->address1;
 667   push @address, $cust_main->address2
 668     if $cust_main->address2;
 669   push @address,
 670     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 671   push @address, $invoice_data{'country'}
 672     if $invoice_data{'country'};
 673   push @address, ''
 674     while (scalar(@address) < 5);
 675
 676   $invoice_data{'logo_file'} = $params{'logo_file'}
 677     if $params{'logo_file'};
 678   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 679     if $params{'barcode_file'};
 680   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 681     if $params{'barcode_img'};
 682   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 683     if $params{'barcode_cid'};
 684
 685   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 686 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 687   #my $balance_due = $self->owed + $pr_total - $cr_total;
 688   my $balance_due = $self->owed + $pr_total;
 689
 690   # the sum of amount owed on all invoices
 691   # (this is used in the summary & on the payment coupon)
 692   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 693
 694   # info from customer's last invoice before this one, for some
 695   # summary formats
 696   $invoice_data{'last_bill'} = {};
 697
 698   if ( $self->custnum && $self->invnum ) {
 699
 700     my $last_bill = $self->previous_bill;
 701     if ( $last_bill ) {
 702
 703       # "balance_date_range" unfortunately is unsuitable for this, since it
 704       # cares about application dates.  We want to know the sum of all
 705       # _top-level transactions_ dated before the last invoice.
 706       my @sql =
 707         map "$_ WHERE _date <= ? AND custnum = ?", (
 708           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 709           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 710           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 711           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 712         );
 713
 714       # the customer's current balance immediately after generating the last
 715       # bill
 716
 717       my $last_bill_balance = $last_bill->charged;
 718       foreach (@sql) {
 719         my $delta = FS::Record->scalar_sql(
 720           $_,
 721           $last_bill->_date - 1,
 722           $self->custnum,
 723         );
 724         $last_bill_balance += $delta;
 725       }
 726
 727       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 728
 729       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 730         $last_bill->invnum,
 731         $self->time2str_local('%D', $last_bill->_date),
 732         $last_bill_balance
 733       ) if $DEBUG > 0;
 734       # ("true_previous_balance" is a terrible name, but at least it's no
 735       # longer stored in the database)
 736       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 737
 738       # the change in balance from immediately after that invoice
 739       # to immediately before this one
 740       my $before_this_bill_balance = 0;
 741       foreach (@sql) {
 742         my $delta = FS::Record->scalar_sql(
 743           $_,
 744           $self->_date - 1,
 745           $self->custnum,
 746         );
 747         $before_this_bill_balance += $delta;
 748       }
 749       $invoice_data{'balance_adjustments'} =
 750         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 751
 752       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 753                    $invoice_data{'balance_adjustments'}
 754       ) if $DEBUG > 0;
 755
 756       # the sum of amount owed on all previous invoices
 757       # ($pr_total is used elsewhere but not as $previous_balance)
 758       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 759
 760       $invoice_data{'last_bill'} = {
 761         '_date'     => $last_bill->_date, #unformatted
 762       };
 763       my (@payments, @credits);
 764       # for formats that itemize previous payments
 765       foreach my $cust_pay ( qsearch('cust_pay', {
 766                               'custnum' => $self->custnum,
 767                               '_date'   => { op => '>=',
 768                                              value => $last_bill->_date }
 769                              } ) )
 770       {
 771         next if $cust_pay->_date > $self->_date;
 772         push @payments, {
 773             '_date'       => $cust_pay->_date,
 774             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 775             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 776             'amount'      => sprintf('%.2f', $cust_pay->paid),
 777         };
 778         # not concerned about applications
 779       }
 780       foreach my $cust_credit ( qsearch('cust_credit', {
 781                               'custnum' => $self->custnum,
 782                               '_date'   => { op => '>=',
 783                                              value => $last_bill->_date }
 784                              } ) )
 785       {
 786         next if $cust_credit->_date > $self->_date;
 787         push @credits, {
 788             '_date'       => $cust_credit->_date,
 789             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 790             'creditreason'=> $cust_credit->reason,
 791             'amount'      => sprintf('%.2f', $cust_credit->amount),
 792         };
 793       }
 794       $invoice_data{'previous_payments'} = \@payments;
 795       $invoice_data{'previous_credits'}  = \@credits;
 796     } else {
 797       # there is no $last_bill
 798       $invoice_data{'true_previous_balance'} =
 799       $invoice_data{'balance_adjustments'}   =
 800       $invoice_data{'previous_balance'}      = '0.00';
 801       $invoice_data{'previous_payments'} = [];
 802       $invoice_data{'previous_credits'} = [];
 803     }
 804   } # if this is an invoice
 805
 806   my $summarypage = '';
 807   if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 808     $summarypage = 1;
 809   }
 810   $invoice_data{'summarypage'} = $summarypage;
 811
 812   warn "$me substituting variables in notes, footer, smallfooter\n"
 813     if $DEBUG > 1;
 814
 815   my $tc = $self->template_conf;
 816   my @include = ( [ $tc,        'notes' ],
 817                   [ 'invoice_', 'footer' ],
 818                   [ 'invoice_', 'smallfooter', ],
 819                 );
 820   push @include, [ $tc,        'coupon', ]
 821     unless $params{'no_coupon'};
 822
 823   foreach my $i (@include) {
 824
 825     my($base, $include) = @$i;
 826
 827     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 828     my @inc_src;
 829
 830     if ( $conf->exists($inc_file, $agentnum)
 831          && length( $conf->config($inc_file, $agentnum) ) ) {
 832
 833       @inc_src = $conf->config($inc_file, $agentnum);
 834
 835     } else {
 836
 837       $inc_file = $conf->key_orbase("${base}latex$include", $template);
 838
 839       my $convert_map = $convert_maps{$format}{$include};
 840
 841       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
 842                        s/--\@\]/$delimiters{$format}[1]/g;
 843                        $_;
 844                      }
 845                  &$convert_map( $conf->config($inc_file, $agentnum) );
 846
 847     }
 848
 849     my $inc_tt = new Text::Template (
 850       TYPE       => 'ARRAY',
 851       SOURCE     => [ map "$_\n", @inc_src ],
 852       DELIMITERS => $delimiters{$format},
 853     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 854
 855     unless ( $inc_tt->compile() ) {
 856       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 857       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 858       die $error;
 859     }
 860
 861     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 862
 863     $invoice_data{$include} =~ s/\n+$//
 864       if ($format eq 'latex');
 865   }
 866
 867   # let invoices use either of these as needed
 868   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 869     ? $cust_main->payinfo : '';
 870   $invoice_data{'po_line'} =
 871     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 872       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 873       : $nbsp;
 874
 875   my %money_chars = ( 'latex'    => '',
 876                       'html'     => $conf->config('money_char') || '$',
 877                       'template' => '',
 878                     );
 879   my $money_char = $money_chars{$format};
 880
 881   # extremely dubious
 882   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 883                             'html'     => $conf->config('money_char') || '$',
 884                             'template' => '',
 885                           );
 886   my $other_money_char = $other_money_chars{$format};
 887   $invoice_data{'dollar'} = $other_money_char;
 888
 889   my %minus_signs = ( 'latex'    => '$-$',
 890                       'html'     => '&minus;',
 891                       'template' => '- ' );
 892   my $minus = $minus_signs{$format};
 893
 894   my @detail_items = ();
 895   my @total_items = ();
 896   my @buf = ();
 897   my @sections = ();
 898
 899   $invoice_data{'detail_items'} = \@detail_items;
 900   $invoice_data{'total_items'} = \@total_items;
 901   $invoice_data{'buf'} = \@buf;
 902   $invoice_data{'sections'} = \@sections;
 903
 904   warn "$me generating sections\n"
 905     if $DEBUG > 1;
 906
 907   my $taxtotal = 0;
 908   my $tax_section = { 'description' => $self->mt('Taxes, Surcharges, and Fees'),
 909                       'subtotal'    => $taxtotal,   # adjusted below
 910                       'tax_section' => 1,
 911                     };
 912   my $tax_weight = _pkg_category($tax_section->{description})
 913                         ? _pkg_category($tax_section->{description})->weight
 914                         : 0;
 915   $tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
 916   $tax_section->{'sort_weight'} = $tax_weight;
 917
 918   my $adjusttotal = 0;
 919   my $adjust_section = {
 920     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 921     'adjust_section' => 1,
 922     'subtotal'       => 0,   # adjusted below
 923   };
 924   my $adjust_weight = _pkg_category($adjust_section->{description})
 925                         ? _pkg_category($adjust_section->{description})->weight
 926                         : 0;
 927   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 928   $adjust_section->{'sort_weight'} = $adjust_weight;
 929
 930   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 931   my $multisection = $conf->exists($tc.'sections', $cust_main->agentnum) ||
 932                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 933   $invoice_data{'multisection'} = $multisection;
 934   my $late_sections;
 935   my $extra_sections = [];
 936   my $extra_lines = ();
 937
 938   # default section ('Charges')
 939   my $default_section = { 'description' => '',
 940                           'subtotal'    => '',
 941                           'no_subtotal' => 1,
 942                         };
 943
 944   # Previous Charges section
 945   # subtotal is the first return value from $self->previous
 946   my $previous_section;
 947   # if the invoice has major sections, or if we're summarizing previous
 948   # charges with a single line, or if we've been specifically told to put them
 949   # in a section, create a section for previous charges:
 950   if ( $multisection or
 951        $conf->exists('previous_balance-summary_only') or
 952        $conf->exists('previous_balance-section') ) {
 953
 954     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 955                            'subtotal'    => $other_money_char.
 956                                             sprintf('%.2f', $pr_total),
 957                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 958                          };
 959     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 960       join(' / ', map { $cust_main->balance_date_range(@$_) }
 961                   $self->_prior_month30s
 962           )
 963       if $conf->exists('invoice_include_aging');
 964
 965   } else {
 966     # otherwise put them in the main section
 967     $previous_section = $default_section;
 968   }
 969
 970   if ( $multisection ) {
 971     ($extra_sections, $extra_lines) =
 972       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 973       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 974       && $self->can('_items_extra_usage_sections');
 975
 976     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 977
 978     push @detail_items, @$extra_lines if $extra_lines;
 979
 980     # the code is written so that both methods can be used together, but
 981     # we haven't yet changed the template to take advantage of that, so for
 982     # now, treat them as mutually exclusive.
 983     my %section_method = ( by_category => 1 );
 984     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 985       %section_method = ( by_location => 1 );
 986     }
 987     my ($early, $late) =
 988       $self->_items_sections( 'summary' => $summarypage,
 989                               'escape'  => $escape_function_nonbsp,
 990                               'extra_sections' => $extra_sections,
 991                               'format'  => $format,
 992                               %section_method
 993                             );
 994     push @sections, @$early;
 995     $late_sections = $late;
 996
 997     if (    $conf->exists('svc_phone_sections')
 998          && $self->can('_items_svc_phone_sections')
 999        )
1000     {
1001       my ($phone_sections, $phone_lines) =
1002         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1003       push @{$late_sections}, @$phone_sections;
1004       push @detail_items, @$phone_lines;
1005     }
1006     if ( $conf->exists('voip-cust_accountcode_cdr')
1007          && $cust_main->accountcode_cdr
1008          && $self->can('_items_accountcode_cdr')
1009        )
1010     {
1011       my ($accountcode_section, $accountcode_lines) =
1012         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1013       if ( scalar(@$accountcode_lines) ) {
1014           push @{$late_sections}, $accountcode_section;
1015           push @detail_items, @$accountcode_lines;
1016       }
1017     }
1018   } else {# not multisection
1019     # make a default section
1020     push @sections, $default_section;
1021     # and calculate the finance charge total, since it won't get done otherwise.
1022     # and the default section total
1023     # XXX possibly finance_pkgclass should not be used in this manner?
1024     my @finance_charges;
1025     my @charges;
1026     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1027       if ( $invoice_data{finance_section} and
1028         grep { $_->section eq $invoice_data{finance_section} }
1029            $cust_bill_pkg->cust_bill_pkg_display ) {
1030         # I think these are always setup fees, but just to be sure...
1031         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1032       } else {
1033         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1034       }
1035     }
1036     $invoice_data{finance_amount} =
1037       sprintf('%.2f', sum( @finance_charges ) || 0);
1038     $default_section->{subtotal} = $other_money_char.
1039                                     sprintf('%.2f', sum( @charges ) || 0);
1040   }
1041
1042   # start setting up summary subtotals
1043   my @summary_subtotals;
1044   my $method = $conf->config('summary_subtotals_method');
1045   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1046     # then re-section them by the correct method
1047     my %section_method = ( by_category => 1 );
1048     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1049       %section_method = ( by_location => 1 );
1050     }
1051     my ($early, $late) =
1052       $self->_items_sections( 'summary' => $summarypage,
1053                               'escape'  => $escape_function_nonbsp,
1054                               'extra_sections' => $extra_sections,
1055                               'format'  => $format,
1056                               %section_method
1057                             );
1058     foreach ( @$early ) {
1059       next if $_->{subtotal} == 0;
1060       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1061       push @summary_subtotals, $_;
1062     }
1063   } else {
1064     # subtotal sectioning is the same as for the actual invoice sections
1065     @summary_subtotals = @sections;
1066   }
1067
1068   # Hereafter, push sections to both @sections and @summary_subtotals
1069   # if they belong in both places (e.g. tax section).  Late sections are
1070   # never in @summary_subtotals.
1071
1072   # previous invoice balances in the Previous Charges section if there
1073   # is one, otherwise in the main detail section
1074   # (except if summary_only is enabled, don't show them at all)
1075   if ( $self->can('_items_previous') &&
1076        $self->enable_previous &&
1077        ! $conf->exists('previous_balance-summary_only') ) {
1078
1079     warn "$me adding previous balances\n"
1080       if $DEBUG > 1;
1081
1082     foreach my $line_item ( $self->_items_previous ) {
1083
1084       my $detail = {
1085         ref             => $line_item->{'pkgnum'},
1086         pkgpart         => $line_item->{'pkgpart'},
1087         #quantity        => 1, # not really correct
1088         section         => $previous_section, # which might be $default_section
1089         description     => &$escape_function($line_item->{'description'}),
1090         ext_description => [ map { &$escape_function($_) }
1091                              @{ $line_item->{'ext_description'} || [] }
1092                            ],
1093         amount          => $money_char . $line_item->{'amount'},
1094         product_code    => $line_item->{'pkgpart'} || 'N/A',
1095       };
1096
1097       push @detail_items, $detail;
1098       push @buf, [ $detail->{'description'},
1099                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1100                  ];
1101     }
1102
1103   }
1104
1105   if ( @pr_cust_bill && $self->enable_previous ) {
1106     push @buf, ['','-----------'];
1107     push @buf, [ $self->mt('Total Previous Balance'),
1108                  $money_char. sprintf("%10.2f", $pr_total) ];
1109     push @buf, ['',''];
1110   }
1111
1112   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1113       warn "$me adding DID summary\n"
1114         if $DEBUG > 1;
1115
1116       my ($didsummary,$minutes) = $self->_did_summary;
1117       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1118       push @detail_items,
1119        { 'description' => $didsummary_desc,
1120            'ext_description' => [ $didsummary, $minutes ],
1121        };
1122   }
1123
1124   foreach my $section (@sections, @$late_sections) {
1125
1126     # begin some normalization
1127     $section->{'subtotal'} = $section->{'amount'}
1128       if $multisection
1129          && !exists($section->{subtotal})
1130          && exists($section->{amount});
1131
1132     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1133       if ( $invoice_data{finance_section} &&
1134            $section->{'description'} eq $invoice_data{finance_section} );
1135
1136     $section->{'subtotal'} = $other_money_char.
1137                              sprintf('%.2f', $section->{'subtotal'})
1138       if $multisection;
1139
1140     # continue some normalization
1141     $section->{'amount'}   = $section->{'subtotal'}
1142       if $multisection;
1143
1144
1145     if ( $section->{'description'} ) {
1146       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1147                    [ '', '' ],
1148                  );
1149     }
1150
1151     warn "$me   setting options\n"
1152       if $DEBUG > 1;
1153
1154     my %options = ();
1155     $options{'section'} = $section if $multisection;
1156     $options{'format'} = $format;
1157     $options{'escape_function'} = $escape_function;
1158     $options{'no_usage'} = 1 unless $unsquelched;
1159     $options{'unsquelched'} = $unsquelched;
1160     $options{'summary_page'} = $summarypage;
1161     $options{'skip_usage'} =
1162       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1163     $options{'preref_callback'} = $params{'preref_callback'};
1164
1165     warn "$me   searching for line items\n"
1166       if $DEBUG > 1;
1167
1168     foreach my $line_item ( $self->_items_pkg(%options),
1169                             $self->_items_fee(%options) ) {
1170
1171       warn "$me     adding line item ".
1172            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1173         if $DEBUG > 1;
1174
1175       push @buf, ( [ $line_item->{'description'},
1176                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1177                    ],
1178                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1179                  );
1180
1181       $line_item->{'ref'} = $line_item->{'pkgnum'};
1182       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1183       $line_item->{'section'} = $section;
1184       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1185       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1186
1187       if ( length($line_item->{'unit_amount'}) ) {
1188         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1189       }
1190       $line_item->{'ext_description'} ||= [];
1191
1192       push @detail_items, $line_item;
1193     }
1194
1195     if ( $section->{'description'} ) {
1196       push @buf, ( ['','-----------'],
1197                    [ $section->{'description'}. ' sub-total',
1198                       $section->{'subtotal'} # already formatted this
1199                    ],
1200                    [ '', '' ],
1201                    [ '', '' ],
1202                  );
1203     }
1204
1205   }
1206
1207   $invoice_data{current_less_finance} =
1208     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1209
1210   # if there's anything in the Previous Charges section, prepend it to the list
1211   if ( $pr_total and $previous_section ne $default_section ) {
1212     unshift @sections, $previous_section;
1213     # but not @summary_subtotals
1214   }
1215
1216   warn "$me adding taxes\n"
1217     if $DEBUG > 1;
1218
1219   my @items_tax = $self->_items_tax;
1220   foreach my $tax ( @items_tax ) {
1221
1222     $taxtotal += $tax->{'amount'};
1223
1224     my $description = &$escape_function( $tax->{'description'} );
1225     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1226
1227     if ( $multisection ) {
1228
1229       push @detail_items, {
1230         ext_description => [],
1231         ref          => '',
1232         quantity     => '',
1233         description  => $description,
1234         amount       => $money_char. $amount,
1235         product_code => '',
1236         section      => $tax_section,
1237       };
1238
1239     } else {
1240
1241       push @total_items, {
1242         'total_item'   => $description,
1243         'total_amount' => $other_money_char. $amount,
1244       };
1245
1246     }
1247
1248     push @buf,[ $description,
1249                 $money_char. $amount,
1250               ];
1251
1252   }
1253
1254   if ( @items_tax ) {
1255     my $total = {};
1256     $total->{'total_item'} = $self->mt('Sub-total');
1257     $total->{'total_amount'} =
1258       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1259
1260     if ( $multisection ) {
1261       $tax_section->{'subtotal'} = $other_money_char.
1262                                    sprintf('%.2f', $taxtotal);
1263       $tax_section->{'pretotal'} = 'New charges sub-total '.
1264                                    $total->{'total_amount'};
1265       if ( $taxtotal ) {
1266         push @sections, $tax_section;
1267         push @summary_subtotals, $tax_section;
1268       }
1269     } else {
1270       unshift @total_items, $total;
1271     }
1272   }
1273   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1274
1275   push @buf,['','-----------'];
1276   push @buf,[$self->mt(
1277               (!$self->enable_previous)
1278                ? 'Total Charges'
1279                : 'Total New Charges'
1280              ),
1281              $money_char. sprintf("%10.2f",$self->charged) ];
1282   push @buf,['',''];
1283
1284
1285   ###
1286   # Totals
1287   ###
1288
1289   my %embolden_functions = (
1290     'latex'    => sub { return '\textbf{'. shift(). '}' },
1291     'html'     => sub { return '<b>'. shift(). '</b>' },
1292     'template' => sub { shift },
1293   );
1294   my $embolden_function = $embolden_functions{$format};
1295
1296   if ( $self->can('_items_total') ) { # quotations
1297
1298     $self->_items_total(\@total_items);
1299
1300     foreach ( @total_items ) {
1301       $_->{'total_item'}   = &$embolden_function( $_->{'total_item'} );
1302       $_->{'total_amount'} = &$embolden_function( $other_money_char.
1303                                                    $_->{'total_amount'}
1304                                                 );
1305     }
1306
1307   } else { #normal invoice case
1308
1309     # calculate total, possibly including total owed on previous
1310     # invoices
1311     my $total = {};
1312     my $item = 'Total';
1313     $item = $conf->config('previous_balance-exclude_from_total')
1314          || 'Total New Charges'
1315       if $conf->exists('previous_balance-exclude_from_total');
1316     my $amount = $self->charged;
1317     if ( $self->enable_previous and !$conf->exists('previous_balance-exclude_from_total') ) {
1318       $amount += $pr_total;
1319     }
1320
1321     $total->{'total_item'} = &$embolden_function($self->mt($item));
1322     $total->{'total_amount'} =
1323       &$embolden_function( $other_money_char.  sprintf( '%.2f', $amount ) );
1324     if ( $multisection ) {
1325       if ( $adjust_section->{'sort_weight'} ) {
1326         $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1327           $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1328       } else {
1329         $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1330           $other_money_char.  sprintf('%.2f', $self->charged );
1331       }
1332     } else {
1333       push @total_items, $total;
1334     }
1335     push @buf,['','-----------'];
1336     push @buf,[$item,
1337                $money_char.
1338                sprintf( '%10.2f', $amount )
1339               ];
1340     push @buf,['',''];
1341
1342     # if we're showing previous invoices, also show previous
1343     # credits and payments
1344     if ( $self->enable_previous
1345           and $self->can('_items_credits')
1346           and $self->can('_items_payments') )
1347       {
1348       #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
1349
1350       # credits
1351       my $credittotal = 0;
1352       foreach my $credit (
1353         $self->_items_credits( 'template' => $template, 'trim_len' => 60 )
1354       ) {
1355
1356         my $total;
1357         $total->{'total_item'} = &$escape_function($credit->{'description'});
1358         $credittotal += $credit->{'amount'};
1359         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1360         $adjusttotal += $credit->{'amount'};
1361         if ( $multisection ) {
1362           push @detail_items, {
1363             ext_description => [],
1364             ref          => '',
1365             quantity     => '',
1366             description  => &$escape_function($credit->{'description'}),
1367             amount       => $money_char . $credit->{'amount'},
1368             product_code => '',
1369             section      => $adjust_section,
1370           };
1371         } else {
1372           push @total_items, $total;
1373         }
1374
1375       }
1376       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1377
1378       #credits (again)
1379       foreach my $credit (
1380         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1381       ) {
1382         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1383       }
1384
1385       # payments
1386       my $paymenttotal = 0;
1387       foreach my $payment (
1388         $self->_items_payments( 'template' => $template )
1389       ) {
1390         my $total = {};
1391         $total->{'total_item'} = &$escape_function($payment->{'description'});
1392         $paymenttotal += $payment->{'amount'};
1393         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1394         $adjusttotal += $payment->{'amount'};
1395         if ( $multisection ) {
1396           push @detail_items, {
1397             ext_description => [],
1398             ref          => '',
1399             quantity     => '',
1400             description  => &$escape_function($payment->{'description'}),
1401             amount       => $money_char . $payment->{'amount'},
1402             product_code => '',
1403             section      => $adjust_section,
1404           };
1405         }else{
1406           push @total_items, $total;
1407         }
1408         push @buf, [ $payment->{'description'},
1409                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1410                    ];
1411       }
1412       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1413
1414       if ( $multisection ) {
1415         $adjust_section->{'subtotal'} = $other_money_char.
1416                                         sprintf('%.2f', $adjusttotal);
1417         push @sections, $adjust_section
1418           unless $adjust_section->{sort_weight};
1419         # do not summarize; adjustments there are shown according to
1420         # different rules
1421       }
1422
1423       # create Balance Due message
1424       {
1425         my $total;
1426         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1427         $total->{'total_amount'} =
1428           &$embolden_function(
1429             $other_money_char. sprintf('%.2f', #why? $summarypage
1430                                                #  ? $self->charged +
1431                                                #    $self->billing_balance
1432                                                #  :
1433                                                    $self->owed + $pr_total
1434                                       )
1435           );
1436         if ( $multisection && !$adjust_section->{sort_weight} ) {
1437           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1438                                            $total->{'total_amount'};
1439         }else{
1440           push @total_items, $total;
1441         }
1442         push @buf,['','-----------'];
1443         push @buf,[$self->balance_due_msg, $money_char.
1444           sprintf("%10.2f", $balance_due ) ];
1445       }
1446
1447       if ( $conf->exists('previous_balance-show_credit')
1448           and $cust_main->balance < 0 ) {
1449         my $credit_total = {
1450           'total_item'    => &$embolden_function($self->credit_balance_msg),
1451           'total_amount'  => &$embolden_function(
1452             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1453           ),
1454         };
1455         if ( $multisection ) {
1456           $adjust_section->{'posttotal'} .= $newline_token .
1457             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1458         }
1459         else {
1460           push @total_items, $credit_total;
1461         }
1462         push @buf,['','-----------'];
1463         push @buf,[$self->credit_balance_msg, $money_char.
1464           sprintf("%10.2f", -$cust_main->balance ) ];
1465       }
1466     }
1467
1468   } #end of default total adding ! can('_items_total')
1469
1470   if ( $multisection ) {
1471     if (    $conf->exists('svc_phone_sections')
1472          && $self->can('_items_svc_phone_sections')
1473        )
1474     {
1475       my $total;
1476       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1477       $total->{'total_amount'} =
1478         &$embolden_function(
1479           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1480         );
1481       my $last_section = pop @sections;
1482       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1483                                      $total->{'total_amount'};
1484       push @sections, $last_section;
1485     }
1486     push @sections, @$late_sections
1487       if $unsquelched;
1488   }
1489
1490   # make a discounts-available section, even without multisection
1491   if ( $conf->exists('discount-show_available')
1492        and my @discounts_avail = $self->_items_discounts_avail ) {
1493     my $discount_section = {
1494       'description' => $self->mt('Discounts Available'),
1495       'subtotal'    => '',
1496       'no_subtotal' => 1,
1497     };
1498
1499     push @sections, $discount_section; # do not summarize
1500     push @detail_items, map { +{
1501         'ref'         => '', #should this be something else?
1502         'section'     => $discount_section,
1503         'description' => &$escape_function( $_->{description} ),
1504         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1505         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1506     } } @discounts_avail;
1507   }
1508
1509   # not adding any more sections after this
1510   $invoice_data{summary_subtotals} = \@summary_subtotals;
1511
1512   # usage subtotals
1513   if ( $conf->exists('usage_class_summary')
1514        and $self->can('_items_usage_class_summary') ) {
1515     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1516     if ( @usage_subtotals ) {
1517       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1518       unshift @detail_items, @usage_subtotals;
1519     }
1520   }
1521
1522   # invoice history "section" (not really a section)
1523   # not to be included in any subtotals, completely independent of
1524   # everything...
1525   if ( $conf->exists('previous_invoice_history') ) {
1526     my %history;
1527     my %monthorder;
1528     foreach my $cust_bill ( $cust_main->cust_bill ) {
1529       # XXX hardcoded format, and currently only 'charged'; add other fields
1530       # if they become necessary
1531       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1532       $history{$date} ||= 0;
1533       $history{$date} += $cust_bill->charged;
1534       # just so we have a numeric sort key
1535       $monthorder{$date} ||= $cust_bill->_date;
1536     }
1537     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1538                         keys %history;
1539     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1540     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1541   }
1542
1543   # service locations: another option for template customization
1544   my %location_info;
1545   foreach my $item (@detail_items) {
1546     if ( $item->{locationnum} ) {
1547       $location_info{ $item->{locationnum} } ||= {
1548         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1549       };
1550     }
1551   }
1552   $invoice_data{location_info} = \%location_info;
1553
1554   # debugging hook: call this with 'diag' => 1 to just get a hash of
1555   # the invoice variables
1556   return \%invoice_data if ( $params{'diag'} );
1557
1558   # All sections and items are built; now fill in templates.
1559   my @includelist = ();
1560   push @includelist, 'summary' if $summarypage;
1561   foreach my $include ( @includelist ) {
1562
1563     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1564     my @inc_src;
1565
1566     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1567
1568       @inc_src = $conf->config($inc_file, $agentnum);
1569
1570     } else {
1571
1572       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1573
1574       my $convert_map = $convert_maps{$format}{$include};
1575
1576       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1577                        s/--\@\]/$delimiters{$format}[1]/g;
1578                        $_;
1579                      }
1580                  &$convert_map( $conf->config($inc_file, $agentnum) );
1581
1582     }
1583
1584     my $inc_tt = new Text::Template (
1585       TYPE       => 'ARRAY',
1586       SOURCE     => [ map "$_\n", @inc_src ],
1587       DELIMITERS => $delimiters{$format},
1588     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1589
1590     unless ( $inc_tt->compile() ) {
1591       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1592       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1593       die $error;
1594     }
1595
1596     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1597
1598     $invoice_data{$include} =~ s/\n+$//
1599       if ($format eq 'latex');
1600   }
1601
1602   $invoice_lines = 0;
1603   my $wasfunc = 0;
1604   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1605     /invoice_lines\((\d*)\)/;
1606     $invoice_lines += $1 || scalar(@buf);
1607     $wasfunc=1;
1608   }
1609   die "no invoice_lines() functions in template?"
1610     if ( $format eq 'template' && !$wasfunc );
1611
1612   if ($format eq 'template') {
1613
1614     if ( $invoice_lines ) {
1615       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1616       $invoice_data{'total_pages'}++
1617         if scalar(@buf) % $invoice_lines;
1618     }
1619
1620     #setup subroutine for the template
1621     $invoice_data{invoice_lines} = sub {
1622       my $lines = shift || scalar(@buf);
1623       map {
1624         scalar(@buf)
1625           ? shift @buf
1626           : [ '', '' ];
1627       }
1628       ( 1 .. $lines );
1629     };
1630
1631     my $lines;
1632     my @collect;
1633     while (@buf) {
1634       push @collect, split("\n",
1635         $text_template->fill_in( HASH => \%invoice_data )
1636       );
1637       $invoice_data{'page'}++;
1638     }
1639     map "$_\n", @collect;
1640
1641   } else { # this is where we actually create the invoice
1642
1643     warn "filling in template for invoice ". $self->invnum. "\n"
1644       if $DEBUG;
1645     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1646       if $DEBUG > 1;
1647
1648     $text_template->fill_in(HASH => \%invoice_data);
1649   }
1650 }
1651
1652 sub notice_name { '('.shift->table.')'; }
1653
1654 sub template_conf { 'invoice_'; }
1655
1656 # helper routine for generating date ranges
1657 sub _prior_month30s {
1658   my $self = shift;
1659   my @ranges = (
1660    [ 1,       2592000 ], # 0-30 days ago
1661    [ 2592000, 5184000 ], # 30-60 days ago
1662    [ 5184000, 7776000 ], # 60-90 days ago
1663    [ 7776000, 0       ], # 90+   days ago
1664   );
1665
1666   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1667           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1668       ] }
1669   @ranges;
1670 }
1671
1672 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1673
1674 Returns an postscript invoice, as a scalar.
1675
1676 Options can be passed as a hashref (recommended) or as a list of time, template
1677 and then any key/value pairs for any other options.
1678
1679 I<time> an optional value used to control the printing of overdue messages.  The
1680 default is now.  It isn't the date of the invoice; that's the `_date' field.
1681 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1682 L<Time::Local> and L<Date::Parse> for conversion functions.
1683
1684 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1685
1686 =cut
1687
1688 sub print_ps {
1689   my $self = shift;
1690
1691   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1692   my $ps = generate_ps($file);
1693   unlink($logofile);
1694   unlink($barcodefile) if $barcodefile;
1695
1696   $ps;
1697 }
1698
1699 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1700
1701 Returns an PDF invoice, as a scalar.
1702
1703 Options can be passed as a hashref (recommended) or as a list of time, template
1704 and then any key/value pairs for any other options.
1705
1706 I<time> an optional value used to control the printing of overdue messages.  The
1707 default is now.  It isn't the date of the invoice; that's the `_date' field.
1708 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1709 L<Time::Local> and L<Date::Parse> for conversion functions.
1710
1711 I<template>, if specified, is the name of a suffix for alternate invoices.
1712
1713 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1714
1715 =cut
1716
1717 sub print_pdf {
1718   my $self = shift;
1719
1720   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1721   my $pdf = generate_pdf($file);
1722   unlink($logofile);
1723   unlink($barcodefile) if $barcodefile;
1724
1725   $pdf;
1726 }
1727
1728 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1729
1730 Returns an HTML invoice, as a scalar.
1731
1732 I<time> an optional value used to control the printing of overdue messages.  The
1733 default is now.  It isn't the date of the invoice; that's the `_date' field.
1734 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1735 L<Time::Local> and L<Date::Parse> for conversion functions.
1736
1737 I<template>, if specified, is the name of a suffix for alternate invoices.
1738
1739 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1740
1741 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1742 when emailing the invoice as part of a multipart/related MIME email.
1743
1744 =cut
1745
1746 sub print_html {
1747   my $self = shift;
1748   my %params;
1749   if ( ref($_[0]) ) {
1750     %params = %{ shift() };
1751   } else {
1752     %params = @_;
1753   }
1754   $params{'format'} = 'html';
1755
1756   $self->print_generic( %params );
1757 }
1758
1759 # quick subroutine for print_latex
1760 #
1761 # There are ten characters that LaTeX treats as special characters, which
1762 # means that they do not simply typeset themselves:
1763 #      # $ % & ~ _ ^ \ { }
1764 #
1765 # TeX ignores blanks following an escaped character; if you want a blank (as
1766 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1767
1768 sub _latex_escape {
1769   my $value = shift;
1770   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1771   $value =~ s/([<>])/\$$1\$/g;
1772   $value;
1773 }
1774
1775 sub _html_escape {
1776   my $value = shift;
1777   encode_entities($value);
1778   $value;
1779 }
1780
1781 sub _html_escape_nbsp {
1782   my $value = _html_escape(shift);
1783   $value =~ s/ +/&nbsp;/g;
1784   $value;
1785 }
1786
1787 #utility methods for print_*
1788
1789 sub _translate_old_latex_format {
1790   warn "_translate_old_latex_format called\n"
1791     if $DEBUG;
1792
1793   my @template = ();
1794   while ( @_ ) {
1795     my $line = shift;
1796
1797     if ( $line =~ /^%%Detail\s*$/ ) {
1798
1799       push @template, q![@--!,
1800                       q!  foreach my $_tr_line (@detail_items) {!,
1801                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1802                       q!      $_tr_line->{'description'} .= !,
1803                       q!        "\\tabularnewline\n~~".!,
1804                       q!        join( "\\tabularnewline\n~~",!,
1805                       q!          @{$_tr_line->{'ext_description'}}!,
1806                       q!        );!,
1807                       q!    }!;
1808
1809       while ( ( my $line_item_line = shift )
1810               !~ /^%%EndDetail\s*$/                            ) {
1811         $line_item_line =~ s/'/\\'/g;    # nice LTS
1812         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1813         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1814         push @template, "    \$OUT .= '$line_item_line';";
1815       }
1816
1817       push @template, '}',
1818                       '--@]';
1819       #' doh, gvim
1820     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1821
1822       push @template, '[@--',
1823                       '  foreach my $_tr_line (@total_items) {';
1824
1825       while ( ( my $total_item_line = shift )
1826               !~ /^%%EndTotalDetails\s*$/                      ) {
1827         $total_item_line =~ s/'/\\'/g;    # nice LTS
1828         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1829         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1830         push @template, "    \$OUT .= '$total_item_line';";
1831       }
1832
1833       push @template, '}',
1834                       '--@]';
1835
1836     } else {
1837       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1838       push @template, $line;
1839     }
1840
1841   }
1842
1843   if ($DEBUG) {
1844     warn "$_\n" foreach @template;
1845   }
1846
1847   (@template);
1848 }
1849
1850 =item terms
1851
1852 =cut
1853
1854 sub terms {
1855   my $self = shift;
1856   my $conf = $self->conf;
1857
1858   #check for an invoice-specific override
1859   return $self->invoice_terms if $self->invoice_terms;
1860
1861   #check for a customer- specific override
1862   my $cust_main = $self->cust_main;
1863   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1864
1865   my $agentnum = '';
1866   if ( $cust_main ) {
1867     $agentnum = $cust_main->agentnum;
1868   } elsif ( my $prospect_main = $self->prospect_main ) {
1869     $agentnum = $prospect_main->agentnum;
1870   }
1871
1872   #use configured default
1873   $conf->config('invoice_default_terms', $agentnum) || '';
1874 }
1875
1876 =item due_date
1877
1878 =cut
1879
1880 sub due_date {
1881   my $self = shift;
1882   my $duedate = '';
1883   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1884     $duedate = $self->_date() + ( $1 * 86400 );
1885   }
1886   $duedate;
1887 }
1888
1889 =item due_date2str
1890
1891 =cut
1892
1893 sub due_date2str {
1894   my $self = shift;
1895   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1896 }
1897
1898 =item balance_due_msg
1899
1900 =cut
1901
1902 sub balance_due_msg {
1903   my $self = shift;
1904   my $msg = $self->mt('Balance Due');
1905   return $msg unless $self->terms;
1906   if ( $self->due_date ) {
1907     $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1908       $self->due_date2str('short');
1909   } elsif ( $self->terms ) {
1910     $msg .= ' - '. $self->terms;
1911   }
1912   $msg;
1913 }
1914
1915 =item balance_due_date
1916
1917 =cut
1918
1919 sub balance_due_date {
1920   my $self = shift;
1921   my $conf = $self->conf;
1922   my $duedate = '';
1923   my $terms = $self->terms;
1924   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1925     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1926   }
1927   $duedate;
1928 }
1929
1930 sub credit_balance_msg {
1931   my $self = shift;
1932   $self->mt('Credit Balance Remaining')
1933 }
1934
1935 =item _date_pretty
1936
1937 Returns a string with the date, for example: "3/20/2008", localized for the
1938 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1939
1940 =cut
1941
1942 sub _date_pretty {
1943   my $self = shift;
1944   $self->time2str_local('short', $self->_date);
1945 }
1946
1947 =item _date_pretty_unlocalized
1948
1949 Returns a string with the date, for example: "3/20/2008", in the format
1950 configured for the back-office.  Use _date_pretty for end-customer display use.
1951
1952 =cut
1953
1954 sub _date_pretty_unlocalized {
1955   my $self = shift;
1956   time2str($date_format, $self->_date);
1957 }
1958
1959 =item email HASHREF
1960
1961 Emails this template.
1962
1963 Options are passed as a hashref.  Available options:
1964
1965 =over 4
1966
1967 =item from
1968
1969 If specified, overrides the default From: address.
1970
1971 =item notice_name
1972
1973 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1974
1975 =item template
1976
1977 (Deprecated) If specified, is the name of a suffix for alternate template files.
1978
1979 =back
1980
1981 Options accepted by generate_email can also be used.
1982
1983 =cut
1984
1985 sub email {
1986   my $self = shift;
1987   my $opt = shift || {};
1988   if ($opt and !ref($opt)) {
1989     die ref($self). '->email called with positional parameters';
1990   }
1991
1992   return if $self->hide;
1993
1994   my $error = send_email(
1995     $self->generate_email(
1996       'subject'     => $self->email_subject($opt->{template}),
1997       %$opt, # template, etc.
1998     )
1999   );
2000
2001   die "can't email: $error\n" if $error;
2002 }
2003
2004 =item generate_email OPTION => VALUE ...
2005
2006 Options:
2007
2008 =over 4
2009
2010 =item from
2011
2012 sender address, required
2013
2014 =item template
2015
2016 alternate template name, optional
2017
2018 =item print_text
2019
2020 text attachment arrayref, optional
2021
2022 =item subject
2023
2024 email subject, optional
2025
2026 =item notice_name
2027
2028 notice name instead of "Invoice", optional
2029
2030 =back
2031
2032 Returns an argument list to be passed to L<FS::Misc::send_email>.
2033
2034 =cut
2035
2036 use MIME::Entity;
2037
2038 sub generate_email {
2039
2040   my $self = shift;
2041   my %args = @_;
2042   my $conf = $self->conf;
2043
2044   my $me = '[FS::Template_Mixin::generate_email]';
2045
2046   my %return = (
2047     'from'      => $args{'from'},
2048     'subject'   => ($args{'subject'} || $self->email_subject),
2049     'custnum'   => $self->custnum,
2050     'msgtype'   => 'invoice',
2051   );
2052
2053   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2054
2055   my $cust_main = $self->cust_main;
2056
2057   if (ref($args{'to'}) eq 'ARRAY') {
2058     $return{'to'} = $args{'to'};
2059   } elsif ( $cust_main ) {
2060     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2061   }
2062
2063   my $tc = $self->template_conf;
2064
2065   if ( $conf->exists($tc.'html') ) {
2066
2067     warn "$me creating HTML/text multipart message"
2068       if $DEBUG;
2069
2070     $return{'nobody'} = 1;
2071
2072     my $alternative = build MIME::Entity
2073       'Type'        => 'multipart/alternative',
2074       #'Encoding'    => '7bit',
2075       'Disposition' => 'inline'
2076     ;
2077
2078     my $data = '';
2079     if ( $conf->exists($tc. 'email_pdf')
2080          and scalar($conf->config($tc. 'email_pdf_note')) ) {
2081
2082       warn "$me using '${tc}email_pdf_note' in multipart message"
2083         if $DEBUG;
2084       $data = [ map { $_ . "\n" }
2085                     $conf->config($tc.'email_pdf_note')
2086               ];
2087
2088     } else {
2089
2090       warn "$me not using '${tc}email_pdf_note' in multipart message"
2091         if $DEBUG;
2092       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
2093         $data = $args{'print_text'};
2094       } elsif ( $conf->exists($tc.'template') ) { #plaintext invoice_template
2095         $data = [ $self->print_text(\%args) ];
2096       }
2097
2098     }
2099
2100     if ( $data ) {
2101       $alternative->attach(
2102         'Type'        => 'text/plain',
2103         'Encoding'    => 'quoted-printable',
2104         'Charset'     => 'UTF-8',
2105         #'Encoding'    => '7bit',
2106         'Data'        => $data,
2107         'Disposition' => 'inline',
2108       );
2109     }
2110
2111     my $htmldata;
2112     my $image = '';
2113     my $barcode = '';
2114     if ( $conf->exists($tc.'email_pdf')
2115          and scalar($conf->config($tc.'email_pdf_note')) ) {
2116
2117       $htmldata = join('<BR>', $conf->config($tc.'email_pdf_note') );
2118
2119     } else {
2120
2121       $args{'from'} =~ /\@([\w\.\-]+)/;
2122       my $from = $1 || 'example.com';
2123       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2124
2125       my $logo;
2126       my $agentnum = $cust_main ? $cust_main->agentnum
2127                                 : $self->prospect_main->agentnum;
2128       if ( defined($args{'template'}) && length($args{'template'})
2129            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2130          )
2131       {
2132         $logo = 'logo_'. $args{'template'}. '.png';
2133       } else {
2134         $logo = "logo.png";
2135       }
2136       my $image_data = $conf->config_binary( $logo, $agentnum);
2137
2138       $image = build MIME::Entity
2139         'Type'       => 'image/png',
2140         'Encoding'   => 'base64',
2141         'Data'       => $image_data,
2142         'Filename'   => 'logo.png',
2143         'Content-ID' => "<$content_id>",
2144       ;
2145
2146       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2147         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2148         $barcode = build MIME::Entity
2149           'Type'       => 'image/png',
2150           'Encoding'   => 'base64',
2151           'Data'       => $self->invoice_barcode(0),
2152           'Filename'   => 'barcode.png',
2153           'Content-ID' => "<$barcode_content_id>",
2154         ;
2155         $args{'barcode_cid'} = $barcode_content_id;
2156       }
2157
2158       $htmldata = $self->print_html({ 'cid'=>$content_id, %args });
2159     }
2160
2161     $alternative->attach(
2162       'Type'        => 'text/html',
2163       'Encoding'    => 'quoted-printable',
2164       'Data'        => [ '<html>',
2165                          '  <head>',
2166                          '    <title>',
2167                          '      '. encode_entities($return{'subject'}),
2168                          '    </title>',
2169                          '  </head>',
2170                          '  <body bgcolor="#e8e8e8">',
2171                          $htmldata,
2172                          '  </body>',
2173                          '</html>',
2174                        ],
2175       'Disposition' => 'inline',
2176       #'Filename'    => 'invoice.pdf',
2177     );
2178
2179
2180     my @otherparts = ();
2181     if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2182
2183       push @otherparts, build MIME::Entity
2184         'Type'        => 'text/csv',
2185         'Encoding'    => '7bit',
2186         'Data'        => [ map { "$_\n" }
2187                              $self->call_details('prepend_billed_number' => 1)
2188                          ],
2189         'Disposition' => 'attachment',
2190         'Filename'    => 'usage-'. $self->invnum. '.csv',
2191       ;
2192
2193     }
2194
2195     if ( $conf->exists($tc.'email_pdf') ) {
2196
2197       #attaching pdf too:
2198       # multipart/mixed
2199       #   multipart/related
2200       #     multipart/alternative
2201       #       text/plain
2202       #       text/html
2203       #     image/png
2204       #   application/pdf
2205
2206       my $related = build MIME::Entity 'Type'     => 'multipart/related',
2207                                        'Encoding' => '7bit';
2208
2209       #false laziness w/Misc::send_email
2210       $related->head->replace('Content-type',
2211         $related->mime_type.
2212         '; boundary="'. $related->head->multipart_boundary. '"'.
2213         '; type=multipart/alternative'
2214       );
2215
2216       $related->add_part($alternative);
2217
2218       $related->add_part($image) if $image;
2219
2220       my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2221
2222       $return{'mimeparts'} = [ $related, $pdf, @otherparts ];
2223
2224     } else {
2225
2226       #no other attachment:
2227       # multipart/related
2228       #   multipart/alternative
2229       #     text/plain
2230       #     text/html
2231       #   image/png
2232
2233       $return{'content-type'} = 'multipart/related';
2234       if ($conf->exists('invoice-barcode') && $barcode) {
2235         $return{'mimeparts'} = [ $alternative, $image, $barcode, @otherparts ];
2236       } else {
2237         $return{'mimeparts'} = [ $alternative, $image, @otherparts ];
2238       }
2239       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
2240       #$return{'disposition'} = 'inline';
2241
2242     }
2243
2244   } else {
2245
2246     if ( $conf->exists($tc.'email_pdf') ) {
2247       warn "$me creating PDF attachment"
2248         if $DEBUG;
2249
2250       #mime parts arguments a la MIME::Entity->build().
2251       $return{'mimeparts'} = [
2252         { $self->mimebuild_pdf(\%args) }
2253       ];
2254     }
2255
2256     if ( $conf->exists($tc.'email_pdf')
2257          and scalar($conf->config($tc.'email_pdf_note')) ) {
2258
2259       warn "$me using '${tc}email_pdf_note'"
2260         if $DEBUG;
2261       $return{'body'} = [ map { $_ . "\n" }
2262                               $conf->config($tc.'email_pdf_note')
2263                         ];
2264
2265     } else {
2266
2267       warn "$me not using '${tc}email_pdf_note'"
2268         if $DEBUG;
2269       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
2270         $return{'body'} = $args{'print_text'};
2271       } else {
2272         $return{'body'} = [ $self->print_text(\%args) ];
2273       }
2274
2275     }
2276
2277   }
2278
2279   %return;
2280
2281 }
2282
2283 =item mimebuild_pdf
2284
2285 Returns a list suitable for passing to MIME::Entity->build(), representing
2286 this invoice as PDF attachment.
2287
2288 =cut
2289
2290 sub mimebuild_pdf {
2291   my $self = shift;
2292   (
2293     'Type'        => 'application/pdf',
2294     'Encoding'    => 'base64',
2295     'Data'        => [ $self->print_pdf(@_) ],
2296     'Disposition' => 'attachment',
2297     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2298   );
2299 }
2300
2301 =item _items_sections OPTIONS
2302
2303 Generate section information for all items appearing on this invoice.
2304 This will only be called for multi-section invoices.
2305
2306 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2307 related display records (L<FS::cust_bill_pkg_display>) and organize
2308 them into two groups ("early" and "late" according to whether they come
2309 before or after the total), then into sections.  A subtotal is calculated
2310 for each section.
2311
2312 Section descriptions are returned in sort weight order.  Each consists
2313 of a hash containing:
2314
2315 description: the package category name, escaped
2316 subtotal: the total charges in that section
2317 tax_section: a flag indicating that the section contains only tax charges
2318 summarized: same as tax_section, for some reason
2319 sort_weight: the package category's sort weight
2320
2321 If 'condense' is set on the display record, it also contains everything
2322 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2323 coderefs to generate parts of the invoice.  This is not advised.
2324
2325 The method returns two arrayrefs, one of "early" sections and one of "late"
2326 sections.
2327
2328 OPTIONS may include:
2329
2330 by_location: a flag to divide the invoice into sections by location.
2331 Each section hash will have a 'location' element containing a hashref of
2332 the location fields (see L<FS::cust_location>).  The section description
2333 will be the location label, but the template can use any of the location
2334 fields to create a suitable label.
2335
2336 by_category: a flag to divide the invoice into sections using display
2337 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2338 behavior.  Each section hash will have a 'category' element containing
2339 the section name from the display record (which probably equals the
2340 category name of the package, but may not in some cases).
2341
2342 summary: a flag indicating that this is a summary-format invoice.
2343 Turning this on has the following effects:
2344 - Ignores display items with the 'summary' flag.
2345 - Places all sections in the "early" group even if they have post_total.
2346 - Creates sections for all non-disabled package categories, even if they
2347 have no charges on this invoice, as well as a section with no name.
2348
2349 escape: an escape function to use for section titles.
2350
2351 extra_sections: an arrayref of additional sections to return after the
2352 sorted list.  If there are any of these, section subtotals exclude
2353 usage charges.
2354
2355 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2356 passed through to C<_condense_section()>.
2357
2358 =cut
2359
2360 use vars qw(%pkg_category_cache);
2361 sub _items_sections {
2362   my $self = shift;
2363   my %opt = @_;
2364
2365   my $escape = $opt{escape};
2366   my @extra_sections = @{ $opt{extra_sections} || [] };
2367
2368   # $subtotal{$locationnum}{$categoryname} = amount.
2369   # if we're not using by_location, $locationnum is undef.
2370   # if we're not using by_category, you guessed it, $categoryname is undef.
2371   # if we're not using either one, we shouldn't be here in the first place...
2372   my %subtotal = ();
2373   my %late_subtotal = ();
2374   my %not_tax = ();
2375
2376   # About tax items + multisection invoices:
2377   # If either invoice_*summary option is enabled, AND there is a
2378   # package category with the name of the tax, then there will be
2379   # a display record assigning the tax item to that category.
2380   #
2381   # However, the taxes are always placed in the "Taxes, Surcharges,
2382   # and Fees" section regardless of that.  The only effect of the
2383   # display record is to create a subtotal for the summary page.
2384
2385   # cache these
2386   my $pkg_hash = $self->cust_pkg_hash;
2387
2388   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2389   {
2390
2391       my $usage = $cust_bill_pkg->usage;
2392
2393       my $locationnum;
2394       if ( $opt{by_location} ) {
2395         if ( $cust_bill_pkg->pkgnum ) {
2396           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2397         } else {
2398           $locationnum = '';
2399         }
2400       } else {
2401         $locationnum = undef;
2402       }
2403
2404       # as in _items_cust_pkg, if a line item has no display records,
2405       # cust_bill_pkg_display() returns a default record for it
2406
2407       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2408         next if ( $display->summary && $opt{summary} );
2409
2410         my $section = $display->section;
2411         my $type    = $display->type;
2412         # Set $section = undef if we're sectioning by location and this
2413         # line item _has_ a location (i.e. isn't a fee).
2414         $section = undef if $locationnum;
2415
2416         # set this flag if the section is not tax-only
2417         $not_tax{$locationnum}{$section} = 1
2418           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2419
2420         # there's actually a very important piece of logic buried in here:
2421         # incrementing $late_subtotal{$section} CREATES
2422         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2423         # to define the list of late sections, and likewise keys(%subtotal).
2424         # When _items_cust_bill_pkg is called to generate line items for
2425         # real, it will be called with 'section' => $section for each
2426         # of these.
2427         if ( $display->post_total && !$opt{summary} ) {
2428           if (! $type || $type eq 'S') {
2429             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2430               if $cust_bill_pkg->setup != 0
2431               || $cust_bill_pkg->setup_show_zero;
2432           }
2433
2434           if (! $type) {
2435             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2436               if $cust_bill_pkg->recur != 0
2437               || $cust_bill_pkg->recur_show_zero;
2438           }
2439
2440           if ($type && $type eq 'R') {
2441             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2442               if $cust_bill_pkg->recur != 0
2443               || $cust_bill_pkg->recur_show_zero;
2444           }
2445
2446           if ($type && $type eq 'U') {
2447             $late_subtotal{$locationnum}{$section} += $usage
2448               unless scalar(@extra_sections);
2449           }
2450
2451         } else { # it's a pre-total (normal) section
2452
2453           # skip tax items unless they're explicitly included in a section
2454           next if $cust_bill_pkg->pkgnum == 0 and
2455                   ! $cust_bill_pkg->feepart   and
2456                   ! $section;
2457
2458           if ( $type eq 'S' ) {
2459             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2460               if $cust_bill_pkg->setup != 0
2461               || $cust_bill_pkg->setup_show_zero;
2462           } elsif ( $type eq 'R' ) {
2463             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2464               if $cust_bill_pkg->recur != 0
2465               || $cust_bill_pkg->recur_show_zero;
2466           } elsif ( $type eq 'U' ) {
2467             $subtotal{$locationnum}{$section} += $usage
2468               unless scalar(@extra_sections);
2469           } elsif ( !$type ) {
2470             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2471                                                + $cust_bill_pkg->recur;
2472           }
2473
2474         }
2475
2476       }
2477
2478   }
2479
2480   %pkg_category_cache = ();
2481
2482   # summary invoices need subtotals for all non-disabled package categories,
2483   # even if they're zero
2484   # but currently assume that there are no location sections, or at least
2485   # that the summary page doesn't care about them
2486   if ( $opt{summary} ) {
2487     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2488       $subtotal{''}{$category->categoryname} ||= 0;
2489     }
2490     $subtotal{''}{''} ||= 0;
2491   }
2492
2493   my @sections;
2494   foreach my $post_total (0,1) {
2495     my @these;
2496     my $s = $post_total ? \%late_subtotal : \%subtotal;
2497     foreach my $locationnum (keys %$s) {
2498       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2499         my $section = {
2500                         'subtotal'    => $s->{$locationnum}{$sectionname},
2501                         'post_total'  => $post_total,
2502                         'sort_weight' => 0,
2503                       };
2504         if ( $locationnum ) {
2505           $section->{'locationnum'} = $locationnum;
2506           my $location = FS::cust_location->by_key($locationnum);
2507           $section->{'description'} = &{ $escape }($location->location_label);
2508           # Better ideas? This will roughly group them by proximity,
2509           # which alpha sorting on any of the address fields won't.
2510           # Sorting by locationnum is meaningless.
2511           # We have to sort on _something_ or the order may change
2512           # randomly from one invoice to the next, which will confuse
2513           # people.
2514           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2515                                       $locationnum;
2516           $section->{'location'} = {
2517             label_prefix => &{ $escape }($location->label_prefix),
2518             map { $_ => &{ $escape }($location->get($_)) }
2519               $location->fields
2520           };
2521         } else {
2522           $section->{'category'} = $sectionname;
2523           $section->{'description'} = &{ $escape }($sectionname);
2524           if ( _pkg_category($sectionname) ) {
2525             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2526             if ( _pkg_category($sectionname)->condense ) {
2527               $section = { %$section, $self->_condense_section($opt{format}) };
2528             }
2529           }
2530         }
2531         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2532           # then it's a tax-only section
2533           $section->{'summarized'} = 'Y';
2534           $section->{'tax_section'} = 'Y';
2535         }
2536         push @these, $section;
2537       } # foreach $sectionname
2538     } #foreach $locationnum
2539     push @these, @extra_sections if $post_total == 0;
2540     # need an alpha sort for location sections, because postal codes can
2541     # be non-numeric
2542     $sections[ $post_total ] = [ sort {
2543       $opt{'by_location'} ?
2544         ($a->{sort_weight} cmp $b->{sort_weight}) :
2545         ($a->{sort_weight} <=> $b->{sort_weight})
2546       } @these ];
2547   } #foreach $post_total
2548
2549   return @sections; # early, late
2550 }
2551
2552 #helper subs for above
2553
2554 sub cust_pkg_hash {
2555   my $self = shift;
2556   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2557 }
2558
2559 sub _pkg_category {
2560   my $categoryname = shift;
2561   $pkg_category_cache{$categoryname} ||=
2562     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2563 }
2564
2565 my %condensed_format = (
2566   'label' => [ qw( Description Qty Amount ) ],
2567   'fields' => [
2568                 sub { shift->{description} },
2569                 sub { shift->{quantity} },
2570                 sub { my($href, %opt) = @_;
2571                       ($opt{dollar} || ''). $href->{amount};
2572                     },
2573               ],
2574   'align'  => [ qw( l r r ) ],
2575   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2576   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2577 );
2578
2579 sub _condense_section {
2580   my ( $self, $format ) = ( shift, shift );
2581   ( 'condensed' => 1,
2582     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2583       qw( description_generator
2584           header_generator
2585           total_generator
2586           total_line_generator
2587         )
2588   );
2589 }
2590
2591 sub _condensed_generator_defaults {
2592   my ( $self, $format ) = ( shift, shift );
2593   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2594 }
2595
2596 my %html_align = (
2597   'c' => 'center',
2598   'l' => 'left',
2599   'r' => 'right',
2600 );
2601
2602 sub _condensed_header_generator {
2603   my ( $self, $format ) = ( shift, shift );
2604
2605   my ( $f, $prefix, $suffix, $separator, $column ) =
2606     _condensed_generator_defaults($format);
2607
2608   if ($format eq 'latex') {
2609     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2610     $suffix = "\\\\\n\\hline";
2611     $separator = "&\n";
2612     $column =
2613       sub { my ($d,$a,$s,$w) = @_;
2614             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2615           };
2616   } elsif ( $format eq 'html' ) {
2617     $prefix = '<th></th>';
2618     $suffix = '';
2619     $separator = '';
2620     $column =
2621       sub { my ($d,$a,$s,$w) = @_;
2622             return qq!<th align="$html_align{$a}">$d</th>!;
2623       };
2624   }
2625
2626   sub {
2627     my @args = @_;
2628     my @result = ();
2629
2630     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2631       push @result,
2632         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2633     }
2634
2635     $prefix. join($separator, @result). $suffix;
2636   };
2637
2638 }
2639
2640 sub _condensed_description_generator {
2641   my ( $self, $format ) = ( shift, shift );
2642
2643   my ( $f, $prefix, $suffix, $separator, $column ) =
2644     _condensed_generator_defaults($format);
2645
2646   my $money_char = '$';
2647   if ($format eq 'latex') {
2648     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2649     $suffix = '\\\\';
2650     $separator = " & \n";
2651     $column =
2652       sub { my ($d,$a,$s,$w) = @_;
2653             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2654           };
2655     $money_char = '\\dollar';
2656   }elsif ( $format eq 'html' ) {
2657     $prefix = '"><td align="center"></td>';
2658     $suffix = '';
2659     $separator = '';
2660     $column =
2661       sub { my ($d,$a,$s,$w) = @_;
2662             return qq!<td align="$html_align{$a}">$d</td>!;
2663       };
2664     #$money_char = $conf->config('money_char') || '$';
2665     $money_char = '';  # this is madness
2666   }
2667
2668   sub {
2669     #my @args = @_;
2670     my $href = shift;
2671     my @result = ();
2672
2673     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2674       my $dollar = '';
2675       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2676       push @result,
2677         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2678                     map { $f->{$_}->[$i] } qw(align span width)
2679                   );
2680     }
2681
2682     $prefix. join( $separator, @result ). $suffix;
2683   };
2684
2685 }
2686
2687 sub _condensed_total_generator {
2688   my ( $self, $format ) = ( shift, shift );
2689
2690   my ( $f, $prefix, $suffix, $separator, $column ) =
2691     _condensed_generator_defaults($format);
2692   my $style = '';
2693
2694   if ($format eq 'latex') {
2695     $prefix = "& ";
2696     $suffix = "\\\\\n";
2697     $separator = " & \n";
2698     $column =
2699       sub { my ($d,$a,$s,$w) = @_;
2700             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2701           };
2702   }elsif ( $format eq 'html' ) {
2703     $prefix = '';
2704     $suffix = '';
2705     $separator = '';
2706     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2707     $column =
2708       sub { my ($d,$a,$s,$w) = @_;
2709             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2710       };
2711   }
2712
2713
2714   sub {
2715     my @args = @_;
2716     my @result = ();
2717
2718     #  my $r = &{$f->{fields}->[$i]}(@args);
2719     #  $r .= ' Total' unless $i;
2720
2721     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2722       push @result,
2723         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2724                     map { $f->{$_}->[$i] } qw(align span width)
2725                   );
2726     }
2727
2728     $prefix. join( $separator, @result ). $suffix;
2729   };
2730
2731 }
2732
2733 =item total_line_generator FORMAT
2734
2735 Returns a coderef used for generation of invoice total line items for this
2736 usage_class.  FORMAT is either html or latex
2737
2738 =cut
2739
2740 # should not be used: will have issues with hash element names (description vs
2741 # total_item and amount vs total_amount -- another array of functions?
2742
2743 sub _condensed_total_line_generator {
2744   my ( $self, $format ) = ( shift, shift );
2745
2746   my ( $f, $prefix, $suffix, $separator, $column ) =
2747     _condensed_generator_defaults($format);
2748   my $style = '';
2749
2750   if ($format eq 'latex') {
2751     $prefix = "& ";
2752     $suffix = "\\\\\n";
2753     $separator = " & \n";
2754     $column =
2755       sub { my ($d,$a,$s,$w) = @_;
2756             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2757           };
2758   }elsif ( $format eq 'html' ) {
2759     $prefix = '';
2760     $suffix = '';
2761     $separator = '';
2762     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2763     $column =
2764       sub { my ($d,$a,$s,$w) = @_;
2765             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2766       };
2767   }
2768
2769
2770   sub {
2771     my @args = @_;
2772     my @result = ();
2773
2774     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2775       push @result,
2776         &{$column}( &{$f->{fields}->[$i]}(@args),
2777                     map { $f->{$_}->[$i] } qw(align span width)
2778                   );
2779     }
2780
2781     $prefix. join( $separator, @result ). $suffix;
2782   };
2783
2784 }
2785
2786 =item _items_pkg [ OPTIONS ]
2787
2788 Return line item hashes for each package item on this invoice. Nearly
2789 equivalent to
2790
2791 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2792
2793 The only OPTIONS accepted is 'section', which may point to a hashref
2794 with a key named 'condensed', which may have a true value.  If it
2795 does, this method tries to merge identical items into items with
2796 'quantity' equal to the number of items (not the sum of their
2797 separate quantities, for some reason).
2798
2799 =cut
2800
2801 sub _items_nontax {
2802   my $self = shift;
2803   # The order of these is important.  Bundled line items will be merged into
2804   # the most recent non-hidden item, so it needs to be the one with:
2805   # - the same pkgnum
2806   # - the same start date
2807   # - no pkgpart_override
2808   #
2809   # So: sort by pkgnum,
2810   # then by sdate
2811   # then sort the base line item before any overrides
2812   # then sort hidden before non-hidden add-ons
2813   # then sort by override pkgpart (for consistency)
2814   sort { $a->pkgnum <=> $b->pkgnum        or
2815          $a->sdate  <=> $b->sdate         or
2816          ($a->pkgpart_override ? 0 : -1)  or
2817          ($b->pkgpart_override ? 0 : 1)   or
2818          $b->hidden cmp $a->hidden        or
2819          $a->pkgpart_override <=> $b->pkgpart_override
2820        }
2821   # and of course exclude taxes and fees
2822   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2823 }
2824
2825 sub _items_fee {
2826   my $self = shift;
2827   my %options = @_;
2828   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2829   my @items;
2830   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2831     # cache this, so we don't look it up again in every section
2832     my $part_fee = $cust_bill_pkg->get('part_fee')
2833        || $cust_bill_pkg->part_fee;
2834     $cust_bill_pkg->set('part_fee', $part_fee);
2835     if (!$part_fee) {
2836       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2837       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2838       next;
2839     }
2840     if ( exists($options{section}) and exists($options{section}{category}) )
2841     {
2842       my $categoryname = $options{section}{category};
2843       # then filter for items that have that section
2844       if ( $part_fee->categoryname ne $categoryname ) {
2845         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2846         next;
2847       }
2848     } # otherwise include them all in the main section
2849     # XXX what to do when sectioning by location?
2850
2851     my @ext_desc;
2852     my %base_invnums; # invnum => invoice date
2853     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2854       if ($_->base_invnum) {
2855         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2856         my $base_date = $self->time2str_local('short', $base_bill->_date)
2857           if $base_bill;
2858         $base_invnums{$_->base_invnum} = $base_date || '';
2859       }
2860     }
2861     foreach (sort keys(%base_invnums)) {
2862       next if $_ == $self->invnum;
2863       push @ext_desc,
2864         $self->mt('from invoice \\#[_1] on [_2]', $_, $base_invnums{$_});
2865     }
2866     push @items,
2867       { feepart     => $cust_bill_pkg->feepart,
2868         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2869         description => $part_fee->itemdesc_locale($self->cust_main->locale),
2870         ext_description => \@ext_desc
2871         # sdate/edate?
2872       };
2873   }
2874   @items;
2875 }
2876
2877 sub _items_pkg {
2878   my $self = shift;
2879   my %options = @_;
2880
2881   warn "$me _items_pkg searching for all package line items\n"
2882     if $DEBUG > 1;
2883
2884   my @cust_bill_pkg = $self->_items_nontax;
2885
2886   warn "$me _items_pkg filtering line items\n"
2887     if $DEBUG > 1;
2888   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2889
2890   if ($options{section} && $options{section}->{condensed}) {
2891
2892     warn "$me _items_pkg condensing section\n"
2893       if $DEBUG > 1;
2894
2895     my %itemshash = ();
2896     local $Storable::canonical = 1;
2897     foreach ( @items ) {
2898       my $item = { %$_ };
2899       delete $item->{ref};
2900       delete $item->{ext_description};
2901       my $key = freeze($item);
2902       $itemshash{$key} ||= 0;
2903       $itemshash{$key} ++; # += $item->{quantity};
2904     }
2905     @items = sort { $a->{description} cmp $b->{description} }
2906              map { my $i = thaw($_);
2907                    $i->{quantity} = $itemshash{$_};
2908                    $i->{amount} =
2909                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2910                    $i;
2911                  }
2912              keys %itemshash;
2913   }
2914
2915   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2916     if $DEBUG > 1;
2917
2918   @items;
2919 }
2920
2921 sub _taxsort {
2922   return 0 unless $a->itemdesc cmp $b->itemdesc;
2923   return -1 if $b->itemdesc eq 'Tax';
2924   return 1 if $a->itemdesc eq 'Tax';
2925   return -1 if $b->itemdesc eq 'Other surcharges';
2926   return 1 if $a->itemdesc eq 'Other surcharges';
2927   $a->itemdesc cmp $b->itemdesc;
2928 }
2929
2930 sub _items_tax {
2931   my $self = shift;
2932   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2933     $self->cust_bill_pkg;
2934   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2935
2936   if ( $self->conf->exists('always_show_tax') ) {
2937     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2938     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2939       push @items,
2940         { 'description' => $itemdesc,
2941           'amount'      => 0.00 };
2942     }
2943   }
2944   @items;
2945 }
2946
2947 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2948
2949 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2950 list of hashrefs describing the line items they generate on the invoice.
2951
2952 OPTIONS may include:
2953
2954 format: the invoice format.
2955
2956 escape_function: the function used to escape strings.
2957
2958 DEPRECATED? (expensive, mostly unused?)
2959 format_function: the function used to format CDRs.
2960
2961 section: a hashref containing 'category' and/or 'locationnum'; if this
2962 is present, only returns line items that belong to that category and/or
2963 location (whichever is defined).
2964
2965 multisection: a flag indicating that this is a multisection invoice,
2966 which does something complicated.
2967
2968 preref_callback: coderef run for each line item, code should return HTML to be
2969 displayed before that line item (quotations only)
2970
2971 Returns a list of hashrefs, each of which may contain:
2972
2973 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2974 ext_description, which is an arrayref of detail lines to show below
2975 the package line.
2976
2977 =cut
2978
2979 sub _items_cust_bill_pkg {
2980   my $self = shift;
2981   my $conf = $self->conf;
2982   my $cust_bill_pkgs = shift;
2983   my %opt = @_;
2984
2985   my $format = $opt{format} || '';
2986   my $escape_function = $opt{escape_function} || sub { shift };
2987   my $format_function = $opt{format_function} || '';
2988   my $no_usage = $opt{no_usage} || '';
2989   my $unsquelched = $opt{unsquelched} || ''; #unused
2990   my ($section, $locationnum, $category);
2991   if ( $opt{section} ) {
2992     $category = $opt{section}->{category};
2993     $locationnum = $opt{section}->{locationnum};
2994   }
2995   my $summary_page = $opt{summary_page} || ''; #unused
2996   my $multisection = defined($category) || defined($locationnum);
2997   my $discount_show_always = 0;
2998
2999   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 50;
3000
3001   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3002                                    # and location labels
3003
3004   my @b = (); # accumulator for the line item hashes that we'll return
3005   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3006             # the 'current' line item hashes for setup, recur, usage, discount
3007   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3008   {
3009     # if the current line item is waiting to go out, and the one we're about
3010     # to start is not bundled, then push out the current one and start a new
3011     # one.
3012     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3013       if ( $_ && !$cust_bill_pkg->hidden ) {
3014         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3015         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3016         if (exists($_->{unit_amount})) {
3017           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3018         }
3019         push @b, { %$_ }
3020           if $_->{amount} != 0
3021           || $discount_show_always
3022           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3023           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3024         ;
3025         $_ = undef;
3026       }
3027     }
3028
3029     if ( $locationnum ) {
3030       # this is a location section; skip packages that aren't at this
3031       # service location.
3032       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3033       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3034               != $locationnum;
3035     }
3036
3037     # Consider display records for this item to determine if it belongs
3038     # in this section.  Note that if there are no display records, there
3039     # will be a default pseudo-record that includes all charge types
3040     # and has no section name.
3041     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3042                                   ? $cust_bill_pkg->cust_bill_pkg_display
3043                                   : ( $cust_bill_pkg );
3044
3045     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3046          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3047       if $DEBUG > 1;
3048
3049     if ( defined($category) ) {
3050       # then this is a package category section; process all display records
3051       # that belong to this section.
3052       @cust_bill_pkg_display = grep { $_->section eq $category }
3053                                 @cust_bill_pkg_display;
3054     } else {
3055       # otherwise, process all display records that aren't usage summaries
3056       # (I don't think there should be usage summaries if you aren't using
3057       # category sections, but this is the historical behavior)
3058       @cust_bill_pkg_display = grep { !$_->summary }
3059                                 @cust_bill_pkg_display;
3060     }
3061
3062     my $classname = ''; # package class name, will fill in later
3063
3064     foreach my $display (@cust_bill_pkg_display) {
3065
3066       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3067            $display->billpkgdisplaynum. "\n"
3068         if $DEBUG > 1;
3069
3070       my $type = $display->type;
3071
3072       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3073       $desc = substr($desc, 0, $maxlength). '...'
3074         if $format eq 'latex' && length($desc) > $maxlength;
3075
3076       my %details_opt = ( 'format'          => $format,
3077                           'escape_function' => $escape_function,
3078                           'format_function' => $format_function,
3079                           'no_usage'        => $opt{'no_usage'},
3080                         );
3081
3082       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3083
3084         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3085           if $DEBUG > 1;
3086         # quotation_pkgs are never fees, so don't worry about the case where
3087         # part_pkg is undefined
3088
3089         # and I guess they're never bundled either?
3090         if ( $cust_bill_pkg->setup != 0 ) {
3091           my $description = $desc;
3092           $description .= ' Setup'
3093             if $cust_bill_pkg->recur != 0
3094             || $discount_show_always
3095             || $cust_bill_pkg->recur_show_zero;
3096           push @b, {
3097             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3098             'description' => $description,
3099             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3100             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3101             'quantity'    => $cust_bill_pkg->quantity,
3102             'preref_html' => ( $opt{preref_callback}
3103                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3104                                  : ''
3105                              ),
3106           };
3107         }
3108         if ( $cust_bill_pkg->recur != 0 ) {
3109           push @b, {
3110             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3111             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3112             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3113             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3114             'quantity'    => $cust_bill_pkg->quantity,
3115            'preref_html'  => ( $opt{preref_callback}
3116                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3117                                  : ''
3118                              ),
3119           };
3120         }
3121
3122       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3123         # a "normal" package line item (not a quotation, not a fee, not a tax)
3124
3125         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3126           if $DEBUG > 1;
3127
3128         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3129         my $part_pkg = $cust_pkg->part_pkg;
3130
3131         # which pkgpart to show for display purposes?
3132         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3133
3134         # start/end dates for invoice formats that do nonstandard
3135         # things with them
3136         my %item_dates = ();
3137         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3138           unless $part_pkg->option('disable_line_item_date_ranges',1);
3139
3140         # not normally used, but pass this to the template anyway
3141         $classname = $part_pkg->classname;
3142
3143         if (    (!$type || $type eq 'S')
3144              && (    $cust_bill_pkg->setup != 0
3145                   || $cust_bill_pkg->setup_show_zero
3146                 )
3147            )
3148          {
3149
3150           warn "$me _items_cust_bill_pkg adding setup\n"
3151             if $DEBUG > 1;
3152
3153           my $description = $desc;
3154           $description .= ' Setup'
3155             if $cust_bill_pkg->recur != 0
3156             || $discount_show_always
3157             || $cust_bill_pkg->recur_show_zero;
3158
3159           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3160                                                               $self->agentnum )
3161             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3162                                      # triggered by the recurring charge freq
3163                                      # (RT#26274)
3164             && $cust_bill_pkg->recur == 0
3165             && ! $cust_bill_pkg->recur_show_zero;
3166
3167           my @d = ();
3168           my $svc_label;
3169
3170           # always pass the svc_label through to the template, even if
3171           # not displaying it as an ext_description
3172           my @svc_labels = map &{$escape_function}($_),
3173                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3174
3175           $svc_label = $svc_labels[0];
3176
3177           unless ( $cust_pkg->part_pkg->hide_svc_detail
3178                 || $cust_bill_pkg->hidden )
3179           {
3180
3181             push @d, @svc_labels
3182               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3183             my $lnum = $cust_main ? $cust_main->ship_locationnum
3184                                   : $self->prospect_main->locationnum;
3185             # show the location label if it's not the customer's default
3186             # location, and we're not grouping items by location already
3187             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3188               my $loc = $cust_pkg->location_label;
3189               $loc = substr($loc, 0, $maxlength). '...'
3190                 if $format eq 'latex' && length($loc) > $maxlength;
3191               push @d, &{$escape_function}($loc);
3192             }
3193
3194           } #unless hiding service details
3195
3196           push @d, $cust_bill_pkg->details(%details_opt)
3197             if $cust_bill_pkg->recur == 0;
3198
3199           if ( $cust_bill_pkg->hidden ) {
3200             $s->{amount}      += $cust_bill_pkg->setup;
3201             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3202             push @{ $s->{ext_description} }, @d;
3203           } else {
3204             $s = {
3205               _is_setup       => 1,
3206               description     => $description,
3207               pkgpart         => $pkgpart,
3208               pkgnum          => $cust_bill_pkg->pkgnum,
3209               amount          => $cust_bill_pkg->setup,
3210               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3211               unit_amount     => $cust_bill_pkg->unitsetup,
3212               quantity        => $cust_bill_pkg->quantity,
3213               ext_description => \@d,
3214               svc_label       => ($svc_label || ''),
3215               locationnum     => $cust_pkg->locationnum, # sure, why not?
3216             };
3217           };
3218
3219         }
3220
3221         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3222              && (
3223                      $cust_bill_pkg->recur != 0
3224                   || $cust_bill_pkg->setup == 0
3225                   || $discount_show_always
3226                   || $cust_bill_pkg->recur_show_zero
3227                 )
3228            )
3229         {
3230
3231           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3232             if $DEBUG > 1;
3233
3234           my $is_summary = $display->summary;
3235           my $description = $desc;
3236           if ( $type eq 'U' and defined($r) ) {
3237             # don't just show the same description as the recur line
3238             $description = $self->mt('Usage charges');
3239           }
3240
3241           my $part_pkg = $cust_pkg->part_pkg;
3242
3243           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3244                                                               $self->agentnum );
3245
3246           my @d = ();
3247           my @seconds = (); # for display of usage info
3248           my $svc_label = '';
3249
3250           #at least until cust_bill_pkg has "past" ranges in addition to
3251           #the "future" sdate/edate ones... see #3032
3252           my @dates = ( $self->_date );
3253           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3254           push @dates, $prev->sdate if $prev;
3255           push @dates, undef if !$prev;
3256
3257           my @svc_labels = map &{$escape_function}($_),
3258                       $cust_pkg->h_labels_short(@dates, 'I');
3259           $svc_label = $svc_labels[0];
3260
3261           # show service labels, unless...
3262                     # the package is set not to display them
3263           unless ( $part_pkg->hide_svc_detail
3264                     # or this is a tax-like line item
3265                 || $cust_bill_pkg->itemdesc
3266                     # or this is a hidden (bundled) line item
3267                 || $cust_bill_pkg->hidden
3268                     # or this is a usage summary line
3269                 || $is_summary && $type && $type eq 'U'
3270                     # or this is a usage line and there's a recurring line
3271                     # for the package in the same section (which will
3272                     # have service labels already)
3273                 || ($type eq 'U' and defined($r))
3274               )
3275           {
3276
3277             warn "$me _items_cust_bill_pkg adding service details\n"
3278               if $DEBUG > 1;
3279
3280             push @d, @svc_labels
3281               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3282             warn "$me _items_cust_bill_pkg done adding service details\n"
3283               if $DEBUG > 1;
3284
3285             my $lnum = $cust_main ? $cust_main->ship_locationnum
3286                                   : $self->prospect_main->locationnum;
3287             # show the location label if it's not the customer's default
3288             # location, and we're not grouping items by location already
3289             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3290               my $loc = $cust_pkg->location_label;
3291               $loc = substr($loc, 0, $maxlength). '...'
3292                 if $format eq 'latex' && length($loc) > $maxlength;
3293               push @d, &{$escape_function}($loc);
3294             }
3295
3296             # Display of seconds_since_sqlradacct:
3297             # On the invoice, when processing @detail_items, look for a field
3298             # named 'seconds'.  This will contain total seconds for each
3299             # service, in the same order as @ext_description.  For services
3300             # that don't support this it will show undef.
3301             if ( $conf->exists('svc_acct-usage_seconds')
3302                  and ! $cust_bill_pkg->pkgpart_override ) {
3303               foreach my $cust_svc (
3304                   $cust_pkg->h_cust_svc(@dates, 'I')
3305                 ) {
3306
3307                 # eval because not having any part_export_usage exports
3308                 # is a fatal error, last_bill/_date because that's how
3309                 # sqlradius_hour billing does it
3310                 my $sec = eval {
3311                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3312                 };
3313                 push @seconds, $sec;
3314               }
3315             } #if svc_acct-usage_seconds
3316
3317           } # if we are showing service labels
3318
3319           unless ( $is_summary ) {
3320             warn "$me _items_cust_bill_pkg adding details\n"
3321               if $DEBUG > 1;
3322
3323             #instead of omitting details entirely in this case (unwanted side
3324             # effects), just omit CDRs
3325             $details_opt{'no_usage'} = 1
3326               if $type && $type eq 'R';
3327
3328             push @d, $cust_bill_pkg->details(%details_opt);
3329           }
3330
3331           warn "$me _items_cust_bill_pkg calculating amount\n"
3332             if $DEBUG > 1;
3333
3334           my $amount = 0;
3335           if (!$type) {
3336             $amount = $cust_bill_pkg->recur;
3337           } elsif ($type eq 'R') {
3338             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3339           } elsif ($type eq 'U') {
3340             $amount = $cust_bill_pkg->usage;
3341           }
3342
3343           if ( !$type || $type eq 'R' ) {
3344
3345             warn "$me _items_cust_bill_pkg adding recur\n"
3346               if $DEBUG > 1;
3347
3348             my $unit_amount =
3349               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3350                                                 : $amount;
3351
3352             if ( $cust_bill_pkg->hidden ) {
3353               $r->{amount}      += $amount;
3354               $r->{unit_amount} += $unit_amount;
3355               push @{ $r->{ext_description} }, @d;
3356             } else {
3357               $r = {
3358                 description     => $description,
3359                 pkgpart         => $pkgpart,
3360                 pkgnum          => $cust_bill_pkg->pkgnum,
3361                 amount          => $amount,
3362                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3363                 unit_amount     => $unit_amount,
3364                 quantity        => $cust_bill_pkg->quantity,
3365                 %item_dates,
3366                 ext_description => \@d,
3367                 svc_label       => ($svc_label || ''),
3368                 locationnum     => $cust_pkg->locationnum,
3369               };
3370               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3371             }
3372
3373           } else {  # $type eq 'U'
3374
3375             warn "$me _items_cust_bill_pkg adding usage\n"
3376               if $DEBUG > 1;
3377
3378             if ( $cust_bill_pkg->hidden and defined($u) ) {
3379               # if this is a hidden package and there's already a usage
3380               # line for the bundle, add this package's total amount and
3381               # usage details to it
3382               $u->{amount}      += $amount;
3383               push @{ $u->{ext_description} }, @d;
3384             } elsif ( $amount ) {
3385               # create a new usage line
3386               $u = {
3387                 description     => $description,
3388                 pkgpart         => $pkgpart,
3389                 pkgnum          => $cust_bill_pkg->pkgnum,
3390                 amount          => $amount,
3391                 usage_item      => 1,
3392                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3393                 %item_dates,
3394                 ext_description => \@d,
3395                 locationnum     => $cust_pkg->locationnum,
3396               };
3397             } # else this has no usage, so don't create a usage section
3398           }
3399
3400         } # recurring or usage with recurring charge
3401
3402         # decide whether to show active discounts here
3403         if (
3404             # case 1: we are showing a single line for the package
3405             ( !$type )
3406             # case 2: we are showing a setup line for a package that has
3407             # no base recurring fee
3408             or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3409             # case 3: we are showing a recur line for a package that has
3410             # a base recurring fee
3411             or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3412         ) {
3413
3414           # the line item hashref for the line that will show the original
3415           # price
3416           # (use the recur or single line for the package, unless we're
3417           # showing a setup line for a package with no recurring fee)
3418           my $active_line = $r;
3419           if ( $type eq 'S' ) {
3420             $active_line = $s;
3421           }
3422
3423           my @discounts = $cust_bill_pkg->cust_bill_pkg_discount;
3424           # special case: if there are old "discount details" on this line
3425           # item, don't show discount line items
3426           if ( FS::cust_bill_pkg_detail->count(
3427               "detail LIKE 'Includes discount%' AND billpkgnum = " .
3428               $cust_bill_pkg->billpkgnum
3429              ) > 0 ) {
3430              @discounts = ();
3431           }
3432           if ( @discounts ) {
3433             warn "$me _items_cust_bill_pkg including discounts for ".
3434               $cust_bill_pkg->billpkgnum."\n"
3435               if $DEBUG;
3436             my $discount_amount = sum( map {$_->amount} @discounts );
3437             # if multiple discounts apply to the same package, how to display
3438             # them? ext_description lines, apparently
3439             #
3440             # # discount amounts are negative
3441             if ( $d and $cust_bill_pkg->hidden ) {
3442               $d->{amount}      -= $discount_amount;
3443             } else {
3444               my @ext;
3445               $d = {
3446                 _is_discount    => 1,
3447                 description     => $self->mt('Discount'),
3448                 amount          => -1 * $discount_amount,
3449                 ext_description => \@ext,
3450               };
3451               foreach my $cust_bill_pkg_discount (@discounts) {
3452                 my $discount = $cust_bill_pkg_discount->cust_pkg_discount->discount;
3453                 my $discount_desc = $discount->description_short;
3454
3455                 if ($discount->months) {
3456
3457                   # calculate months remaining after this invoice
3458                   my $used = FS::Record->scalar_sql(
3459                     'SELECT SUM(months) FROM cust_bill_pkg_discount
3460                       JOIN cust_bill_pkg USING (billpkgnum)
3461                       JOIN cust_bill USING (invnum)
3462                       WHERE pkgdiscountnum = ? AND _date <= ?',
3463                     $cust_bill_pkg_discount->pkgdiscountnum,
3464                     $self->_date
3465                   );
3466                   $used ||= 0;
3467                   my $remaining = sprintf('%.2f', $discount->months - $used);
3468                   # append "for X months (Y months remaining)"
3469                   $discount_desc .= $self->mt(' for [quant,_1,month] ([quant,_2,month] remaining)',
3470                     $cust_bill_pkg_discount->months,
3471                     $remaining
3472                   );
3473                 } # else it's not time-limited
3474                 push @ext, &{$escape_function}($discount_desc);
3475               }
3476             }
3477
3478             # update the active line (before the discount) to show the
3479             # original price (whether this is a hidden line or not)
3480             $active_line->{amount} += $discount_amount;
3481
3482           } # if there are any discounts
3483         } # if this is an appropriate place to show discounts
3484
3485       } else { # taxes and fees
3486
3487         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3488           if $DEBUG > 1;
3489
3490         # items of this kind should normally not have sdate/edate.
3491         push @b, {
3492           'description' => $desc,
3493           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3494                                            + $cust_bill_pkg->recur)
3495         };
3496
3497       } # if quotation / package line item / other line item
3498
3499     } # foreach $display
3500
3501     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3502                                 && $conf->exists('discount-show-always'));
3503
3504   }
3505
3506   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3507     if ( $_  ) {
3508       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3509         if exists($_->{amount});
3510       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3511       if (exists($_->{unit_amount})) {
3512         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3513       }
3514
3515       push @b, { %$_ }
3516         if $_->{amount} != 0
3517         || $discount_show_always
3518         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3519         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3520     }
3521   }
3522
3523   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3524     if $DEBUG > 1;
3525
3526   @b;
3527
3528 }
3529
3530 =item _items_discounts_avail
3531
3532 Returns an array of line item hashrefs representing available term discounts
3533 for this invoice.  This makes the same assumptions that apply to term
3534 discounts in general: that the package is billed monthly, at a flat rate,
3535 with no usage charges.  A prorated first month will be handled, as will
3536 a setup fee if the discount is allowed to apply to setup fees.
3537
3538 =cut
3539
3540 sub _items_discounts_avail {
3541   my $self = shift;
3542
3543   #maybe move this method from cust_bill when quotations support discount_plans
3544   return () unless $self->can('discount_plans');
3545   my %plans = $self->discount_plans;
3546
3547   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3548   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3549
3550   map {
3551     my $months = $_;
3552     my $plan = $plans{$months};
3553
3554     my $term_total = sprintf('%.2f', $plan->discounted_total);
3555     my $percent = sprintf('%.0f',
3556                           100 * (1 - $term_total / $plan->base_total) );
3557     my $permonth = sprintf('%.2f', $term_total / $months);
3558     my $detail = $self->mt('discount on item'). ' '.
3559                  join(', ', map { "#$_" } $plan->pkgnums)
3560       if $list_pkgnums;
3561
3562     # discounts for non-integer months don't work anyway
3563     $months = sprintf("%d", $months);
3564
3565     +{
3566       description => $self->mt('Save [_1]% by paying for [_2] months',
3567                                 $percent, $months),
3568       amount      => $self->mt('[_1] ([_2] per month)',
3569                                 $term_total, $money_char.$permonth),
3570       ext_description => ($detail || ''),
3571     }
3572   } #map
3573   sort { $b <=> $a } keys %plans;
3574
3575 }
3576
3577 1;