FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319
 320   my $locale = $params{'locale'} || $cust_main->locale;
 321
 322   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 323                      'html'     => [ '<%=', '%>' ],
 324                      'template' => [ '{', '}' ],
 325                    );
 326
 327   warn "$me print_generic creating template\n"
 328     if $DEBUG > 1;
 329
 330   # set the notice name here, and nowhere else.
 331   my $notice_name =  $params{notice_name}
 332                   || $conf->config('notice_name')
 333                   || $self->notice_name;
 334
 335   #create the template
 336   my $template = $params{template} ? $params{template} : $self->_agent_template;
 337   my $templatefile = $self->template_conf. $format;
 338   $templatefile .= "_$template"
 339     if length($template) && $conf->exists($templatefile."_$template");
 340
 341   # the base template
 342   my @invoice_template = map "$_\n", $conf->config($templatefile)
 343     or die "cannot load config data $templatefile";
 344
 345   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 346     #change this to a die when the old code is removed
 347     # it's been almost ten years, changing it to a die
 348     die "old-style invoice template $templatefile; ".
 349          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 350          #$old_latex = 'true';
 351          #@invoice_template = _translate_old_latex_format(@invoice_template);
 352   }
 353
 354   warn "$me print_generic creating T:T object\n"
 355     if $DEBUG > 1;
 356
 357   my $text_template = new Text::Template(
 358     TYPE => 'ARRAY',
 359     SOURCE => \@invoice_template,
 360     DELIMITERS => $delimiters{$format},
 361   );
 362
 363   warn "$me print_generic compiling T:T object\n"
 364     if $DEBUG > 1;
 365
 366   $text_template->compile()
 367     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 368
 369
 370   # additional substitution could possibly cause breakage in existing templates
 371   my %convert_maps = (
 372     'latex' => {
 373                  'notes'         => sub { map "$_", @_ },
 374                  'footer'        => sub { map "$_", @_ },
 375                  'smallfooter'   => sub { map "$_", @_ },
 376                  'returnaddress' => sub { map "$_", @_ },
 377                  'coupon'        => sub { map "$_", @_ },
 378                  'summary'       => sub { map "$_", @_ },
 379                },
 380     'html'  => {
 381                  'notes' =>
 382                    sub {
 383                      map {
 384                        s/%%(.*)$/<!-- $1 -->/g;
 385                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 386                        s/\\begin\{enumerate\}/<ol>/g;
 387                        s/\\item /  <li>/g;
 388                        s/\\end\{enumerate\}/<\/ol>/g;
 389                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 390                        s/\\\\\*/<br>/g;
 391                        s/\\dollar ?/\$/g;
 392                        s/\\#/#/g;
 393                        s/~/&nbsp;/g;
 394                        $_;
 395                      }  @_
 396                    },
 397                  'footer' =>
 398                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 399                  'smallfooter' =>
 400                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 401                  'returnaddress' =>
 402                    sub {
 403                      map {
 404                        s/~/&nbsp;/g;
 405                        s/\\\\\*?\s*$/<BR>/;
 406                        s/\\hyphenation\{[\w\s\-]+}//;
 407                        s/\\([&])/$1/g;
 408                        $_;
 409                      }  @_
 410                    },
 411                  'coupon'        => sub { "" },
 412                  'summary'       => sub { "" },
 413                },
 414     'template' => {
 415                  'notes' =>
 416                    sub {
 417                      map {
 418                        s/%%.*$//g;
 419                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 420                        s/\\begin\{enumerate\}//g;
 421                        s/\\item /  * /g;
 422                        s/\\end\{enumerate\}//g;
 423                        s/\\textbf\{(.*)\}/$1/g;
 424                        s/\\\\\*/ /;
 425                        s/\\dollar ?/\$/g;
 426                        $_;
 427                      }  @_
 428                    },
 429                  'footer' =>
 430                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 431                  'smallfooter' =>
 432                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 433                  'returnaddress' =>
 434                    sub {
 435                      map {
 436                        s/~/ /g;
 437                        s/\\\\\*?\s*$/\n/;             # dubious
 438                        s/\\hyphenation\{[\w\s\-]+}//;
 439                        $_;
 440                      }  @_
 441                    },
 442                  'coupon'        => sub { "" },
 443                  'summary'       => sub { "" },
 444                },
 445   );
 446
 447
 448   # hashes for differing output formats
 449   my %nbsps = ( 'latex'    => '~',
 450                 'html'     => '',    # '&nbps;' would be nice
 451                 'template' => '',    # not used
 452               );
 453   my $nbsp = $nbsps{$format};
 454
 455   my %escape_functions = ( 'latex'    => \&_latex_escape,
 456                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 457                            'template' => sub { shift },
 458                          );
 459   my $escape_function = $escape_functions{$format};
 460   my $escape_function_nonbsp = ($format eq 'html')
 461                                  ? \&_html_escape : $escape_function;
 462
 463   my %newline_tokens = (  'latex'     => '\\\\',
 464                           'html'      => '<br>',
 465                           'template'  => "\n",
 466                         );
 467   my $newline_token = $newline_tokens{$format};
 468
 469   warn "$me generating template variables\n"
 470     if $DEBUG > 1;
 471
 472   # generate template variables
 473   my $returnaddress;
 474
 475   if (
 476          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 477                                         $template
 478                                       )
 479                 )
 480        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 481                                         $template
 482                                       )
 483                 )
 484   ) {
 485
 486     $returnaddress = join("\n",
 487       $conf->config_orbase("invoice_${format}returnaddress", $template)
 488     );
 489
 490   } elsif ( grep /\S/,
 491             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 492
 493     my $convert_map = $convert_maps{$format}{'returnaddress'};
 494     $returnaddress =
 495       join( "\n",
 496             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 497                                                  $template
 498                                                )
 499                          )
 500           );
 501   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 502
 503     my $convert_map = $convert_maps{$format}{'returnaddress'};
 504     $returnaddress = join( "\n", &$convert_map(
 505                                    map { s/( {2,})/'~' x length($1)/eg;
 506                                          s/$/\\\\\*/;
 507                                          $_
 508                                        }
 509                                      ( $conf->config('company_name', $cust_main->agentnum),
 510                                        $conf->config('company_address', $cust_main->agentnum),
 511                                      )
 512                                  )
 513                      );
 514
 515   } else {
 516
 517     my $warning = "Couldn't find a return address; ".
 518                   "do you need to set the company_address configuration value?";
 519     warn "$warning\n";
 520     $returnaddress = $nbsp;
 521     #$returnaddress = $warning;
 522
 523   }
 524
 525   warn "$me generating invoice data\n"
 526     if $DEBUG > 1;
 527
 528   my $agentnum = $cust_main->agentnum;
 529
 530   my %invoice_data = (
 531
 532     #invoice from info
 533     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 534     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 535     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 536     'returnaddress'   => $returnaddress,
 537     'agent'           => &$escape_function($cust_main->agent->agent),
 538
 539     #invoice/quotation info
 540     'no_number'       => $params{'no_number'},
 541     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 542     'quotationnum'    => $self->quotationnum,
 543     'no_date'         => $params{'no_date'},
 544     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 545       # workaround for inconsistent behavior in the early plain text
 546       # templates; see RT#28271
 547     'date'            => ( $params{'no_date'}
 548                              ? ''
 549                              : ($format eq 'template'
 550                                ? $self->_date
 551                                : $self->time2str_local('long', $self->_date, $format)
 552                                )
 553                          ),
 554     'today'           => $self->time2str_local('long', $today, $format),
 555     'terms'           => $self->terms,
 556     'template'        => $template, #params{'template'},
 557     'notice_name'     => $notice_name, # escape?
 558     'current_charges' => sprintf("%.2f", $self->charged),
 559     'duedate'         => $self->due_date2str('rdate'), #date_format?
 560
 561     #customer info
 562     'custnum'         => $cust_main->display_custnum,
 563     'prospectnum'     => $cust_main->prospectnum,
 564     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 565     ( map { $_ => &$escape_function($cust_main->$_()) }
 566         qw( company address1 address2 city state zip fax )
 567     ),
 568     'payname'         => &$escape_function( $cust_main->invoice_attn
 569                                              || $cust_main->contact_firstlast ),
 570
 571     #global config
 572     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 573     'unitprices'      => $conf->exists('invoice-unitprice'),
 574     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 575     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 576     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 577
 578     #layout info -- would be fancy to calc some of this and bury the template
 579     #               here in the code
 580     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 581     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 582     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 583     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 584     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 585     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 586     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 587     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 588     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 589     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 590
 591     # better hang on to conf_dir for a while (for old templates)
 592     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 593
 594     #these are only used when doing paged plaintext
 595     'page'            => 1,
 596     'total_pages'     => 1,
 597
 598   );
 599
 600   #localization
 601   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 602   # prototype here to silence warnings
 603   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 604
 605   my $min_sdate = 999999999999;
 606   my $max_edate = 0;
 607   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 608     next unless $cust_bill_pkg->pkgnum > 0;
 609     $min_sdate = $cust_bill_pkg->sdate
 610       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 611     $max_edate = $cust_bill_pkg->edate
 612       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 613   }
 614
 615   $invoice_data{'bill_period'} = '';
 616   $invoice_data{'bill_period'} =
 617       $self->time2str_local('%e %h', $min_sdate, $format)
 618       . " to " .
 619       $self->time2str_local('%e %h', $max_edate, $format)
 620     if ($max_edate != 0 && $min_sdate != 999999999999);
 621
 622   $invoice_data{finance_section} = '';
 623   if ( $conf->config('finance_pkgclass') ) {
 624     my $pkg_class =
 625       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 626     $invoice_data{finance_section} = $pkg_class->categoryname;
 627   }
 628   $invoice_data{finance_amount} = '0.00';
 629   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 630
 631   my $countrydefault = $conf->config('countrydefault') || 'US';
 632   foreach ( qw( address1 address2 city state zip country fax) ){
 633     my $method = 'ship_'.$_;
 634     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 635   }
 636   if ( length($cust_main->ship_company) ) {
 637     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 638   } else {
 639     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 640   }
 641   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 642   $invoice_data{'ship_country'} = ''
 643     if ( $invoice_data{'ship_country'} eq $countrydefault );
 644
 645   $invoice_data{'cid'} = $params{'cid'}
 646     if $params{'cid'};
 647
 648   if ( $cust_main->country eq $countrydefault ) {
 649     $invoice_data{'country'} = '';
 650   } else {
 651     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 652   }
 653
 654   my @address = ();
 655   $invoice_data{'address'} = \@address;
 656   push @address,
 657     $invoice_data{'payname'}.
 658       ( $cust_main->po_number
 659           ? " (P.O. #". $cust_main->po_number. ")"
 660           : ''
 661       )
 662   ;
 663   push @address, $cust_main->company
 664     if $cust_main->company;
 665   push @address, $cust_main->address1;
 666   push @address, $cust_main->address2
 667     if $cust_main->address2;
 668   push @address,
 669     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 670   push @address, $invoice_data{'country'}
 671     if $invoice_data{'country'};
 672   push @address, ''
 673     while (scalar(@address) < 5);
 674
 675   $invoice_data{'logo_file'} = $params{'logo_file'}
 676     if $params{'logo_file'};
 677   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 678     if $params{'barcode_file'};
 679   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 680     if $params{'barcode_img'};
 681   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 682     if $params{'barcode_cid'};
 683
 684   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 685 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 686   #my $balance_due = $self->owed + $pr_total - $cr_total;
 687   my $balance_due = $self->owed + $pr_total;
 688
 689   # the sum of amount owed on all invoices
 690   # (this is used in the summary & on the payment coupon)
 691   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 692
 693   # flag telling this invoice to have a first-page summary
 694   my $summarypage = '';
 695
 696   if ( $self->custnum && $self->invnum ) {
 697     # XXX should be an FS::cust_bill method to set the defaults, instead
 698     # of checking the type here
 699
 700     my $last_bill = $self->previous_bill;
 701     if ( $last_bill ) {
 702
 703       # "balance_date_range" unfortunately is unsuitable for this, since it
 704       # cares about application dates.  We want to know the sum of all
 705       # _top-level transactions_ dated before the last invoice.
 706       my @sql =
 707         map "$_ WHERE _date <= ? AND custnum = ?", (
 708           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 709           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 710           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 711           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 712         );
 713
 714       # the customer's current balance immediately after generating the last
 715       # bill
 716
 717       my $last_bill_balance = $last_bill->charged;
 718       foreach (@sql) {
 719         my $delta = FS::Record->scalar_sql(
 720           $_,
 721           $last_bill->_date - 1,
 722           $self->custnum,
 723         );
 724         $last_bill_balance += $delta;
 725       }
 726
 727       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 728
 729       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 730         $last_bill->invnum,
 731         $self->time2str_local('%D', $last_bill->_date),
 732         $last_bill_balance
 733       ) if $DEBUG > 0;
 734       # ("true_previous_balance" is a terrible name, but at least it's no
 735       # longer stored in the database)
 736       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 737
 738       # the change in balance from immediately after that invoice
 739       # to immediately before this one
 740       my $before_this_bill_balance = 0;
 741       foreach (@sql) {
 742         my $delta = FS::Record->scalar_sql(
 743           $_,
 744           $self->_date - 1,
 745           $self->custnum,
 746         );
 747         $before_this_bill_balance += $delta;
 748       }
 749       $invoice_data{'balance_adjustments'} =
 750         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 751
 752       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 753                    $invoice_data{'balance_adjustments'}
 754       ) if $DEBUG > 0;
 755
 756       # the sum of amount owed on all previous invoices
 757       # ($pr_total is used elsewhere but not as $previous_balance)
 758       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 759
 760       $invoice_data{'last_bill'} = {
 761         '_date'     => $last_bill->_date, #unformatted
 762       };
 763       my (@payments, @credits);
 764       # for formats that itemize previous payments
 765       foreach my $cust_pay ( qsearch('cust_pay', {
 766                               'custnum' => $self->custnum,
 767                               '_date'   => { op => '>=',
 768                                              value => $last_bill->_date }
 769                              } ) )
 770       {
 771         next if $cust_pay->_date > $self->_date;
 772         push @payments, {
 773             '_date'       => $cust_pay->_date,
 774             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 775             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 776             'amount'      => sprintf('%.2f', $cust_pay->paid),
 777         };
 778         # not concerned about applications
 779       }
 780       foreach my $cust_credit ( qsearch('cust_credit', {
 781                               'custnum' => $self->custnum,
 782                               '_date'   => { op => '>=',
 783                                              value => $last_bill->_date }
 784                              } ) )
 785       {
 786         next if $cust_credit->_date > $self->_date;
 787         push @credits, {
 788             '_date'       => $cust_credit->_date,
 789             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 790             'creditreason'=> $cust_credit->reason,
 791             'amount'      => sprintf('%.2f', $cust_credit->amount),
 792         };
 793       }
 794       $invoice_data{'previous_payments'} = \@payments;
 795       $invoice_data{'previous_credits'}  = \@credits;
 796     } else {
 797       # there is no $last_bill
 798       $invoice_data{'true_previous_balance'} =
 799       $invoice_data{'balance_adjustments'}   =
 800       $invoice_data{'previous_balance'}      = '0.00';
 801       $invoice_data{'previous_payments'} = [];
 802       $invoice_data{'previous_credits'} = [];
 803     }
 804
 805     # info from customer's last invoice before this one, for some
 806     # summary formats
 807     $invoice_data{'last_bill'} = {};
 808
 809     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 810       $invoice_data{'summarypage'} = $summarypage = 1;
 811     }
 812
 813   } # if this is an invoice
 814
 815   warn "$me substituting variables in notes, footer, smallfooter\n"
 816     if $DEBUG > 1;
 817
 818   my $tc = $self->template_conf;
 819   my @include = ( [ $tc,        'notes' ],
 820                   [ 'invoice_', 'footer' ],
 821                   [ 'invoice_', 'smallfooter', ],
 822                 );
 823   push @include, [ $tc,        'coupon', ]
 824     unless $params{'no_coupon'};
 825
 826   foreach my $i (@include) {
 827
 828     my($base, $include) = @$i;
 829
 830     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 831     my @inc_src;
 832
 833     if ( $conf->exists($inc_file, $agentnum)
 834          && length( $conf->config($inc_file, $agentnum) ) ) {
 835
 836       @inc_src = $conf->config($inc_file, $agentnum);
 837
 838     } else {
 839
 840       $inc_file = $conf->key_orbase("${base}latex$include", $template);
 841
 842       my $convert_map = $convert_maps{$format}{$include};
 843
 844       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
 845                        s/--\@\]/$delimiters{$format}[1]/g;
 846                        $_;
 847                      }
 848                  &$convert_map( $conf->config($inc_file, $agentnum) );
 849
 850     }
 851
 852     my $inc_tt = new Text::Template (
 853       TYPE       => 'ARRAY',
 854       SOURCE     => [ map "$_\n", @inc_src ],
 855       DELIMITERS => $delimiters{$format},
 856     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 857
 858     unless ( $inc_tt->compile() ) {
 859       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 860       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 861       die $error;
 862     }
 863
 864     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 865
 866     $invoice_data{$include} =~ s/\n+$//
 867       if ($format eq 'latex');
 868   }
 869
 870   # let invoices use either of these as needed
 871   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 872     ? $cust_main->payinfo : '';
 873   $invoice_data{'po_line'} =
 874     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 875       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 876       : $nbsp;
 877
 878   my %money_chars = ( 'latex'    => '',
 879                       'html'     => $conf->config('money_char') || '$',
 880                       'template' => '',
 881                     );
 882   my $money_char = $money_chars{$format};
 883
 884   # extremely dubious
 885   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 886                             'html'     => $conf->config('money_char') || '$',
 887                             'template' => '',
 888                           );
 889   my $other_money_char = $other_money_chars{$format};
 890   $invoice_data{'dollar'} = $other_money_char;
 891
 892   my %minus_signs = ( 'latex'    => '$-$',
 893                       'html'     => '&minus;',
 894                       'template' => '- ' );
 895   my $minus = $minus_signs{$format};
 896
 897   my @detail_items = ();
 898   my @total_items = ();
 899   my @buf = ();
 900   my @sections = ();
 901
 902   $invoice_data{'detail_items'} = \@detail_items;
 903   $invoice_data{'total_items'} = \@total_items;
 904   $invoice_data{'buf'} = \@buf;
 905   $invoice_data{'sections'} = \@sections;
 906
 907   warn "$me generating sections\n"
 908     if $DEBUG > 1;
 909
 910   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 911   my $multisection = $conf->exists($tc.'sections', $cust_main->agentnum) ||
 912                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 913   $invoice_data{'multisection'} = $multisection;
 914   my $late_sections;
 915   my $extra_sections = [];
 916   my $extra_lines = ();
 917
 918   # default section ('Charges')
 919   my $default_section = { 'description' => '',
 920                           'subtotal'    => '',
 921                           'no_subtotal' => 1,
 922                         };
 923
 924   # Previous Charges section
 925   # subtotal is the first return value from $self->previous
 926   my $previous_section;
 927   # if the invoice has major sections, or if we're summarizing previous
 928   # charges with a single line, or if we've been specifically told to put them
 929   # in a section, create a section for previous charges:
 930   if ( $multisection or
 931        $conf->exists('previous_balance-summary_only') or
 932        $conf->exists('previous_balance-section') ) {
 933
 934     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 935                            'subtotal'    => $other_money_char.
 936                                             sprintf('%.2f', $pr_total),
 937                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 938                          };
 939     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 940       join(' / ', map { $cust_main->balance_date_range(@$_) }
 941                   $self->_prior_month30s
 942           )
 943       if $conf->exists('invoice_include_aging');
 944
 945   } else {
 946     # otherwise put them in the main section
 947     $previous_section = $default_section;
 948   }
 949
 950   my $adjust_section = {
 951     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 952     'adjust_section' => 1,
 953     'subtotal'       => 0,   # adjusted below
 954   };
 955   my $adjust_weight = _pkg_category($adjust_section->{description})
 956                         ? _pkg_category($adjust_section->{description})->weight
 957                         : 0;
 958   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 959   # Note: 'sort_weight' here is actually a flag telling whether there is an
 960   # explicit package category for the adjust section. If so, certain behavior
 961   # happens.
 962   $adjust_section->{'sort_weight'} = $adjust_weight;
 963
 964
 965   if ( $multisection ) {
 966     ($extra_sections, $extra_lines) =
 967       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 968       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 969       && $self->can('_items_extra_usage_sections');
 970
 971     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 972
 973     push @detail_items, @$extra_lines if $extra_lines;
 974
 975     # the code is written so that both methods can be used together, but
 976     # we haven't yet changed the template to take advantage of that, so for
 977     # now, treat them as mutually exclusive.
 978     my %section_method = ( by_category => 1 );
 979     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 980       %section_method = ( by_location => 1 );
 981     }
 982     my ($early, $late) =
 983       $self->_items_sections( 'summary' => $summarypage,
 984                               'escape'  => $escape_function_nonbsp,
 985                               'extra_sections' => $extra_sections,
 986                               'format'  => $format,
 987                               %section_method
 988                             );
 989     push @sections, @$early;
 990     $late_sections = $late;
 991
 992     if (    $conf->exists('svc_phone_sections')
 993          && $self->can('_items_svc_phone_sections')
 994        )
 995     {
 996       my ($phone_sections, $phone_lines) =
 997         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
 998       push @{$late_sections}, @$phone_sections;
 999       push @detail_items, @$phone_lines;
1000     }
1001     if ( $conf->exists('voip-cust_accountcode_cdr')
1002          && $cust_main->accountcode_cdr
1003          && $self->can('_items_accountcode_cdr')
1004        )
1005     {
1006       my ($accountcode_section, $accountcode_lines) =
1007         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1008       if ( scalar(@$accountcode_lines) ) {
1009           push @{$late_sections}, $accountcode_section;
1010           push @detail_items, @$accountcode_lines;
1011       }
1012     }
1013   } else {# not multisection
1014     # make a default section
1015     push @sections, $default_section;
1016     # and calculate the finance charge total, since it won't get done otherwise.
1017     # and the default section total
1018     # XXX possibly finance_pkgclass should not be used in this manner?
1019     my @finance_charges;
1020     my @charges;
1021     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1022       if ( $invoice_data{finance_section} and
1023         grep { $_->section eq $invoice_data{finance_section} }
1024            $cust_bill_pkg->cust_bill_pkg_display ) {
1025         # I think these are always setup fees, but just to be sure...
1026         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1027       } else {
1028         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1029       }
1030     }
1031     $invoice_data{finance_amount} =
1032       sprintf('%.2f', sum( @finance_charges ) || 0);
1033     $default_section->{subtotal} = $other_money_char.
1034                                     sprintf('%.2f', sum( @charges ) || 0);
1035   }
1036
1037   # start setting up summary subtotals
1038   my @summary_subtotals;
1039   my $method = $conf->config('summary_subtotals_method');
1040   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1041     # then re-section them by the correct method
1042     my %section_method = ( by_category => 1 );
1043     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1044       %section_method = ( by_location => 1 );
1045     }
1046     my ($early, $late) =
1047       $self->_items_sections( 'summary' => $summarypage,
1048                               'escape'  => $escape_function_nonbsp,
1049                               'extra_sections' => $extra_sections,
1050                               'format'  => $format,
1051                               %section_method
1052                             );
1053     foreach ( @$early ) {
1054       next if $_->{subtotal} == 0;
1055       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1056       push @summary_subtotals, $_;
1057     }
1058   } else {
1059     # subtotal sectioning is the same as for the actual invoice sections
1060     @summary_subtotals = @sections;
1061   }
1062
1063   # Hereafter, push sections to both @sections and @summary_subtotals
1064   # if they belong in both places (e.g. tax section).  Late sections are
1065   # never in @summary_subtotals.
1066
1067   # previous invoice balances in the Previous Charges section if there
1068   # is one, otherwise in the main detail section
1069   # (except if summary_only is enabled, don't show them at all)
1070   if ( $self->can('_items_previous') &&
1071        $self->enable_previous &&
1072        ! $conf->exists('previous_balance-summary_only') ) {
1073
1074     warn "$me adding previous balances\n"
1075       if $DEBUG > 1;
1076
1077     foreach my $line_item ( $self->_items_previous ) {
1078
1079       my $detail = {
1080         ref             => $line_item->{'pkgnum'},
1081         pkgpart         => $line_item->{'pkgpart'},
1082         #quantity        => 1, # not really correct
1083         section         => $previous_section, # which might be $default_section
1084         description     => &$escape_function($line_item->{'description'}),
1085         ext_description => [ map { &$escape_function($_) }
1086                              @{ $line_item->{'ext_description'} || [] }
1087                            ],
1088         amount          => $money_char . $line_item->{'amount'},
1089         product_code    => $line_item->{'pkgpart'} || 'N/A',
1090       };
1091
1092       push @detail_items, $detail;
1093       push @buf, [ $detail->{'description'},
1094                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1095                  ];
1096     }
1097
1098   }
1099
1100   if ( @pr_cust_bill && $self->enable_previous ) {
1101     push @buf, ['','-----------'];
1102     push @buf, [ $self->mt('Total Previous Balance'),
1103                  $money_char. sprintf("%10.2f", $pr_total) ];
1104     push @buf, ['',''];
1105   }
1106
1107   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1108       warn "$me adding DID summary\n"
1109         if $DEBUG > 1;
1110
1111       my ($didsummary,$minutes) = $self->_did_summary;
1112       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1113       push @detail_items,
1114        { 'description' => $didsummary_desc,
1115            'ext_description' => [ $didsummary, $minutes ],
1116        };
1117   }
1118
1119   foreach my $section (@sections, @$late_sections) {
1120
1121     # begin some normalization
1122     $section->{'subtotal'} = $section->{'amount'}
1123       if $multisection
1124          && !exists($section->{subtotal})
1125          && exists($section->{amount});
1126
1127     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1128       if ( $invoice_data{finance_section} &&
1129            $section->{'description'} eq $invoice_data{finance_section} );
1130
1131     $section->{'subtotal'} = $other_money_char.
1132                              sprintf('%.2f', $section->{'subtotal'})
1133       if $multisection;
1134
1135     # continue some normalization
1136     $section->{'amount'}   = $section->{'subtotal'}
1137       if $multisection;
1138
1139
1140     if ( $section->{'description'} ) {
1141       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1142                    [ '', '' ],
1143                  );
1144     }
1145
1146     warn "$me   setting options\n"
1147       if $DEBUG > 1;
1148
1149     my %options = ();
1150     $options{'section'} = $section if $multisection;
1151     $options{'format'} = $format;
1152     $options{'escape_function'} = $escape_function;
1153     $options{'no_usage'} = 1 unless $unsquelched;
1154     $options{'unsquelched'} = $unsquelched;
1155     $options{'summary_page'} = $summarypage;
1156     $options{'skip_usage'} =
1157       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1158     $options{'preref_callback'} = $params{'preref_callback'};
1159
1160     warn "$me   searching for line items\n"
1161       if $DEBUG > 1;
1162
1163     foreach my $line_item ( $self->_items_pkg(%options),
1164                             $self->_items_fee(%options) ) {
1165
1166       warn "$me     adding line item ".
1167            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1168         if $DEBUG > 1;
1169
1170       push @buf, ( [ $line_item->{'description'},
1171                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1172                    ],
1173                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1174                  );
1175
1176       $line_item->{'ref'} = $line_item->{'pkgnum'};
1177       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1178       $line_item->{'section'} = $section;
1179       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1180       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1181
1182       if ( length($line_item->{'unit_amount'}) ) {
1183         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1184       }
1185       $line_item->{'ext_description'} ||= [];
1186
1187       push @detail_items, $line_item;
1188     }
1189
1190     if ( $section->{'description'} ) {
1191       push @buf, ( ['','-----------'],
1192                    [ $section->{'description'}. ' sub-total',
1193                       $section->{'subtotal'} # already formatted this
1194                    ],
1195                    [ '', '' ],
1196                    [ '', '' ],
1197                  );
1198     }
1199
1200   }
1201
1202   $invoice_data{current_less_finance} =
1203     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1204
1205   # if there's anything in the Previous Charges section, prepend it to the list
1206   if ( $pr_total and $previous_section ne $default_section ) {
1207     unshift @sections, $previous_section;
1208     # but not @summary_subtotals
1209   }
1210
1211   warn "$me adding taxes\n"
1212     if $DEBUG > 1;
1213
1214   # create a tax section if we don't yet have one
1215   my $tax_description = 'Taxes, Surcharges, and Fees';
1216   my $tax_section =
1217     List::Util::first { $_->{description} eq $tax_description } @sections;
1218   if (!$tax_section) {
1219     $tax_section = { 'description' => $tax_description };
1220     push @sections, $tax_section if $multisection;
1221   }
1222   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1223   # if this is an existing tax section, we're merging the tax items into it.
1224   # grab the taxtotal that's already there, strip the money symbol if any
1225   my $taxtotal = $tax_section->{'subtotal'} || 0;
1226   $taxtotal =~ s/^\Q$other_money_char\E//;
1227
1228   # this does nothing
1229   #my $tax_weight = _pkg_category($tax_section->{description})
1230   #                      ? _pkg_category($tax_section->{description})->weight
1231   #                      : 0;
1232   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1233   #$tax_section->{'sort_weight'} = $tax_weight;
1234
1235   my @items_tax = $self->_items_tax;
1236   foreach my $tax ( @items_tax ) {
1237
1238     $taxtotal += $tax->{'amount'};
1239
1240     my $description = &$escape_function( $tax->{'description'} );
1241     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1242
1243     if ( $multisection ) {
1244
1245       push @detail_items, {
1246         ext_description => [],
1247         ref          => '',
1248         quantity     => '',
1249         description  => $description,
1250         amount       => $money_char. $amount,
1251         product_code => '',
1252         section      => $tax_section,
1253       };
1254
1255     } else {
1256
1257       push @total_items, {
1258         'total_item'   => $description,
1259         'total_amount' => $other_money_char. $amount,
1260       };
1261
1262     }
1263
1264     push @buf,[ $description,
1265                 $money_char. $amount,
1266               ];
1267
1268   }
1269
1270   if ( @items_tax ) {
1271     my $total = {};
1272     $total->{'total_item'} = $self->mt('Sub-total');
1273     $total->{'total_amount'} =
1274       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1275
1276     if ( $multisection ) {
1277       if ( $taxtotal > 0 ) {
1278         $tax_section->{'subtotal'} = $other_money_char.
1279                                      sprintf('%.2f', $taxtotal);
1280         $tax_section->{'pretotal'} = 'New charges sub-total '.
1281                                      $total->{'total_amount'};
1282         $tax_section->{'description'} = $self->mt($tax_description);
1283
1284         # append it if it's not already there
1285         if ( !grep $tax_section, @sections ) {
1286           push @sections, $tax_section;
1287           push @summary_subtotals, $tax_section;
1288         }
1289       }
1290
1291     } else {
1292       unshift @total_items, $total;
1293     }
1294   }
1295   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1296
1297   push @buf,['','-----------'];
1298   push @buf,[$self->mt(
1299               (!$self->enable_previous)
1300                ? 'Total Charges'
1301                : 'Total New Charges'
1302              ),
1303              $money_char. sprintf("%10.2f",$self->charged) ];
1304   push @buf,['',''];
1305
1306   ###
1307   # Totals
1308   ###
1309
1310   my %embolden_functions = (
1311     'latex'    => sub { return '\textbf{'. shift(). '}' },
1312     'html'     => sub { return '<b>'. shift(). '</b>' },
1313     'template' => sub { shift },
1314   );
1315   my $embolden_function = $embolden_functions{$format};
1316
1317   if ( $self->can('_items_total') ) { # quotations
1318
1319     my @new_total_items = $self->_items_total;
1320
1321     foreach ( @new_total_items ) {
1322       $_->{'total_item'}   = &$embolden_function( $_->{'total_item'} );
1323       $_->{'total_amount'} = &$embolden_function( $other_money_char.$_->{'total_amount'});
1324       push @total_items, $_;
1325     }
1326
1327   } else { #normal invoice case
1328
1329     # calculate total, possibly including total owed on previous
1330     # invoices
1331     my $total = {};
1332     my $item = 'Total';
1333     $item = $conf->config('previous_balance-exclude_from_total')
1334          || 'Total New Charges'
1335       if $conf->exists('previous_balance-exclude_from_total');
1336     my $amount = $self->charged;
1337     if ( $self->enable_previous and !$conf->exists('previous_balance-exclude_from_total') ) {
1338       $amount += $pr_total;
1339     }
1340
1341     $total->{'total_item'} = &$embolden_function($self->mt($item));
1342     $total->{'total_amount'} =
1343       &$embolden_function( $other_money_char.  sprintf( '%.2f', $amount ) );
1344     if ( $multisection ) {
1345       if ( $adjust_section->{'sort_weight'} ) {
1346         $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1347           $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1348       } else {
1349         $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1350           $other_money_char.  sprintf('%.2f', $self->charged );
1351       }
1352     } else {
1353       push @total_items, $total;
1354     }
1355     push @buf,['','-----------'];
1356     push @buf,[$item,
1357                $money_char.
1358                sprintf( '%10.2f', $amount )
1359               ];
1360     push @buf,['',''];
1361
1362     # if we're showing previous invoices, also show previous
1363     # credits and payments
1364     if ( $self->enable_previous
1365           and $self->can('_items_credits')
1366           and $self->can('_items_payments') )
1367       {
1368       #foreach my $thing ( sort { $a->_date <=> $b->_date } $self->_items_credits, $self->_items_payments
1369
1370       # credits
1371       my $credittotal = 0;
1372       foreach my $credit (
1373         $self->_items_credits( 'template' => $template, 'trim_len' => 60 )
1374       ) {
1375
1376         my $total;
1377         $total->{'total_item'} = &$escape_function($credit->{'description'});
1378         $credittotal += $credit->{'amount'};
1379         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1380         if ( $multisection ) {
1381           push @detail_items, {
1382             ext_description => [],
1383             ref          => '',
1384             quantity     => '',
1385             description  => &$escape_function($credit->{'description'}),
1386             amount       => $money_char . $credit->{'amount'},
1387             product_code => '',
1388             section      => $adjust_section,
1389           };
1390         } else {
1391           push @total_items, $total;
1392         }
1393
1394       }
1395       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1396
1397       #credits (again)
1398       foreach my $credit (
1399         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1400       ) {
1401         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1402       }
1403
1404       # payments
1405       my $paymenttotal = 0;
1406       foreach my $payment (
1407         $self->_items_payments( 'template' => $template )
1408       ) {
1409         my $total = {};
1410         $total->{'total_item'} = &$escape_function($payment->{'description'});
1411         $paymenttotal += $payment->{'amount'};
1412         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1413         if ( $multisection ) {
1414           push @detail_items, {
1415             ext_description => [],
1416             ref          => '',
1417             quantity     => '',
1418             description  => &$escape_function($payment->{'description'}),
1419             amount       => $money_char . $payment->{'amount'},
1420             product_code => '',
1421             section      => $adjust_section,
1422           };
1423         }else{
1424           push @total_items, $total;
1425         }
1426         push @buf, [ $payment->{'description'},
1427                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1428                    ];
1429       }
1430       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1431
1432       if ( $multisection ) {
1433         $adjust_section->{'subtotal'} = $other_money_char.
1434                                         sprintf('%.2f', $credittotal + $paymenttotal);
1435
1436         #why this? because {sort_weight} forces the adjust_section to appear
1437         #in @extra_sections instead of @sections. obviously.
1438         push @sections, $adjust_section
1439           unless $adjust_section->{sort_weight};
1440         # do not summarize; adjustments there are shown according to
1441         # different rules
1442       }
1443
1444       # create Balance Due message
1445       {
1446         my $total;
1447         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1448         $total->{'total_amount'} =
1449           &$embolden_function(
1450             $other_money_char. sprintf('%.2f', #why? $summarypage
1451                                                #  ? $self->charged +
1452                                                #    $self->billing_balance
1453                                                #  :
1454                                                    $self->owed + $pr_total
1455                                       )
1456           );
1457         if ( $multisection && !$adjust_section->{sort_weight} ) {
1458           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1459                                            $total->{'total_amount'};
1460         }else{
1461           push @total_items, $total;
1462         }
1463         push @buf,['','-----------'];
1464         push @buf,[$self->balance_due_msg, $money_char.
1465           sprintf("%10.2f", $balance_due ) ];
1466       }
1467
1468       if ( $conf->exists('previous_balance-show_credit')
1469           and $cust_main->balance < 0 ) {
1470         my $credit_total = {
1471           'total_item'    => &$embolden_function($self->credit_balance_msg),
1472           'total_amount'  => &$embolden_function(
1473             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1474           ),
1475         };
1476         if ( $multisection ) {
1477           $adjust_section->{'posttotal'} .= $newline_token .
1478             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1479         }
1480         else {
1481           push @total_items, $credit_total;
1482         }
1483         push @buf,['','-----------'];
1484         push @buf,[$self->credit_balance_msg, $money_char.
1485           sprintf("%10.2f", -$cust_main->balance ) ];
1486       }
1487     }
1488
1489   } #end of default total adding ! can('_items_total')
1490
1491   if ( $multisection ) {
1492     if (    $conf->exists('svc_phone_sections')
1493          && $self->can('_items_svc_phone_sections')
1494        )
1495     {
1496       my $total;
1497       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1498       $total->{'total_amount'} =
1499         &$embolden_function(
1500           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1501         );
1502       my $last_section = pop @sections;
1503       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1504                                      $total->{'total_amount'};
1505       push @sections, $last_section;
1506     }
1507     push @sections, @$late_sections
1508       if $unsquelched;
1509   }
1510
1511   # make a discounts-available section, even without multisection
1512   if ( $conf->exists('discount-show_available')
1513        and my @discounts_avail = $self->_items_discounts_avail ) {
1514     my $discount_section = {
1515       'description' => $self->mt('Discounts Available'),
1516       'subtotal'    => '',
1517       'no_subtotal' => 1,
1518     };
1519
1520     push @sections, $discount_section; # do not summarize
1521     push @detail_items, map { +{
1522         'ref'         => '', #should this be something else?
1523         'section'     => $discount_section,
1524         'description' => &$escape_function( $_->{description} ),
1525         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1526         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1527     } } @discounts_avail;
1528   }
1529
1530   # not adding any more sections after this
1531   $invoice_data{summary_subtotals} = \@summary_subtotals;
1532
1533   # usage subtotals
1534   if ( $conf->exists('usage_class_summary')
1535        and $self->can('_items_usage_class_summary') ) {
1536     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1537     if ( @usage_subtotals ) {
1538       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1539       unshift @detail_items, @usage_subtotals;
1540     }
1541   }
1542
1543   # invoice history "section" (not really a section)
1544   # not to be included in any subtotals, completely independent of
1545   # everything...
1546   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1547     my %history;
1548     my %monthorder;
1549     foreach my $cust_bill ( $cust_main->cust_bill ) {
1550       # XXX hardcoded format, and currently only 'charged'; add other fields
1551       # if they become necessary
1552       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1553       $history{$date} ||= 0;
1554       $history{$date} += $cust_bill->charged;
1555       # just so we have a numeric sort key
1556       $monthorder{$date} ||= $cust_bill->_date;
1557     }
1558     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1559                         keys %history;
1560     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1561     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1562   }
1563
1564   # service locations: another option for template customization
1565   my %location_info;
1566   foreach my $item (@detail_items) {
1567     if ( $item->{locationnum} ) {
1568       $location_info{ $item->{locationnum} } ||= {
1569         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1570       };
1571     }
1572   }
1573   $invoice_data{location_info} = \%location_info;
1574
1575   # debugging hook: call this with 'diag' => 1 to just get a hash of
1576   # the invoice variables
1577   return \%invoice_data if ( $params{'diag'} );
1578
1579   # All sections and items are built; now fill in templates.
1580   my @includelist = ();
1581   push @includelist, 'summary' if $summarypage;
1582   foreach my $include ( @includelist ) {
1583
1584     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1585     my @inc_src;
1586
1587     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1588
1589       @inc_src = $conf->config($inc_file, $agentnum);
1590
1591     } else {
1592
1593       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1594
1595       my $convert_map = $convert_maps{$format}{$include};
1596
1597       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1598                        s/--\@\]/$delimiters{$format}[1]/g;
1599                        $_;
1600                      }
1601                  &$convert_map( $conf->config($inc_file, $agentnum) );
1602
1603     }
1604
1605     my $inc_tt = new Text::Template (
1606       TYPE       => 'ARRAY',
1607       SOURCE     => [ map "$_\n", @inc_src ],
1608       DELIMITERS => $delimiters{$format},
1609     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1610
1611     unless ( $inc_tt->compile() ) {
1612       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1613       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1614       die $error;
1615     }
1616
1617     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1618
1619     $invoice_data{$include} =~ s/\n+$//
1620       if ($format eq 'latex');
1621   }
1622
1623   $invoice_lines = 0;
1624   my $wasfunc = 0;
1625   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1626     /invoice_lines\((\d*)\)/;
1627     $invoice_lines += $1 || scalar(@buf);
1628     $wasfunc=1;
1629   }
1630   die "no invoice_lines() functions in template?"
1631     if ( $format eq 'template' && !$wasfunc );
1632
1633   if ($format eq 'template') {
1634
1635     if ( $invoice_lines ) {
1636       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1637       $invoice_data{'total_pages'}++
1638         if scalar(@buf) % $invoice_lines;
1639     }
1640
1641     #setup subroutine for the template
1642     $invoice_data{invoice_lines} = sub {
1643       my $lines = shift || scalar(@buf);
1644       map {
1645         scalar(@buf)
1646           ? shift @buf
1647           : [ '', '' ];
1648       }
1649       ( 1 .. $lines );
1650     };
1651
1652     my $lines;
1653     my @collect;
1654     while (@buf) {
1655       push @collect, split("\n",
1656         $text_template->fill_in( HASH => \%invoice_data )
1657       );
1658       $invoice_data{'page'}++;
1659     }
1660     map "$_\n", @collect;
1661
1662   } else { # this is where we actually create the invoice
1663
1664     warn "filling in template for invoice ". $self->invnum. "\n"
1665       if $DEBUG;
1666     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1667       if $DEBUG > 1;
1668
1669     $text_template->fill_in(HASH => \%invoice_data);
1670   }
1671 }
1672
1673 sub notice_name { '('.shift->table.')'; }
1674
1675 sub template_conf { 'invoice_'; }
1676
1677 # helper routine for generating date ranges
1678 sub _prior_month30s {
1679   my $self = shift;
1680   my @ranges = (
1681    [ 1,       2592000 ], # 0-30 days ago
1682    [ 2592000, 5184000 ], # 30-60 days ago
1683    [ 5184000, 7776000 ], # 60-90 days ago
1684    [ 7776000, 0       ], # 90+   days ago
1685   );
1686
1687   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1688           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1689       ] }
1690   @ranges;
1691 }
1692
1693 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1694
1695 Returns an postscript invoice, as a scalar.
1696
1697 Options can be passed as a hashref (recommended) or as a list of time, template
1698 and then any key/value pairs for any other options.
1699
1700 I<time> an optional value used to control the printing of overdue messages.  The
1701 default is now.  It isn't the date of the invoice; that's the `_date' field.
1702 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1703 L<Time::Local> and L<Date::Parse> for conversion functions.
1704
1705 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1706
1707 =cut
1708
1709 sub print_ps {
1710   my $self = shift;
1711
1712   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1713   my $ps = generate_ps($file);
1714   unlink($logofile);
1715   unlink($barcodefile) if $barcodefile;
1716
1717   $ps;
1718 }
1719
1720 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1721
1722 Returns an PDF invoice, as a scalar.
1723
1724 Options can be passed as a hashref (recommended) or as a list of time, template
1725 and then any key/value pairs for any other options.
1726
1727 I<time> an optional value used to control the printing of overdue messages.  The
1728 default is now.  It isn't the date of the invoice; that's the `_date' field.
1729 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1730 L<Time::Local> and L<Date::Parse> for conversion functions.
1731
1732 I<template>, if specified, is the name of a suffix for alternate invoices.
1733
1734 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1735
1736 =cut
1737
1738 sub print_pdf {
1739   my $self = shift;
1740
1741   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1742   my $pdf = generate_pdf($file);
1743   unlink($logofile);
1744   unlink($barcodefile) if $barcodefile;
1745
1746   $pdf;
1747 }
1748
1749 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1750
1751 Returns an HTML invoice, as a scalar.
1752
1753 I<time> an optional value used to control the printing of overdue messages.  The
1754 default is now.  It isn't the date of the invoice; that's the `_date' field.
1755 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1756 L<Time::Local> and L<Date::Parse> for conversion functions.
1757
1758 I<template>, if specified, is the name of a suffix for alternate invoices.
1759
1760 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1761
1762 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1763 when emailing the invoice as part of a multipart/related MIME email.
1764
1765 =cut
1766
1767 sub print_html {
1768   my $self = shift;
1769   my %params;
1770   if ( ref($_[0]) ) {
1771     %params = %{ shift() };
1772   } else {
1773     %params = @_;
1774   }
1775   $params{'format'} = 'html';
1776
1777   $self->print_generic( %params );
1778 }
1779
1780 # quick subroutine for print_latex
1781 #
1782 # There are ten characters that LaTeX treats as special characters, which
1783 # means that they do not simply typeset themselves:
1784 #      # $ % & ~ _ ^ \ { }
1785 #
1786 # TeX ignores blanks following an escaped character; if you want a blank (as
1787 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1788
1789 sub _latex_escape {
1790   my $value = shift;
1791   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1792   $value =~ s/([<>])/\$$1\$/g;
1793   $value;
1794 }
1795
1796 sub _html_escape {
1797   my $value = shift;
1798   encode_entities($value);
1799   $value;
1800 }
1801
1802 sub _html_escape_nbsp {
1803   my $value = _html_escape(shift);
1804   $value =~ s/ +/&nbsp;/g;
1805   $value;
1806 }
1807
1808 #utility methods for print_*
1809
1810 sub _translate_old_latex_format {
1811   warn "_translate_old_latex_format called\n"
1812     if $DEBUG;
1813
1814   my @template = ();
1815   while ( @_ ) {
1816     my $line = shift;
1817
1818     if ( $line =~ /^%%Detail\s*$/ ) {
1819
1820       push @template, q![@--!,
1821                       q!  foreach my $_tr_line (@detail_items) {!,
1822                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1823                       q!      $_tr_line->{'description'} .= !,
1824                       q!        "\\tabularnewline\n~~".!,
1825                       q!        join( "\\tabularnewline\n~~",!,
1826                       q!          @{$_tr_line->{'ext_description'}}!,
1827                       q!        );!,
1828                       q!    }!;
1829
1830       while ( ( my $line_item_line = shift )
1831               !~ /^%%EndDetail\s*$/                            ) {
1832         $line_item_line =~ s/'/\\'/g;    # nice LTS
1833         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1834         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1835         push @template, "    \$OUT .= '$line_item_line';";
1836       }
1837
1838       push @template, '}',
1839                       '--@]';
1840       #' doh, gvim
1841     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1842
1843       push @template, '[@--',
1844                       '  foreach my $_tr_line (@total_items) {';
1845
1846       while ( ( my $total_item_line = shift )
1847               !~ /^%%EndTotalDetails\s*$/                      ) {
1848         $total_item_line =~ s/'/\\'/g;    # nice LTS
1849         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1850         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1851         push @template, "    \$OUT .= '$total_item_line';";
1852       }
1853
1854       push @template, '}',
1855                       '--@]';
1856
1857     } else {
1858       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1859       push @template, $line;
1860     }
1861
1862   }
1863
1864   if ($DEBUG) {
1865     warn "$_\n" foreach @template;
1866   }
1867
1868   (@template);
1869 }
1870
1871 =item terms
1872
1873 =cut
1874
1875 sub terms {
1876   my $self = shift;
1877   my $conf = $self->conf;
1878
1879   #check for an invoice-specific override
1880   return $self->invoice_terms if $self->invoice_terms;
1881
1882   #check for a customer- specific override
1883   my $cust_main = $self->cust_main;
1884   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1885
1886   my $agentnum = '';
1887   if ( $cust_main ) {
1888     $agentnum = $cust_main->agentnum;
1889   } elsif ( my $prospect_main = $self->prospect_main ) {
1890     $agentnum = $prospect_main->agentnum;
1891   }
1892
1893   #use configured default
1894   $conf->config('invoice_default_terms', $agentnum) || '';
1895 }
1896
1897 =item due_date
1898
1899 =cut
1900
1901 sub due_date {
1902   my $self = shift;
1903   my $duedate = '';
1904   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1905     $duedate = $self->_date() + ( $1 * 86400 );
1906   }
1907   $duedate;
1908 }
1909
1910 =item due_date2str
1911
1912 =cut
1913
1914 sub due_date2str {
1915   my $self = shift;
1916   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1917 }
1918
1919 =item balance_due_msg
1920
1921 =cut
1922
1923 sub balance_due_msg {
1924   my $self = shift;
1925   my $msg = $self->mt('Balance Due');
1926   return $msg unless $self->terms;
1927   if ( $self->due_date ) {
1928     $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1929       $self->due_date2str('short');
1930   } elsif ( $self->terms ) {
1931     $msg .= ' - '. $self->terms;
1932   }
1933   $msg;
1934 }
1935
1936 =item balance_due_date
1937
1938 =cut
1939
1940 sub balance_due_date {
1941   my $self = shift;
1942   my $conf = $self->conf;
1943   my $duedate = '';
1944   my $terms = $self->terms;
1945   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1946     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1947   }
1948   $duedate;
1949 }
1950
1951 sub credit_balance_msg {
1952   my $self = shift;
1953   $self->mt('Credit Balance Remaining')
1954 }
1955
1956 =item _date_pretty
1957
1958 Returns a string with the date, for example: "3/20/2008", localized for the
1959 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1960
1961 =cut
1962
1963 sub _date_pretty {
1964   my $self = shift;
1965   $self->time2str_local('short', $self->_date);
1966 }
1967
1968 =item _date_pretty_unlocalized
1969
1970 Returns a string with the date, for example: "3/20/2008", in the format
1971 configured for the back-office.  Use _date_pretty for end-customer display use.
1972
1973 =cut
1974
1975 sub _date_pretty_unlocalized {
1976   my $self = shift;
1977   time2str($date_format, $self->_date);
1978 }
1979
1980 =item email HASHREF
1981
1982 Emails this template.
1983
1984 Options are passed as a hashref.  Available options:
1985
1986 =over 4
1987
1988 =item from
1989
1990 If specified, overrides the default From: address.
1991
1992 =item notice_name
1993
1994 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1995
1996 =item template
1997
1998 (Deprecated) If specified, is the name of a suffix for alternate template files.
1999
2000 =back
2001
2002 Options accepted by generate_email can also be used.
2003
2004 =cut
2005
2006 sub email {
2007   my $self = shift;
2008   my $opt = shift || {};
2009   if ($opt and !ref($opt)) {
2010     die ref($self). '->email called with positional parameters';
2011   }
2012
2013   return if $self->hide;
2014
2015   my $error = send_email(
2016     $self->generate_email(
2017       'subject'     => $self->email_subject($opt->{template}),
2018       %$opt, # template, etc.
2019     )
2020   );
2021
2022   die "can't email: $error\n" if $error;
2023 }
2024
2025 =item generate_email OPTION => VALUE ...
2026
2027 Options:
2028
2029 =over 4
2030
2031 =item from
2032
2033 sender address, required
2034
2035 =item template
2036
2037 alternate template name, optional
2038
2039 =item subject
2040
2041 email subject, optional
2042
2043 =item notice_name
2044
2045 notice name instead of "Invoice", optional
2046
2047 =back
2048
2049 Returns an argument list to be passed to L<FS::Misc::send_email>.
2050
2051 =cut
2052
2053 use MIME::Entity;
2054
2055 sub generate_email {
2056
2057   my $self = shift;
2058   my %args = @_;
2059   my $conf = $self->conf;
2060
2061   my $me = '[FS::Template_Mixin::generate_email]';
2062
2063   my %return = (
2064     'from'      => $args{'from'},
2065     'subject'   => ($args{'subject'} || $self->email_subject),
2066     'custnum'   => $self->custnum,
2067     'msgtype'   => 'invoice',
2068   );
2069
2070   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2071
2072   my $cust_main = $self->cust_main;
2073
2074   if (ref($args{'to'}) eq 'ARRAY') {
2075     $return{'to'} = $args{'to'};
2076   } elsif ( $cust_main ) {
2077     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2078   }
2079
2080   my $tc = $self->template_conf;
2081
2082   my @text; # array of lines
2083   my $html; # a big string
2084   my @related_parts; # will contain the text/HTML alternative, and images
2085   my $related; # will contain the multipart/related object
2086
2087   if ( $conf->exists($tc. 'email_pdf') ) {
2088     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2089
2090       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2091         if $DEBUG;
2092
2093       my $msg_template = FS::msg_template->by_key($msgnum)
2094         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2095       my %prepared = $msg_template->prepare(
2096         cust_main => $self->cust_main,
2097         object    => $self
2098       );
2099
2100       @text = split(/(?=\n)/, $prepared{'text_body'});
2101       $html = $prepared{'html_body'};
2102
2103     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2104
2105       warn "$me using '${tc}email_pdf_note' in multipart message"
2106         if $DEBUG;
2107       @text = $conf->config($tc.'email_pdf_note');
2108       $html = join('<BR>', @text);
2109
2110     } # else use the plain text invoice
2111   }
2112
2113   if (!@text) {
2114
2115     warn "$me generating plain text invoice"
2116       if $DEBUG;
2117
2118     # 'print_text' argument is no longer used
2119     @text = $self->print_text(\%args);
2120
2121   }
2122
2123   my $text_part = build MIME::Entity (
2124     'Type'        => 'text/plain',
2125     'Encoding'    => 'quoted-printable',
2126     'Charset'     => 'UTF-8',
2127     #'Encoding'    => '7bit',
2128     'Data'        => \@text,
2129     'Disposition' => 'inline',
2130   );
2131
2132   if (!$html) {
2133
2134     if ( $conf->exists($tc.'html') ) {
2135       warn "$me generating HTML invoice"
2136         if $DEBUG;
2137
2138       $args{'from'} =~ /\@([\w\.\-]+)/;
2139       my $from = $1 || 'example.com';
2140       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2141
2142       my $logo;
2143       my $agentnum = $cust_main ? $cust_main->agentnum
2144                                 : $self->prospect_main->agentnum;
2145       if ( defined($args{'template'}) && length($args{'template'})
2146            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2147          )
2148       {
2149         $logo = 'logo_'. $args{'template'}. '.png';
2150       } else {
2151         $logo = "logo.png";
2152       }
2153       my $image_data = $conf->config_binary( $logo, $agentnum);
2154
2155       push @related_parts, build MIME::Entity
2156         'Type'       => 'image/png',
2157         'Encoding'   => 'base64',
2158         'Data'       => $image_data,
2159         'Filename'   => 'logo.png',
2160         'Content-ID' => "<$content_id>",
2161       ;
2162
2163       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2164         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2165         push @related_parts, build MIME::Entity
2166           'Type'       => 'image/png',
2167           'Encoding'   => 'base64',
2168           'Data'       => $self->invoice_barcode(0),
2169           'Filename'   => 'barcode.png',
2170           'Content-ID' => "<$barcode_content_id>",
2171         ;
2172         $args{'barcode_cid'} = $barcode_content_id;
2173       }
2174
2175       $html = $self->print_html({ 'cid'=>$content_id, %args });
2176     }
2177
2178   }
2179
2180   if ( $html ) {
2181
2182     warn "$me creating HTML/text multipart message"
2183       if $DEBUG;
2184
2185     $return{'nobody'} = 1;
2186
2187     my $alternative = build MIME::Entity
2188       'Type'        => 'multipart/alternative',
2189       #'Encoding'    => '7bit',
2190       'Disposition' => 'inline'
2191     ;
2192
2193     if ( @text ) {
2194       $alternative->add_part($text_part);
2195     }
2196
2197     $alternative->attach(
2198       'Type'        => 'text/html',
2199       'Encoding'    => 'quoted-printable',
2200       'Data'        => [ '<html>',
2201                          '  <head>',
2202                          '    <title>',
2203                          '      '. encode_entities($return{'subject'}),
2204                          '    </title>',
2205                          '  </head>',
2206                          '  <body bgcolor="#e8e8e8">',
2207                          $html,
2208                          '  </body>',
2209                          '</html>',
2210                        ],
2211       'Disposition' => 'inline',
2212       #'Filename'    => 'invoice.pdf',
2213     );
2214
2215     unshift @related_parts, $alternative;
2216
2217     $related = build MIME::Entity 'Type'     => 'multipart/related',
2218                                   'Encoding' => '7bit';
2219
2220     #false laziness w/Misc::send_email
2221     $related->head->replace('Content-type',
2222       $related->mime_type.
2223       '; boundary="'. $related->head->multipart_boundary. '"'.
2224       '; type=multipart/alternative'
2225     );
2226
2227     $related->add_part($_) foreach @related_parts;
2228
2229   }
2230
2231   my @otherparts = ();
2232   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2233
2234     push @otherparts, build MIME::Entity
2235       'Type'        => 'text/csv',
2236       'Encoding'    => '7bit',
2237       'Data'        => [ map { "$_\n" }
2238                            $self->call_details('prepend_billed_number' => 1)
2239                        ],
2240       'Disposition' => 'attachment',
2241       'Filename'    => 'usage-'. $self->invnum. '.csv',
2242     ;
2243
2244   }
2245
2246   if ( $conf->exists($tc.'email_pdf') ) {
2247
2248     #attaching pdf too:
2249     # multipart/mixed
2250     #   multipart/related
2251     #     multipart/alternative
2252     #       text/plain
2253     #       text/html
2254     #     image/png
2255     #   application/pdf
2256
2257     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2258     push @otherparts, $pdf;
2259   }
2260
2261   if (@otherparts) {
2262     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2263     if ( $html ) {
2264       $return{'mimeparts'} = [ $related, @otherparts ];
2265       $return{'type'} = 'multipart/related'; # of the first part
2266     } else {
2267       $return{'mimeparts'} = [ $text_part, @otherparts ];
2268       $return{'type'} = 'text/plain';
2269     }
2270   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2271     $return{'mimeparts'} = \@related_parts;
2272     $return{'content-type'} = 'multipart/related';
2273     $return{'type'} = 'multipart/alternative';
2274   } else { # no HTML either
2275     $return{'body'} = \@text;
2276     $return{'content-type'} = 'text/plain';
2277   }
2278
2279   %return;
2280
2281 }
2282
2283 =item mimebuild_pdf
2284
2285 Returns a list suitable for passing to MIME::Entity->build(), representing
2286 this invoice as PDF attachment.
2287
2288 =cut
2289
2290 sub mimebuild_pdf {
2291   my $self = shift;
2292   (
2293     'Type'        => 'application/pdf',
2294     'Encoding'    => 'base64',
2295     'Data'        => [ $self->print_pdf(@_) ],
2296     'Disposition' => 'attachment',
2297     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2298   );
2299 }
2300
2301 =item _items_sections OPTIONS
2302
2303 Generate section information for all items appearing on this invoice.
2304 This will only be called for multi-section invoices.
2305
2306 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2307 related display records (L<FS::cust_bill_pkg_display>) and organize
2308 them into two groups ("early" and "late" according to whether they come
2309 before or after the total), then into sections.  A subtotal is calculated
2310 for each section.
2311
2312 Section descriptions are returned in sort weight order.  Each consists
2313 of a hash containing:
2314
2315 description: the package category name, escaped
2316 subtotal: the total charges in that section
2317 tax_section: a flag indicating that the section contains only tax charges
2318 summarized: same as tax_section, for some reason
2319 sort_weight: the package category's sort weight
2320
2321 If 'condense' is set on the display record, it also contains everything
2322 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2323 coderefs to generate parts of the invoice.  This is not advised.
2324
2325 The method returns two arrayrefs, one of "early" sections and one of "late"
2326 sections.
2327
2328 OPTIONS may include:
2329
2330 by_location: a flag to divide the invoice into sections by location.
2331 Each section hash will have a 'location' element containing a hashref of
2332 the location fields (see L<FS::cust_location>).  The section description
2333 will be the location label, but the template can use any of the location
2334 fields to create a suitable label.
2335
2336 by_category: a flag to divide the invoice into sections using display
2337 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2338 behavior.  Each section hash will have a 'category' element containing
2339 the section name from the display record (which probably equals the
2340 category name of the package, but may not in some cases).
2341
2342 summary: a flag indicating that this is a summary-format invoice.
2343 Turning this on has the following effects:
2344 - Ignores display items with the 'summary' flag.
2345 - Places all sections in the "early" group even if they have post_total.
2346 - Creates sections for all non-disabled package categories, even if they
2347 have no charges on this invoice, as well as a section with no name.
2348
2349 escape: an escape function to use for section titles.
2350
2351 extra_sections: an arrayref of additional sections to return after the
2352 sorted list.  If there are any of these, section subtotals exclude
2353 usage charges.
2354
2355 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2356 passed through to C<_condense_section()>.
2357
2358 =cut
2359
2360 use vars qw(%pkg_category_cache);
2361 sub _items_sections {
2362   my $self = shift;
2363   my %opt = @_;
2364
2365   my $escape = $opt{escape};
2366   my @extra_sections = @{ $opt{extra_sections} || [] };
2367
2368   # $subtotal{$locationnum}{$categoryname} = amount.
2369   # if we're not using by_location, $locationnum is undef.
2370   # if we're not using by_category, you guessed it, $categoryname is undef.
2371   # if we're not using either one, we shouldn't be here in the first place...
2372   my %subtotal = ();
2373   my %late_subtotal = ();
2374   my %not_tax = ();
2375
2376   # About tax items + multisection invoices:
2377   # If either invoice_*summary option is enabled, AND there is a
2378   # package category with the name of the tax, then there will be
2379   # a display record assigning the tax item to that category.
2380   #
2381   # However, the taxes are always placed in the "Taxes, Surcharges,
2382   # and Fees" section regardless of that.  The only effect of the
2383   # display record is to create a subtotal for the summary page.
2384
2385   # cache these
2386   my $pkg_hash = $self->cust_pkg_hash;
2387
2388   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2389   {
2390
2391       my $usage = $cust_bill_pkg->usage;
2392
2393       my $locationnum;
2394       if ( $opt{by_location} ) {
2395         if ( $cust_bill_pkg->pkgnum ) {
2396           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2397         } else {
2398           $locationnum = '';
2399         }
2400       } else {
2401         $locationnum = undef;
2402       }
2403
2404       # as in _items_cust_pkg, if a line item has no display records,
2405       # cust_bill_pkg_display() returns a default record for it
2406
2407       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2408         next if ( $display->summary && $opt{summary} );
2409
2410         my $section = $display->section;
2411         my $type    = $display->type;
2412         # Set $section = undef if we're sectioning by location and this
2413         # line item _has_ a location (i.e. isn't a fee).
2414         $section = undef if $locationnum;
2415
2416         # set this flag if the section is not tax-only
2417         $not_tax{$locationnum}{$section} = 1
2418           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2419
2420         # there's actually a very important piece of logic buried in here:
2421         # incrementing $late_subtotal{$section} CREATES
2422         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2423         # to define the list of late sections, and likewise keys(%subtotal).
2424         # When _items_cust_bill_pkg is called to generate line items for
2425         # real, it will be called with 'section' => $section for each
2426         # of these.
2427         if ( $display->post_total && !$opt{summary} ) {
2428           if (! $type || $type eq 'S') {
2429             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2430               if $cust_bill_pkg->setup != 0
2431               || $cust_bill_pkg->setup_show_zero;
2432           }
2433
2434           if (! $type) {
2435             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2436               if $cust_bill_pkg->recur != 0
2437               || $cust_bill_pkg->recur_show_zero;
2438           }
2439
2440           if ($type && $type eq 'R') {
2441             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2442               if $cust_bill_pkg->recur != 0
2443               || $cust_bill_pkg->recur_show_zero;
2444           }
2445
2446           if ($type && $type eq 'U') {
2447             $late_subtotal{$locationnum}{$section} += $usage
2448               unless scalar(@extra_sections);
2449           }
2450
2451         } else { # it's a pre-total (normal) section
2452
2453           # skip tax items unless they're explicitly included in a section
2454           next if $cust_bill_pkg->pkgnum == 0 and
2455                   ! $cust_bill_pkg->feepart   and
2456                   ! $section;
2457
2458           if ( $type eq 'S' ) {
2459             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2460               if $cust_bill_pkg->setup != 0
2461               || $cust_bill_pkg->setup_show_zero;
2462           } elsif ( $type eq 'R' ) {
2463             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2464               if $cust_bill_pkg->recur != 0
2465               || $cust_bill_pkg->recur_show_zero;
2466           } elsif ( $type eq 'U' ) {
2467             $subtotal{$locationnum}{$section} += $usage
2468               unless scalar(@extra_sections);
2469           } elsif ( !$type ) {
2470             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2471                                                + $cust_bill_pkg->recur;
2472           }
2473
2474         }
2475
2476       }
2477
2478   }
2479
2480   %pkg_category_cache = ();
2481
2482   # summary invoices need subtotals for all non-disabled package categories,
2483   # even if they're zero
2484   # but currently assume that there are no location sections, or at least
2485   # that the summary page doesn't care about them
2486   if ( $opt{summary} ) {
2487     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2488       $subtotal{''}{$category->categoryname} ||= 0;
2489     }
2490     $subtotal{''}{''} ||= 0;
2491   }
2492
2493   my @sections;
2494   foreach my $post_total (0,1) {
2495     my @these;
2496     my $s = $post_total ? \%late_subtotal : \%subtotal;
2497     foreach my $locationnum (keys %$s) {
2498       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2499         my $section = {
2500                         'subtotal'    => $s->{$locationnum}{$sectionname},
2501                         'post_total'  => $post_total,
2502                         'sort_weight' => 0,
2503                       };
2504         if ( $locationnum ) {
2505           $section->{'locationnum'} = $locationnum;
2506           my $location = FS::cust_location->by_key($locationnum);
2507           $section->{'description'} = &{ $escape }($location->location_label);
2508           # Better ideas? This will roughly group them by proximity,
2509           # which alpha sorting on any of the address fields won't.
2510           # Sorting by locationnum is meaningless.
2511           # We have to sort on _something_ or the order may change
2512           # randomly from one invoice to the next, which will confuse
2513           # people.
2514           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2515                                       $locationnum;
2516           $section->{'location'} = {
2517             label_prefix => &{ $escape }($location->label_prefix),
2518             map { $_ => &{ $escape }($location->get($_)) }
2519               $location->fields
2520           };
2521         } else {
2522           $section->{'category'} = $sectionname;
2523           $section->{'description'} = &{ $escape }($sectionname);
2524           if ( _pkg_category($sectionname) ) {
2525             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2526             if ( _pkg_category($sectionname)->condense ) {
2527               $section = { %$section, $self->_condense_section($opt{format}) };
2528             }
2529           }
2530         }
2531         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2532           # then it's a tax-only section
2533           $section->{'summarized'} = 'Y';
2534           $section->{'tax_section'} = 'Y';
2535         }
2536         push @these, $section;
2537       } # foreach $sectionname
2538     } #foreach $locationnum
2539     push @these, @extra_sections if $post_total == 0;
2540     # need an alpha sort for location sections, because postal codes can
2541     # be non-numeric
2542     $sections[ $post_total ] = [ sort {
2543       $opt{'by_location'} ?
2544         ($a->{sort_weight} cmp $b->{sort_weight}) :
2545         ($a->{sort_weight} <=> $b->{sort_weight})
2546       } @these ];
2547   } #foreach $post_total
2548
2549   return @sections; # early, late
2550 }
2551
2552 #helper subs for above
2553
2554 sub cust_pkg_hash {
2555   my $self = shift;
2556   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2557 }
2558
2559 sub _pkg_category {
2560   my $categoryname = shift;
2561   $pkg_category_cache{$categoryname} ||=
2562     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2563 }
2564
2565 my %condensed_format = (
2566   'label' => [ qw( Description Qty Amount ) ],
2567   'fields' => [
2568                 sub { shift->{description} },
2569                 sub { shift->{quantity} },
2570                 sub { my($href, %opt) = @_;
2571                       ($opt{dollar} || ''). $href->{amount};
2572                     },
2573               ],
2574   'align'  => [ qw( l r r ) ],
2575   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2576   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2577 );
2578
2579 sub _condense_section {
2580   my ( $self, $format ) = ( shift, shift );
2581   ( 'condensed' => 1,
2582     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2583       qw( description_generator
2584           header_generator
2585           total_generator
2586           total_line_generator
2587         )
2588   );
2589 }
2590
2591 sub _condensed_generator_defaults {
2592   my ( $self, $format ) = ( shift, shift );
2593   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2594 }
2595
2596 my %html_align = (
2597   'c' => 'center',
2598   'l' => 'left',
2599   'r' => 'right',
2600 );
2601
2602 sub _condensed_header_generator {
2603   my ( $self, $format ) = ( shift, shift );
2604
2605   my ( $f, $prefix, $suffix, $separator, $column ) =
2606     _condensed_generator_defaults($format);
2607
2608   if ($format eq 'latex') {
2609     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2610     $suffix = "\\\\\n\\hline";
2611     $separator = "&\n";
2612     $column =
2613       sub { my ($d,$a,$s,$w) = @_;
2614             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2615           };
2616   } elsif ( $format eq 'html' ) {
2617     $prefix = '<th></th>';
2618     $suffix = '';
2619     $separator = '';
2620     $column =
2621       sub { my ($d,$a,$s,$w) = @_;
2622             return qq!<th align="$html_align{$a}">$d</th>!;
2623       };
2624   }
2625
2626   sub {
2627     my @args = @_;
2628     my @result = ();
2629
2630     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2631       push @result,
2632         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2633     }
2634
2635     $prefix. join($separator, @result). $suffix;
2636   };
2637
2638 }
2639
2640 sub _condensed_description_generator {
2641   my ( $self, $format ) = ( shift, shift );
2642
2643   my ( $f, $prefix, $suffix, $separator, $column ) =
2644     _condensed_generator_defaults($format);
2645
2646   my $money_char = '$';
2647   if ($format eq 'latex') {
2648     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2649     $suffix = '\\\\';
2650     $separator = " & \n";
2651     $column =
2652       sub { my ($d,$a,$s,$w) = @_;
2653             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2654           };
2655     $money_char = '\\dollar';
2656   }elsif ( $format eq 'html' ) {
2657     $prefix = '"><td align="center"></td>';
2658     $suffix = '';
2659     $separator = '';
2660     $column =
2661       sub { my ($d,$a,$s,$w) = @_;
2662             return qq!<td align="$html_align{$a}">$d</td>!;
2663       };
2664     #$money_char = $conf->config('money_char') || '$';
2665     $money_char = '';  # this is madness
2666   }
2667
2668   sub {
2669     #my @args = @_;
2670     my $href = shift;
2671     my @result = ();
2672
2673     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2674       my $dollar = '';
2675       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2676       push @result,
2677         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2678                     map { $f->{$_}->[$i] } qw(align span width)
2679                   );
2680     }
2681
2682     $prefix. join( $separator, @result ). $suffix;
2683   };
2684
2685 }
2686
2687 sub _condensed_total_generator {
2688   my ( $self, $format ) = ( shift, shift );
2689
2690   my ( $f, $prefix, $suffix, $separator, $column ) =
2691     _condensed_generator_defaults($format);
2692   my $style = '';
2693
2694   if ($format eq 'latex') {
2695     $prefix = "& ";
2696     $suffix = "\\\\\n";
2697     $separator = " & \n";
2698     $column =
2699       sub { my ($d,$a,$s,$w) = @_;
2700             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2701           };
2702   }elsif ( $format eq 'html' ) {
2703     $prefix = '';
2704     $suffix = '';
2705     $separator = '';
2706     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2707     $column =
2708       sub { my ($d,$a,$s,$w) = @_;
2709             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2710       };
2711   }
2712
2713
2714   sub {
2715     my @args = @_;
2716     my @result = ();
2717
2718     #  my $r = &{$f->{fields}->[$i]}(@args);
2719     #  $r .= ' Total' unless $i;
2720
2721     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2722       push @result,
2723         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2724                     map { $f->{$_}->[$i] } qw(align span width)
2725                   );
2726     }
2727
2728     $prefix. join( $separator, @result ). $suffix;
2729   };
2730
2731 }
2732
2733 =item total_line_generator FORMAT
2734
2735 Returns a coderef used for generation of invoice total line items for this
2736 usage_class.  FORMAT is either html or latex
2737
2738 =cut
2739
2740 # should not be used: will have issues with hash element names (description vs
2741 # total_item and amount vs total_amount -- another array of functions?
2742
2743 sub _condensed_total_line_generator {
2744   my ( $self, $format ) = ( shift, shift );
2745
2746   my ( $f, $prefix, $suffix, $separator, $column ) =
2747     _condensed_generator_defaults($format);
2748   my $style = '';
2749
2750   if ($format eq 'latex') {
2751     $prefix = "& ";
2752     $suffix = "\\\\\n";
2753     $separator = " & \n";
2754     $column =
2755       sub { my ($d,$a,$s,$w) = @_;
2756             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2757           };
2758   }elsif ( $format eq 'html' ) {
2759     $prefix = '';
2760     $suffix = '';
2761     $separator = '';
2762     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2763     $column =
2764       sub { my ($d,$a,$s,$w) = @_;
2765             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2766       };
2767   }
2768
2769
2770   sub {
2771     my @args = @_;
2772     my @result = ();
2773
2774     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2775       push @result,
2776         &{$column}( &{$f->{fields}->[$i]}(@args),
2777                     map { $f->{$_}->[$i] } qw(align span width)
2778                   );
2779     }
2780
2781     $prefix. join( $separator, @result ). $suffix;
2782   };
2783
2784 }
2785
2786 =item _items_pkg [ OPTIONS ]
2787
2788 Return line item hashes for each package item on this invoice. Nearly
2789 equivalent to
2790
2791 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2792
2793 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2794 'format' and 'escape_function' at minimum.
2795
2796 To produce items for a specific invoice section, OPTIONS should include
2797 'section', a hashref containing 'category' and/or 'locationnum' keys.
2798
2799 'section' may also contain a key named 'condensed'. If this is present
2800 and has a true value, _items_pkg will try to merge identical items into items
2801 with 'quantity' equal to the number of items (not the sum of their separate
2802 quantities, for some reason).
2803
2804 =cut
2805
2806 sub _items_nontax {
2807   my $self = shift;
2808   # The order of these is important.  Bundled line items will be merged into
2809   # the most recent non-hidden item, so it needs to be the one with:
2810   # - the same pkgnum
2811   # - the same start date
2812   # - no pkgpart_override
2813   #
2814   # So: sort by pkgnum,
2815   # then by sdate
2816   # then sort the base line item before any overrides
2817   # then sort hidden before non-hidden add-ons
2818   # then sort by override pkgpart (for consistency)
2819   sort { $a->pkgnum <=> $b->pkgnum        or
2820          $a->sdate  <=> $b->sdate         or
2821          ($a->pkgpart_override ? 0 : -1)  or
2822          ($b->pkgpart_override ? 0 : 1)   or
2823          $b->hidden cmp $a->hidden        or
2824          $a->pkgpart_override <=> $b->pkgpart_override
2825        }
2826   # and of course exclude taxes and fees
2827   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2828 }
2829
2830 sub _items_fee {
2831   my $self = shift;
2832   my %options = @_;
2833   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2834   my $escape_function = $options{escape_function};
2835
2836   my @items;
2837   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2838     # cache this, so we don't look it up again in every section
2839     my $part_fee = $cust_bill_pkg->get('part_fee')
2840        || $cust_bill_pkg->part_fee;
2841     $cust_bill_pkg->set('part_fee', $part_fee);
2842     if (!$part_fee) {
2843       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2844       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2845       next;
2846     }
2847     if ( exists($options{section}) and exists($options{section}{category}) )
2848     {
2849       my $categoryname = $options{section}{category};
2850       # then filter for items that have that section
2851       if ( $part_fee->categoryname ne $categoryname ) {
2852         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2853         next;
2854       }
2855     } # otherwise include them all in the main section
2856     # XXX what to do when sectioning by location?
2857
2858     my @ext_desc;
2859     my %base_invnums; # invnum => invoice date
2860     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2861       if ($_->base_invnum) {
2862         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2863         my $base_date = $self->time2str_local('short', $base_bill->_date)
2864           if $base_bill;
2865         $base_invnums{$_->base_invnum} = $base_date || '';
2866       }
2867     }
2868     foreach (sort keys(%base_invnums)) {
2869       next if $_ == $self->invnum;
2870       # per convention, we must escape ext_description lines
2871       push @ext_desc,
2872         &{$escape_function}(
2873           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2874         );
2875     }
2876     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2877     # but not escape the base description line
2878
2879     push @items,
2880       { feepart     => $cust_bill_pkg->feepart,
2881         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2882         description => $desc,
2883         ext_description => \@ext_desc
2884         # sdate/edate?
2885       };
2886   }
2887   @items;
2888 }
2889
2890 sub _items_pkg {
2891   my $self = shift;
2892   my %options = @_;
2893
2894   warn "$me _items_pkg searching for all package line items\n"
2895     if $DEBUG > 1;
2896
2897   my @cust_bill_pkg = $self->_items_nontax;
2898
2899   warn "$me _items_pkg filtering line items\n"
2900     if $DEBUG > 1;
2901   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2902
2903   if ($options{section} && $options{section}->{condensed}) {
2904
2905     warn "$me _items_pkg condensing section\n"
2906       if $DEBUG > 1;
2907
2908     my %itemshash = ();
2909     local $Storable::canonical = 1;
2910     foreach ( @items ) {
2911       my $item = { %$_ };
2912       delete $item->{ref};
2913       delete $item->{ext_description};
2914       my $key = freeze($item);
2915       $itemshash{$key} ||= 0;
2916       $itemshash{$key} ++; # += $item->{quantity};
2917     }
2918     @items = sort { $a->{description} cmp $b->{description} }
2919              map { my $i = thaw($_);
2920                    $i->{quantity} = $itemshash{$_};
2921                    $i->{amount} =
2922                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2923                    $i;
2924                  }
2925              keys %itemshash;
2926   }
2927
2928   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2929     if $DEBUG > 1;
2930
2931   @items;
2932 }
2933
2934 sub _taxsort {
2935   return 0 unless $a->itemdesc cmp $b->itemdesc;
2936   return -1 if $b->itemdesc eq 'Tax';
2937   return 1 if $a->itemdesc eq 'Tax';
2938   return -1 if $b->itemdesc eq 'Other surcharges';
2939   return 1 if $a->itemdesc eq 'Other surcharges';
2940   $a->itemdesc cmp $b->itemdesc;
2941 }
2942
2943 sub _items_tax {
2944   my $self = shift;
2945   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2946     $self->cust_bill_pkg;
2947   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2948
2949   if ( $self->conf->exists('always_show_tax') ) {
2950     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2951     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2952       push @items,
2953         { 'description' => $itemdesc,
2954           'amount'      => 0.00 };
2955     }
2956   }
2957   @items;
2958 }
2959
2960 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2961
2962 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2963 list of hashrefs describing the line items they generate on the invoice.
2964
2965 OPTIONS may include:
2966
2967 format: the invoice format.
2968
2969 escape_function: the function used to escape strings.
2970
2971 DEPRECATED? (expensive, mostly unused?)
2972 format_function: the function used to format CDRs.
2973
2974 section: a hashref containing 'category' and/or 'locationnum'; if this
2975 is present, only returns line items that belong to that category and/or
2976 location (whichever is defined).
2977
2978 multisection: a flag indicating that this is a multisection invoice,
2979 which does something complicated.
2980
2981 preref_callback: coderef run for each line item, code should return HTML to be
2982 displayed before that line item (quotations only)
2983
2984 Returns a list of hashrefs, each of which may contain:
2985
2986 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2987 ext_description, which is an arrayref of detail lines to show below
2988 the package line.
2989
2990 =cut
2991
2992 sub _items_cust_bill_pkg {
2993   my $self = shift;
2994   my $conf = $self->conf;
2995   my $cust_bill_pkgs = shift;
2996   my %opt = @_;
2997
2998   my $format = $opt{format} || '';
2999   my $escape_function = $opt{escape_function} || sub { shift };
3000   my $format_function = $opt{format_function} || '';
3001   my $no_usage = $opt{no_usage} || '';
3002   my $unsquelched = $opt{unsquelched} || ''; #unused
3003   my ($section, $locationnum, $category);
3004   if ( $opt{section} ) {
3005     $category = $opt{section}->{category};
3006     $locationnum = $opt{section}->{locationnum};
3007   }
3008   my $summary_page = $opt{summary_page} || ''; #unused
3009   my $multisection = defined($category) || defined($locationnum);
3010   my $discount_show_always = 0;
3011
3012   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 50;
3013
3014   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3015                                    # and location labels
3016
3017   my @b = (); # accumulator for the line item hashes that we'll return
3018   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3019             # the 'current' line item hashes for setup, recur, usage, discount
3020   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3021   {
3022     # if the current line item is waiting to go out, and the one we're about
3023     # to start is not bundled, then push out the current one and start a new
3024     # one.
3025     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3026       if ( $_ && !$cust_bill_pkg->hidden ) {
3027         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3028         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3029         if (exists($_->{unit_amount})) {
3030           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3031         }
3032         push @b, { %$_ }
3033           if $_->{amount} != 0
3034           || $discount_show_always
3035           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3036           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3037         ;
3038         $_ = undef;
3039       }
3040     }
3041
3042     if ( $locationnum ) {
3043       # this is a location section; skip packages that aren't at this
3044       # service location.
3045       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3046       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3047               != $locationnum;
3048     }
3049
3050     # Consider display records for this item to determine if it belongs
3051     # in this section.  Note that if there are no display records, there
3052     # will be a default pseudo-record that includes all charge types
3053     # and has no section name.
3054     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3055                                   ? $cust_bill_pkg->cust_bill_pkg_display
3056                                   : ( $cust_bill_pkg );
3057
3058     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3059          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3060       if $DEBUG > 1;
3061
3062     if ( defined($category) ) {
3063       # then this is a package category section; process all display records
3064       # that belong to this section.
3065       @cust_bill_pkg_display = grep { $_->section eq $category }
3066                                 @cust_bill_pkg_display;
3067     } else {
3068       # otherwise, process all display records that aren't usage summaries
3069       # (I don't think there should be usage summaries if you aren't using
3070       # category sections, but this is the historical behavior)
3071       @cust_bill_pkg_display = grep { !$_->summary }
3072                                 @cust_bill_pkg_display;
3073     }
3074
3075     my $classname = ''; # package class name, will fill in later
3076
3077     foreach my $display (@cust_bill_pkg_display) {
3078
3079       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3080            $display->billpkgdisplaynum. "\n"
3081         if $DEBUG > 1;
3082
3083       my $type = $display->type;
3084
3085       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3086       $desc = substr($desc, 0, $maxlength). '...'
3087         if $format eq 'latex' && length($desc) > $maxlength;
3088
3089       my %details_opt = ( 'format'          => $format,
3090                           'escape_function' => $escape_function,
3091                           'format_function' => $format_function,
3092                           'no_usage'        => $opt{'no_usage'},
3093                         );
3094
3095       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3096         # XXX this should be pulled out into quotation_pkg
3097
3098         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3099           if $DEBUG > 1;
3100         # quotation_pkgs are never fees, so don't worry about the case where
3101         # part_pkg is undefined
3102
3103         # and I guess they're never bundled either?
3104         if ( $cust_bill_pkg->setup != 0 ) {
3105           my $description = $desc;
3106           $description .= ' Setup'
3107             if $cust_bill_pkg->recur != 0
3108             || $discount_show_always
3109             || $cust_bill_pkg->recur_show_zero;
3110           #push @b, {
3111           # keep it consistent, please
3112           $s = {
3113             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3114             'description' => $description,
3115             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3116             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3117             'quantity'    => $cust_bill_pkg->quantity,
3118             'preref_html' => ( $opt{preref_callback}
3119                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3120                                  : ''
3121                              ),
3122           };
3123         }
3124         if ( $cust_bill_pkg->recur != 0 ) {
3125           #push @b, {
3126           $r = {
3127             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3128             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3129             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3130             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3131             'quantity'    => $cust_bill_pkg->quantity,
3132            'preref_html'  => ( $opt{preref_callback}
3133                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3134                                  : ''
3135                              ),
3136           };
3137         }
3138
3139       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3140         # a "normal" package line item (not a quotation, not a fee, not a tax)
3141
3142         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3143           if $DEBUG > 1;
3144
3145         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3146         my $part_pkg = $cust_pkg->part_pkg;
3147
3148         # which pkgpart to show for display purposes?
3149         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3150
3151         # start/end dates for invoice formats that do nonstandard
3152         # things with them
3153         my %item_dates = ();
3154         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3155           unless $part_pkg->option('disable_line_item_date_ranges',1);
3156
3157         # not normally used, but pass this to the template anyway
3158         $classname = $part_pkg->classname;
3159
3160         if (    (!$type || $type eq 'S')
3161              && (    $cust_bill_pkg->setup != 0
3162                   || $cust_bill_pkg->setup_show_zero
3163                 )
3164            )
3165          {
3166
3167           warn "$me _items_cust_bill_pkg adding setup\n"
3168             if $DEBUG > 1;
3169
3170           my $description = $desc;
3171           $description .= ' Setup'
3172             if $cust_bill_pkg->recur != 0
3173             || $discount_show_always
3174             || $cust_bill_pkg->recur_show_zero;
3175
3176           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3177                                                               $self->agentnum )
3178             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3179                                      # triggered by the recurring charge freq
3180                                      # (RT#26274)
3181             && $cust_bill_pkg->recur == 0
3182             && ! $cust_bill_pkg->recur_show_zero;
3183
3184           my @d = ();
3185           my $svc_label;
3186
3187           # always pass the svc_label through to the template, even if
3188           # not displaying it as an ext_description
3189           my @svc_labels = map &{$escape_function}($_),
3190                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3191
3192           $svc_label = $svc_labels[0];
3193
3194           unless ( $cust_pkg->part_pkg->hide_svc_detail
3195                 || $cust_bill_pkg->hidden )
3196           {
3197
3198             push @d, @svc_labels
3199               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3200             my $lnum = $cust_main ? $cust_main->ship_locationnum
3201                                   : $self->prospect_main->locationnum;
3202             # show the location label if it's not the customer's default
3203             # location, and we're not grouping items by location already
3204             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3205               my $loc = $cust_pkg->location_label;
3206               $loc = substr($loc, 0, $maxlength). '...'
3207                 if $format eq 'latex' && length($loc) > $maxlength;
3208               push @d, &{$escape_function}($loc);
3209             }
3210
3211           } #unless hiding service details
3212
3213           push @d, $cust_bill_pkg->details(%details_opt)
3214             if $cust_bill_pkg->recur == 0;
3215
3216           if ( $cust_bill_pkg->hidden ) {
3217             $s->{amount}      += $cust_bill_pkg->setup;
3218             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3219             push @{ $s->{ext_description} }, @d;
3220           } else {
3221             $s = {
3222               _is_setup       => 1,
3223               description     => $description,
3224               pkgpart         => $pkgpart,
3225               pkgnum          => $cust_bill_pkg->pkgnum,
3226               amount          => $cust_bill_pkg->setup,
3227               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3228               unit_amount     => $cust_bill_pkg->unitsetup,
3229               quantity        => $cust_bill_pkg->quantity,
3230               ext_description => \@d,
3231               svc_label       => ($svc_label || ''),
3232               locationnum     => $cust_pkg->locationnum, # sure, why not?
3233             };
3234           };
3235
3236         }
3237
3238         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3239              && (
3240                      $cust_bill_pkg->recur != 0
3241                   || $cust_bill_pkg->setup == 0
3242                   || $discount_show_always
3243                   || $cust_bill_pkg->recur_show_zero
3244                 )
3245            )
3246         {
3247
3248           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3249             if $DEBUG > 1;
3250
3251           my $is_summary = $display->summary;
3252           my $description = $desc;
3253           if ( $type eq 'U' and defined($r) ) {
3254             # don't just show the same description as the recur line
3255             $description = $self->mt('Usage charges');
3256           }
3257
3258           my $part_pkg = $cust_pkg->part_pkg;
3259
3260           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3261                                                               $self->agentnum );
3262
3263           my @d = ();
3264           my @seconds = (); # for display of usage info
3265           my $svc_label = '';
3266
3267           #at least until cust_bill_pkg has "past" ranges in addition to
3268           #the "future" sdate/edate ones... see #3032
3269           my @dates = ( $self->_date );
3270           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3271           push @dates, $prev->sdate if $prev;
3272           push @dates, undef if !$prev;
3273
3274           my @svc_labels = map &{$escape_function}($_),
3275                       $cust_pkg->h_labels_short(@dates, 'I');
3276           $svc_label = $svc_labels[0];
3277
3278           # show service labels, unless...
3279                     # the package is set not to display them
3280           unless ( $part_pkg->hide_svc_detail
3281                     # or this is a tax-like line item
3282                 || $cust_bill_pkg->itemdesc
3283                     # or this is a hidden (bundled) line item
3284                 || $cust_bill_pkg->hidden
3285                     # or this is a usage summary line
3286                 || $is_summary && $type && $type eq 'U'
3287                     # or this is a usage line and there's a recurring line
3288                     # for the package in the same section (which will
3289                     # have service labels already)
3290                 || ($type eq 'U' and defined($r))
3291               )
3292           {
3293
3294             warn "$me _items_cust_bill_pkg adding service details\n"
3295               if $DEBUG > 1;
3296
3297             push @d, @svc_labels
3298               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3299             warn "$me _items_cust_bill_pkg done adding service details\n"
3300               if $DEBUG > 1;
3301
3302             my $lnum = $cust_main ? $cust_main->ship_locationnum
3303                                   : $self->prospect_main->locationnum;
3304             # show the location label if it's not the customer's default
3305             # location, and we're not grouping items by location already
3306             if ( $cust_pkg->locationnum != $lnum and !defined($locationnum) ) {
3307               my $loc = $cust_pkg->location_label;
3308               $loc = substr($loc, 0, $maxlength). '...'
3309                 if $format eq 'latex' && length($loc) > $maxlength;
3310               push @d, &{$escape_function}($loc);
3311             }
3312
3313             # Display of seconds_since_sqlradacct:
3314             # On the invoice, when processing @detail_items, look for a field
3315             # named 'seconds'.  This will contain total seconds for each
3316             # service, in the same order as @ext_description.  For services
3317             # that don't support this it will show undef.
3318             if ( $conf->exists('svc_acct-usage_seconds')
3319                  and ! $cust_bill_pkg->pkgpart_override ) {
3320               foreach my $cust_svc (
3321                   $cust_pkg->h_cust_svc(@dates, 'I')
3322                 ) {
3323
3324                 # eval because not having any part_export_usage exports
3325                 # is a fatal error, last_bill/_date because that's how
3326                 # sqlradius_hour billing does it
3327                 my $sec = eval {
3328                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3329                 };
3330                 push @seconds, $sec;
3331               }
3332             } #if svc_acct-usage_seconds
3333
3334           } # if we are showing service labels
3335
3336           unless ( $is_summary ) {
3337             warn "$me _items_cust_bill_pkg adding details\n"
3338               if $DEBUG > 1;
3339
3340             #instead of omitting details entirely in this case (unwanted side
3341             # effects), just omit CDRs
3342             $details_opt{'no_usage'} = 1
3343               if $type && $type eq 'R';
3344
3345             push @d, $cust_bill_pkg->details(%details_opt);
3346           }
3347
3348           warn "$me _items_cust_bill_pkg calculating amount\n"
3349             if $DEBUG > 1;
3350
3351           my $amount = 0;
3352           if (!$type) {
3353             $amount = $cust_bill_pkg->recur;
3354           } elsif ($type eq 'R') {
3355             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3356           } elsif ($type eq 'U') {
3357             $amount = $cust_bill_pkg->usage;
3358           }
3359
3360           if ( !$type || $type eq 'R' ) {
3361
3362             warn "$me _items_cust_bill_pkg adding recur\n"
3363               if $DEBUG > 1;
3364
3365             my $unit_amount =
3366               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3367                                                 : $amount;
3368
3369             if ( $cust_bill_pkg->hidden ) {
3370               $r->{amount}      += $amount;
3371               $r->{unit_amount} += $unit_amount;
3372               push @{ $r->{ext_description} }, @d;
3373             } else {
3374               $r = {
3375                 description     => $description,
3376                 pkgpart         => $pkgpart,
3377                 pkgnum          => $cust_bill_pkg->pkgnum,
3378                 amount          => $amount,
3379                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3380                 unit_amount     => $unit_amount,
3381                 quantity        => $cust_bill_pkg->quantity,
3382                 %item_dates,
3383                 ext_description => \@d,
3384                 svc_label       => ($svc_label || ''),
3385                 locationnum     => $cust_pkg->locationnum,
3386               };
3387               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3388             }
3389
3390           } else {  # $type eq 'U'
3391
3392             warn "$me _items_cust_bill_pkg adding usage\n"
3393               if $DEBUG > 1;
3394
3395             if ( $cust_bill_pkg->hidden and defined($u) ) {
3396               # if this is a hidden package and there's already a usage
3397               # line for the bundle, add this package's total amount and
3398               # usage details to it
3399               $u->{amount}      += $amount;
3400               push @{ $u->{ext_description} }, @d;
3401             } elsif ( $amount ) {
3402               # create a new usage line
3403               $u = {
3404                 description     => $description,
3405                 pkgpart         => $pkgpart,
3406                 pkgnum          => $cust_bill_pkg->pkgnum,
3407                 amount          => $amount,
3408                 usage_item      => 1,
3409                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3410                 %item_dates,
3411                 ext_description => \@d,
3412                 locationnum     => $cust_pkg->locationnum,
3413               };
3414             } # else this has no usage, so don't create a usage section
3415           }
3416
3417         } # recurring or usage with recurring charge
3418
3419       } else { # taxes and fees
3420
3421         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3422           if $DEBUG > 1;
3423
3424         # items of this kind should normally not have sdate/edate.
3425         push @b, {
3426           'description' => $desc,
3427           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3428                                            + $cust_bill_pkg->recur)
3429         };
3430
3431       } # if quotation / package line item / other line item
3432
3433       # decide whether to show active discounts here
3434       if (
3435           # case 1: we are showing a single line for the package
3436           ( !$type )
3437           # case 2: we are showing a setup line for a package that has
3438           # no base recurring fee
3439           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3440           # case 3: we are showing a recur line for a package that has
3441           # a base recurring fee
3442           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3443       ) {
3444
3445         my $item_discount = $cust_bill_pkg->_item_discount;
3446         if ( $item_discount ) {
3447           # $item_discount->{amount} is negative
3448
3449           if ( $d and $cust_bill_pkg->hidden ) {
3450             $d->{amount}      += $item_discount->{amount};
3451           } else {
3452             $d = $item_discount;
3453             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3454           }
3455
3456           # update the active line (before the discount) to show the
3457           # original price (whether this is a hidden line or not)
3458           #
3459           # quotation discounts keep track of setup and recur; invoice
3460           # discounts currently don't
3461           if ( exists $item_discount->{setup_amount} ) {
3462
3463             $s->{amount} -= $item_discount->{setup_amount} if $s;
3464             $r->{amount} -= $item_discount->{recur_amount} if $r;
3465
3466           } else {
3467
3468             # $active_line is the line item hashref for the line that will
3469             # show the original price
3470             # (use the recur or single line for the package, unless we're
3471             # showing a setup line for a package with no recurring fee)
3472             my $active_line = $r;
3473             if ( $type eq 'S' ) {
3474               $active_line = $s;
3475             }
3476             $active_line->{amount} -= $item_discount->{amount};
3477
3478           }
3479
3480         } # if there are any discounts
3481       } # if this is an appropriate place to show discounts
3482
3483     } # foreach $display
3484
3485     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3486                                 && $conf->exists('discount-show-always'));
3487
3488   }
3489
3490   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3491     if ( $_  ) {
3492       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3493         if exists($_->{amount});
3494       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3495       if (exists($_->{unit_amount})) {
3496         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3497       }
3498
3499       push @b, { %$_ }
3500         if $_->{amount} != 0
3501         || $discount_show_always
3502         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3503         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3504     }
3505   }
3506
3507   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3508     if $DEBUG > 1;
3509
3510   @b;
3511
3512 }
3513
3514 =item _items_discounts_avail
3515
3516 Returns an array of line item hashrefs representing available term discounts
3517 for this invoice.  This makes the same assumptions that apply to term
3518 discounts in general: that the package is billed monthly, at a flat rate,
3519 with no usage charges.  A prorated first month will be handled, as will
3520 a setup fee if the discount is allowed to apply to setup fees.
3521
3522 =cut
3523
3524 sub _items_discounts_avail {
3525   my $self = shift;
3526
3527   #maybe move this method from cust_bill when quotations support discount_plans
3528   return () unless $self->can('discount_plans');
3529   my %plans = $self->discount_plans;
3530
3531   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3532   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3533
3534   map {
3535     my $months = $_;
3536     my $plan = $plans{$months};
3537
3538     my $term_total = sprintf('%.2f', $plan->discounted_total);
3539     my $percent = sprintf('%.0f',
3540                           100 * (1 - $term_total / $plan->base_total) );
3541     my $permonth = sprintf('%.2f', $term_total / $months);
3542     my $detail = $self->mt('discount on item'). ' '.
3543                  join(', ', map { "#$_" } $plan->pkgnums)
3544       if $list_pkgnums;
3545
3546     # discounts for non-integer months don't work anyway
3547     $months = sprintf("%d", $months);
3548
3549     +{
3550       description => $self->mt('Save [_1]% by paying for [_2] months',
3551                                 $percent, $months),
3552       amount      => $self->mt('[_1] ([_2] per month)',
3553                                 $term_total, $money_char.$permonth),
3554       ext_description => ($detail || ''),
3555     }
3556   } #map
3557   sort { $b <=> $a } keys %plans;
3558
3559 }
3560
3561 1;