FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum first);
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 320     unless $cust_main->payname
 321         && $cust_main->payby !~ /^(CARD|DCRD|CHEK|DCHK)$/;
 322
 323   my $locale = $params{'locale'} || $cust_main->locale;
 324
 325   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 326                      'html'     => [ '<%=', '%>' ],
 327                      'template' => [ '{', '}' ],
 328                    );
 329
 330   warn "$me print_generic creating template\n"
 331     if $DEBUG > 1;
 332
 333   # set the notice name here, and nowhere else.
 334   my $notice_name =  $params{notice_name}
 335                   || $conf->config('notice_name')
 336                   || $self->notice_name;
 337
 338   #create the template
 339   my $template = $params{template} ? $params{template} : $self->_agent_template;
 340   my $templatefile = $self->template_conf. $format;
 341   $templatefile .= "_$template"
 342     if length($template) && $conf->exists($templatefile."_$template");
 343
 344   # the base template
 345   my @invoice_template = map "$_\n", $conf->config($templatefile)
 346     or die "cannot load config data $templatefile";
 347
 348   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 349     #change this to a die when the old code is removed
 350     # it's been almost ten years, changing it to a die
 351     die "old-style invoice template $templatefile; ".
 352          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 353          #$old_latex = 'true';
 354          #@invoice_template = _translate_old_latex_format(@invoice_template);
 355   }
 356
 357   warn "$me print_generic creating T:T object\n"
 358     if $DEBUG > 1;
 359
 360   my $text_template = new Text::Template(
 361     TYPE => 'ARRAY',
 362     SOURCE => \@invoice_template,
 363     DELIMITERS => $delimiters{$format},
 364   );
 365
 366   warn "$me print_generic compiling T:T object\n"
 367     if $DEBUG > 1;
 368
 369   $text_template->compile()
 370     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 371
 372
 373   # additional substitution could possibly cause breakage in existing templates
 374   my %convert_maps = (
 375     'latex' => {
 376                  'notes'         => sub { map "$_", @_ },
 377                  'footer'        => sub { map "$_", @_ },
 378                  'smallfooter'   => sub { map "$_", @_ },
 379                  'returnaddress' => sub { map "$_", @_ },
 380                  'coupon'        => sub { map "$_", @_ },
 381                  'summary'       => sub { map "$_", @_ },
 382                },
 383     'html'  => {
 384                  'notes' =>
 385                    sub {
 386                      map {
 387                        s/%%(.*)$/<!-- $1 -->/g;
 388                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 389                        s/\\begin\{enumerate\}/<ol>/g;
 390                        s/\\item /  <li>/g;
 391                        s/\\end\{enumerate\}/<\/ol>/g;
 392                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 393                        s/\\\\\*/<br>/g;
 394                        s/\\dollar ?/\$/g;
 395                        s/\\#/#/g;
 396                        s/~/&nbsp;/g;
 397                        $_;
 398                      }  @_
 399                    },
 400                  'footer' =>
 401                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 402                  'smallfooter' =>
 403                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 404                  'returnaddress' =>
 405                    sub {
 406                      map {
 407                        s/~/&nbsp;/g;
 408                        s/\\\\\*?\s*$/<BR>/;
 409                        s/\\hyphenation\{[\w\s\-]+}//;
 410                        s/\\([&])/$1/g;
 411                        $_;
 412                      }  @_
 413                    },
 414                  'coupon'        => sub { "" },
 415                  'summary'       => sub { "" },
 416                },
 417     'template' => {
 418                  'notes' =>
 419                    sub {
 420                      map {
 421                        s/%%.*$//g;
 422                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 423                        s/\\begin\{enumerate\}//g;
 424                        s/\\item /  * /g;
 425                        s/\\end\{enumerate\}//g;
 426                        s/\\textbf\{(.*)\}/$1/g;
 427                        s/\\\\\*/ /;
 428                        s/\\dollar ?/\$/g;
 429                        $_;
 430                      }  @_
 431                    },
 432                  'footer' =>
 433                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 434                  'smallfooter' =>
 435                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 436                  'returnaddress' =>
 437                    sub {
 438                      map {
 439                        s/~/ /g;
 440                        s/\\\\\*?\s*$/\n/;             # dubious
 441                        s/\\hyphenation\{[\w\s\-]+}//;
 442                        $_;
 443                      }  @_
 444                    },
 445                  'coupon'        => sub { "" },
 446                  'summary'       => sub { "" },
 447                },
 448   );
 449
 450
 451   # hashes for differing output formats
 452   my %nbsps = ( 'latex'    => '~',
 453                 'html'     => '',    # '&nbps;' would be nice
 454                 'template' => '',    # not used
 455               );
 456   my $nbsp = $nbsps{$format};
 457
 458   my %escape_functions = ( 'latex'    => \&_latex_escape,
 459                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 460                            'template' => sub { shift },
 461                          );
 462   my $escape_function = $escape_functions{$format};
 463   my $escape_function_nonbsp = ($format eq 'html')
 464                                  ? \&_html_escape : $escape_function;
 465
 466   my %newline_tokens = (  'latex'     => '\\\\',
 467                           'html'      => '<br>',
 468                           'template'  => "\n",
 469                         );
 470   my $newline_token = $newline_tokens{$format};
 471
 472   warn "$me generating template variables\n"
 473     if $DEBUG > 1;
 474
 475   # generate template variables
 476   my $returnaddress;
 477
 478   if (
 479          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 480                                         $template
 481                                       )
 482                 )
 483        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 484                                         $template
 485                                       )
 486                 )
 487   ) {
 488
 489     $returnaddress = join("\n",
 490       $conf->config_orbase("invoice_${format}returnaddress", $template)
 491     );
 492
 493   } elsif ( grep /\S/,
 494             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 495
 496     my $convert_map = $convert_maps{$format}{'returnaddress'};
 497     $returnaddress =
 498       join( "\n",
 499             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 500                                                  $template
 501                                                )
 502                          )
 503           );
 504   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 505
 506     my $convert_map = $convert_maps{$format}{'returnaddress'};
 507     $returnaddress = join( "\n", &$convert_map(
 508                                    map { s/( {2,})/'~' x length($1)/eg;
 509                                          s/$/\\\\\*/;
 510                                          $_
 511                                        }
 512                                      ( $conf->config('company_name', $cust_main->agentnum),
 513                                        $conf->config('company_address', $cust_main->agentnum),
 514                                      )
 515                                  )
 516                      );
 517
 518   } else {
 519
 520     my $warning = "Couldn't find a return address; ".
 521                   "do you need to set the company_address configuration value?";
 522     warn "$warning\n";
 523     $returnaddress = $nbsp;
 524     #$returnaddress = $warning;
 525
 526   }
 527
 528   warn "$me generating invoice data\n"
 529     if $DEBUG > 1;
 530
 531   my $agentnum = $cust_main->agentnum;
 532
 533   my %invoice_data = (
 534
 535     #invoice from info
 536     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 537     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 538     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 539     'returnaddress'   => $returnaddress,
 540     'agent'           => &$escape_function($cust_main->agent->agent),
 541
 542     #invoice/quotation info
 543     'no_number'       => $params{'no_number'},
 544     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 545     'quotationnum'    => $self->quotationnum,
 546     'no_date'         => $params{'no_date'},
 547     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 548       # workaround for inconsistent behavior in the early plain text
 549       # templates; see RT#28271
 550     'date'            => ( $params{'no_date'}
 551                              ? ''
 552                              : ($format eq 'template'
 553                                ? $self->_date
 554                                : $self->time2str_local('long', $self->_date, $format)
 555                                )
 556                          ),
 557     'today'           => $self->time2str_local('long', $today, $format),
 558     'terms'           => $self->terms,
 559     'template'        => $template, #params{'template'},
 560     'notice_name'     => $notice_name, # escape?
 561     'current_charges' => sprintf("%.2f", $self->charged),
 562     'duedate'         => $self->due_date2str('rdate'), #date_format?
 563
 564     #customer info
 565     'custnum'         => $cust_main->display_custnum,
 566     'prospectnum'     => $cust_main->prospectnum,
 567     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 568     ( map { $_ => &$escape_function($cust_main->$_()) } qw(
 569       payname company address1 address2 city state zip fax
 570     )),
 571
 572     #global config
 573     'ship_enable'     => $conf->exists('invoice-ship_address'),
 574     'unitprices'      => $conf->exists('invoice-unitprice'),
 575     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 576     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 577     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 578
 579     #layout info -- would be fancy to calc some of this and bury the template
 580     #               here in the code
 581     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 582     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 583     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 584     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 585     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 586     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 587     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 588     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 589     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 590     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 591
 592     # better hang on to conf_dir for a while (for old templates)
 593     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 594
 595     #these are only used when doing paged plaintext
 596     'page'            => 1,
 597     'total_pages'     => 1,
 598
 599   );
 600
 601   #localization
 602   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 603   # prototype here to silence warnings
 604   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 605
 606   my $min_sdate = 999999999999;
 607   my $max_edate = 0;
 608   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 609     next unless $cust_bill_pkg->pkgnum > 0;
 610     $min_sdate = $cust_bill_pkg->sdate
 611       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 612     $max_edate = $cust_bill_pkg->edate
 613       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 614   }
 615
 616   $invoice_data{'bill_period'} = '';
 617   $invoice_data{'bill_period'} =
 618       $self->time2str_local('%e %h', $min_sdate, $format)
 619       . " to " .
 620       $self->time2str_local('%e %h', $max_edate, $format)
 621     if ($max_edate != 0 && $min_sdate != 999999999999);
 622
 623   $invoice_data{finance_section} = '';
 624   if ( $conf->config('finance_pkgclass') ) {
 625     my $pkg_class =
 626       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 627     $invoice_data{finance_section} = $pkg_class->categoryname;
 628   }
 629   $invoice_data{finance_amount} = '0.00';
 630   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 631
 632   my $countrydefault = $conf->config('countrydefault') || 'US';
 633   foreach ( qw( address1 address2 city state zip country fax) ){
 634     my $method = 'ship_'.$_;
 635     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 636   }
 637   if ( length($cust_main->ship_company) ) {
 638     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 639   } else {
 640     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 641   }
 642   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 643   $invoice_data{'ship_country'} = ''
 644     if ( $invoice_data{'ship_country'} eq $countrydefault );
 645
 646   $invoice_data{'cid'} = $params{'cid'}
 647     if $params{'cid'};
 648
 649   if ( $cust_main->country eq $countrydefault ) {
 650     $invoice_data{'country'} = '';
 651   } else {
 652     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 653   }
 654
 655   my @address = ();
 656   $invoice_data{'address'} = \@address;
 657   push @address,
 658     $cust_main->payname.
 659       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 660         ? " (P.O. #". $cust_main->payinfo. ")"
 661         : ''
 662       )
 663   ;
 664   push @address, $cust_main->company
 665     if $cust_main->company;
 666   push @address, $cust_main->address1;
 667   push @address, $cust_main->address2
 668     if $cust_main->address2;
 669   push @address,
 670     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 671   push @address, $invoice_data{'country'}
 672     if $invoice_data{'country'};
 673   push @address, ''
 674     while (scalar(@address) < 5);
 675
 676   $invoice_data{'logo_file'} = $params{'logo_file'}
 677     if $params{'logo_file'};
 678   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 679     if $params{'barcode_file'};
 680   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 681     if $params{'barcode_img'};
 682   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 683     if $params{'barcode_cid'};
 684
 685   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 686 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 687   #my $balance_due = $self->owed + $pr_total - $cr_total;
 688   my $balance_due = $self->owed + $pr_total;
 689
 690   # the sum of amount owed on all invoices
 691   # (this is used in the summary & on the payment coupon)
 692   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 693
 694   # flag telling this invoice to have a first-page summary
 695   my $summarypage = '';
 696
 697   if ( $self->custnum && $self->invnum ) {
 698     # XXX should be an FS::cust_bill method to set the defaults, instead
 699     # of checking the type here
 700
 701     my $last_bill = $self->previous_bill;
 702     if ( $last_bill ) {
 703
 704       # "balance_date_range" unfortunately is unsuitable for this, since it
 705       # cares about application dates.  We want to know the sum of all
 706       # _top-level transactions_ dated before the last invoice.
 707       my @sql =
 708         map "$_ WHERE _date <= ? AND custnum = ?", (
 709           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 710           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 711           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 712           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 713         );
 714
 715       # the customer's current balance immediately after generating the last
 716       # bill
 717
 718       my $last_bill_balance = $last_bill->charged;
 719       foreach (@sql) {
 720         my $delta = FS::Record->scalar_sql(
 721           $_,
 722           $last_bill->_date - 1,
 723           $self->custnum,
 724         );
 725         $last_bill_balance += $delta;
 726       }
 727
 728       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 729
 730       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 731         $last_bill->invnum,
 732         $self->time2str_local('%D', $last_bill->_date),
 733         $last_bill_balance
 734       ) if $DEBUG > 0;
 735       # ("true_previous_balance" is a terrible name, but at least it's no
 736       # longer stored in the database)
 737       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 738
 739       # the change in balance from immediately after that invoice
 740       # to immediately before this one
 741       my $before_this_bill_balance = 0;
 742       foreach (@sql) {
 743         my $delta = FS::Record->scalar_sql(
 744           $_,
 745           $self->_date - 1,
 746           $self->custnum,
 747         );
 748         $before_this_bill_balance += $delta;
 749       }
 750       $invoice_data{'balance_adjustments'} =
 751         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 752
 753       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 754                    $invoice_data{'balance_adjustments'}
 755       ) if $DEBUG > 0;
 756
 757       # the sum of amount owed on all previous invoices
 758       # ($pr_total is used elsewhere but not as $previous_balance)
 759       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 760
 761       $invoice_data{'last_bill'} = {
 762         '_date'     => $last_bill->_date, #unformatted
 763       };
 764       my (@payments, @credits);
 765       # for formats that itemize previous payments
 766       foreach my $cust_pay ( qsearch('cust_pay', {
 767                               'custnum' => $self->custnum,
 768                               '_date'   => { op => '>=',
 769                                              value => $last_bill->_date }
 770                              } ) )
 771       {
 772         next if $cust_pay->_date > $self->_date;
 773         push @payments, {
 774             '_date'       => $cust_pay->_date,
 775             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 776             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 777             'amount'      => sprintf('%.2f', $cust_pay->paid),
 778         };
 779         # not concerned about applications
 780       }
 781       foreach my $cust_credit ( qsearch('cust_credit', {
 782                               'custnum' => $self->custnum,
 783                               '_date'   => { op => '>=',
 784                                              value => $last_bill->_date }
 785                              } ) )
 786       {
 787         next if $cust_credit->_date > $self->_date;
 788         push @credits, {
 789             '_date'       => $cust_credit->_date,
 790             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 791             'creditreason'=> $cust_credit->reason,
 792             'amount'      => sprintf('%.2f', $cust_credit->amount),
 793         };
 794       }
 795       $invoice_data{'previous_payments'} = \@payments;
 796       $invoice_data{'previous_credits'}  = \@credits;
 797     } else {
 798       # there is no $last_bill
 799       $invoice_data{'true_previous_balance'} =
 800       $invoice_data{'balance_adjustments'}   =
 801       $invoice_data{'previous_balance'}      = '0.00';
 802       $invoice_data{'previous_payments'} = [];
 803       $invoice_data{'previous_credits'} = [];
 804     }
 805
 806     # info from customer's last invoice before this one, for some
 807     # summary formats
 808     $invoice_data{'last_bill'} = {};
 809
 810     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 811       $invoice_data{'summarypage'} = $summarypage = 1;
 812     }
 813
 814   } # if this is an invoice
 815
 816   warn "$me substituting variables in notes, footer, smallfooter\n"
 817     if $DEBUG > 1;
 818
 819   my $tc = $self->template_conf;
 820   my @include = ( [ $tc,        'notes' ],
 821                   [ 'invoice_', 'footer' ],
 822                   [ 'invoice_', 'smallfooter', ],
 823                 );
 824   push @include, [ $tc,        'coupon', ]
 825     unless $params{'no_coupon'};
 826
 827   foreach my $i (@include) {
 828
 829     my($base, $include) = @$i;
 830
 831     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 832     my @inc_src;
 833
 834     if ( $conf->exists($inc_file, $agentnum)
 835          && length( $conf->config($inc_file, $agentnum) ) ) {
 836
 837       @inc_src = $conf->config($inc_file, $agentnum);
 838
 839     } else {
 840
 841       $inc_file = $conf->key_orbase("${base}latex$include", $template);
 842
 843       my $convert_map = $convert_maps{$format}{$include};
 844
 845       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
 846                        s/--\@\]/$delimiters{$format}[1]/g;
 847                        $_;
 848                      }
 849                  &$convert_map( $conf->config($inc_file, $agentnum) );
 850
 851     }
 852
 853     my $inc_tt = new Text::Template (
 854       TYPE       => 'ARRAY',
 855       SOURCE     => [ map "$_\n", @inc_src ],
 856       DELIMITERS => $delimiters{$format},
 857     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 858
 859     unless ( $inc_tt->compile() ) {
 860       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 861       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 862       die $error;
 863     }
 864
 865     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 866
 867     $invoice_data{$include} =~ s/\n+$//
 868       if ($format eq 'latex');
 869   }
 870
 871   # let invoices use either of these as needed
 872   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 873     ? $cust_main->payinfo : '';
 874   $invoice_data{'po_line'} =
 875     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 876       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 877       : $nbsp;
 878
 879   my %money_chars = ( 'latex'    => '',
 880                       'html'     => $conf->config('money_char') || '$',
 881                       'template' => '',
 882                     );
 883   my $money_char = $money_chars{$format};
 884
 885   # extremely dubious
 886   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 887                             'html'     => $conf->config('money_char') || '$',
 888                             'template' => '',
 889                           );
 890   my $other_money_char = $other_money_chars{$format};
 891   $invoice_data{'dollar'} = $other_money_char;
 892
 893   my %minus_signs = ( 'latex'    => '$-$',
 894                       'html'     => '&minus;',
 895                       'template' => '- ' );
 896   my $minus = $minus_signs{$format};
 897
 898   my @detail_items = ();
 899   my @total_items = ();
 900   my @buf = ();
 901   my @sections = ();
 902
 903   $invoice_data{'detail_items'} = \@detail_items;
 904   $invoice_data{'total_items'} = \@total_items;
 905   $invoice_data{'buf'} = \@buf;
 906   $invoice_data{'sections'} = \@sections;
 907
 908   warn "$me generating sections\n"
 909     if $DEBUG > 1;
 910
 911   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 912   my $multisection = $conf->exists($tc.'sections', $cust_main->agentnum) ||
 913                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 914   $invoice_data{'multisection'} = $multisection;
 915   my $late_sections;
 916   my $extra_sections = [];
 917   my $extra_lines = ();
 918
 919   # default section ('Charges')
 920   my $default_section = { 'description' => '',
 921                           'subtotal'    => '',
 922                           'no_subtotal' => 1,
 923                         };
 924
 925   # Previous Charges section
 926   # subtotal is the first return value from $self->previous
 927   my $previous_section;
 928   # if the invoice has major sections, or if we're summarizing previous
 929   # charges with a single line, or if we've been specifically told to put them
 930   # in a section, create a section for previous charges:
 931   if ( $multisection or
 932        $conf->exists('previous_balance-summary_only') or
 933        $conf->exists('previous_balance-section') ) {
 934
 935     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 936                            'subtotal'    => $other_money_char.
 937                                             sprintf('%.2f', $pr_total),
 938                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 939                          };
 940     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 941       join(' / ', map { $cust_main->balance_date_range(@$_) }
 942                   $self->_prior_month30s
 943           )
 944       if $conf->exists('invoice_include_aging');
 945
 946   } else {
 947     # otherwise put them in the main section
 948     $previous_section = $default_section;
 949   }
 950
 951   my $adjust_section = {
 952     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 953     'adjust_section' => 1,
 954     'subtotal'       => 0,   # adjusted below
 955   };
 956   my $adjust_weight = _pkg_category($adjust_section->{description})
 957                         ? _pkg_category($adjust_section->{description})->weight
 958                         : 0;
 959   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 960   # Note: 'sort_weight' here is actually a flag telling whether there is an
 961   # explicit package category for the adjust section. If so, certain behavior
 962   # happens.
 963   $adjust_section->{'sort_weight'} = $adjust_weight;
 964
 965
 966   if ( $multisection ) {
 967     ($extra_sections, $extra_lines) =
 968       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 969       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 970       && $self->can('_items_extra_usage_sections');
 971
 972     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 973
 974     push @detail_items, @$extra_lines if $extra_lines;
 975
 976     # the code is written so that both methods can be used together, but
 977     # we haven't yet changed the template to take advantage of that, so for
 978     # now, treat them as mutually exclusive.
 979     my %section_method = ( by_category => 1 );
 980     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 981       %section_method = ( by_location => 1 );
 982     }
 983     my ($early, $late) =
 984       $self->_items_sections( 'summary' => $summarypage,
 985                               'escape'  => $escape_function_nonbsp,
 986                               'extra_sections' => $extra_sections,
 987                               'format'  => $format,
 988                               %section_method
 989                             );
 990     push @sections, @$early;
 991     $late_sections = $late;
 992
 993     if (    $conf->exists('svc_phone_sections')
 994          && $self->can('_items_svc_phone_sections')
 995        )
 996     {
 997       my ($phone_sections, $phone_lines) =
 998         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
 999       push @{$late_sections}, @$phone_sections;
1000       push @detail_items, @$phone_lines;
1001     }
1002     if ( $conf->exists('voip-cust_accountcode_cdr')
1003          && $cust_main->accountcode_cdr
1004          && $self->can('_items_accountcode_cdr')
1005        )
1006     {
1007       my ($accountcode_section, $accountcode_lines) =
1008         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1009       if ( scalar(@$accountcode_lines) ) {
1010           push @{$late_sections}, $accountcode_section;
1011           push @detail_items, @$accountcode_lines;
1012       }
1013     }
1014   } else {# not multisection
1015     # make a default section
1016     push @sections, $default_section;
1017     # and calculate the finance charge total, since it won't get done otherwise.
1018     # and the default section total
1019     # XXX possibly finance_pkgclass should not be used in this manner?
1020     my @finance_charges;
1021     my @charges;
1022     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1023       if ( $invoice_data{finance_section} and
1024         grep { $_->section eq $invoice_data{finance_section} }
1025            $cust_bill_pkg->cust_bill_pkg_display ) {
1026         # I think these are always setup fees, but just to be sure...
1027         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1028       } else {
1029         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1030       }
1031     }
1032     $invoice_data{finance_amount} =
1033       sprintf('%.2f', sum( @finance_charges ) || 0);
1034     $default_section->{subtotal} = $other_money_char.
1035                                     sprintf('%.2f', sum( @charges ) || 0);
1036   }
1037
1038   # start setting up summary subtotals
1039   my @summary_subtotals;
1040   my $method = $conf->config('summary_subtotals_method');
1041   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1042     # then re-section them by the correct method
1043     my %section_method = ( by_category => 1 );
1044     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1045       %section_method = ( by_location => 1 );
1046     }
1047     my ($early, $late) =
1048       $self->_items_sections( 'summary' => $summarypage,
1049                               'escape'  => $escape_function_nonbsp,
1050                               'extra_sections' => $extra_sections,
1051                               'format'  => $format,
1052                               %section_method
1053                             );
1054     foreach ( @$early ) {
1055       next if $_->{subtotal} == 0;
1056       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1057       push @summary_subtotals, $_;
1058     }
1059   } else {
1060     # subtotal sectioning is the same as for the actual invoice sections
1061     @summary_subtotals = @sections;
1062   }
1063
1064   # Hereafter, push sections to both @sections and @summary_subtotals
1065   # if they belong in both places (e.g. tax section).  Late sections are
1066   # never in @summary_subtotals.
1067
1068   # previous invoice balances in the Previous Charges section if there
1069   # is one, otherwise in the main detail section
1070   # (except if summary_only is enabled, don't show them at all)
1071   if ( $self->can('_items_previous') &&
1072        $self->enable_previous &&
1073        ! $conf->exists('previous_balance-summary_only') ) {
1074
1075     warn "$me adding previous balances\n"
1076       if $DEBUG > 1;
1077
1078     foreach my $line_item ( $self->_items_previous ) {
1079
1080       my $detail = {
1081         ref             => $line_item->{'pkgnum'},
1082         pkgpart         => $line_item->{'pkgpart'},
1083         #quantity        => 1, # not really correct
1084         section         => $previous_section, # which might be $default_section
1085         description     => &$escape_function($line_item->{'description'}),
1086         ext_description => [ map { &$escape_function($_) }
1087                              @{ $line_item->{'ext_description'} || [] }
1088                            ],
1089         amount          => $money_char . $line_item->{'amount'},
1090         product_code    => $line_item->{'pkgpart'} || 'N/A',
1091       };
1092
1093       push @detail_items, $detail;
1094       push @buf, [ $detail->{'description'},
1095                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1096                  ];
1097     }
1098
1099   }
1100
1101   if ( @pr_cust_bill && $self->enable_previous ) {
1102     push @buf, ['','-----------'];
1103     push @buf, [ $self->mt('Total Previous Balance'),
1104                  $money_char. sprintf("%10.2f", $pr_total) ];
1105     push @buf, ['',''];
1106   }
1107
1108   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1109       warn "$me adding DID summary\n"
1110         if $DEBUG > 1;
1111
1112       my ($didsummary,$minutes) = $self->_did_summary;
1113       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1114       push @detail_items,
1115        { 'description' => $didsummary_desc,
1116            'ext_description' => [ $didsummary, $minutes ],
1117        };
1118   }
1119
1120   foreach my $section (@sections, @$late_sections) {
1121
1122     # begin some normalization
1123     $section->{'subtotal'} = $section->{'amount'}
1124       if $multisection
1125          && !exists($section->{subtotal})
1126          && exists($section->{amount});
1127
1128     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1129       if ( $invoice_data{finance_section} &&
1130            $section->{'description'} eq $invoice_data{finance_section} );
1131
1132     $section->{'subtotal'} = $other_money_char.
1133                              sprintf('%.2f', $section->{'subtotal'})
1134       if $multisection;
1135
1136     # continue some normalization
1137     $section->{'amount'}   = $section->{'subtotal'}
1138       if $multisection;
1139
1140
1141     if ( $section->{'description'} ) {
1142       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1143                    [ '', '' ],
1144                  );
1145     }
1146
1147     warn "$me   setting options\n"
1148       if $DEBUG > 1;
1149
1150     my %options = ();
1151     $options{'section'} = $section if $multisection;
1152     $options{'format'} = $format;
1153     $options{'escape_function'} = $escape_function;
1154     $options{'no_usage'} = 1 unless $unsquelched;
1155     $options{'unsquelched'} = $unsquelched;
1156     $options{'summary_page'} = $summarypage;
1157     $options{'skip_usage'} =
1158       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1159     $options{'preref_callback'} = $params{'preref_callback'};
1160
1161     warn "$me   searching for line items\n"
1162       if $DEBUG > 1;
1163
1164     foreach my $line_item ( $self->_items_pkg(%options),
1165                             $self->_items_fee(%options) ) {
1166
1167       warn "$me     adding line item ".
1168            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1169         if $DEBUG > 1;
1170
1171       push @buf, ( [ $line_item->{'description'},
1172                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1173                    ],
1174                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1175                  );
1176
1177       $line_item->{'ref'} = $line_item->{'pkgnum'};
1178       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1179       $line_item->{'section'} = $section;
1180       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1181       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1182
1183       if ( length($line_item->{'unit_amount'}) ) {
1184         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1185       }
1186       $line_item->{'ext_description'} ||= [];
1187
1188       push @detail_items, $line_item;
1189     }
1190
1191     if ( $section->{'description'} ) {
1192       push @buf, ( ['','-----------'],
1193                    [ $section->{'description'}. ' sub-total',
1194                       $section->{'subtotal'} # already formatted this
1195                    ],
1196                    [ '', '' ],
1197                    [ '', '' ],
1198                  );
1199     }
1200
1201   }
1202
1203   $invoice_data{current_less_finance} =
1204     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1205
1206   # if there's anything in the Previous Charges section, prepend it to the list
1207   if ( $pr_total and $previous_section ne $default_section ) {
1208     unshift @sections, $previous_section;
1209     # but not @summary_subtotals
1210   }
1211
1212   warn "$me adding taxes\n"
1213     if $DEBUG > 1;
1214
1215   # create a tax section if we don't yet have one
1216   my $tax_description = 'Taxes, Surcharges, and Fees';
1217   my $tax_section = first { $_->{description} eq $tax_description } @sections;
1218   if (!$tax_section) {
1219     $tax_section = { 'description' => $tax_description };
1220     push @sections, $tax_section if $multisection;
1221   }
1222   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1223   # if this is an existing tax section, we're merging the tax items into it.
1224   # grab the taxtotal that's already there, strip the money symbol if any
1225   my $taxtotal = $tax_section->{'subtotal'} || 0;
1226   $taxtotal =~ s/^\Q$other_money_char\E//;
1227
1228   # this does nothing
1229   #my $tax_weight = _pkg_category($tax_section->{description})
1230   #                      ? _pkg_category($tax_section->{description})->weight
1231   #                      : 0;
1232   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1233   #$tax_section->{'sort_weight'} = $tax_weight;
1234
1235   my @items_tax = $self->_items_tax;
1236   foreach my $tax ( @items_tax ) {
1237
1238     $taxtotal += $tax->{'amount'};
1239
1240     my $description = &$escape_function( $tax->{'description'} );
1241     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1242
1243     if ( $multisection ) {
1244
1245       push @detail_items, {
1246         ext_description => [],
1247         ref          => '',
1248         quantity     => '',
1249         description  => $description,
1250         amount       => $money_char. $amount,
1251         product_code => '',
1252         section      => $tax_section,
1253       };
1254
1255     } else {
1256
1257       push @total_items, {
1258         'total_item'   => $description,
1259         'total_amount' => $other_money_char. $amount,
1260       };
1261
1262     }
1263
1264     push @buf,[ $description,
1265                 $money_char. $amount,
1266               ];
1267
1268   }
1269
1270   if ( @items_tax ) {
1271     my $total = {};
1272     $total->{'total_item'} = $self->mt('Sub-total');
1273     $total->{'total_amount'} =
1274       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1275
1276     if ( $multisection ) {
1277       if ( $taxtotal > 0 ) {
1278         $tax_section->{'subtotal'} = $other_money_char.
1279                                      sprintf('%.2f', $taxtotal);
1280         $tax_section->{'pretotal'} = 'New charges sub-total '.
1281                                      $total->{'total_amount'};
1282         $tax_section->{'description'} = $self->mt($tax_description);
1283
1284         # append it if it's not already there
1285         if ( !grep $tax_section, @sections ) {
1286           push @sections, $tax_section;
1287           push @summary_subtotals, $tax_section;
1288         }
1289       }
1290
1291     } else {
1292       unshift @total_items, $total;
1293     }
1294   }
1295   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1296
1297   push @buf,['','-----------'];
1298   push @buf,[$self->mt(
1299               (!$self->enable_previous)
1300                ? 'Total Charges'
1301                : 'Total New Charges'
1302              ),
1303              $money_char. sprintf("%10.2f",$self->charged) ];
1304   push @buf,['',''];
1305
1306   ###
1307   # Totals
1308   ###
1309
1310   my %embolden_functions = (
1311     'latex'    => sub { return '\textbf{'. shift(). '}' },
1312     'html'     => sub { return '<b>'. shift(). '</b>' },
1313     'template' => sub { shift },
1314   );
1315   my $embolden_function = $embolden_functions{$format};
1316
1317   if ( $self->can('_items_total') ) { # quotations
1318
1319     $self->_items_total(\@total_items);
1320
1321     foreach ( @total_items ) {
1322       $_->{'total_item'}   = &$embolden_function( $_->{'total_item'} );
1323       $_->{'total_amount'} = &$embolden_function( $other_money_char.
1324                                                    $_->{'total_amount'}
1325                                                 );
1326     }
1327
1328   } else { #normal invoice case
1329
1330     # calculate total, possibly including total owed on previous
1331     # invoices
1332     my $total = {};
1333     my $item = 'Total';
1334     $item = $conf->config('previous_balance-exclude_from_total')
1335          || 'Total New Charges'
1336       if $conf->exists('previous_balance-exclude_from_total');
1337     my $amount = $self->charged;
1338     if ( $self->enable_previous and !$conf->exists('previous_balance-exclude_from_total') ) {
1339       $amount += $pr_total;
1340     }
1341
1342     $total->{'total_item'} = &$embolden_function($self->mt($item));
1343     $total->{'total_amount'} =
1344       &$embolden_function( $other_money_char.  sprintf( '%.2f', $amount ) );
1345     if ( $multisection ) {
1346       if ( $adjust_section->{'sort_weight'} ) {
1347         $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1348           $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1349       } else {
1350         $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1351           $other_money_char.  sprintf('%.2f', $self->charged );
1352       }
1353     } else {
1354       push @total_items, $total;
1355     }
1356     push @buf,['','-----------'];
1357     push @buf,[$item,
1358                $money_char.
1359                sprintf( '%10.2f', $amount )
1360               ];
1361     push @buf,['',''];
1362
1363     # if we're showing previous invoices, also show previous
1364     # credits and payments
1365     if ( $self->enable_previous
1366           and $self->can('_items_credits')
1367           and $self->can('_items_payments') )
1368       {
1369       #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
1370
1371       # credits
1372       my $credittotal = 0;
1373       foreach my $credit (
1374         $self->_items_credits( 'template' => $template, 'trim_len' => 60 )
1375       ) {
1376
1377         my $total;
1378         $total->{'total_item'} = &$escape_function($credit->{'description'});
1379         $credittotal += $credit->{'amount'};
1380         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1381         if ( $multisection ) {
1382           push @detail_items, {
1383             ext_description => [],
1384             ref          => '',
1385             quantity     => '',
1386             description  => &$escape_function($credit->{'description'}),
1387             amount       => $money_char . $credit->{'amount'},
1388             product_code => '',
1389             section      => $adjust_section,
1390           };
1391         } else {
1392           push @total_items, $total;
1393         }
1394
1395       }
1396       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1397
1398       #credits (again)
1399       foreach my $credit (
1400         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1401       ) {
1402         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1403       }
1404
1405       # payments
1406       my $paymenttotal = 0;
1407       foreach my $payment (
1408         $self->_items_payments( 'template' => $template )
1409       ) {
1410         my $total = {};
1411         $total->{'total_item'} = &$escape_function($payment->{'description'});
1412         $paymenttotal += $payment->{'amount'};
1413         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1414         if ( $multisection ) {
1415           push @detail_items, {
1416             ext_description => [],
1417             ref          => '',
1418             quantity     => '',
1419             description  => &$escape_function($payment->{'description'}),
1420             amount       => $money_char . $payment->{'amount'},
1421             product_code => '',
1422             section      => $adjust_section,
1423           };
1424         }else{
1425           push @total_items, $total;
1426         }
1427         push @buf, [ $payment->{'description'},
1428                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1429                    ];
1430       }
1431       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1432
1433       if ( $multisection ) {
1434         $adjust_section->{'subtotal'} = $other_money_char.
1435                                         sprintf('%.2f', $credittotal + $paymenttotal);
1436
1437         #why this? because {sort_weight} forces the adjust_section to appear
1438         #in @extra_sections instead of @sections. obviously.
1439         push @sections, $adjust_section
1440           unless $adjust_section->{sort_weight};
1441         # do not summarize; adjustments there are shown according to
1442         # different rules
1443       }
1444
1445       # create Balance Due message
1446       {
1447         my $total;
1448         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1449         $total->{'total_amount'} =
1450           &$embolden_function(
1451             $other_money_char. sprintf('%.2f', #why? $summarypage
1452                                                #  ? $self->charged +
1453                                                #    $self->billing_balance
1454                                                #  :
1455                                                    $self->owed + $pr_total
1456                                       )
1457           );
1458         if ( $multisection && !$adjust_section->{sort_weight} ) {
1459           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1460                                            $total->{'total_amount'};
1461         }else{
1462           push @total_items, $total;
1463         }
1464         push @buf,['','-----------'];
1465         push @buf,[$self->balance_due_msg, $money_char.
1466           sprintf("%10.2f", $balance_due ) ];
1467       }
1468
1469       if ( $conf->exists('previous_balance-show_credit')
1470           and $cust_main->balance < 0 ) {
1471         my $credit_total = {
1472           'total_item'    => &$embolden_function($self->credit_balance_msg),
1473           'total_amount'  => &$embolden_function(
1474             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1475           ),
1476         };
1477         if ( $multisection ) {
1478           $adjust_section->{'posttotal'} .= $newline_token .
1479             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1480         }
1481         else {
1482           push @total_items, $credit_total;
1483         }
1484         push @buf,['','-----------'];
1485         push @buf,[$self->credit_balance_msg, $money_char.
1486           sprintf("%10.2f", -$cust_main->balance ) ];
1487       }
1488     }
1489
1490   } #end of default total adding ! can('_items_total')
1491
1492   if ( $multisection ) {
1493     if (    $conf->exists('svc_phone_sections')
1494          && $self->can('_items_svc_phone_sections')
1495        )
1496     {
1497       my $total;
1498       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1499       $total->{'total_amount'} =
1500         &$embolden_function(
1501           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1502         );
1503       my $last_section = pop @sections;
1504       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1505                                      $total->{'total_amount'};
1506       push @sections, $last_section;
1507     }
1508     push @sections, @$late_sections
1509       if $unsquelched;
1510   }
1511
1512   # make a discounts-available section, even without multisection
1513   if ( $conf->exists('discount-show_available')
1514        and my @discounts_avail = $self->_items_discounts_avail ) {
1515     my $discount_section = {
1516       'description' => $self->mt('Discounts Available'),
1517       'subtotal'    => '',
1518       'no_subtotal' => 1,
1519     };
1520
1521     push @sections, $discount_section; # do not summarize
1522     push @detail_items, map { +{
1523         'ref'         => '', #should this be something else?
1524         'section'     => $discount_section,
1525         'description' => &$escape_function( $_->{description} ),
1526         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1527         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1528     } } @discounts_avail;
1529   }
1530
1531   # not adding any more sections after this
1532   $invoice_data{summary_subtotals} = \@summary_subtotals;
1533
1534   # usage subtotals
1535   if ( $conf->exists('usage_class_summary')
1536        and $self->can('_items_usage_class_summary') ) {
1537     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1538     if ( @usage_subtotals ) {
1539       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1540       unshift @detail_items, @usage_subtotals;
1541     }
1542   }
1543
1544   # invoice history "section" (not really a section)
1545   # not to be included in any subtotals, completely independent of
1546   # everything...
1547   if ( $conf->exists('previous_invoice_history') ) {
1548     my %history;
1549     my %monthorder;
1550     foreach my $cust_bill ( $cust_main->cust_bill ) {
1551       # XXX hardcoded format, and currently only 'charged'; add other fields
1552       # if they become necessary
1553       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1554       $history{$date} ||= 0;
1555       $history{$date} += $cust_bill->charged;
1556       # just so we have a numeric sort key
1557       $monthorder{$date} ||= $cust_bill->_date;
1558     }
1559     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1560                         keys %history;
1561     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1562     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1563   }
1564
1565   # service locations: another option for template customization
1566   my %location_info;
1567   foreach my $item (@detail_items) {
1568     if ( $item->{locationnum} ) {
1569       $location_info{ $item->{locationnum} } ||= {
1570         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1571       };
1572     }
1573   }
1574   $invoice_data{location_info} = \%location_info;
1575
1576   # debugging hook: call this with 'diag' => 1 to just get a hash of
1577   # the invoice variables
1578   return \%invoice_data if ( $params{'diag'} );
1579
1580   # All sections and items are built; now fill in templates.
1581   my @includelist = ();
1582   push @includelist, 'summary' if $summarypage;
1583   foreach my $include ( @includelist ) {
1584
1585     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1586     my @inc_src;
1587
1588     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1589
1590       @inc_src = $conf->config($inc_file, $agentnum);
1591
1592     } else {
1593
1594       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1595
1596       my $convert_map = $convert_maps{$format}{$include};
1597
1598       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1599                        s/--\@\]/$delimiters{$format}[1]/g;
1600                        $_;
1601                      }
1602                  &$convert_map( $conf->config($inc_file, $agentnum) );
1603
1604     }
1605
1606     my $inc_tt = new Text::Template (
1607       TYPE       => 'ARRAY',
1608       SOURCE     => [ map "$_\n", @inc_src ],
1609       DELIMITERS => $delimiters{$format},
1610     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1611
1612     unless ( $inc_tt->compile() ) {
1613       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1614       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1615       die $error;
1616     }
1617
1618     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1619
1620     $invoice_data{$include} =~ s/\n+$//
1621       if ($format eq 'latex');
1622   }
1623
1624   $invoice_lines = 0;
1625   my $wasfunc = 0;
1626   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1627     /invoice_lines\((\d*)\)/;
1628     $invoice_lines += $1 || scalar(@buf);
1629     $wasfunc=1;
1630   }
1631   die "no invoice_lines() functions in template?"
1632     if ( $format eq 'template' && !$wasfunc );
1633
1634   if ($format eq 'template') {
1635
1636     if ( $invoice_lines ) {
1637       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1638       $invoice_data{'total_pages'}++
1639         if scalar(@buf) % $invoice_lines;
1640     }
1641
1642     #setup subroutine for the template
1643     $invoice_data{invoice_lines} = sub {
1644       my $lines = shift || scalar(@buf);
1645       map {
1646         scalar(@buf)
1647           ? shift @buf
1648           : [ '', '' ];
1649       }
1650       ( 1 .. $lines );
1651     };
1652
1653     my $lines;
1654     my @collect;
1655     while (@buf) {
1656       push @collect, split("\n",
1657         $text_template->fill_in( HASH => \%invoice_data )
1658       );
1659       $invoice_data{'page'}++;
1660     }
1661     map "$_\n", @collect;
1662
1663   } else { # this is where we actually create the invoice
1664
1665     warn "filling in template for invoice ". $self->invnum. "\n"
1666       if $DEBUG;
1667     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1668       if $DEBUG > 1;
1669
1670     $text_template->fill_in(HASH => \%invoice_data);
1671   }
1672 }
1673
1674 sub notice_name { '('.shift->table.')'; }
1675
1676 sub template_conf { 'invoice_'; }
1677
1678 # helper routine for generating date ranges
1679 sub _prior_month30s {
1680   my $self = shift;
1681   my @ranges = (
1682    [ 1,       2592000 ], # 0-30 days ago
1683    [ 2592000, 5184000 ], # 30-60 days ago
1684    [ 5184000, 7776000 ], # 60-90 days ago
1685    [ 7776000, 0       ], # 90+   days ago
1686   );
1687
1688   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1689           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1690       ] }
1691   @ranges;
1692 }
1693
1694 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1695
1696 Returns an postscript invoice, as a scalar.
1697
1698 Options can be passed as a hashref (recommended) or as a list of time, template
1699 and then any key/value pairs for any other options.
1700
1701 I<time> an optional value used to control the printing of overdue messages.  The
1702 default is now.  It isn't the date of the invoice; that's the `_date' field.
1703 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1704 L<Time::Local> and L<Date::Parse> for conversion functions.
1705
1706 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1707
1708 =cut
1709
1710 sub print_ps {
1711   my $self = shift;
1712
1713   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1714   my $ps = generate_ps($file);
1715   unlink($logofile);
1716   unlink($barcodefile) if $barcodefile;
1717
1718   $ps;
1719 }
1720
1721 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1722
1723 Returns an PDF invoice, as a scalar.
1724
1725 Options can be passed as a hashref (recommended) or as a list of time, template
1726 and then any key/value pairs for any other options.
1727
1728 I<time> an optional value used to control the printing of overdue messages.  The
1729 default is now.  It isn't the date of the invoice; that's the `_date' field.
1730 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1731 L<Time::Local> and L<Date::Parse> for conversion functions.
1732
1733 I<template>, if specified, is the name of a suffix for alternate invoices.
1734
1735 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1736
1737 =cut
1738
1739 sub print_pdf {
1740   my $self = shift;
1741
1742   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1743   my $pdf = generate_pdf($file);
1744   unlink($logofile);
1745   unlink($barcodefile) if $barcodefile;
1746
1747   $pdf;
1748 }
1749
1750 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1751
1752 Returns an HTML invoice, as a scalar.
1753
1754 I<time> an optional value used to control the printing of overdue messages.  The
1755 default is now.  It isn't the date of the invoice; that's the `_date' field.
1756 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1757 L<Time::Local> and L<Date::Parse> for conversion functions.
1758
1759 I<template>, if specified, is the name of a suffix for alternate invoices.
1760
1761 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1762
1763 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1764 when emailing the invoice as part of a multipart/related MIME email.
1765
1766 =cut
1767
1768 sub print_html {
1769   my $self = shift;
1770   my %params;
1771   if ( ref($_[0]) ) {
1772     %params = %{ shift() };
1773   } else {
1774     %params = @_;
1775   }
1776   $params{'format'} = 'html';
1777
1778   $self->print_generic( %params );
1779 }
1780
1781 # quick subroutine for print_latex
1782 #
1783 # There are ten characters that LaTeX treats as special characters, which
1784 # means that they do not simply typeset themselves:
1785 #      # $ % & ~ _ ^ \ { }
1786 #
1787 # TeX ignores blanks following an escaped character; if you want a blank (as
1788 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1789
1790 sub _latex_escape {
1791   my $value = shift;
1792   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1793   $value =~ s/([<>])/\$$1\$/g;
1794   $value;
1795 }
1796
1797 sub _html_escape {
1798   my $value = shift;
1799   encode_entities($value);
1800   $value;
1801 }
1802
1803 sub _html_escape_nbsp {
1804   my $value = _html_escape(shift);
1805   $value =~ s/ +/&nbsp;/g;
1806   $value;
1807 }
1808
1809 #utility methods for print_*
1810
1811 sub _translate_old_latex_format {
1812   warn "_translate_old_latex_format called\n"
1813     if $DEBUG;
1814
1815   my @template = ();
1816   while ( @_ ) {
1817     my $line = shift;
1818
1819     if ( $line =~ /^%%Detail\s*$/ ) {
1820
1821       push @template, q![@--!,
1822                       q!  foreach my $_tr_line (@detail_items) {!,
1823                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1824                       q!      $_tr_line->{'description'} .= !,
1825                       q!        "\\tabularnewline\n~~".!,
1826                       q!        join( "\\tabularnewline\n~~",!,
1827                       q!          @{$_tr_line->{'ext_description'}}!,
1828                       q!        );!,
1829                       q!    }!;
1830
1831       while ( ( my $line_item_line = shift )
1832               !~ /^%%EndDetail\s*$/                            ) {
1833         $line_item_line =~ s/'/\\'/g;    # nice LTS
1834         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1835         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1836         push @template, "    \$OUT .= '$line_item_line';";
1837       }
1838
1839       push @template, '}',
1840                       '--@]';
1841       #' doh, gvim
1842     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1843
1844       push @template, '[@--',
1845                       '  foreach my $_tr_line (@total_items) {';
1846
1847       while ( ( my $total_item_line = shift )
1848               !~ /^%%EndTotalDetails\s*$/                      ) {
1849         $total_item_line =~ s/'/\\'/g;    # nice LTS
1850         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1851         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1852         push @template, "    \$OUT .= '$total_item_line';";
1853       }
1854
1855       push @template, '}',
1856                       '--@]';
1857
1858     } else {
1859       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1860       push @template, $line;
1861     }
1862
1863   }
1864
1865   if ($DEBUG) {
1866     warn "$_\n" foreach @template;
1867   }
1868
1869   (@template);
1870 }
1871
1872 =item terms
1873
1874 =cut
1875
1876 sub terms {
1877   my $self = shift;
1878   my $conf = $self->conf;
1879
1880   #check for an invoice-specific override
1881   return $self->invoice_terms if $self->invoice_terms;
1882
1883   #check for a customer- specific override
1884   my $cust_main = $self->cust_main;
1885   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1886
1887   my $agentnum = '';
1888   if ( $cust_main ) {
1889     $agentnum = $cust_main->agentnum;
1890   } elsif ( my $prospect_main = $self->prospect_main ) {
1891     $agentnum = $prospect_main->agentnum;
1892   }
1893
1894   #use configured default
1895   $conf->config('invoice_default_terms', $agentnum) || '';
1896 }
1897
1898 =item due_date
1899
1900 =cut
1901
1902 sub due_date {
1903   my $self = shift;
1904   my $duedate = '';
1905   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1906     $duedate = $self->_date() + ( $1 * 86400 );
1907   }
1908   $duedate;
1909 }
1910
1911 =item due_date2str
1912
1913 =cut
1914
1915 sub due_date2str {
1916   my $self = shift;
1917   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1918 }
1919
1920 =item balance_due_msg
1921
1922 =cut
1923
1924 sub balance_due_msg {
1925   my $self = shift;
1926   my $msg = $self->mt('Balance Due');
1927   return $msg unless $self->terms;
1928   if ( $self->due_date ) {
1929     $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1930       $self->due_date2str('short');
1931   } elsif ( $self->terms ) {
1932     $msg .= ' - '. $self->terms;
1933   }
1934   $msg;
1935 }
1936
1937 =item balance_due_date
1938
1939 =cut
1940
1941 sub balance_due_date {
1942   my $self = shift;
1943   my $conf = $self->conf;
1944   my $duedate = '';
1945   my $terms = $self->terms;
1946   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1947     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1948   }
1949   $duedate;
1950 }
1951
1952 sub credit_balance_msg {
1953   my $self = shift;
1954   $self->mt('Credit Balance Remaining')
1955 }
1956
1957 =item _date_pretty
1958
1959 Returns a string with the date, for example: "3/20/2008", localized for the
1960 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1961
1962 =cut
1963
1964 sub _date_pretty {
1965   my $self = shift;
1966   $self->time2str_local('short', $self->_date);
1967 }
1968
1969 =item _date_pretty_unlocalized
1970
1971 Returns a string with the date, for example: "3/20/2008", in the format
1972 configured for the back-office.  Use _date_pretty for end-customer display use.
1973
1974 =cut
1975
1976 sub _date_pretty_unlocalized {
1977   my $self = shift;
1978   time2str($date_format, $self->_date);
1979 }
1980
1981 =item email HASHREF
1982
1983 Emails this template.
1984
1985 Options are passed as a hashref.  Available options:
1986
1987 =over 4
1988
1989 =item from
1990
1991 If specified, overrides the default From: address.
1992
1993 =item notice_name
1994
1995 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1996
1997 =item template
1998
1999 (Deprecated) If specified, is the name of a suffix for alternate template files.
2000
2001 =back
2002
2003 Options accepted by generate_email can also be used.
2004
2005 =cut
2006
2007 sub email {
2008   my $self = shift;
2009   my $opt = shift || {};
2010   if ($opt and !ref($opt)) {
2011     die ref($self). '->email called with positional parameters';
2012   }
2013
2014   return if $self->hide;
2015
2016   my $error = send_email(
2017     $self->generate_email(
2018       'subject'     => $self->email_subject($opt->{template}),
2019       %$opt, # template, etc.
2020     )
2021   );
2022
2023   die "can't email: $error\n" if $error;
2024 }
2025
2026 =item generate_email OPTION => VALUE ...
2027
2028 Options:
2029
2030 =over 4
2031
2032 =item from
2033
2034 sender address, required
2035
2036 =item template
2037
2038 alternate template name, optional
2039
2040 =item print_text
2041
2042 text attachment arrayref, optional
2043
2044 =item subject
2045
2046 email subject, optional
2047
2048 =item notice_name
2049
2050 notice name instead of "Invoice", optional
2051
2052 =back
2053
2054 Returns an argument list to be passed to L<FS::Misc::send_email>.
2055
2056 =cut
2057
2058 use MIME::Entity;
2059
2060 sub generate_email {
2061
2062   my $self = shift;
2063   my %args = @_;
2064   my $conf = $self->conf;
2065
2066   my $me = '[FS::Template_Mixin::generate_email]';
2067
2068   my %return = (
2069     'from'      => $args{'from'},
2070     'subject'   => ($args{'subject'} || $self->email_subject),
2071     'custnum'   => $self->custnum,
2072     'msgtype'   => 'invoice',
2073   );
2074
2075   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2076
2077   my $cust_main = $self->cust_main;
2078
2079   if (ref($args{'to'}) eq 'ARRAY') {
2080     $return{'to'} = $args{'to'};
2081   } elsif ( $cust_main ) {
2082     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2083   }
2084
2085   my $tc = $self->template_conf;
2086
2087   if ( $conf->exists($tc.'html') ) {
2088
2089     warn "$me creating HTML/text multipart message"
2090       if $DEBUG;
2091
2092     $return{'nobody'} = 1;
2093
2094     my $alternative = build MIME::Entity
2095       'Type'        => 'multipart/alternative',
2096       #'Encoding'    => '7bit',
2097       'Disposition' => 'inline'
2098     ;
2099
2100     my $data = '';
2101     if ( $conf->exists($tc. 'email_pdf')
2102          and scalar($conf->config($tc. 'email_pdf_note')) ) {
2103
2104       warn "$me using '${tc}email_pdf_note' in multipart message"
2105         if $DEBUG;
2106       $data = [ map { $_ . "\n" }
2107                     $conf->config($tc.'email_pdf_note')
2108               ];
2109
2110     } else {
2111
2112       warn "$me not using '${tc}email_pdf_note' in multipart message"
2113         if $DEBUG;
2114       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
2115         $data = $args{'print_text'};
2116       } elsif ( $conf->exists($tc.'template') ) { #plaintext invoice_template
2117         $data = [ $self->print_text(\%args) ];
2118       }
2119
2120     }
2121
2122     if ( $data ) {
2123       $alternative->attach(
2124         'Type'        => 'text/plain',
2125         'Encoding'    => 'quoted-printable',
2126         'Charset'     => 'UTF-8',
2127         #'Encoding'    => '7bit',
2128         'Data'        => $data,
2129         'Disposition' => 'inline',
2130       );
2131     }
2132
2133     my $htmldata;
2134     my $image = '';
2135     my $barcode = '';
2136     if ( $conf->exists($tc.'email_pdf')
2137          and scalar($conf->config($tc.'email_pdf_note')) ) {
2138
2139       $htmldata = join('<BR>', $conf->config($tc.'email_pdf_note') );
2140
2141     } else {
2142
2143       $args{'from'} =~ /\@([\w\.\-]+)/;
2144       my $from = $1 || 'example.com';
2145       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2146
2147       my $logo;
2148       my $agentnum = $cust_main ? $cust_main->agentnum
2149                                 : $self->prospect_main->agentnum;
2150       if ( defined($args{'template'}) && length($args{'template'})
2151            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2152          )
2153       {
2154         $logo = 'logo_'. $args{'template'}. '.png';
2155       } else {
2156         $logo = "logo.png";
2157       }
2158       my $image_data = $conf->config_binary( $logo, $agentnum);
2159
2160       $image = build MIME::Entity
2161         'Type'       => 'image/png',
2162         'Encoding'   => 'base64',
2163         'Data'       => $image_data,
2164         'Filename'   => 'logo.png',
2165         'Content-ID' => "<$content_id>",
2166       ;
2167
2168       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2169         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2170         $barcode = build MIME::Entity
2171           'Type'       => 'image/png',
2172           'Encoding'   => 'base64',
2173           'Data'       => $self->invoice_barcode(0),
2174           'Filename'   => 'barcode.png',
2175           'Content-ID' => "<$barcode_content_id>",
2176         ;
2177         $args{'barcode_cid'} = $barcode_content_id;
2178       }
2179
2180       $htmldata = $self->print_html({ 'cid'=>$content_id, %args });
2181     }
2182
2183     $alternative->attach(
2184       'Type'        => 'text/html',
2185       'Encoding'    => 'quoted-printable',
2186       'Data'        => [ '<html>',
2187                          '  <head>',
2188                          '    <title>',
2189                          '      '. encode_entities($return{'subject'}),
2190                          '    </title>',
2191                          '  </head>',
2192                          '  <body bgcolor="#e8e8e8">',
2193                          $htmldata,
2194                          '  </body>',
2195                          '</html>',
2196                        ],
2197       'Disposition' => 'inline',
2198       #'Filename'    => 'invoice.pdf',
2199     );
2200
2201
2202     my @otherparts = ();
2203     if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2204
2205       push @otherparts, build MIME::Entity
2206         'Type'        => 'text/csv',
2207         'Encoding'    => '7bit',
2208         'Data'        => [ map { "$_\n" }
2209                              $self->call_details('prepend_billed_number' => 1)
2210                          ],
2211         'Disposition' => 'attachment',
2212         'Filename'    => 'usage-'. $self->invnum. '.csv',
2213       ;
2214
2215     }
2216
2217     if ( $conf->exists($tc.'email_pdf') ) {
2218
2219       #attaching pdf too:
2220       # multipart/mixed
2221       #   multipart/related
2222       #     multipart/alternative
2223       #       text/plain
2224       #       text/html
2225       #     image/png
2226       #   application/pdf
2227
2228       my $related = build MIME::Entity 'Type'     => 'multipart/related',
2229                                        'Encoding' => '7bit';
2230
2231       #false laziness w/Misc::send_email
2232       $related->head->replace('Content-type',
2233         $related->mime_type.
2234         '; boundary="'. $related->head->multipart_boundary. '"'.
2235         '; type=multipart/alternative'
2236       );
2237
2238       $related->add_part($alternative);
2239
2240       $related->add_part($image) if $image;
2241
2242       my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2243
2244       $return{'mimeparts'} = [ $related, $pdf, @otherparts ];
2245
2246     } else {
2247
2248       #no other attachment:
2249       # multipart/related
2250       #   multipart/alternative
2251       #     text/plain
2252       #     text/html
2253       #   image/png
2254
2255       $return{'content-type'} = 'multipart/related';
2256       if ($conf->exists('invoice-barcode') && $barcode) {
2257         $return{'mimeparts'} = [ $alternative, $image, $barcode, @otherparts ];
2258       } else {
2259         $return{'mimeparts'} = [ $alternative, $image, @otherparts ];
2260       }
2261       $return{'type'} = 'multipart/alternative'; #Content-Type of first part...
2262       #$return{'disposition'} = 'inline';
2263
2264     }
2265
2266   } else {
2267
2268     if ( $conf->exists($tc.'email_pdf') ) {
2269       warn "$me creating PDF attachment"
2270         if $DEBUG;
2271
2272       #mime parts arguments a la MIME::Entity->build().
2273       $return{'mimeparts'} = [
2274         { $self->mimebuild_pdf(\%args) }
2275       ];
2276     }
2277
2278     if ( $conf->exists($tc.'email_pdf')
2279          and scalar($conf->config($tc.'email_pdf_note')) ) {
2280
2281       warn "$me using '${tc}email_pdf_note'"
2282         if $DEBUG;
2283       $return{'body'} = [ map { $_ . "\n" }
2284                               $conf->config($tc.'email_pdf_note')
2285                         ];
2286
2287     } else {
2288
2289       warn "$me not using '${tc}email_pdf_note'"
2290         if $DEBUG;
2291       if ( ref($args{'print_text'}) eq 'ARRAY' ) {
2292         $return{'body'} = $args{'print_text'};
2293       } else {
2294         $return{'body'} = [ $self->print_text(\%args) ];
2295       }
2296
2297     }
2298
2299   }
2300
2301   %return;
2302
2303 }
2304
2305 =item mimebuild_pdf
2306
2307 Returns a list suitable for passing to MIME::Entity->build(), representing
2308 this invoice as PDF attachment.
2309
2310 =cut
2311
2312 sub mimebuild_pdf {
2313   my $self = shift;
2314   (
2315     'Type'        => 'application/pdf',
2316     'Encoding'    => 'base64',
2317     'Data'        => [ $self->print_pdf(@_) ],
2318     'Disposition' => 'attachment',
2319     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2320   );
2321 }
2322
2323 =item _items_sections OPTIONS
2324
2325 Generate section information for all items appearing on this invoice.
2326 This will only be called for multi-section invoices.
2327
2328 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2329 related display records (L<FS::cust_bill_pkg_display>) and organize
2330 them into two groups ("early" and "late" according to whether they come
2331 before or after the total), then into sections.  A subtotal is calculated
2332 for each section.
2333
2334 Section descriptions are returned in sort weight order.  Each consists
2335 of a hash containing:
2336
2337 description: the package category name, escaped
2338 subtotal: the total charges in that section
2339 tax_section: a flag indicating that the section contains only tax charges
2340 summarized: same as tax_section, for some reason
2341 sort_weight: the package category's sort weight
2342
2343 If 'condense' is set on the display record, it also contains everything
2344 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2345 coderefs to generate parts of the invoice.  This is not advised.
2346
2347 The method returns two arrayrefs, one of "early" sections and one of "late"
2348 sections.
2349
2350 OPTIONS may include:
2351
2352 by_location: a flag to divide the invoice into sections by location.
2353 Each section hash will have a 'location' element containing a hashref of
2354 the location fields (see L<FS::cust_location>).  The section description
2355 will be the location label, but the template can use any of the location
2356 fields to create a suitable label.
2357
2358 by_category: a flag to divide the invoice into sections using display
2359 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2360 behavior.  Each section hash will have a 'category' element containing
2361 the section name from the display record (which probably equals the
2362 category name of the package, but may not in some cases).
2363
2364 summary: a flag indicating that this is a summary-format invoice.
2365 Turning this on has the following effects:
2366 - Ignores display items with the 'summary' flag.
2367 - Places all sections in the "early" group even if they have post_total.
2368 - Creates sections for all non-disabled package categories, even if they
2369 have no charges on this invoice, as well as a section with no name.
2370
2371 escape: an escape function to use for section titles.
2372
2373 extra_sections: an arrayref of additional sections to return after the
2374 sorted list.  If there are any of these, section subtotals exclude
2375 usage charges.
2376
2377 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2378 passed through to C<_condense_section()>.
2379
2380 =cut
2381
2382 use vars qw(%pkg_category_cache);
2383 sub _items_sections {
2384   my $self = shift;
2385   my %opt = @_;
2386
2387   my $escape = $opt{escape};
2388   my @extra_sections = @{ $opt{extra_sections} || [] };
2389
2390   # $subtotal{$locationnum}{$categoryname} = amount.
2391   # if we're not using by_location, $locationnum is undef.
2392   # if we're not using by_category, you guessed it, $categoryname is undef.
2393   # if we're not using either one, we shouldn't be here in the first place...
2394   my %subtotal = ();
2395   my %late_subtotal = ();
2396   my %not_tax = ();
2397
2398   # About tax items + multisection invoices:
2399   # If either invoice_*summary option is enabled, AND there is a
2400   # package category with the name of the tax, then there will be
2401   # a display record assigning the tax item to that category.
2402   #
2403   # However, the taxes are always placed in the "Taxes, Surcharges,
2404   # and Fees" section regardless of that.  The only effect of the
2405   # display record is to create a subtotal for the summary page.
2406
2407   # cache these
2408   my $pkg_hash = $self->cust_pkg_hash;
2409
2410   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2411   {
2412
2413       my $usage = $cust_bill_pkg->usage;
2414
2415       my $locationnum;
2416       if ( $opt{by_location} ) {
2417         if ( $cust_bill_pkg->pkgnum ) {
2418           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2419         } else {
2420           $locationnum = '';
2421         }
2422       } else {
2423         $locationnum = undef;
2424       }
2425
2426       # as in _items_cust_pkg, if a line item has no display records,
2427       # cust_bill_pkg_display() returns a default record for it
2428
2429       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2430         next if ( $display->summary && $opt{summary} );
2431
2432         my $section = $display->section;
2433         my $type    = $display->type;
2434         # Set $section = undef if we're sectioning by location and this
2435         # line item _has_ a location (i.e. isn't a fee).
2436         $section = undef if $locationnum;
2437
2438         # set this flag if the section is not tax-only
2439         $not_tax{$locationnum}{$section} = 1
2440           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2441
2442         # there's actually a very important piece of logic buried in here:
2443         # incrementing $late_subtotal{$section} CREATES
2444         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2445         # to define the list of late sections, and likewise keys(%subtotal).
2446         # When _items_cust_bill_pkg is called to generate line items for
2447         # real, it will be called with 'section' => $section for each
2448         # of these.
2449         if ( $display->post_total && !$opt{summary} ) {
2450           if (! $type || $type eq 'S') {
2451             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2452               if $cust_bill_pkg->setup != 0
2453               || $cust_bill_pkg->setup_show_zero;
2454           }
2455
2456           if (! $type) {
2457             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2458               if $cust_bill_pkg->recur != 0
2459               || $cust_bill_pkg->recur_show_zero;
2460           }
2461
2462           if ($type && $type eq 'R') {
2463             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2464               if $cust_bill_pkg->recur != 0
2465               || $cust_bill_pkg->recur_show_zero;
2466           }
2467
2468           if ($type && $type eq 'U') {
2469             $late_subtotal{$locationnum}{$section} += $usage
2470               unless scalar(@extra_sections);
2471           }
2472
2473         } else { # it's a pre-total (normal) section
2474
2475           # skip tax items unless they're explicitly included in a section
2476           next if $cust_bill_pkg->pkgnum == 0 and
2477                   ! $cust_bill_pkg->feepart   and
2478                   ! $section;
2479
2480           if ( $type eq 'S' ) {
2481             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2482               if $cust_bill_pkg->setup != 0
2483               || $cust_bill_pkg->setup_show_zero;
2484           } elsif ( $type eq 'R' ) {
2485             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2486               if $cust_bill_pkg->recur != 0
2487               || $cust_bill_pkg->recur_show_zero;
2488           } elsif ( $type eq 'U' ) {
2489             $subtotal{$locationnum}{$section} += $usage
2490               unless scalar(@extra_sections);
2491           } elsif ( !$type ) {
2492             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2493                                                + $cust_bill_pkg->recur;
2494           }
2495
2496         }
2497
2498       }
2499
2500   }
2501
2502   %pkg_category_cache = ();
2503
2504   # summary invoices need subtotals for all non-disabled package categories,
2505   # even if they're zero
2506   # but currently assume that there are no location sections, or at least
2507   # that the summary page doesn't care about them
2508   if ( $opt{summary} ) {
2509     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2510       $subtotal{''}{$category->categoryname} ||= 0;
2511     }
2512     $subtotal{''}{''} ||= 0;
2513   }
2514
2515   my @sections;
2516   foreach my $post_total (0,1) {
2517     my @these;
2518     my $s = $post_total ? \%late_subtotal : \%subtotal;
2519     foreach my $locationnum (keys %$s) {
2520       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2521         my $section = {
2522                         'subtotal'    => $s->{$locationnum}{$sectionname},
2523                         'post_total'  => $post_total,
2524                         'sort_weight' => 0,
2525                       };
2526         if ( $locationnum ) {
2527           $section->{'locationnum'} = $locationnum;
2528           my $location = FS::cust_location->by_key($locationnum);
2529           $section->{'description'} = &{ $escape }($location->location_label);
2530           # Better ideas? This will roughly group them by proximity,
2531           # which alpha sorting on any of the address fields won't.
2532           # Sorting by locationnum is meaningless.
2533           # We have to sort on _something_ or the order may change
2534           # randomly from one invoice to the next, which will confuse
2535           # people.
2536           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2537                                       $locationnum;
2538           $section->{'location'} = {
2539             label_prefix => &{ $escape }($location->label_prefix),
2540             map { $_ => &{ $escape }($location->get($_)) }
2541               $location->fields
2542           };
2543         } else {
2544           $section->{'category'} = $sectionname;
2545           $section->{'description'} = &{ $escape }($sectionname);
2546           if ( _pkg_category($sectionname) ) {
2547             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2548             if ( _pkg_category($sectionname)->condense ) {
2549               $section = { %$section, $self->_condense_section($opt{format}) };
2550             }
2551           }
2552         }
2553         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2554           # then it's a tax-only section
2555           $section->{'summarized'} = 'Y';
2556           $section->{'tax_section'} = 'Y';
2557         }
2558         push @these, $section;
2559       } # foreach $sectionname
2560     } #foreach $locationnum
2561     push @these, @extra_sections if $post_total == 0;
2562     # need an alpha sort for location sections, because postal codes can
2563     # be non-numeric
2564     $sections[ $post_total ] = [ sort {
2565       $opt{'by_location'} ?
2566         ($a->{sort_weight} cmp $b->{sort_weight}) :
2567         ($a->{sort_weight} <=> $b->{sort_weight})
2568       } @these ];
2569   } #foreach $post_total
2570
2571   return @sections; # early, late
2572 }
2573
2574 #helper subs for above
2575
2576 sub cust_pkg_hash {
2577   my $self = shift;
2578   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2579 }
2580
2581 sub _pkg_category {
2582   my $categoryname = shift;
2583   $pkg_category_cache{$categoryname} ||=
2584     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2585 }
2586
2587 my %condensed_format = (
2588   'label' => [ qw( Description Qty Amount ) ],
2589   'fields' => [
2590                 sub { shift->{description} },
2591                 sub { shift->{quantity} },
2592                 sub { my($href, %opt) = @_;
2593                       ($opt{dollar} || ''). $href->{amount};
2594                     },
2595               ],
2596   'align'  => [ qw( l r r ) ],
2597   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2598   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2599 );
2600
2601 sub _condense_section {
2602   my ( $self, $format ) = ( shift, shift );
2603   ( 'condensed' => 1,
2604     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2605       qw( description_generator
2606           header_generator
2607           total_generator
2608           total_line_generator
2609         )
2610   );
2611 }
2612
2613 sub _condensed_generator_defaults {
2614   my ( $self, $format ) = ( shift, shift );
2615   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2616 }
2617
2618 my %html_align = (
2619   'c' => 'center',
2620   'l' => 'left',
2621   'r' => 'right',
2622 );
2623
2624 sub _condensed_header_generator {
2625   my ( $self, $format ) = ( shift, shift );
2626
2627   my ( $f, $prefix, $suffix, $separator, $column ) =
2628     _condensed_generator_defaults($format);
2629
2630   if ($format eq 'latex') {
2631     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2632     $suffix = "\\\\\n\\hline";
2633     $separator = "&\n";
2634     $column =
2635       sub { my ($d,$a,$s,$w) = @_;
2636             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2637           };
2638   } elsif ( $format eq 'html' ) {
2639     $prefix = '<th></th>';
2640     $suffix = '';
2641     $separator = '';
2642     $column =
2643       sub { my ($d,$a,$s,$w) = @_;
2644             return qq!<th align="$html_align{$a}">$d</th>!;
2645       };
2646   }
2647
2648   sub {
2649     my @args = @_;
2650     my @result = ();
2651
2652     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2653       push @result,
2654         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2655     }
2656
2657     $prefix. join($separator, @result). $suffix;
2658   };
2659
2660 }
2661
2662 sub _condensed_description_generator {
2663   my ( $self, $format ) = ( shift, shift );
2664
2665   my ( $f, $prefix, $suffix, $separator, $column ) =
2666     _condensed_generator_defaults($format);
2667
2668   my $money_char = '$';
2669   if ($format eq 'latex') {
2670     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2671     $suffix = '\\\\';
2672     $separator = " & \n";
2673     $column =
2674       sub { my ($d,$a,$s,$w) = @_;
2675             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2676           };
2677     $money_char = '\\dollar';
2678   }elsif ( $format eq 'html' ) {
2679     $prefix = '"><td align="center"></td>';
2680     $suffix = '';
2681     $separator = '';
2682     $column =
2683       sub { my ($d,$a,$s,$w) = @_;
2684             return qq!<td align="$html_align{$a}">$d</td>!;
2685       };
2686     #$money_char = $conf->config('money_char') || '$';
2687     $money_char = '';  # this is madness
2688   }
2689
2690   sub {
2691     #my @args = @_;
2692     my $href = shift;
2693     my @result = ();
2694
2695     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2696       my $dollar = '';
2697       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2698       push @result,
2699         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2700                     map { $f->{$_}->[$i] } qw(align span width)
2701                   );
2702     }
2703
2704     $prefix. join( $separator, @result ). $suffix;
2705   };
2706
2707 }
2708
2709 sub _condensed_total_generator {
2710   my ( $self, $format ) = ( shift, shift );
2711
2712   my ( $f, $prefix, $suffix, $separator, $column ) =
2713     _condensed_generator_defaults($format);
2714   my $style = '';
2715
2716   if ($format eq 'latex') {
2717     $prefix = "& ";
2718     $suffix = "\\\\\n";
2719     $separator = " & \n";
2720     $column =
2721       sub { my ($d,$a,$s,$w) = @_;
2722             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2723           };
2724   }elsif ( $format eq 'html' ) {
2725     $prefix = '';
2726     $suffix = '';
2727     $separator = '';
2728     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2729     $column =
2730       sub { my ($d,$a,$s,$w) = @_;
2731             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2732       };
2733   }
2734
2735
2736   sub {
2737     my @args = @_;
2738     my @result = ();
2739
2740     #  my $r = &{$f->{fields}->[$i]}(@args);
2741     #  $r .= ' Total' unless $i;
2742
2743     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2744       push @result,
2745         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2746                     map { $f->{$_}->[$i] } qw(align span width)
2747                   );
2748     }
2749
2750     $prefix. join( $separator, @result ). $suffix;
2751   };
2752
2753 }
2754
2755 =item total_line_generator FORMAT
2756
2757 Returns a coderef used for generation of invoice total line items for this
2758 usage_class.  FORMAT is either html or latex
2759
2760 =cut
2761
2762 # should not be used: will have issues with hash element names (description vs
2763 # total_item and amount vs total_amount -- another array of functions?
2764
2765 sub _condensed_total_line_generator {
2766   my ( $self, $format ) = ( shift, shift );
2767
2768   my ( $f, $prefix, $suffix, $separator, $column ) =
2769     _condensed_generator_defaults($format);
2770   my $style = '';
2771
2772   if ($format eq 'latex') {
2773     $prefix = "& ";
2774     $suffix = "\\\\\n";
2775     $separator = " & \n";
2776     $column =
2777       sub { my ($d,$a,$s,$w) = @_;
2778             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2779           };
2780   }elsif ( $format eq 'html' ) {
2781     $prefix = '';
2782     $suffix = '';
2783     $separator = '';
2784     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2785     $column =
2786       sub { my ($d,$a,$s,$w) = @_;
2787             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2788       };
2789   }
2790
2791
2792   sub {
2793     my @args = @_;
2794     my @result = ();
2795
2796     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2797       push @result,
2798         &{$column}( &{$f->{fields}->[$i]}(@args),
2799                     map { $f->{$_}->[$i] } qw(align span width)
2800                   );
2801     }
2802
2803     $prefix. join( $separator, @result ). $suffix;
2804   };
2805
2806 }
2807
2808 =item _items_pkg [ OPTIONS ]
2809
2810 Return line item hashes for each package item on this invoice. Nearly
2811 equivalent to
2812
2813 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2814
2815 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2816 'format' and 'escape_function' at minimum.
2817
2818 To produce items for a specific invoice section, OPTIONS should include
2819 'section', a hashref containing 'category' and/or 'locationnum' keys.
2820
2821 'section' may also contain a key named 'condensed'. If this is present
2822 and has a true value, _items_pkg will try to merge identical items into items
2823 with 'quantity' equal to the number of items (not the sum of their separate
2824 quantities, for some reason).
2825
2826 =cut
2827
2828 sub _items_nontax {
2829   my $self = shift;
2830   # The order of these is important.  Bundled line items will be merged into
2831   # the most recent non-hidden item, so it needs to be the one with:
2832   # - the same pkgnum
2833   # - the same start date
2834   # - no pkgpart_override
2835   #
2836   # So: sort by pkgnum,
2837   # then by sdate
2838   # then sort the base line item before any overrides
2839   # then sort hidden before non-hidden add-ons
2840   # then sort by override pkgpart (for consistency)
2841   sort { $a->pkgnum <=> $b->pkgnum        or
2842          $a->sdate  <=> $b->sdate         or
2843          ($a->pkgpart_override ? 0 : -1)  or
2844          ($b->pkgpart_override ? 0 : 1)   or
2845          $b->hidden cmp $a->hidden        or
2846          $a->pkgpart_override <=> $b->pkgpart_override
2847        }
2848   # and of course exclude taxes and fees
2849   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2850 }
2851
2852 sub _items_fee {
2853   my $self = shift;
2854   my %options = @_;
2855   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2856   my $escape_function = $options{escape_function};
2857
2858   my @items;
2859   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2860     # cache this, so we don't look it up again in every section
2861     my $part_fee = $cust_bill_pkg->get('part_fee')
2862        || $cust_bill_pkg->part_fee;
2863     $cust_bill_pkg->set('part_fee', $part_fee);
2864     if (!$part_fee) {
2865       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2866       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2867       next;
2868     }
2869     if ( exists($options{section}) and exists($options{section}{category}) )
2870     {
2871       my $categoryname = $options{section}{category};
2872       # then filter for items that have that section
2873       if ( $part_fee->categoryname ne $categoryname ) {
2874         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2875         next;
2876       }
2877     } # otherwise include them all in the main section
2878     # XXX what to do when sectioning by location?
2879
2880     my @ext_desc;
2881     my %base_invnums; # invnum => invoice date
2882     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2883       if ($_->base_invnum) {
2884         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2885         my $base_date = $self->time2str_local('short', $base_bill->_date)
2886           if $base_bill;
2887         $base_invnums{$_->base_invnum} = $base_date || '';
2888       }
2889     }
2890     foreach (sort keys(%base_invnums)) {
2891       next if $_ == $self->invnum;
2892       # per convention, we must escape ext_description lines
2893       push @ext_desc,
2894         &{$escape_function}(
2895           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2896         );
2897     }
2898     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2899     # but not escape the base description line
2900
2901     push @items,
2902       { feepart     => $cust_bill_pkg->feepart,
2903         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2904         description => $desc,
2905         ext_description => \@ext_desc
2906         # sdate/edate?
2907       };
2908   }
2909   @items;
2910 }
2911
2912 sub _items_pkg {
2913   my $self = shift;
2914   my %options = @_;
2915
2916   warn "$me _items_pkg searching for all package line items\n"
2917     if $DEBUG > 1;
2918
2919   my @cust_bill_pkg = $self->_items_nontax;
2920
2921   warn "$me _items_pkg filtering line items\n"
2922     if $DEBUG > 1;
2923   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2924
2925   if ($options{section} && $options{section}->{condensed}) {
2926
2927     warn "$me _items_pkg condensing section\n"
2928       if $DEBUG > 1;
2929
2930     my %itemshash = ();
2931     local $Storable::canonical = 1;
2932     foreach ( @items ) {
2933       my $item = { %$_ };
2934       delete $item->{ref};
2935       delete $item->{ext_description};
2936       my $key = freeze($item);
2937       $itemshash{$key} ||= 0;
2938       $itemshash{$key} ++; # += $item->{quantity};
2939     }
2940     @items = sort { $a->{description} cmp $b->{description} }
2941              map { my $i = thaw($_);
2942                    $i->{quantity} = $itemshash{$_};
2943                    $i->{amount} =
2944                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2945                    $i;
2946                  }
2947              keys %itemshash;
2948   }
2949
2950   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2951     if $DEBUG > 1;
2952
2953   @items;
2954 }
2955
2956 sub _taxsort {
2957   return 0 unless $a->itemdesc cmp $b->itemdesc;
2958   return -1 if $b->itemdesc eq 'Tax';
2959   return 1 if $a->itemdesc eq 'Tax';
2960   return -1 if $b->itemdesc eq 'Other surcharges';
2961   return 1 if $a->itemdesc eq 'Other surcharges';
2962   $a->itemdesc cmp $b->itemdesc;
2963 }
2964
2965 sub _items_tax {
2966   my $self = shift;
2967   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2968     $self->cust_bill_pkg;
2969   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2970
2971   if ( $self->conf->exists('always_show_tax') ) {
2972     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2973     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2974       push @items,
2975         { 'description' => $itemdesc,
2976           'amount'      => 0.00 };
2977     }
2978   }
2979   @items;
2980 }
2981
2982 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2983
2984 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2985 list of hashrefs describing the line items they generate on the invoice.
2986
2987 OPTIONS may include:
2988
2989 format: the invoice format.
2990
2991 escape_function: the function used to escape strings.
2992
2993 DEPRECATED? (expensive, mostly unused?)
2994 format_function: the function used to format CDRs.
2995
2996 section: a hashref containing 'category' and/or 'locationnum'; if this
2997 is present, only returns line items that belong to that category and/or
2998 location (whichever is defined).
2999
3000 multisection: a flag indicating that this is a multisection invoice,
3001 which does something complicated.
3002
3003 preref_callback: coderef run for each line item, code should return HTML to be
3004 displayed before that line item (quotations only)
3005
3006 Returns a list of hashrefs, each of which may contain:
3007
3008 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
3009 ext_description, which is an arrayref of detail lines to show below
3010 the package line.
3011
3012 =cut
3013
3014 sub _items_cust_bill_pkg {
3015   my $self = shift;
3016   my $conf = $self->conf;
3017   my $cust_bill_pkgs = shift;
3018   my %opt = @_;
3019
3020   my $format = $opt{format} || '';
3021   my $escape_function = $opt{escape_function} || sub { shift };
3022   my $format_function = $opt{format_function} || '';
3023   my $no_usage = $opt{no_usage} || '';
3024   my $unsquelched = $opt{unsquelched} || ''; #unused
3025   my ($section, $locationnum, $category);
3026   if ( $opt{section} ) {
3027     $category = $opt{section}->{category};
3028     $locationnum = $opt{section}->{locationnum};
3029   }
3030   my $summary_page = $opt{summary_page} || ''; #unused
3031   my $multisection = defined($category) || defined($locationnum);
3032   my $discount_show_always = 0;
3033
3034   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 50;
3035
3036   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3037                                    # and location labels
3038
3039   my @b = (); # accumulator for the line item hashes that we'll return
3040   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3041             # the 'current' line item hashes for setup, recur, usage, discount
3042   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3043   {
3044     # if the current line item is waiting to go out, and the one we're about
3045     # to start is not bundled, then push out the current one and start a new
3046     # one.
3047     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3048       if ( $_ && !$cust_bill_pkg->hidden ) {
3049         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3050         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3051         if (exists($_->{unit_amount})) {
3052           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3053         }
3054         push @b, { %$_ }
3055           if $_->{amount} != 0
3056           || $discount_show_always
3057           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3058           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3059         ;
3060         $_ = undef;
3061       }
3062     }
3063
3064     if ( $locationnum ) {
3065       # this is a location section; skip packages that aren't at this
3066       # service location.
3067       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3068       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3069               != $locationnum;
3070     }
3071
3072     # Consider display records for this item to determine if it belongs
3073     # in this section.  Note that if there are no display records, there
3074     # will be a default pseudo-record that includes all charge types
3075     # and has no section name.
3076     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3077                                   ? $cust_bill_pkg->cust_bill_pkg_display
3078                                   : ( $cust_bill_pkg );
3079
3080     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3081          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3082       if $DEBUG > 1;
3083
3084     if ( defined($category) ) {
3085       # then this is a package category section; process all display records
3086       # that belong to this section.
3087       @cust_bill_pkg_display = grep { $_->section eq $category }
3088                                 @cust_bill_pkg_display;
3089     } else {
3090       # otherwise, process all display records that aren't usage summaries
3091       # (I don't think there should be usage summaries if you aren't using
3092       # category sections, but this is the historical behavior)
3093       @cust_bill_pkg_display = grep { !$_->summary }
3094                                 @cust_bill_pkg_display;
3095     }
3096
3097     my $classname = ''; # package class name, will fill in later
3098
3099     foreach my $display (@cust_bill_pkg_display) {
3100
3101       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3102            $display->billpkgdisplaynum. "\n"
3103         if $DEBUG > 1;
3104
3105       my $type = $display->type;
3106
3107       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3108       $desc = substr($desc, 0, $maxlength). '...'
3109         if $format eq 'latex' && length($desc) > $maxlength;
3110
3111       my %details_opt = ( 'format'          => $format,
3112                           'escape_function' => $escape_function,
3113                           'format_function' => $format_function,
3114                           'no_usage'        => $opt{'no_usage'},
3115                         );
3116
3117       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3118
3119         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3120           if $DEBUG > 1;
3121         # quotation_pkgs are never fees, so don't worry about the case where
3122         # part_pkg is undefined
3123
3124         # and I guess they're never bundled either?
3125         if ( $cust_bill_pkg->setup != 0 ) {
3126           my $description = $desc;
3127           $description .= ' Setup'
3128             if $cust_bill_pkg->recur != 0
3129             || $discount_show_always
3130             || $cust_bill_pkg->recur_show_zero;
3131           #push @b, {
3132           # keep it consistent, please
3133           $s = {
3134             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3135             'description' => $description,
3136             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3137             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3138             'quantity'    => $cust_bill_pkg->quantity,
3139             'preref_html' => ( $opt{preref_callback}
3140                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3141                                  : ''
3142                              ),
3143           };
3144         }
3145         if ( $cust_bill_pkg->recur != 0 ) {
3146           #push @b, {
3147           $r = {
3148             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3149             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3150             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3151             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3152             'quantity'    => $cust_bill_pkg->quantity,
3153            'preref_html'  => ( $opt{preref_callback}
3154                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3155                                  : ''
3156                              ),
3157           };
3158         }
3159
3160       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3161         # a "normal" package line item (not a quotation, not a fee, not a tax)
3162
3163         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3164           if $DEBUG > 1;
3165
3166         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3167         my $part_pkg = $cust_pkg->part_pkg;
3168
3169         # which pkgpart to show for display purposes?
3170         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3171
3172         # start/end dates for invoice formats that do nonstandard
3173         # things with them
3174         my %item_dates = ();
3175         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3176           unless $part_pkg->option('disable_line_item_date_ranges',1);
3177
3178         # not normally used, but pass this to the template anyway
3179         $classname = $part_pkg->classname;
3180
3181         if (    (!$type || $type eq 'S')
3182              && (    $cust_bill_pkg->setup != 0
3183                   || $cust_bill_pkg->setup_show_zero
3184                 )
3185            )
3186          {
3187
3188           warn "$me _items_cust_bill_pkg adding setup\n"
3189             if $DEBUG > 1;
3190
3191           my $description = $desc;
3192           $description .= ' Setup'
3193             if $cust_bill_pkg->recur != 0
3194             || $discount_show_always
3195             || $cust_bill_pkg->recur_show_zero;
3196
3197           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3198                                                               $self->agentnum )
3199             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3200                                      # triggered by the recurring charge freq
3201                                      # (RT#26274)
3202             && $cust_bill_pkg->recur == 0
3203             && ! $cust_bill_pkg->recur_show_zero;
3204
3205           my @d = ();
3206           my $svc_label;
3207
3208           # always pass the svc_label through to the template, even if
3209           # not displaying it as an ext_description
3210           my @svc_labels = map &{$escape_function}($_),
3211                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3212
3213           $svc_label = $svc_labels[0];
3214
3215           unless ( $cust_pkg->part_pkg->hide_svc_detail
3216                 || $cust_bill_pkg->hidden )
3217           {
3218
3219             push @d, @svc_labels
3220               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3221             my $lnum = $cust_main ? $cust_main->ship_locationnum
3222                                   : $self->prospect_main->locationnum;
3223             # show the location label if it's not the customer's default
3224             # location, and we're not grouping items by location already
3225             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3226               my $loc = $cust_pkg->location_label;
3227               $loc = substr($loc, 0, $maxlength). '...'
3228                 if $format eq 'latex' && length($loc) > $maxlength;
3229               push @d, &{$escape_function}($loc);
3230             }
3231
3232           } #unless hiding service details
3233
3234           push @d, $cust_bill_pkg->details(%details_opt)
3235             if $cust_bill_pkg->recur == 0;
3236
3237           if ( $cust_bill_pkg->hidden ) {
3238             $s->{amount}      += $cust_bill_pkg->setup;
3239             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3240             push @{ $s->{ext_description} }, @d;
3241           } else {
3242             $s = {
3243               _is_setup       => 1,
3244               description     => $description,
3245               pkgpart         => $pkgpart,
3246               pkgnum          => $cust_bill_pkg->pkgnum,
3247               amount          => $cust_bill_pkg->setup,
3248               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3249               unit_amount     => $cust_bill_pkg->unitsetup,
3250               quantity        => $cust_bill_pkg->quantity,
3251               ext_description => \@d,
3252               svc_label       => ($svc_label || ''),
3253               locationnum     => $cust_pkg->locationnum, # sure, why not?
3254             };
3255           };
3256
3257         }
3258
3259         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3260              && (
3261                      $cust_bill_pkg->recur != 0
3262                   || $cust_bill_pkg->setup == 0
3263                   || $discount_show_always
3264                   || $cust_bill_pkg->recur_show_zero
3265                 )
3266            )
3267         {
3268
3269           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3270             if $DEBUG > 1;
3271
3272           my $is_summary = $display->summary;
3273           my $description = $desc;
3274           if ( $type eq 'U' and defined($r) ) {
3275             # don't just show the same description as the recur line
3276             $description = $self->mt('Usage charges');
3277           }
3278
3279           my $part_pkg = $cust_pkg->part_pkg;
3280
3281           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3282                                                               $self->agentnum );
3283
3284           my @d = ();
3285           my @seconds = (); # for display of usage info
3286           my $svc_label = '';
3287
3288           #at least until cust_bill_pkg has "past" ranges in addition to
3289           #the "future" sdate/edate ones... see #3032
3290           my @dates = ( $self->_date );
3291           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3292           push @dates, $prev->sdate if $prev;
3293           push @dates, undef if !$prev;
3294
3295           my @svc_labels = map &{$escape_function}($_),
3296                       $cust_pkg->h_labels_short(@dates, 'I');
3297           $svc_label = $svc_labels[0];
3298
3299           # show service labels, unless...
3300                     # the package is set not to display them
3301           unless ( $part_pkg->hide_svc_detail
3302                     # or this is a tax-like line item
3303                 || $cust_bill_pkg->itemdesc
3304                     # or this is a hidden (bundled) line item
3305                 || $cust_bill_pkg->hidden
3306                     # or this is a usage summary line
3307                 || $is_summary && $type && $type eq 'U'
3308                     # or this is a usage line and there's a recurring line
3309                     # for the package in the same section (which will
3310                     # have service labels already)
3311                 || ($type eq 'U' and defined($r))
3312               )
3313           {
3314
3315             warn "$me _items_cust_bill_pkg adding service details\n"
3316               if $DEBUG > 1;
3317
3318             push @d, @svc_labels
3319               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3320             warn "$me _items_cust_bill_pkg done adding service details\n"
3321               if $DEBUG > 1;
3322
3323             my $lnum = $cust_main ? $cust_main->ship_locationnum
3324                                   : $self->prospect_main->locationnum;
3325             # show the location label if it's not the customer's default
3326             # location, and we're not grouping items by location already
3327             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3328               my $loc = $cust_pkg->location_label;
3329               $loc = substr($loc, 0, $maxlength). '...'
3330                 if $format eq 'latex' && length($loc) > $maxlength;
3331               push @d, &{$escape_function}($loc);
3332             }
3333
3334             # Display of seconds_since_sqlradacct:
3335             # On the invoice, when processing @detail_items, look for a field
3336             # named 'seconds'.  This will contain total seconds for each
3337             # service, in the same order as @ext_description.  For services
3338             # that don't support this it will show undef.
3339             if ( $conf->exists('svc_acct-usage_seconds')
3340                  and ! $cust_bill_pkg->pkgpart_override ) {
3341               foreach my $cust_svc (
3342                   $cust_pkg->h_cust_svc(@dates, 'I')
3343                 ) {
3344
3345                 # eval because not having any part_export_usage exports
3346                 # is a fatal error, last_bill/_date because that's how
3347                 # sqlradius_hour billing does it
3348                 my $sec = eval {
3349                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3350                 };
3351                 push @seconds, $sec;
3352               }
3353             } #if svc_acct-usage_seconds
3354
3355           } # if we are showing service labels
3356
3357           unless ( $is_summary ) {
3358             warn "$me _items_cust_bill_pkg adding details\n"
3359               if $DEBUG > 1;
3360
3361             #instead of omitting details entirely in this case (unwanted side
3362             # effects), just omit CDRs
3363             $details_opt{'no_usage'} = 1
3364               if $type && $type eq 'R';
3365
3366             push @d, $cust_bill_pkg->details(%details_opt);
3367           }
3368
3369           warn "$me _items_cust_bill_pkg calculating amount\n"
3370             if $DEBUG > 1;
3371
3372           my $amount = 0;
3373           if (!$type) {
3374             $amount = $cust_bill_pkg->recur;
3375           } elsif ($type eq 'R') {
3376             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3377           } elsif ($type eq 'U') {
3378             $amount = $cust_bill_pkg->usage;
3379           }
3380
3381           if ( !$type || $type eq 'R' ) {
3382
3383             warn "$me _items_cust_bill_pkg adding recur\n"
3384               if $DEBUG > 1;
3385
3386             my $unit_amount =
3387               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3388                                                 : $amount;
3389
3390             if ( $cust_bill_pkg->hidden ) {
3391               $r->{amount}      += $amount;
3392               $r->{unit_amount} += $unit_amount;
3393               push @{ $r->{ext_description} }, @d;
3394             } else {
3395               $r = {
3396                 description     => $description,
3397                 pkgpart         => $pkgpart,
3398                 pkgnum          => $cust_bill_pkg->pkgnum,
3399                 amount          => $amount,
3400                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3401                 unit_amount     => $unit_amount,
3402                 quantity        => $cust_bill_pkg->quantity,
3403                 %item_dates,
3404                 ext_description => \@d,
3405                 svc_label       => ($svc_label || ''),
3406                 locationnum     => $cust_pkg->locationnum,
3407               };
3408               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3409             }
3410
3411           } else {  # $type eq 'U'
3412
3413             warn "$me _items_cust_bill_pkg adding usage\n"
3414               if $DEBUG > 1;
3415
3416             if ( $cust_bill_pkg->hidden and defined($u) ) {
3417               # if this is a hidden package and there's already a usage
3418               # line for the bundle, add this package's total amount and
3419               # usage details to it
3420               $u->{amount}      += $amount;
3421               push @{ $u->{ext_description} }, @d;
3422             } elsif ( $amount ) {
3423               # create a new usage line
3424               $u = {
3425                 description     => $description,
3426                 pkgpart         => $pkgpart,
3427                 pkgnum          => $cust_bill_pkg->pkgnum,
3428                 amount          => $amount,
3429                 usage_item      => 1,
3430                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3431                 %item_dates,
3432                 ext_description => \@d,
3433                 locationnum     => $cust_pkg->locationnum,
3434               };
3435             } # else this has no usage, so don't create a usage section
3436           }
3437
3438         } # recurring or usage with recurring charge
3439
3440       } else { # taxes and fees
3441
3442         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3443           if $DEBUG > 1;
3444
3445         # items of this kind should normally not have sdate/edate.
3446         push @b, {
3447           'description' => $desc,
3448           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3449                                            + $cust_bill_pkg->recur)
3450         };
3451
3452       } # if quotation / package line item / other line item
3453
3454       # decide whether to show active discounts here
3455       if (
3456           # case 1: we are showing a single line for the package
3457           ( !$type )
3458           # case 2: we are showing a setup line for a package that has
3459           # no base recurring fee
3460           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3461           # case 3: we are showing a recur line for a package that has
3462           # a base recurring fee
3463           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3464       ) {
3465
3466         my $item_discount = $cust_bill_pkg->_item_discount;
3467         if ( $item_discount ) {
3468           # $item_discount->{amount} is negative
3469
3470           if ( $d and $cust_bill_pkg->hidden ) {
3471             $d->{amount}      += $item_discount->{amount};
3472           } else {
3473             $d = $item_discount;
3474             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3475           }
3476
3477           # update the active line (before the discount) to show the
3478           # original price (whether this is a hidden line or not)
3479           #
3480           # quotation discounts keep track of setup and recur; invoice
3481           # discounts currently don't
3482           if ( exists $item_discount->{setup_amount} ) {
3483
3484             $s->{amount} -= $item_discount->{setup_amount} if $s;
3485             $r->{amount} -= $item_discount->{recur_amount} if $r;
3486
3487           } else {
3488
3489             # $active_line is the line item hashref for the line that will
3490             # show the original price
3491             # (use the recur or single line for the package, unless we're
3492             # showing a setup line for a package with no recurring fee)
3493             my $active_line = $r;
3494             if ( $type eq 'S' ) {
3495               $active_line = $s;
3496             }
3497             $active_line->{amount} -= $item_discount->{amount};
3498
3499           }
3500
3501         } # if there are any discounts
3502       } # if this is an appropriate place to show discounts
3503
3504     } # foreach $display
3505
3506     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3507                                 && $conf->exists('discount-show-always'));
3508
3509   }
3510
3511   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3512     if ( $_  ) {
3513       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3514         if exists($_->{amount});
3515       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3516       if (exists($_->{unit_amount})) {
3517         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3518       }
3519
3520       push @b, { %$_ }
3521         if $_->{amount} != 0
3522         || $discount_show_always
3523         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3524         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3525     }
3526   }
3527
3528   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3529     if $DEBUG > 1;
3530
3531   @b;
3532
3533 }
3534
3535 =item _items_discounts_avail
3536
3537 Returns an array of line item hashrefs representing available term discounts
3538 for this invoice.  This makes the same assumptions that apply to term
3539 discounts in general: that the package is billed monthly, at a flat rate,
3540 with no usage charges.  A prorated first month will be handled, as will
3541 a setup fee if the discount is allowed to apply to setup fees.
3542
3543 =cut
3544
3545 sub _items_discounts_avail {
3546   my $self = shift;
3547
3548   #maybe move this method from cust_bill when quotations support discount_plans
3549   return () unless $self->can('discount_plans');
3550   my %plans = $self->discount_plans;
3551
3552   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3553   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3554
3555   map {
3556     my $months = $_;
3557     my $plan = $plans{$months};
3558
3559     my $term_total = sprintf('%.2f', $plan->discounted_total);
3560     my $percent = sprintf('%.0f',
3561                           100 * (1 - $term_total / $plan->base_total) );
3562     my $permonth = sprintf('%.2f', $term_total / $months);
3563     my $detail = $self->mt('discount on item'). ' '.
3564                  join(', ', map { "#$_" } $plan->pkgnums)
3565       if $list_pkgnums;
3566
3567     # discounts for non-integer months don't work anyway
3568     $months = sprintf("%d", $months);
3569
3570     +{
3571       description => $self->mt('Save [_1]% by paying for [_2] months',
3572                                 $percent, $months),
3573       amount      => $self->mt('[_1] ([_2] per month)',
3574                                 $term_total, $money_char.$permonth),
3575       ext_description => ($detail || ''),
3576     }
3577   } #map
3578   sort { $b <=> $a } keys %plans;
3579
3580 }
3581
3582 1;