FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Time::Local qw( timelocal );
  14 use Text::Template 1.20;
  15 use File::Temp 0.14;
  16 use Archive::Zip qw( :ERROR_CODES :CONSTANTS );
  17 use IO::Scalar;
  18 use HTML::Entities;
  19 use Cwd;
  20 use FS::UID;
  21 use FS::Misc qw( send_email );
  22 use FS::Record qw( qsearch qsearchs );
  23 use FS::Conf;
  24 use FS::Misc qw( generate_ps generate_pdf );
  25 use FS::pkg_category;
  26 use FS::pkg_class;
  27 use FS::invoice_mode;
  28 use FS::L10N;
  29
  30 $DEBUG = 0;
  31 $me = '[FS::Template_Mixin]';
  32 FS::UID->install_callback( sub {
  33   my $conf = new FS::Conf; #global
  34   $money_char  = $conf->config('money_char')  || '$';
  35   $date_format = $conf->config('date_format') || '%x'; #/YY
  36 } );
  37
  38 =item conf [ MODE ]
  39
  40 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  41
  42 If the "mode" pseudo-field is set on the object, the configuration handle
  43 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  44 locale).
  45
  46 =cut
  47
  48 sub conf {
  49   my $self = shift;
  50   my $mode = $self->get('mode');
  51   if ($self->{_conf} and !defined($mode)) {
  52     return $self->{_conf};
  53   }
  54
  55   my $cust_main = $self->cust_main;
  56   my $locale = $cust_main ? $cust_main->locale : '';
  57   my $conf;
  58   if ( $mode ) {
  59     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  60       $mode = $mode->modenum;
  61     } elsif ( $mode =~ /\D/ ) {
  62       die "invalid invoice mode $mode";
  63     }
  64     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  65     if (!$conf) {
  66       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  67       # it doesn't have a locale, but system conf still might
  68       $conf->set('locale' => $locale) if $conf;
  69     }
  70   }
  71   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  72   # and locale, then use the system config only (but with the locale)
  73   $conf ||= FS::Conf->new({ 'locale' => $locale });
  74   # cache it
  75   return $self->{_conf} = $conf;
  76 }
  77
  78 =item print_text OPTIONS
  79
  80 Returns an text invoice, as a list of lines.
  81
  82 Options can be passed as a hash.
  83
  84 I<time>, if specified, is used to control the printing of overdue messages.  The
  85 default is now.  It isn't the date of the invoice; that's the `_date' field.
  86 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  87 L<Time::Local> and L<Date::Parse> for conversion functions.
  88
  89 I<template>, if specified, is the name of a suffix for alternate invoices.
  90
  91 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  92
  93 =cut
  94
  95 sub print_text {
  96   my $self = shift;
  97   my %params;
  98   if ( ref($_[0]) ) {
  99     %params = %{ shift() };
 100   } else {
 101     %params = @_;
 102   }
 103
 104   $params{'format'} = 'template'; # for some reason
 105
 106   $self->print_generic( %params );
 107 }
 108
 109 =item print_latex HASHREF
 110
 111 Internal method - returns a filename of a filled-in LaTeX template for this
 112 invoice (Note: add ".tex" to get the actual filename), and a filename of
 113 an associated logo (with the .eps extension included).
 114
 115 See print_ps and print_pdf for methods that return PostScript and PDF output.
 116
 117 Options can be passed as a hash.
 118
 119 I<time>, if specified, is used to control the printing of overdue messages.  The
 120 default is now.  It isn't the date of the invoice; that's the `_date' field.
 121 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 122 L<Time::Local> and L<Date::Parse> for conversion functions.
 123
 124 I<template>, if specified, is the name of a suffix for alternate invoices.
 125 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 126 customize invoice templates for different purposes.
 127
 128 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 129
 130 =cut
 131
 132 sub print_latex {
 133   my $self = shift;
 134   my %params;
 135
 136   if ( ref($_[0]) ) {
 137     %params = %{ shift() };
 138   } else {
 139     %params = @_;
 140   }
 141
 142   $params{'format'} = 'latex';
 143   my $conf = $self->conf;
 144
 145   # this needs to go away
 146   my $template = $params{'template'};
 147   # and this especially
 148   $template ||= $self->_agent_template
 149     if $self->can('_agent_template');
 150
 151   #the new way
 152   $self->set('mode', $params{mode})
 153     if $params{mode};
 154
 155   my $pkey = $self->primary_key;
 156   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 157
 158   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 159   my $lh = new File::Temp(
 160     TEMPLATE => $tmp_template,
 161     DIR      => $dir,
 162     SUFFIX   => '.eps',
 163     UNLINK   => 0,
 164   ) or die "can't open temp file: $!\n";
 165
 166   my $agentnum = $self->agentnum;
 167
 168   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 169     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 170       or die "can't write temp file: $!\n";
 171   } else {
 172     print $lh $conf->config_binary('logo.eps', $agentnum)
 173       or die "can't write temp file: $!\n";
 174   }
 175   close $lh;
 176   $params{'logo_file'} = $lh->filename;
 177
 178   if( $conf->exists('invoice-barcode')
 179         && $self->can('invoice_barcode')
 180         && $self->invnum ) { # don't try to barcode statements
 181       my $png_file = $self->invoice_barcode($dir);
 182       my $eps_file = $png_file;
 183       $eps_file =~ s/\.png$/.eps/g;
 184       $png_file =~ /(barcode.*png)/;
 185       $png_file = $1;
 186       $eps_file =~ /(barcode.*eps)/;
 187       $eps_file = $1;
 188
 189       my $curr_dir = cwd();
 190       chdir($dir);
 191       # after painfuly long experimentation, it was determined that sam2p won't
 192       # accept : and other chars in the path, no matter how hard I tried to
 193       # escape them, hence the chdir (and chdir back, just to be safe)
 194       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 195         or die "sam2p failed: $!\n";
 196       unlink($png_file);
 197       chdir($curr_dir);
 198
 199       $params{'barcode_file'} = $eps_file;
 200   }
 201
 202   my @filled_in = $self->print_generic( %params );
 203
 204   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 205                            DIR      => $dir,
 206                            SUFFIX   => '.tex',
 207                            UNLINK   => 0,
 208                          ) or die "can't open temp file: $!\n";
 209   binmode($fh, ':utf8'); # language support
 210   print $fh join('', @filled_in );
 211   close $fh;
 212
 213   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 214   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 215
 216 }
 217
 218 sub agentnum {
 219   my $self = shift;
 220   my $cust_main = $self->cust_main;
 221   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 222 }
 223
 224 =item print_generic OPTION => VALUE ...
 225
 226 Internal method - returns a filled-in template for this invoice as a scalar.
 227
 228 See print_ps and print_pdf for methods that return PostScript and PDF output.
 229
 230 Required options
 231
 232 =over 4
 233
 234 =item format
 235
 236 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 237
 238 =back
 239
 240 Additional options
 241
 242 =over 4
 243
 244 =item notice_name
 245
 246 Overrides "Invoice" as the name of the sent document.
 247
 248 =item today
 249
 250 Used to control the printing of overdue messages.  The
 251 default is now.  It isn't the date of the invoice; that's the `_date' field.
 252 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 253 L<Time::Local> and L<Date::Parse> for conversion functions.
 254
 255 =item logo_file
 256
 257 Logo file (path to temporary EPS file on the local filesystem)
 258
 259 =item cid
 260
 261 CID for inline (emailed) images (logo)
 262
 263 =item locale
 264
 265 Override customer's locale
 266
 267 =item unsquelch_cdr
 268
 269 Overrides any per customer cdr squelching when true
 270
 271 =item no_number
 272
 273 Supress the (invoice, quotation, statement, etc.) number
 274
 275 =item no_date
 276
 277 Supress the date
 278
 279 =item no_coupon
 280
 281 Supress the payment coupon
 282
 283 =item barcode_file
 284
 285 Barcode file (path to temporary EPS file on the local filesystem)
 286
 287 =item barcode_img
 288
 289 Flag indicating the barcode image should be a link (normal HTML dipaly)
 290
 291 =item barcode_cid
 292
 293 Barcode CID for inline (emailed) images
 294
 295 =item preref_callback
 296
 297 Coderef run for each line item, code should return HTML to be displayed
 298 before that line item (quotations only)
 299
 300 =item template
 301
 302 Dprecated.  Used as a suffix for a configuration template.  Please
 303 don't use this, it deprecated in favor of more flexible alternatives.
 304
 305 =back
 306
 307 =cut
 308
 309 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 310 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 311 # yes: fixed width/plain text printing will be borked
 312 sub print_generic {
 313   my( $self, %params ) = @_;
 314   my $conf = $self->conf;
 315
 316   my $today = $params{today} ? $params{today} : time;
 317   warn "$me print_generic called on $self with suffix $params{template}\n"
 318     if $DEBUG;
 319
 320   my $format = $params{format};
 321   die "Unknown format: $format"
 322     unless $format =~ /^(latex|html|template)$/;
 323
 324   my $cust_main = $self->cust_main || $self->prospect_main;
 325
 326   my $locale = $params{'locale'} || $cust_main->locale;
 327
 328   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 329                      'html'     => [ '<%=', '%>' ],
 330                      'template' => [ '{', '}' ],
 331                    );
 332
 333   warn "$me print_generic creating template\n"
 334     if $DEBUG > 1;
 335
 336   # set the notice name here, and nowhere else.
 337   my $notice_name =  $params{notice_name}
 338                   || $conf->config('notice_name')
 339                   || $self->notice_name;
 340
 341   #create the template
 342   my $template = $params{template} ? $params{template} : $self->_agent_template;
 343   my $templatefile = $self->template_conf. $format;
 344   $templatefile .= "_$template"
 345     if length($template) && $conf->exists($templatefile."_$template");
 346
 347   $self->set('_template',$template);
 348
 349   # the base template
 350   my @invoice_template = map "$_\n", $conf->config($templatefile)
 351     or die "cannot load config data $templatefile";
 352
 353   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 354     #change this to a die when the old code is removed
 355     # it's been almost ten years, changing it to a die
 356     die "old-style invoice template $templatefile; ".
 357          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 358          #$old_latex = 'true';
 359          #@invoice_template = _translate_old_latex_format(@invoice_template);
 360   }
 361
 362   warn "$me print_generic creating T:T object\n"
 363     if $DEBUG > 1;
 364
 365   my $text_template = new Text::Template(
 366     TYPE => 'ARRAY',
 367     SOURCE => \@invoice_template,
 368     DELIMITERS => $delimiters{$format},
 369   );
 370
 371   warn "$me print_generic compiling T:T object\n"
 372     if $DEBUG > 1;
 373
 374   $text_template->compile()
 375     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 376
 377
 378   # additional substitution could possibly cause breakage in existing templates
 379   my %convert_maps = (
 380     'latex' => {
 381                  'notes'         => sub { map "$_", @_ },
 382                  'footer'        => sub { map "$_", @_ },
 383                  'smallfooter'   => sub { map "$_", @_ },
 384                  'returnaddress' => sub { map "$_", @_ },
 385                  'coupon'        => sub { map "$_", @_ },
 386                  'summary'       => sub { map "$_", @_ },
 387                },
 388     'html'  => {
 389                  'notes' =>
 390                    sub {
 391                      map {
 392                        s/%%(.*)$/<!-- $1 -->/g;
 393                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 394                        s/\\begin\{enumerate\}/<ol>/g;
 395                        s/\\item /  <li>/g;
 396                        s/\\end\{enumerate\}/<\/ol>/g;
 397                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 398                        s/\\\\\*/<br>/g;
 399                        s/\\dollar ?/\$/g;
 400                        s/\\#/#/g;
 401                        s/~/&nbsp;/g;
 402                        $_;
 403                      }  @_
 404                    },
 405                  'footer' =>
 406                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 407                  'smallfooter' =>
 408                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 409                  'returnaddress' =>
 410                    sub {
 411                      map {
 412                        s/~/&nbsp;/g;
 413                        s/\\\\\*?\s*$/<BR>/;
 414                        s/\\hyphenation\{[\w\s\-]+}//;
 415                        s/\\([&])/$1/g;
 416                        $_;
 417                      }  @_
 418                    },
 419                  'coupon'        => sub { "" },
 420                  'summary'       => sub { "" },
 421                },
 422     'template' => {
 423                  'notes' =>
 424                    sub {
 425                      map {
 426                        s/%%.*$//g;
 427                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 428                        s/\\begin\{enumerate\}//g;
 429                        s/\\item /  * /g;
 430                        s/\\end\{enumerate\}//g;
 431                        s/\\textbf\{(.*)\}/$1/g;
 432                        s/\\\\\*/ /;
 433                        s/\\dollar ?/\$/g;
 434                        $_;
 435                      }  @_
 436                    },
 437                  'footer' =>
 438                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 439                  'smallfooter' =>
 440                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 441                  'returnaddress' =>
 442                    sub {
 443                      map {
 444                        s/~/ /g;
 445                        s/\\\\\*?\s*$/\n/;             # dubious
 446                        s/\\hyphenation\{[\w\s\-]+}//;
 447                        $_;
 448                      }  @_
 449                    },
 450                  'coupon'        => sub { "" },
 451                  'summary'       => sub { "" },
 452                },
 453   );
 454
 455
 456   # hashes for differing output formats
 457   my %nbsps = ( 'latex'    => '~',
 458                 'html'     => '',    # '&nbps;' would be nice
 459                 'template' => '',    # not used
 460               );
 461   my $nbsp = $nbsps{$format};
 462
 463   my %escape_functions = ( 'latex'    => \&_latex_escape,
 464                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 465                            'template' => sub { shift },
 466                          );
 467   my $escape_function = $escape_functions{$format};
 468   my $escape_function_nonbsp = ($format eq 'html')
 469                                  ? \&_html_escape : $escape_function;
 470
 471   my %newline_tokens = (  'latex'     => '\\\\',
 472                           'html'      => '<br>',
 473                           'template'  => "\n",
 474                         );
 475   my $newline_token = $newline_tokens{$format};
 476
 477   warn "$me generating template variables\n"
 478     if $DEBUG > 1;
 479
 480   # generate template variables
 481   my $returnaddress;
 482
 483   if (
 484          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 485                                         $template
 486                                       )
 487                 )
 488        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 489                                         $template
 490                                       )
 491                 )
 492   ) {
 493
 494     $returnaddress = join("\n",
 495       $conf->config_orbase("invoice_${format}returnaddress", $template)
 496     );
 497
 498   } elsif ( grep /\S/,
 499             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 500
 501     my $convert_map = $convert_maps{$format}{'returnaddress'};
 502     $returnaddress =
 503       join( "\n",
 504             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 505                                                  $template
 506                                                )
 507                          )
 508           );
 509   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 510
 511     my $convert_map = $convert_maps{$format}{'returnaddress'};
 512     $returnaddress = join( "\n", &$convert_map(
 513                                    map { s/( {2,})/'~' x length($1)/eg;
 514                                          s/$/\\\\\*/;
 515                                          $_
 516                                        }
 517                                      ( $conf->config('company_name', $cust_main->agentnum),
 518                                        $conf->config('company_address', $cust_main->agentnum),
 519                                      )
 520                                  )
 521                      );
 522
 523   } else {
 524
 525     my $warning = "Couldn't find a return address; ".
 526                   "do you need to set the company_address configuration value?";
 527     warn "$warning\n";
 528     $returnaddress = $nbsp;
 529     #$returnaddress = $warning;
 530
 531   }
 532
 533   warn "$me generating invoice data\n"
 534     if $DEBUG > 1;
 535
 536   my $agentnum = $cust_main->agentnum;
 537
 538   my %invoice_data = (
 539
 540     #invoice from info
 541     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 542     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 543     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 544     'returnaddress'   => $returnaddress,
 545     'agent'           => &$escape_function($cust_main->agent->agent),
 546
 547     #invoice/quotation info
 548     'no_number'       => $params{'no_number'},
 549     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 550     'quotationnum'    => $self->quotationnum,
 551     'no_date'         => $params{'no_date'},
 552     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 553       # workaround for inconsistent behavior in the early plain text
 554       # templates; see RT#28271
 555     'date'            => ( $params{'no_date'}
 556                              ? ''
 557                              : ($format eq 'template'
 558                                ? $self->_date
 559                                : $self->time2str_local('long', $self->_date, $format)
 560                                )
 561                          ),
 562     'today'           => $self->time2str_local('long', $today, $format),
 563     'terms'           => $self->terms,
 564     'template'        => $template, #params{'template'},
 565     'notice_name'     => $notice_name, # escape?
 566     'current_charges' => sprintf("%.2f", $self->charged),
 567     'duedate'         => $self->due_date2str('rdate'), #date_format?
 568     'duedate_long'    => $self->due_date2str('long'),
 569
 570     #customer info
 571     'custnum'         => $cust_main->display_custnum,
 572     'prospectnum'     => $cust_main->prospectnum,
 573     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 574     ( map { $_ => &$escape_function($cust_main->$_()) }
 575         qw( company address1 address2 city state zip fax )
 576     ),
 577     'payname'         => &$escape_function( $cust_main->invoice_attn
 578                                              || $cust_main->contact_firstlast ),
 579
 580     #global config
 581     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 582     'unitprices'      => $conf->exists('invoice-unitprice'),
 583     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 584     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 585     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 586
 587     #layout info -- would be fancy to calc some of this and bury the template
 588     #               here in the code
 589     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 590     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 591     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 592     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 593     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 594     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 595     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 596     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 597     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 598     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 599
 600     # better hang on to conf_dir for a while (for old templates)
 601     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 602
 603     #these are only used when doing paged plaintext
 604     'page'            => 1,
 605     'total_pages'     => 1,
 606
 607   );
 608
 609   #quotations have $name
 610   $invoice_data{'name'} = $invoice_data{'payname'};
 611
 612   #localization
 613   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 614   # prototype here to silence warnings
 615   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 616
 617   my $min_sdate = 999999999999;
 618   my $max_edate = 0;
 619   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 620     next unless $cust_bill_pkg->pkgnum > 0;
 621     $min_sdate = $cust_bill_pkg->sdate
 622       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 623     $max_edate = $cust_bill_pkg->edate
 624       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 625   }
 626
 627   $invoice_data{'bill_period'} = '';
 628   $invoice_data{'bill_period'} =
 629       $self->time2str_local('%e %h', $min_sdate, $format)
 630       . " to " .
 631       $self->time2str_local('%e %h', $max_edate, $format)
 632     if ($max_edate != 0 && $min_sdate != 999999999999);
 633
 634   $invoice_data{finance_section} = '';
 635   if ( $conf->config('finance_pkgclass') ) {
 636     my $pkg_class =
 637       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 638     $invoice_data{finance_section} = $pkg_class->categoryname;
 639   }
 640   $invoice_data{finance_amount} = '0.00';
 641   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 642
 643   my $countrydefault = $conf->config('countrydefault') || 'US';
 644   foreach ( qw( address1 address2 city state zip country fax) ){
 645     my $method = 'ship_'.$_;
 646     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 647   }
 648   if ( length($cust_main->ship_company) ) {
 649     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 650   } else {
 651     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 652   }
 653   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 654   $invoice_data{'ship_country'} = ''
 655     if ( $invoice_data{'ship_country'} eq $countrydefault );
 656
 657   $invoice_data{'cid'} = $params{'cid'}
 658     if $params{'cid'};
 659
 660   if ( $cust_main->country eq $countrydefault ) {
 661     $invoice_data{'country'} = '';
 662   } else {
 663     $invoice_data{'country'} = &$escape_function($cust_main->bill_country_full);
 664   }
 665
 666   my @address = ();
 667   $invoice_data{'address'} = \@address;
 668   push @address,
 669     $invoice_data{'payname'}.
 670       ( $cust_main->po_number
 671           ? " (P.O. #". $cust_main->po_number. ")"
 672           : ''
 673       )
 674   ;
 675   push @address, $cust_main->company
 676     if $cust_main->company;
 677   push @address, $cust_main->address1;
 678   push @address, $cust_main->address2
 679     if $cust_main->address2;
 680   push @address,
 681     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 682   push @address, $invoice_data{'country'}
 683     if $invoice_data{'country'};
 684   push @address, ''
 685     while (scalar(@address) < 5);
 686
 687   $invoice_data{'logo_file'} = $params{'logo_file'}
 688     if $params{'logo_file'};
 689   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 690     if $params{'barcode_file'};
 691   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 692     if $params{'barcode_img'};
 693   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 694     if $params{'barcode_cid'};
 695
 696
 697   # re: rt:78190
 698   #   using owed_on_invoice() instead of owed() here for $balance_due
 699   #   using _items_previous_total() instead of ->previous() for $pr_total
 700   #
 701   #   owed_on_invoice() is aware of configuration flags that affect how an
 702   #     invoice is rendered.  May not return actual current balance. Will
 703   #     return balance appropriate for the invoice being rendered, based
 704   #     on which past due items, current charges, and future payments are
 705   #     displayed.
 706   #
 707   #   Going forward, usage of owed(), or bypassing cust_bill helper methods
 708   #     when generating invoice lines may lead to incorrect or misleading
 709   #     math on invoices.
 710   #
 711   #   Helper methods that are aware of invoicing conf flags:
 712   #   - owed_on_invoice          # use instead of owed()
 713   #   - _items_previous()        # use instead of previous()
 714   #   - _items_credits()         # use instead of cust_credit()
 715   #   - _items_payments()
 716   #   - _items_total()
 717   #   - _items_previous_total()  # use instead of previous()
 718   #   - _items_payments_total()
 719   #   - _items_credits_total()   # use instead of cust_credit()
 720
 721   my $pr_total    = $self->_items_previous_total();
 722
 723   my $balance_due = $self->owed_on_invoice();
 724   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 725
 726   # flag telling this invoice to have a first-page summary
 727   my $summarypage = '';
 728
 729   if ( $self->custnum && $self->invnum ) {
 730     # XXX should be an FS::cust_bill method to set the defaults, instead
 731     # of checking the type here
 732
 733     # info from customer's last invoice before this one, for some
 734     # summary formats
 735     $invoice_data{'last_bill'} = {};
 736
 737     #    my $last_bill = $self->previous_bill;
 738     # if ( $last_bill ) {
 739
 740     # Populate template stash for previous balance and payments
 741     if ($pr_total) {
 742       # Used on summary page as "Previous Balance"
 743       $invoice_data{'true_previous_balance'} = sprintf("%.2f", $pr_total);
 744
 745       # Used on summary page as "Payments"
 746       $invoice_data{'balance_adjustments'} = sprintf("%.2f",
 747         $self->_items_payments_total() + $self->_items_credits_total()
 748       );
 749
 750       # Used in invoice template as "Previous Balance"
 751       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 752
 753       # $invoice_data{last_bill}{_date}:
 754       # Not used in default templates, but may be in use by someone
 755       #
 756       # ! May be a problem field if they are using it... this field
 757       #   stores the date of the previous invoice... it is possible to
 758       #   carry a balance, but have the immediately previous invoice paid off.
 759       #   In this case, this field might be presenting bad data?  Not
 760       #   altering the problematic behavior, because someone might be
 761       #   expecting this bad behavior in their templates for some other
 762       #   purpose, such as a "your last bill was dated %_date%"
 763       my $last_bill = $self->previous_bill;
 764       $invoice_data{'last_bill'}{'_date'}
 765         = ref $last_bill
 766         ? $last_bill->_date()
 767         : undef;
 768
 769       # $invoice_data{previous_payments}
 770       # Not used in default templates, but may be in use by someone
 771       #
 772       # Returns an array of hrefs representing payments, each with keys:
 773       #  - _date:       epoch timestamp
 774       #  - date:        text formatted date
 775       #  - amount:      money formatted amount string
 776       #  - payinfo:     string from payby_payinfo_pretty()
 777       #  - paynum:      id for cust_pay
 778       #  - description: Text description for bill line item
 779       #
 780       my @payments = $self->_items_payments();
 781       $invoice_data{previous_payments} = \@payments;
 782
 783       # $invoice_data{previous_credits}
 784       # Not used in default templates, but may be in use by someone
 785       #
 786       # Returns an array of hrefs representing credits, each with keys:
 787       #  - _date:        epoch timestamp
 788       #  - date:         text formatted date
 789       #  - amount:       money formatted amount string
 790       #  - crednum:      id for cust_credit
 791       #  - description:  Text description for bill line item
 792       #  - creditreason: reason() from cust_credit
 793       #
 794       my @credits = $self->_items_credits();
 795       $invoice_data{previous_credits} = \@credits;
 796
 797       # Populate formatted date field
 798       for my $pmt_href (@payments, @credits) {
 799         $pmt_href->{date} = $self->time2str_local(
 800           'long',
 801           $pmt_href->{_date},
 802           $format
 803         );
 804       }
 805
 806     } else {
 807       # There are no outstanding invoices    = YAPH
 808       $invoice_data{'true_previous_balance'} =
 809       $invoice_data{'balance_adjustments'}   =
 810       $invoice_data{'previous_balance'}      = '0.00';
 811       $invoice_data{'previous_payments'}     =
 812       $invoice_data{'previous_credits'}      = [];
 813     }
 814
 815     # Condencing a lot of debug staements here
 816     if ($DEBUG) {
 817       warn "\$invoice_data{$_}: $invoice_data{$_}"
 818         for qw(
 819           true_previous_balance
 820           balance_adjustments
 821           previous_balance
 822           previous_payments
 823           previous_credits
 824         );
 825     }
 826
 827     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 828       $invoice_data{'summarypage'} = $summarypage = 1;
 829     }
 830
 831   } # if this is an invoice
 832
 833   warn "$me substituting variables in notes, footer, smallfooter\n"
 834     if $DEBUG > 1;
 835
 836   my $tc = $self->template_conf;
 837   my @include = ( [ $tc,        'notes' ],
 838                   [ 'invoice_', 'footer' ],
 839                   [ 'invoice_', 'smallfooter', ],
 840                   [ 'invoice_', 'watermark' ],
 841                 );
 842   push @include, [ $tc,        'coupon', ]
 843     unless $params{'no_coupon'};
 844
 845   foreach my $i (@include) {
 846
 847     # load the configuration for this sub-template
 848
 849     my($base, $include) = @$i;
 850
 851     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 852
 853     my @inc_src = $conf->config($inc_file, $agentnum);
 854     if (!@inc_src) {
 855       my $converter = $convert_maps{$format}{$include};
 856       if ( $converter ) {
 857         # then attempt to convert LaTeX to the requested format
 858         $inc_file = $conf->key_orbase($base.'latex'.$include, $template);
 859         @inc_src = &$converter( $conf->config($inc_file, $agentnum) );
 860         foreach (@inc_src) {
 861           # this isn't included in the convert_maps
 862           my ($open, $close) = @{ $delimiters{$format} };
 863           s/\[\@--/$open/g;
 864           s/--\@\]/$close/g;
 865         }
 866       }
 867     } # else @inc_src is empty and that's fine
 868
 869     # make a Text::Template out of it
 870
 871     my $inc_tt = new Text::Template (
 872       TYPE       => 'ARRAY',
 873       SOURCE     => [ map "$_\n", @inc_src ],
 874       DELIMITERS => $delimiters{$format},
 875     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 876
 877     unless ( $inc_tt->compile() ) {
 878       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 879       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 880       die $error;
 881     }
 882
 883     # fill in variables
 884
 885     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 886
 887     $invoice_data{$include} =~ s/\n+$//
 888       if ($format eq 'latex');
 889   }
 890
 891 # if (well, probably when) we still need PO numbers in the brave new world of
 892 # 4.x, then we'll have to add them back as their own customer fields
 893 #  # let invoices use either of these as needed
 894 #  $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 895 #    ? $cust_main->payinfo : '';
 896 #  $invoice_data{'po_line'} =
 897 #    (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 898 #      ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 899 #      : $nbsp;
 900
 901   my %money_chars = ( 'latex'    => '',
 902                       'html'     => $conf->config('money_char') || '$',
 903                       'template' => '',
 904                     );
 905   my $money_char = $money_chars{$format};
 906
 907   # extremely dubious
 908   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 909                             'html'     => $conf->config('money_char') || '$',
 910                             'template' => '',
 911                           );
 912   my $other_money_char = $other_money_chars{$format};
 913   $invoice_data{'dollar'} = $other_money_char;
 914
 915   my %minus_signs = ( 'latex'    => '$-$',
 916                       'html'     => '&minus;',
 917                       'template' => '- ' );
 918   my $minus = $minus_signs{$format};
 919
 920   my @detail_items = ();
 921   my @total_items = ();
 922   my @buf = ();
 923   my @sections = ();
 924
 925   $invoice_data{'detail_items'} = \@detail_items;
 926   $invoice_data{'total_items'} = \@total_items;
 927   $invoice_data{'buf'} = \@buf;
 928   $invoice_data{'sections'} = \@sections;
 929
 930   warn "$me generating sections\n"
 931     if $DEBUG > 1;
 932
 933   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 934   my $multisection = $self->has_sections;
 935   $conf->exists($tc.'sections', $cust_main->agentnum) ||
 936                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 937   $invoice_data{'multisection'} = $multisection;
 938   my $late_sections;
 939   my $extra_sections = [];
 940   my $extra_lines = ();
 941
 942   # default section ('Charges')
 943   my $default_section = { 'description' => '',
 944                           'subtotal'    => '',
 945                           'no_subtotal' => 1,
 946                         };
 947
 948   # Previous Charges section
 949   # subtotal is the first return value from $self->previous
 950   my $previous_section;
 951   # if the invoice has major sections, or if we're summarizing previous
 952   # charges with a single line, or if we've been specifically told to put them
 953   # in a section, create a section for previous charges:
 954   if ( $multisection or
 955        $conf->exists('previous_balance-summary_only') or
 956        $conf->exists('previous_balance-section') ) {
 957
 958     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 959                            'subtotal'    => $other_money_char.
 960                                             sprintf('%.2f', $pr_total),
 961                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 962                          };
 963
 964     # Include balance aging line and template variables
 965     my @aged_balances = $self->_items_aging_balances();
 966     ( $invoice_data{aged_balance_current},
 967       $invoice_data{aged_balance_30d},
 968       $invoice_data{aged_balance_60d},
 969       $invoice_data{aged_balance_90d}
 970     ) = @aged_balances;
 971
 972     if ($conf->exists('invoice_include_aging')) {
 973       $previous_section->{posttotal} = sprintf(
 974         '0 / 30 / 60 / 90 days overdue %.2f / %.2f / %.2f / %.2f',
 975         @aged_balances,
 976       );
 977     }
 978
 979   } else {
 980     # otherwise put them in the main section
 981     $previous_section = $default_section;
 982   }
 983
 984   my $adjust_section = {
 985     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 986     'adjust_section' => 1,
 987     'subtotal'       => 0,   # adjusted below
 988   };
 989   my $adjust_weight = _pkg_category($adjust_section->{description})
 990                         ? _pkg_category($adjust_section->{description})->weight
 991                         : 0;
 992   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 993   # Note: 'sort_weight' here is actually a flag telling whether there is an
 994   # explicit package category for the adjust section. If so, certain behavior
 995   # happens.
 996   $adjust_section->{'sort_weight'} = $adjust_weight;
 997
 998
 999   if ( $multisection ) {
1000     ($extra_sections, $extra_lines) =
1001       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
1002       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
1003       && $self->can('_items_extra_usage_sections');
1004
1005     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
1006
1007     push @detail_items, @$extra_lines if $extra_lines;
1008
1009     # the code is written so that both methods can be used together, but
1010     # we haven't yet changed the template to take advantage of that, so for
1011     # now, treat them as mutually exclusive.
1012     my %section_method = ( by_category => 1 );
1013     if ( $conf->config($tc.'sections_method') eq 'location' ) {
1014       %section_method = ( by_location => 1 );
1015     }
1016     my ($early, $late) =
1017       $self->_items_sections( 'summary' => $summarypage,
1018                               'escape'  => $escape_function_nonbsp,
1019                               'extra_sections' => $extra_sections,
1020                               'format'  => $format,
1021                               %section_method
1022                             );
1023     push @sections, @$early;
1024     $late_sections = $late;
1025
1026     if (    $conf->exists('svc_phone_sections')
1027          && $self->can('_items_svc_phone_sections')
1028        )
1029     {
1030       my ($phone_sections, $phone_lines) =
1031         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1032       push @{$late_sections}, @$phone_sections;
1033       push @detail_items, @$phone_lines;
1034     }
1035     if ( $conf->exists('voip-cust_accountcode_cdr')
1036          && $cust_main->accountcode_cdr
1037          && $self->can('_items_accountcode_cdr')
1038        )
1039     {
1040       my ($accountcode_section, $accountcode_lines) =
1041         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1042       if ( scalar(@$accountcode_lines) ) {
1043           push @{$late_sections}, $accountcode_section;
1044           push @detail_items, @$accountcode_lines;
1045       }
1046     }
1047   } else {# not multisection
1048     # make a default section
1049     push @sections, $default_section;
1050     # and calculate the finance charge total, since it won't get done otherwise.
1051     # and the default section total
1052     # XXX possibly finance_pkgclass should not be used in this manner?
1053     my @finance_charges;
1054     my @charges;
1055     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1056       if ( $invoice_data{finance_section} and
1057         grep { $_->section eq $invoice_data{finance_section} }
1058            $cust_bill_pkg->cust_bill_pkg_display ) {
1059         # I think these are always setup fees, but just to be sure...
1060         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1061       } else {
1062         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1063       }
1064     }
1065     $invoice_data{finance_amount} =
1066       sprintf('%.2f', sum( @finance_charges ) || 0);
1067     $default_section->{subtotal} = $other_money_char.
1068                                     sprintf('%.2f', sum( @charges ) || 0);
1069   }
1070
1071   # start setting up summary subtotals
1072   my @summary_subtotals;
1073   my $method = $conf->config('summary_subtotals_method');
1074   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1075     # then re-section them by the correct method
1076     my %section_method = ( by_category => 1 );
1077     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1078       %section_method = ( by_location => 1 );
1079     }
1080     my ($early, $late) =
1081       $self->_items_sections( 'summary' => $summarypage,
1082                               'escape'  => $escape_function_nonbsp,
1083                               'extra_sections' => $extra_sections,
1084                               'format'  => $format,
1085                               %section_method
1086                             );
1087     foreach ( @$early ) {
1088       next if $_->{subtotal} == 0;
1089       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1090       push @summary_subtotals, $_;
1091     }
1092   } else {
1093     # subtotal sectioning is the same as for the actual invoice sections
1094     @summary_subtotals = @sections;
1095   }
1096
1097   # Hereafter, push sections to both @sections and @summary_subtotals
1098   # if they belong in both places (e.g. tax section).  Late sections are
1099   # never in @summary_subtotals.
1100
1101   # previous invoice balances in the Previous Charges section if there
1102   # is one, otherwise in the main detail section
1103   # (except if summary_only is enabled, don't show them at all)
1104   if ( $self->can('_items_previous') &&
1105        $self->enable_previous &&
1106        ! $conf->exists('previous_balance-summary_only') ) {
1107
1108     warn "$me adding previous balances\n"
1109       if $DEBUG > 1;
1110
1111     foreach my $line_item ( $self->_items_previous ) {
1112
1113       my $detail = {
1114         ref             => $line_item->{'pkgnum'},
1115         pkgpart         => $line_item->{'pkgpart'},
1116         #quantity        => 1, # not really correct
1117         section         => $previous_section, # which might be $default_section
1118         description     => &$escape_function($line_item->{'description'}),
1119         ext_description => [ map { &$escape_function($_) }
1120                              @{ $line_item->{'ext_description'} || [] }
1121                            ],
1122         amount          => $money_char . $line_item->{'amount'},
1123         product_code    => $line_item->{'pkgpart'} || 'N/A',
1124       };
1125
1126       push @detail_items, $detail;
1127       push @buf, [ $detail->{'description'},
1128                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1129                  ];
1130     }
1131
1132   }
1133
1134   if ( $pr_total && $self->enable_previous ) {
1135     push @buf, ['','-----------'];
1136     push @buf, [ $self->mt('Total Previous Balance'),
1137                  $money_char. sprintf("%10.2f", $pr_total) ];
1138     push @buf, ['',''];
1139   }
1140
1141   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1142       warn "$me adding DID summary\n"
1143         if $DEBUG > 1;
1144
1145       my ($didsummary,$minutes) = $self->_did_summary;
1146       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1147       push @detail_items,
1148        { 'description' => $didsummary_desc,
1149            'ext_description' => [ $didsummary, $minutes ],
1150        };
1151   }
1152
1153   foreach my $section (@sections, @$late_sections) {
1154
1155     # begin some normalization
1156     $section->{'subtotal'} = $section->{'amount'}
1157       if $multisection
1158          && !exists($section->{subtotal})
1159          && exists($section->{amount});
1160
1161     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1162       if ( $invoice_data{finance_section} &&
1163            $section->{'description'} eq $invoice_data{finance_section} );
1164
1165     if ( $multisection ) {
1166
1167       if ( ref($section->{'subtotal'}) ) {
1168
1169         $section->{'subtotal'} =
1170           sprintf("$other_money_char%.2f to $other_money_char%.2f",
1171                     $section->{'subtotal'}[0],
1172                     $section->{'subtotal'}[1]
1173                  );
1174
1175       } else {
1176
1177         $section->{'subtotal'} = $other_money_char.
1178                                  sprintf('%.2f', $section->{'subtotal'})
1179
1180       }
1181
1182       # continue some normalization
1183       $section->{'amount'}   = $section->{'subtotal'}
1184
1185     }
1186
1187     if ( $section->{'description'} ) {
1188       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1189                    [ '', '' ],
1190                  );
1191     }
1192
1193     warn "$me   setting options\n"
1194       if $DEBUG > 1;
1195
1196     my %options = ();
1197     $options{'section'} = $section if $multisection;
1198     $options{'format'} = $format;
1199     $options{'escape_function'} = $escape_function;
1200     $options{'no_usage'} = 1 unless $unsquelched;
1201     $options{'unsquelched'} = $unsquelched;
1202     $options{'summary_page'} = $summarypage;
1203     $options{'skip_usage'} =
1204       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1205     $options{'preref_callback'} = $params{'preref_callback'};
1206
1207     warn "$me   searching for line items\n"
1208       if $DEBUG > 1;
1209
1210     foreach my $line_item ( $self->_items_pkg(%options),
1211                             $self->_items_fee(%options) ) {
1212
1213       warn "$me     adding line item ".
1214            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1215         if $DEBUG > 1;
1216
1217       push @buf, ( [ $line_item->{'description'},
1218                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1219                    ],
1220                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1221                  );
1222
1223       $line_item->{'ref'} = $line_item->{'pkgnum'};
1224       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1225       $line_item->{'section'} = $section;
1226       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1227       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1228
1229       if ( length($line_item->{'unit_amount'}) ) {
1230         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1231       }
1232       $line_item->{'ext_description'} ||= [];
1233
1234       push @detail_items, $line_item;
1235     }
1236
1237     if ( $section->{'description'} ) {
1238       push @buf, ( ['','-----------'],
1239                    [ $section->{'description'}. ' sub-total',
1240                       $section->{'subtotal'} # already formatted this
1241                    ],
1242                    [ '', '' ],
1243                    [ '', '' ],
1244                  );
1245     }
1246
1247   }
1248
1249   $invoice_data{current_less_finance} =
1250     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1251
1252   # if there's anything in the Previous Charges section, prepend it to the list
1253   if ( $pr_total and $previous_section ne $default_section ) {
1254     unshift @sections, $previous_section;
1255     # but not @summary_subtotals
1256   }
1257
1258   warn "$me adding taxes\n"
1259     if $DEBUG > 1;
1260
1261   # create a tax section if we don't yet have one
1262   my @items_tax = $self->_items_tax;
1263   my $tax_description = 'Taxes, Surcharges, and Fees';
1264   my $tax_section =
1265     List::Util::first { $_->{description} eq $tax_description } @sections;
1266   if (!$tax_section) {
1267     $tax_section = { 'description' => $tax_description };
1268     push @sections, $tax_section if $multisection and @items_tax > 0;
1269   }
1270   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1271   # if this is an existing tax section, we're merging the tax items into it.
1272   # grab the taxtotal that's already there, strip the money symbol if any
1273   my $taxtotal = $tax_section->{'subtotal'} || 0;
1274   $taxtotal =~ s/^\Q$other_money_char\E//;
1275
1276   # this does nothing
1277   #my $tax_weight = _pkg_category($tax_section->{description})
1278   #                      ? _pkg_category($tax_section->{description})->weight
1279   #                      : 0;
1280   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1281   #$tax_section->{'sort_weight'} = $tax_weight;
1282
1283   foreach my $tax ( @items_tax ) {
1284
1285     $taxtotal += $tax->{'amount'};
1286
1287     my $description = &$escape_function( $tax->{'description'} );
1288     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1289
1290     if ( $multisection ) {
1291
1292       push @detail_items, {
1293         ext_description => [],
1294         ref          => '',
1295         quantity     => '',
1296         description  => $description,
1297         amount       => $money_char. $amount,
1298         product_code => '',
1299         section      => $tax_section,
1300       };
1301
1302     } else {
1303
1304       push @total_items, {
1305         'total_item'   => $description,
1306         'total_amount' => $other_money_char. $amount,
1307       };
1308
1309     }
1310
1311     push @buf,[ $description,
1312                 $money_char. $amount,
1313               ];
1314
1315   }
1316
1317   if ( @items_tax ) {
1318     my $total = {};
1319     $total->{'total_item'} = $self->mt('Sub-total');
1320     $total->{'total_amount'} =
1321       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1322
1323     if ( $multisection ) {
1324       if ( $taxtotal > 0 ) {
1325         # there are taxes, so prepare the section to be displayed.
1326         # $taxtotal already includes any line items that were already in the
1327         # section (fees, taxes that are charged as packages for some reason).
1328         # also set 'summarized' to false so that this isn't a summary-only
1329         # section.
1330         $tax_section->{'subtotal'} = $other_money_char.
1331                                      sprintf('%.2f', $taxtotal);
1332         $tax_section->{'pretotal'} = 'New charges sub-total '.
1333                                      $total->{'total_amount'};
1334         $tax_section->{'description'} = $self->mt($tax_description);
1335         $tax_section->{'summarized'} = '';
1336
1337         # append it if it's not already there
1338         if ( !grep $tax_section, @sections ) {
1339           push @sections, $tax_section;
1340           push @summary_subtotals, $tax_section;
1341         }
1342       }
1343
1344     } else {
1345       unshift @total_items, $total;
1346     }
1347   }
1348   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1349
1350   ###
1351   # Totals
1352   ###
1353
1354   my %embolden_functions = (
1355     'latex'    => sub { return '\textbf{'. shift(). '}' },
1356     'html'     => sub { return '<b>'. shift(). '</b>' },
1357     'template' => sub { shift },
1358   );
1359   my $embolden_function = $embolden_functions{$format};
1360
1361   if ( $multisection ) {
1362
1363     if ( $adjust_section->{'sort_weight'} ) {
1364       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1365         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1366     } else{
1367       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1368         $other_money_char.  sprintf('%.2f', $self->charged );
1369     }
1370
1371   }
1372
1373   if ( $self->can('_items_total') ) { # should always be true now
1374
1375     # even for multisection, need plain text version
1376
1377     my @new_total_items = $self->_items_total;
1378
1379     push @buf,['','-----------'];
1380
1381     foreach ( @new_total_items ) {
1382       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1383       $_->{'total_item'}   = &$embolden_function( $item );
1384
1385       if ( ref($amount) ) {
1386         $_->{'total_amount'} = &$embolden_function(
1387                                  $other_money_char.$amount->[0]. ' to '.
1388                                  $other_money_char.$amount->[1]
1389                                );
1390       } else {
1391         $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1392       }
1393
1394       # but if it's multisection, don't append to @total_items. the adjust
1395       # section has all this stuff
1396       push @total_items, $_ if !$multisection;
1397       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1398     }
1399
1400     push @buf, [ '', '' ];
1401
1402     # if we're showing previous invoices, also show previous
1403     # credits and payments
1404     if ( $self->enable_previous
1405           and $self->can('_items_credits')
1406           and $self->can('_items_payments') )
1407       {
1408
1409       # credits
1410       my $credittotal = 0;
1411       foreach my $credit (
1412         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1413       ) {
1414
1415         my $total;
1416         $total->{'total_item'} = &$escape_function($credit->{'description'});
1417         $credittotal += $credit->{'amount'};
1418         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1419         if ( $multisection ) {
1420           push @detail_items, {
1421             ext_description => [],
1422             ref          => '',
1423             quantity     => '',
1424             description  => &$escape_function($credit->{'description'}),
1425             amount       => $money_char . $credit->{'amount'},
1426             product_code => '',
1427             section      => $adjust_section,
1428           };
1429         } else {
1430           push @total_items, $total;
1431         }
1432
1433       }
1434       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1435
1436       #credits (again)
1437       foreach my $credit (
1438         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1439       ) {
1440         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1441       }
1442
1443       # payments
1444       my $paymenttotal = 0;
1445       foreach my $payment (
1446         $self->_items_payments( 'template' => $template )
1447       ) {
1448         my $total = {};
1449         $total->{'total_item'} = &$escape_function($payment->{'description'});
1450         $paymenttotal += $payment->{'amount'};
1451         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1452         if ( $multisection ) {
1453           push @detail_items, {
1454             ext_description => [],
1455             ref          => '',
1456             quantity     => '',
1457             description  => &$escape_function($payment->{'description'}),
1458             amount       => $money_char . $payment->{'amount'},
1459             product_code => '',
1460             section      => $adjust_section,
1461           };
1462         }else{
1463           push @total_items, $total;
1464         }
1465         push @buf, [ $payment->{'description'},
1466                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1467                    ];
1468       }
1469       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1470
1471       if ( $multisection ) {
1472         $adjust_section->{'subtotal'} = $other_money_char.
1473                                         sprintf('%.2f', $credittotal + $paymenttotal);
1474
1475         #why this? because {sort_weight} forces the adjust_section to appear
1476         #in @extra_sections instead of @sections. obviously.
1477         push @sections, $adjust_section
1478           unless $adjust_section->{sort_weight};
1479         # do not summarize; adjustments there are shown according to
1480         # different rules
1481       }
1482
1483       # create Balance Due message
1484       {
1485         my $total;
1486         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1487         $total->{'total_amount'} =
1488           &$embolden_function(
1489             $other_money_char. sprintf('%.2f', #why? $summarypage
1490                                                #  ? $self->charged +
1491                                                #    $self->billing_balance
1492                                                #  :
1493                                                    $balance_due
1494                                       )
1495           );
1496         if ( $multisection && !$adjust_section->{sort_weight} ) {
1497           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1498                                            $total->{'total_amount'};
1499         } else {
1500           push @total_items, $total;
1501         }
1502         push @buf,['','-----------'];
1503         push @buf,[$self->balance_due_msg, $money_char.
1504           sprintf("%10.2f", $balance_due ) ];
1505       }
1506
1507       if ( $conf->exists('previous_balance-show_credit')
1508           and $cust_main->balance < 0 ) {
1509         my $credit_total = {
1510           'total_item'    => &$embolden_function($self->credit_balance_msg),
1511           'total_amount'  => &$embolden_function(
1512             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1513           ),
1514         };
1515         if ( $multisection ) {
1516           $adjust_section->{'posttotal'} .= $newline_token .
1517             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1518         }
1519         else {
1520           push @total_items, $credit_total;
1521         }
1522         push @buf,['','-----------'];
1523         push @buf,[$self->credit_balance_msg, $money_char.
1524           sprintf("%10.2f", -$cust_main->balance ) ];
1525       }
1526     }
1527
1528   } #end of default total adding ! can('_items_total')
1529
1530   if ( $multisection ) {
1531     if (    $conf->exists('svc_phone_sections')
1532          && $self->can('_items_svc_phone_sections')
1533        )
1534     {
1535       my $total;
1536       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1537       $total->{'total_amount'} =
1538         &$embolden_function(
1539           $other_money_char. sprintf('%.2f', $balance_due)
1540         );
1541       my $last_section = pop @sections;
1542       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1543                                      $total->{'total_amount'};
1544       push @sections, $last_section;
1545     }
1546     push @sections, @$late_sections
1547       if $unsquelched;
1548   }
1549
1550   # make a discounts-available section, even without multisection
1551   if ( $conf->exists('discount-show_available')
1552        and my @discounts_avail = $self->_items_discounts_avail ) {
1553     my $discount_section = {
1554       'description' => $self->mt('Discounts Available'),
1555       'subtotal'    => '',
1556       'no_subtotal' => 1,
1557     };
1558
1559     push @sections, $discount_section; # do not summarize
1560     push @detail_items, map { +{
1561         'ref'         => '', #should this be something else?
1562         'section'     => $discount_section,
1563         'description' => &$escape_function( $_->{description} ),
1564         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1565         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1566     } } @discounts_avail;
1567   }
1568
1569   # not adding any more sections after this
1570   $invoice_data{summary_subtotals} = \@summary_subtotals;
1571
1572   # usage subtotals
1573   if ( $conf->exists('usage_class_summary')
1574        and $self->can('_items_usage_class_summary') ) {
1575     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function, 'money_char' => $other_money_char);
1576     if ( @usage_subtotals ) {
1577       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1578       unshift @detail_items, @usage_subtotals;
1579     }
1580   }
1581
1582   # invoice history "section" (not really a section)
1583   # not to be included in any subtotals, completely independent of
1584   # everything...
1585   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1586     my %history;
1587     my %monthorder;
1588     foreach my $cust_bill ( $cust_main->cust_bill ) {
1589       # XXX hardcoded format, and currently only 'charged'; add other fields
1590       # if they become necessary
1591       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1592       $history{$date} ||= 0;
1593       $history{$date} += $cust_bill->charged;
1594       # just so we have a numeric sort key
1595       $monthorder{$date} ||= $cust_bill->_date;
1596     }
1597     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1598                         keys %history;
1599     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1600     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1601   }
1602
1603   # service locations: another option for template customization
1604   my %location_info;
1605   foreach my $item (@detail_items) {
1606     if ( $item->{locationnum} ) {
1607       $location_info{ $item->{locationnum} } ||= {
1608         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1609       };
1610     }
1611   }
1612   $invoice_data{location_info} = \%location_info;
1613
1614   # debugging hook: call this with 'diag' => 1 to just get a hash of
1615   # the invoice variables
1616   return \%invoice_data if ( $params{'diag'} );
1617
1618   # All sections and items are built; now fill in templates.
1619   my @includelist = ();
1620   push @includelist, 'summary' if $summarypage;
1621   foreach my $include ( @includelist ) {
1622
1623     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1624     my @inc_src;
1625
1626     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1627
1628       @inc_src = $conf->config($inc_file, $agentnum);
1629
1630     } else {
1631
1632       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1633
1634       my $convert_map = $convert_maps{$format}{$include};
1635
1636       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1637                        s/--\@\]/$delimiters{$format}[1]/g;
1638                        $_;
1639                      }
1640                  &$convert_map( $conf->config($inc_file, $agentnum) );
1641
1642     }
1643
1644     my $inc_tt = new Text::Template (
1645       TYPE       => 'ARRAY',
1646       SOURCE     => [ map "$_\n", @inc_src ],
1647       DELIMITERS => $delimiters{$format},
1648     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1649
1650     unless ( $inc_tt->compile() ) {
1651       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1652       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1653       die $error;
1654     }
1655
1656     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1657
1658     $invoice_data{$include} =~ s/\n+$//
1659       if ($format eq 'latex');
1660   }
1661
1662   $invoice_lines = 0;
1663   my $wasfunc = 0;
1664   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1665     /invoice_lines\((\d*)\)/;
1666     $invoice_lines += $1 || scalar(@buf);
1667     $wasfunc=1;
1668   }
1669   die "no invoice_lines() functions in template?"
1670     if ( $format eq 'template' && !$wasfunc );
1671
1672   if ( $invoice_lines ) {
1673     $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1674     $invoice_data{'total_pages'}++
1675       if scalar(@buf) % $invoice_lines;
1676   }
1677
1678   #setup subroutine for the template
1679   $invoice_data{invoice_lines} = sub {
1680     my $lines = shift || scalar(@buf);
1681     map {
1682       scalar(@buf)
1683         ? shift @buf
1684         : [ '', '' ];
1685     }
1686     ( 1 .. $lines );
1687   };
1688
1689   if ($format eq 'template') {
1690
1691     my $lines;
1692     my @collect;
1693     while (@buf) {
1694       push @collect, split("\n",
1695         $text_template->fill_in( HASH => \%invoice_data )
1696       );
1697       $invoice_data{'page'}++;
1698     }
1699     map "$_\n", @collect;
1700
1701   } else { # this is where we actually create the invoice
1702
1703     if ( $params{no_addresses} ) {
1704       delete $invoice_data{$_} foreach qw(
1705         payname company address1 address2 city state zip country
1706       );
1707       $invoice_data{returnaddress} = '~';
1708     }
1709
1710     warn "filling in template for invoice ". $self->invnum. "\n"
1711       if $DEBUG;
1712     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1713       if $DEBUG > 1;
1714
1715     $text_template->fill_in(HASH => \%invoice_data);
1716   }
1717 }
1718
1719 sub notice_name { '('.shift->table.')'; }
1720
1721 # this is not supposed to happen
1722 sub template_conf { warn "bare FS::Template_Mixin::template_conf";
1723   'invoice_';
1724 }
1725
1726 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1727
1728 Returns an postscript invoice, as a scalar.
1729
1730 Options can be passed as a hashref (recommended) or as a list of time, template
1731 and then any key/value pairs for any other options.
1732
1733 I<time> an optional value used to control the printing of overdue messages.  The
1734 default is now.  It isn't the date of the invoice; that's the `_date' field.
1735 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1736 L<Time::Local> and L<Date::Parse> for conversion functions.
1737
1738 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1739
1740 =cut
1741
1742 sub print_ps {
1743   my $self = shift;
1744
1745   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1746   my $ps = generate_ps($file);
1747   unlink($logofile);
1748   unlink($barcodefile) if $barcodefile;
1749
1750   $ps;
1751 }
1752
1753 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1754
1755 Returns an PDF invoice, as a scalar.
1756
1757 Options can be passed as a hashref (recommended) or as a list of time, template
1758 and then any key/value pairs for any other options.
1759
1760 I<time> an optional value used to control the printing of overdue messages.  The
1761 default is now.  It isn't the date of the invoice; that's the `_date' field.
1762 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1763 L<Time::Local> and L<Date::Parse> for conversion functions.
1764
1765 I<template>, if specified, is the name of a suffix for alternate invoices.
1766
1767 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1768
1769 =cut
1770
1771 sub print_pdf {
1772   my $self = shift;
1773
1774   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1775   my $pdf = generate_pdf($file);
1776   unlink($logofile);
1777   unlink($barcodefile) if $barcodefile;
1778
1779   $pdf;
1780 }
1781
1782 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1783
1784 Returns an HTML invoice, as a scalar.
1785
1786 I<time> an optional value used to control the printing of overdue messages.  The
1787 default is now.  It isn't the date of the invoice; that's the `_date' field.
1788 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1789 L<Time::Local> and L<Date::Parse> for conversion functions.
1790
1791 I<template>, if specified, is the name of a suffix for alternate invoices.
1792
1793 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1794
1795 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1796 when emailing the invoice as part of a multipart/related MIME email.
1797
1798 =cut
1799
1800 sub print_html {
1801   my $self = shift;
1802   my %params;
1803   if ( ref($_[0]) ) {
1804     %params = %{ shift() };
1805   } else {
1806     %params = @_;
1807   }
1808   $params{'format'} = 'html';
1809
1810   $self->print_generic( %params );
1811 }
1812
1813 # quick subroutine for print_latex
1814 #
1815 # There are ten characters that LaTeX treats as special characters, which
1816 # means that they do not simply typeset themselves:
1817 #      # $ % & ~ _ ^ \ { }
1818 #
1819 # TeX ignores blanks following an escaped character; if you want a blank (as
1820 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1821
1822 sub _latex_escape {
1823   my $value = shift;
1824   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1825   $value =~ s/([<>])/\$$1\$/g;
1826   $value;
1827 }
1828
1829 sub _html_escape {
1830   my $value = shift;
1831   encode_entities($value);
1832   $value;
1833 }
1834
1835 sub _html_escape_nbsp {
1836   my $value = _html_escape(shift);
1837   $value =~ s/ +/&nbsp;/g;
1838   $value;
1839 }
1840
1841 #utility methods for print_*
1842
1843 sub _translate_old_latex_format {
1844   warn "_translate_old_latex_format called\n"
1845     if $DEBUG;
1846
1847   my @template = ();
1848   while ( @_ ) {
1849     my $line = shift;
1850
1851     if ( $line =~ /^%%Detail\s*$/ ) {
1852
1853       push @template, q![@--!,
1854                       q!  foreach my $_tr_line (@detail_items) {!,
1855                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1856                       q!      $_tr_line->{'description'} .= !,
1857                       q!        "\\tabularnewline\n~~".!,
1858                       q!        join( "\\tabularnewline\n~~",!,
1859                       q!          @{$_tr_line->{'ext_description'}}!,
1860                       q!        );!,
1861                       q!    }!;
1862
1863       while ( ( my $line_item_line = shift )
1864               !~ /^%%EndDetail\s*$/                            ) {
1865         $line_item_line =~ s/'/\\'/g;    # nice LTS
1866         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1867         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1868         push @template, "    \$OUT .= '$line_item_line';";
1869       }
1870
1871       push @template, '}',
1872                       '--@]';
1873       #' doh, gvim
1874     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1875
1876       push @template, '[@--',
1877                       '  foreach my $_tr_line (@total_items) {';
1878
1879       while ( ( my $total_item_line = shift )
1880               !~ /^%%EndTotalDetails\s*$/                      ) {
1881         $total_item_line =~ s/'/\\'/g;    # nice LTS
1882         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1883         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1884         push @template, "    \$OUT .= '$total_item_line';";
1885       }
1886
1887       push @template, '}',
1888                       '--@]';
1889
1890     } else {
1891       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1892       push @template, $line;
1893     }
1894
1895   }
1896
1897   if ($DEBUG) {
1898     warn "$_\n" foreach @template;
1899   }
1900
1901   (@template);
1902 }
1903
1904 =item terms
1905
1906 =cut
1907
1908 sub terms {
1909   my $self = shift;
1910   my $conf = $self->conf;
1911
1912   #check for an invoice-specific override
1913   return $self->invoice_terms if $self->invoice_terms;
1914
1915   #check for a customer- specific override
1916   my $cust_main = $self->cust_main;
1917   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1918
1919   my $agentnum = '';
1920   if ( $cust_main ) {
1921     $agentnum = $cust_main->agentnum;
1922   } elsif ( my $prospect_main = $self->prospect_main ) {
1923     $agentnum = $prospect_main->agentnum;
1924   }
1925
1926   #use configured default
1927   $conf->config('invoice_default_terms', $agentnum) || '';
1928 }
1929
1930 =item due_date
1931
1932 =cut
1933
1934 sub due_date {
1935   my $self = shift;
1936   my $duedate = '';
1937   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1938     $duedate = $self->_date() + ( $1 * 86400 );
1939   } elsif ( $self->terms =~ /^End of Month$/ ) {
1940     my ($mon,$year) = (localtime($self->_date) )[4,5];
1941     $mon++;
1942     until ( $mon < 12 ) { $mon -= 12; $year++; }
1943     my $nextmonth_first = timelocal(0,0,0,1,$mon,$year);
1944     $duedate = $nextmonth_first - 86400;
1945   }
1946   $duedate;
1947 }
1948
1949 =item due_date2str
1950
1951 =cut
1952
1953 sub due_date2str {
1954   my $self = shift;
1955   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1956 }
1957
1958 =item invoice_pay_by_msg
1959
1960   displays the invoice_pay_by_msg or default Please pay by [_1] if empty.
1961
1962 =cut
1963
1964 sub invoice_pay_by_msg {
1965   my $self = shift;
1966   my $msg = '';
1967   my $please_pay_by =
1968         $self->conf->config('invoice_pay_by_msg', $self->agentnum)
1969         || 'Please pay by [_1]';
1970   $msg .= ' - ' . $self->mt($please_pay_by, $self->due_date2str('short')) . ' ';
1971
1972   $msg;
1973 }
1974
1975 =item balance_due_msg
1976
1977 =cut
1978
1979 sub balance_due_msg {
1980   my $self = shift;
1981   my $msg = $self->mt('Balance Due');
1982   return $msg unless $self->terms; # huh?
1983   if ( !$self->conf->exists('invoice_show_prior_due_date')
1984        or $self->conf->exists('invoice_sections') ) {
1985     # if enabled, the due date is shown with Total New Charges (see
1986     # _items_total) and not here
1987     # (yes, or if invoice_sections is enabled; this is just for compatibility)
1988     if ( $self->due_date ) {
1989       $msg .= $self->invoice_pay_by_msg
1990        unless $self->conf->config_bool('invoice_omit_due_date',$self->agentnum);
1991     } elsif ( $self->terms ) {
1992       $msg .= ' - '. $self->mt($self->terms);
1993     }
1994   }
1995   $msg;
1996 }
1997
1998 =item balance_due_date
1999
2000 =cut
2001
2002 sub balance_due_date {
2003   my $self = shift;
2004   my $conf = $self->conf;
2005   my $duedate = '';
2006   my $terms = $self->terms;
2007   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
2008     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
2009   }
2010   $duedate;
2011 }
2012
2013 sub credit_balance_msg {
2014   my $self = shift;
2015   $self->mt('Credit Balance Remaining')
2016 }
2017
2018 =item _date_pretty
2019
2020 Returns a string with the date, for example: "3/20/2008", localized for the
2021 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
2022
2023 =cut
2024
2025 sub _date_pretty {
2026   my $self = shift;
2027   $self->time2str_local('short', $self->_date);
2028 }
2029
2030 =item _date_pretty_unlocalized
2031
2032 Returns a string with the date, for example: "3/20/2008", in the format
2033 configured for the back-office.  Use _date_pretty for end-customer display use.
2034
2035 =cut
2036
2037 sub _date_pretty_unlocalized {
2038   my $self = shift;
2039   time2str($date_format, $self->_date);
2040 }
2041
2042 =item email HASHREF
2043
2044 Emails this template.
2045
2046 Options are passed as a hashref.  Available options:
2047
2048 =over 4
2049
2050 =item from
2051
2052 If specified, overrides the default From: address.
2053
2054 =item notice_name
2055
2056 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
2057
2058 =item template
2059
2060 (Deprecated) If specified, is the name of a suffix for alternate template files.
2061
2062 =back
2063
2064 Options accepted by generate_email can also be used.
2065
2066 =cut
2067
2068 sub email {
2069   my $self = shift;
2070   my $opt = shift || {};
2071   if ($opt and !ref($opt)) {
2072     die ref($self). '->email called with positional parameters';
2073   }
2074
2075   return if $self->hide;
2076
2077   my $error = send_email(
2078     $self->generate_email(
2079       'subject'     => $self->email_subject($opt->{template}),
2080       %$opt, # template, etc.
2081     )
2082   );
2083
2084   die "can't email: $error\n" if $error;
2085 }
2086
2087 =item generate_email OPTION => VALUE ...
2088
2089 Options:
2090
2091 =over 4
2092
2093 =item from
2094
2095 sender address, required
2096
2097 =item template
2098
2099 alternate template name, optional
2100
2101 =item subject
2102
2103 email subject, optional
2104
2105 =item notice_name
2106
2107 notice name instead of "Invoice", optional
2108
2109 =back
2110
2111 Returns an argument list to be passed to L<FS::Misc::send_email>.
2112
2113 =cut
2114
2115 use MIME::Entity;
2116 use Encode;
2117
2118 sub generate_email {
2119
2120   my $self = shift;
2121   my %args = @_;
2122   my $conf = $self->conf;
2123
2124   my $me = '[FS::Template_Mixin::generate_email]';
2125
2126   my %return = (
2127     'from'      => $args{'from'},
2128     'subject'   => ($args{'subject'} || $self->email_subject),
2129     'custnum'   => $self->custnum,
2130     'msgtype'   => 'invoice',
2131   );
2132
2133   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2134
2135   my $cust_main = $self->cust_main;
2136
2137   if (ref($args{'to'}) eq 'ARRAY') {
2138     $return{'to'} = $args{'to'};
2139   } elsif ( $cust_main ) {
2140     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2141   }
2142
2143   my $tc = $self->template_conf;
2144
2145   my @text; # array of lines
2146   my $html; # a big string
2147   my @related_parts; # will contain the text/HTML alternative, and images
2148   my $related; # will contain the multipart/related object
2149
2150   if ( $conf->exists($tc. 'email_pdf') ) {
2151     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2152
2153       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2154         if $DEBUG;
2155
2156       my $msg_template = FS::msg_template->by_key($msgnum)
2157         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2158       my $cust_msg = $msg_template->prepare(
2159         cust_main => $self->cust_main,
2160         object    => $self,
2161         msgtype   => 'invoice',
2162       );
2163
2164       # XXX hack to make this work in the new cust_msg era; consider replacing
2165       # with cust_bill_send_with_notice events.
2166       my @parts = $cust_msg->parts;
2167       foreach my $part (@parts) { # will only have two parts, normally
2168         if ( $part->mime_type eq 'text/plain' ) {
2169           @text = @{ $part->body };
2170         } elsif ( $part->mime_type eq 'text/html' ) {
2171           $html = $part->bodyhandle->as_string;
2172         }
2173       }
2174
2175     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2176
2177       warn "$me using '${tc}email_pdf_note' in multipart message"
2178         if $DEBUG;
2179       @text = $conf->config($tc.'email_pdf_note');
2180       $html = join('<BR>', @text);
2181
2182     } # else use the plain text invoice
2183   }
2184
2185   if (!@text) {
2186
2187     if ( $conf->config($tc.'template') ) {
2188
2189       warn "$me generating plain text invoice"
2190         if $DEBUG;
2191
2192       # 'print_text' argument is no longer used
2193       @text = map Encode::encode_utf8($_), $self->print_text(\%args);
2194
2195     } else {
2196
2197       warn "$me no plain text version exists; sending empty message body"
2198         if $DEBUG;
2199
2200     }
2201
2202   }
2203
2204   my $text_part = build MIME::Entity (
2205     'Type'        => 'text/plain',
2206     'Encoding'    => 'quoted-printable',
2207     'Charset'     => 'UTF-8',
2208     #'Encoding'    => '7bit',
2209     'Data'        => \@text,
2210     'Disposition' => 'inline',
2211   );
2212
2213   if (!$html) {
2214
2215     if ( $conf->exists($tc.'html') ) {
2216       warn "$me generating HTML invoice"
2217         if $DEBUG;
2218
2219       $args{'from'} =~ /\@([\w\.\-]+)/;
2220       my $from = $1 || 'example.com';
2221       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2222
2223       my $logo;
2224       my $agentnum = $cust_main ? $cust_main->agentnum
2225                                 : $self->prospect_main->agentnum;
2226       if ( defined($args{'template'}) && length($args{'template'})
2227            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2228          )
2229       {
2230         $logo = 'logo_'. $args{'template'}. '.png';
2231       } else {
2232         $logo = "logo.png";
2233       }
2234       my $image_data = $conf->config_binary( $logo, $agentnum);
2235
2236       push @related_parts, build MIME::Entity
2237         'Type'       => 'image/png',
2238         'Encoding'   => 'base64',
2239         'Data'       => $image_data,
2240         'Filename'   => 'logo.png',
2241         'Content-ID' => "<$content_id>",
2242       ;
2243
2244       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2245         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2246         push @related_parts, build MIME::Entity
2247           'Type'       => 'image/png',
2248           'Encoding'   => 'base64',
2249           'Data'       => $self->invoice_barcode(0),
2250           'Filename'   => 'barcode.png',
2251           'Content-ID' => "<$barcode_content_id>",
2252         ;
2253         $args{'barcode_cid'} = $barcode_content_id;
2254       }
2255
2256       $html = $self->print_html({ 'cid'=>$content_id, %args });
2257     }
2258
2259   }
2260
2261   if ( $html ) {
2262
2263     warn "$me creating HTML/text multipart message"
2264       if $DEBUG;
2265
2266     $return{'nobody'} = 1;
2267
2268     my $alternative = build MIME::Entity
2269       'Type'        => 'multipart/alternative',
2270       #'Encoding'    => '7bit',
2271       'Disposition' => 'inline'
2272     ;
2273
2274     if ( @text ) {
2275       $alternative->add_part($text_part);
2276     }
2277
2278     $alternative->attach(
2279       'Type'        => 'text/html',
2280       'Encoding'    => 'quoted-printable',
2281       'Data'        => [ '<html>',
2282                          '  <head>',
2283                          '    <title>',
2284                          '      '. encode_entities($return{'subject'}),
2285                          '    </title>',
2286                          '  </head>',
2287                          '  <body bgcolor="#e8e8e8">',
2288                          Encode::encode_utf8($html),
2289                          '  </body>',
2290                          '</html>',
2291                        ],
2292       'Disposition' => 'inline',
2293       #'Filename'    => 'invoice.pdf',
2294     );
2295
2296     unshift @related_parts, $alternative;
2297
2298     $related = build MIME::Entity 'Type'     => 'multipart/related',
2299                                   'Encoding' => '7bit';
2300
2301     #false laziness w/Misc::send_email
2302     $related->head->replace('Content-type',
2303       $related->mime_type.
2304       '; boundary="'. $related->head->multipart_boundary. '"'.
2305       '; type=multipart/alternative'
2306     );
2307
2308     $related->add_part($_) foreach @related_parts;
2309
2310   }
2311
2312   my @otherparts = ();
2313   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2314
2315     if ( $conf->config('voip-cdr_email_attach') eq 'zip' ) {
2316
2317       my $data = join('', map "$_\n",
2318                    $self->call_details(prepend_billed_number=>1)
2319                  );
2320
2321       my $zip = new Archive::Zip;
2322       my $file = $zip->addString( $data, 'usage-'.$self->invnum.'.csv' );
2323       $file->desiredCompressionMethod( COMPRESSION_DEFLATED );
2324
2325       my $zipdata = '';
2326       my $SH = IO::Scalar->new(\$zipdata);
2327       my $status = $zip->writeToFileHandle($SH);
2328       die "Error zipping CDR attachment: $!" unless $status == AZ_OK;
2329
2330       push @otherparts, build MIME::Entity
2331         'Type'        => 'application/zip',
2332         'Encoding'    => 'base64',
2333         'Data'        => $zipdata,
2334         'Disposition' => 'attachment',
2335         'Filename'    => 'usage-'. $self->invnum. '.zip',
2336       ;
2337
2338     } else { # } elsif ( $conf->config('voip-cdr_email_attach') eq 'csv' ) {
2339
2340       push @otherparts, build MIME::Entity
2341         'Type'        => 'text/csv',
2342         'Encoding'    => '7bit',
2343         'Data'        => [ map { "$_\n" }
2344                              $self->call_details('prepend_billed_number' => 1)
2345                          ],
2346         'Disposition' => 'attachment',
2347         'Filename'    => 'usage-'. $self->invnum. '.csv',
2348       ;
2349
2350     }
2351
2352   }
2353
2354   if ( $conf->exists($tc.'email_pdf') ) {
2355
2356     #attaching pdf too:
2357     # multipart/mixed
2358     #   multipart/related
2359     #     multipart/alternative
2360     #       text/plain
2361     #       text/html
2362     #     image/png
2363     #   application/pdf
2364
2365     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2366     push @otherparts, $pdf;
2367   }
2368
2369   if (@otherparts) {
2370     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2371     if ( $html ) {
2372       $return{'mimeparts'} = [ $related, @otherparts ];
2373       $return{'type'} = 'multipart/related'; # of the first part
2374     } else {
2375       $return{'mimeparts'} = [ $text_part, @otherparts ];
2376       $return{'type'} = 'text/plain';
2377     }
2378   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2379     $return{'mimeparts'} = \@related_parts;
2380     $return{'content-type'} = 'multipart/related';
2381     $return{'type'} = 'multipart/alternative';
2382   } else { # no HTML either
2383     $return{'body'} = \@text;
2384     $return{'content-type'} = 'text/plain';
2385   }
2386
2387   %return;
2388
2389 }
2390
2391 =item mimebuild_pdf
2392
2393 Returns a list suitable for passing to MIME::Entity->build(), representing
2394 this quotation or invoice as PDF attachment.
2395
2396 =cut
2397
2398 sub mimebuild_pdf {
2399   my $self = shift;
2400   (
2401     'Type'        => 'application/pdf',
2402     'Encoding'    => 'base64',
2403     'Data'        => [ $self->print_pdf(@_) ],
2404     'Disposition' => 'attachment',
2405     'Filename'    => $self->pdf_filename,
2406   );
2407 }
2408
2409 =item postal_mail_fsinc
2410
2411 Sends this invoice to the Freeside Internet Services, Inc. print and mail
2412 service.
2413
2414 =cut
2415
2416 use CAM::PDF;
2417 use IO::Socket::SSL;
2418 use LWP::UserAgent;
2419 use HTTP::Request::Common qw( POST );
2420 use Cpanel::JSON::XS;
2421 use MIME::Base64;
2422 sub postal_mail_fsinc {
2423   my ( $self, %opt ) = @_;
2424
2425   my $url = 'https://ws.freeside.biz/print';
2426
2427   my $cust_main = $self->cust_main;
2428   my $agentnum = $cust_main->agentnum;
2429   my $bill_location = $cust_main->bill_location;
2430
2431   die "Extra charges for international mailing; contact support\@freeside.biz to enable\n"
2432     if $bill_location->country ne 'US';
2433
2434   my $conf = new FS::Conf;
2435
2436   my @company_address = $conf->config('company_address', $agentnum);
2437   my ( $company_address1, $company_address2, $company_city, $company_state, $company_zip );
2438   if ( $company_address[2] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2439     $company_address1 = $company_address[0];
2440     $company_address2 = $company_address[1];
2441     $company_city  = $1;
2442     $company_state = $2;
2443     $company_zip   = $3;
2444   } elsif ( $company_address[1] =~ /^\s*(\S.*\S)\s*[\s,](\w\w),?\s*(\d{5}(-\d{4})?)\s*$/ ) {
2445     $company_address1 = $company_address[0];
2446     $company_address2 = '';
2447     $company_city  = $1;
2448     $company_state = $2;
2449     $company_zip   = $3;
2450   } else {
2451     die "Unparsable company_address; contact support\@freeside.biz\n";
2452   }
2453   $company_city =~ s/,$//;
2454
2455   my $file = $self->print_pdf(%opt, 'no_addresses' => 1);
2456   my $pages = CAM::PDF->new($file)->numPages;
2457
2458   my $ua = LWP::UserAgent->new(
2459     'ssl_opts' => {
2460       verify_hostname => 0,
2461       SSL_verify_mode => IO::Socket::SSL::SSL_VERIFY_NONE,
2462       SSL_version     => 'SSLv3',
2463     }
2464   );
2465   my $response = $ua->request( POST $url, [
2466     'support-key'      => scalar($conf->config('support-key')),
2467     'file'             => encode_base64($file),
2468     'pages'            => $pages,
2469
2470     #from:
2471     'company_name'     => scalar( $conf->config('company_name', $agentnum) ),
2472     'company_address1' => $company_address1,
2473     'company_address2' => $company_address2,
2474     'company_city'     => $company_city,
2475     'company_state'    => $company_state,
2476     'company_zip'      => $company_zip,
2477     'company_country'  => 'US',
2478     'company_phonenum' => scalar($conf->config('company_phonenum', $agentnum)),
2479     'company_email'    => scalar($conf->config('invoice_from', $agentnum)),
2480
2481     #to:
2482     'name'             => $cust_main->invoice_attn
2483                             || $cust_main->contact_firstlast,
2484     'company'          => $cust_main->company,
2485     'address1'         => $bill_location->address1,
2486     'address2'         => $bill_location->address2,
2487     'city'             => $bill_location->city,
2488     'state'            => $bill_location->state,
2489     'zip'              => $bill_location->zip,
2490     'country'          => $bill_location->country,
2491   ]);
2492
2493   die "Print connection error: ". $response->message.
2494       ' ('. $response->as_string. ")\n"
2495     unless $response->is_success;
2496
2497   local $@;
2498   my $content = eval { decode_json($response->content) };
2499   die "Print JSON error : $@\n" if $@;
2500
2501   die $content->{error}."\n"
2502     if $content->{error};
2503
2504   #TODO: store this so we can query for a status later
2505   warn "Invoice printed, ID ". $content->{id}. "\n";
2506
2507   $content->{id};
2508
2509 }
2510
2511 =item _items_sections OPTIONS
2512
2513 Generate section information for all items appearing on this invoice.
2514 This will only be called for multi-section invoices.
2515
2516 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2517 related display records (L<FS::cust_bill_pkg_display>) and organize
2518 them into two groups ("early" and "late" according to whether they come
2519 before or after the total), then into sections.  A subtotal is calculated
2520 for each section.
2521
2522 Section descriptions are returned in sort weight order.  Each consists
2523 of a hash containing:
2524
2525 description: the package category name, escaped
2526 subtotal: the total charges in that section
2527 tax_section: a flag indicating that the section contains only tax charges
2528 summarized: same as tax_section, for some reason
2529 sort_weight: the package category's sort weight
2530
2531 If 'condense' is set on the display record, it also contains everything
2532 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2533 coderefs to generate parts of the invoice.  This is not advised.
2534
2535 The method returns two arrayrefs, one of "early" sections and one of "late"
2536 sections.
2537
2538 OPTIONS may include:
2539
2540 by_location: a flag to divide the invoice into sections by location.
2541 Each section hash will have a 'location' element containing a hashref of
2542 the location fields (see L<FS::cust_location>).  The section description
2543 will be the location label, but the template can use any of the location
2544 fields to create a suitable label.
2545
2546 by_category: a flag to divide the invoice into sections using display
2547 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2548 behavior.  Each section hash will have a 'category' element containing
2549 the section name from the display record (which probably equals the
2550 category name of the package, but may not in some cases).
2551
2552 summary: a flag indicating that this is a summary-format invoice.
2553 Turning this on has the following effects:
2554 - Ignores display items with the 'summary' flag.
2555 - Places all sections in the "early" group even if they have post_total.
2556 - Creates sections for all non-disabled package categories, even if they
2557 have no charges on this invoice, as well as a section with no name.
2558
2559 escape: an escape function to use for section titles.
2560
2561 extra_sections: an arrayref of additional sections to return after the
2562 sorted list.  If there are any of these, section subtotals exclude
2563 usage charges.
2564
2565 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2566 passed through to C<_condense_section()>.
2567
2568 =cut
2569
2570 use vars qw(%pkg_category_cache);
2571 sub _items_sections {
2572   my $self = shift;
2573   my %opt = @_;
2574
2575   my $escape = $opt{escape};
2576   my @extra_sections = @{ $opt{extra_sections} || [] };
2577
2578   # $subtotal{$locationnum}{$categoryname} = amount.
2579   # if we're not using by_location, $locationnum is undef.
2580   # if we're not using by_category, you guessed it, $categoryname is undef.
2581   # if we're not using either one, we shouldn't be here in the first place...
2582   my %subtotal = ();
2583   my %late_subtotal = ();
2584   my %not_tax = ();
2585
2586   # About tax items + multisection invoices:
2587   # If either invoice_*summary option is enabled, AND there is a
2588   # package category with the name of the tax, then there will be
2589   # a display record assigning the tax item to that category.
2590   #
2591   # However, the taxes are always placed in the "Taxes, Surcharges,
2592   # and Fees" section regardless of that.  The only effect of the
2593   # display record is to create a subtotal for the summary page.
2594
2595   # cache these
2596   my $pkg_hash = $self->cust_pkg_hash;
2597
2598   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2599   {
2600
2601       my $usage = $cust_bill_pkg->usage;
2602
2603       my $locationnum;
2604       if ( $opt{by_location} ) {
2605         if ( $cust_bill_pkg->pkgnum ) {
2606           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2607         } else {
2608           $locationnum = '';
2609         }
2610       } else {
2611         $locationnum = undef;
2612       }
2613
2614       # as in _items_cust_pkg, if a line item has no display records,
2615       # cust_bill_pkg_display() returns a default record for it
2616
2617       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2618         next if ( $display->summary && $opt{summary} );
2619
2620         my $section = $display->section;
2621         my $type    = $display->type;
2622         # Set $section = undef if we're sectioning by location and this
2623         # line item _has_ a location (i.e. isn't a fee).
2624         $section = undef if $locationnum;
2625
2626         # set this flag if the section is not tax-only
2627         $not_tax{$locationnum}{$section} = 1
2628           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2629
2630         # there's actually a very important piece of logic buried in here:
2631         # incrementing $late_subtotal{$section} CREATES
2632         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2633         # to define the list of late sections, and likewise keys(%subtotal).
2634         # When _items_cust_bill_pkg is called to generate line items for
2635         # real, it will be called with 'section' => $section for each
2636         # of these.
2637         if ( $display->post_total && !$opt{summary} ) {
2638           if (! $type || $type eq 'S') {
2639             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2640               if $cust_bill_pkg->setup != 0
2641               || $cust_bill_pkg->setup_show_zero;
2642           }
2643
2644           if (! $type) {
2645             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2646               if $cust_bill_pkg->recur != 0
2647               || $cust_bill_pkg->recur_show_zero;
2648           }
2649
2650           if ($type && $type eq 'R') {
2651             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2652               if $cust_bill_pkg->recur != 0
2653               || $cust_bill_pkg->recur_show_zero;
2654           }
2655
2656           if ($type && $type eq 'U') {
2657             $late_subtotal{$locationnum}{$section} += $usage
2658               unless scalar(@extra_sections);
2659           }
2660
2661         } else { # it's a pre-total (normal) section
2662
2663           # skip tax items unless they're explicitly included in a section
2664           next if $cust_bill_pkg->pkgnum == 0 and
2665                   ! $cust_bill_pkg->feepart   and
2666                   ! $section;
2667
2668           if ( $type eq 'S' ) {
2669             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2670               if $cust_bill_pkg->setup != 0
2671               || $cust_bill_pkg->setup_show_zero;
2672           } elsif ( $type eq 'R' ) {
2673             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2674               if $cust_bill_pkg->recur != 0
2675               || $cust_bill_pkg->recur_show_zero;
2676           } elsif ( $type eq 'U' ) {
2677             $subtotal{$locationnum}{$section} += $usage
2678               unless scalar(@extra_sections);
2679           } elsif ( !$type ) {
2680             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2681                                                + $cust_bill_pkg->recur;
2682           }
2683
2684         }
2685
2686       }
2687
2688   }
2689
2690   %pkg_category_cache = ();
2691
2692   # summary invoices need subtotals for all non-disabled package categories,
2693   # even if they're zero
2694   # but currently assume that there are no location sections, or at least
2695   # that the summary page doesn't care about them
2696   if ( $opt{summary} ) {
2697     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2698       $subtotal{''}{$category->categoryname} ||= 0;
2699     }
2700     $subtotal{''}{''} ||= 0;
2701   }
2702
2703   my @sections;
2704   foreach my $post_total (0,1) {
2705     my @these;
2706     my $s = $post_total ? \%late_subtotal : \%subtotal;
2707     foreach my $locationnum (keys %$s) {
2708       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2709         my $section = {
2710                         'subtotal'    => $s->{$locationnum}{$sectionname},
2711                         'sort_weight' => 0,
2712                       };
2713         if ( $locationnum ) {
2714           $section->{'locationnum'} = $locationnum;
2715           my $location = FS::cust_location->by_key($locationnum);
2716           $section->{'description'} = &{ $escape }($location->location_label);
2717           # Better ideas? This will roughly group them by proximity,
2718           # which alpha sorting on any of the address fields won't.
2719           # Sorting by locationnum is meaningless.
2720           # We have to sort on _something_ or the order may change
2721           # randomly from one invoice to the next, which will confuse
2722           # people.
2723           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2724                                       $locationnum;
2725           $section->{'location'} = {
2726             label_prefix => &{ $escape }($location->label_prefix),
2727             map { $_ => &{ $escape }($location->get($_)) }
2728               $location->fields
2729           };
2730         } else {
2731           $section->{'category'} = $sectionname;
2732           $section->{'description'} = &{ $escape }($sectionname);
2733           if ( _pkg_category($sectionname) ) {
2734             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2735             if ( _pkg_category($sectionname)->condense ) {
2736               $section = { %$section, $self->_condense_section($opt{format}) };
2737             }
2738           }
2739         }
2740         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2741           # then it's a tax-only section
2742           $section->{'summarized'} = 'Y';
2743           $section->{'tax_section'} = 'Y';
2744         }
2745         push @these, $section;
2746       } # foreach $sectionname
2747     } #foreach $locationnum
2748     push @these, @extra_sections if $post_total == 0;
2749     # need an alpha sort for location sections, because postal codes can
2750     # be non-numeric
2751     $sections[ $post_total ] = [ sort {
2752       $opt{'by_location'} ?
2753         ($a->{sort_weight} cmp $b->{sort_weight}) :
2754         ($a->{sort_weight} <=> $b->{sort_weight})
2755       } @these ];
2756   } #foreach $post_total
2757
2758   return @sections; # early, late
2759 }
2760
2761 #helper subs for above
2762
2763 sub cust_pkg_hash {
2764   my $self = shift;
2765   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2766 }
2767
2768 sub _pkg_category {
2769   my $categoryname = shift;
2770   $pkg_category_cache{$categoryname} ||=
2771     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2772 }
2773
2774 my %condensed_format = (
2775   'label' => [ qw( Description Qty Amount ) ],
2776   'fields' => [
2777                 sub { shift->{description} },
2778                 sub { shift->{quantity} },
2779                 sub { my($href, %opt) = @_;
2780                       ($opt{dollar} || ''). $href->{amount};
2781                     },
2782               ],
2783   'align'  => [ qw( l r r ) ],
2784   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2785   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2786 );
2787
2788 sub _condense_section {
2789   my ( $self, $format ) = ( shift, shift );
2790   ( 'condensed' => 1,
2791     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2792       qw( description_generator
2793           header_generator
2794           total_generator
2795           total_line_generator
2796         )
2797   );
2798 }
2799
2800 sub _condensed_generator_defaults {
2801   my ( $self, $format ) = ( shift, shift );
2802   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2803 }
2804
2805 my %html_align = (
2806   'c' => 'center',
2807   'l' => 'left',
2808   'r' => 'right',
2809 );
2810
2811 sub _condensed_header_generator {
2812   my ( $self, $format ) = ( shift, shift );
2813
2814   my ( $f, $prefix, $suffix, $separator, $column ) =
2815     _condensed_generator_defaults($format);
2816
2817   if ($format eq 'latex') {
2818     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2819     $suffix = "\\\\\n\\hline";
2820     $separator = "&\n";
2821     $column =
2822       sub { my ($d,$a,$s,$w) = @_;
2823             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2824           };
2825   } elsif ( $format eq 'html' ) {
2826     $prefix = '<th></th>';
2827     $suffix = '';
2828     $separator = '';
2829     $column =
2830       sub { my ($d,$a,$s,$w) = @_;
2831             return qq!<th align="$html_align{$a}">$d</th>!;
2832       };
2833   }
2834
2835   sub {
2836     my @args = @_;
2837     my @result = ();
2838
2839     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2840       push @result,
2841         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2842     }
2843
2844     $prefix. join($separator, @result). $suffix;
2845   };
2846
2847 }
2848
2849 sub _condensed_description_generator {
2850   my ( $self, $format ) = ( shift, shift );
2851
2852   my ( $f, $prefix, $suffix, $separator, $column ) =
2853     _condensed_generator_defaults($format);
2854
2855   my $money_char = '$';
2856   if ($format eq 'latex') {
2857     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2858     $suffix = '\\\\';
2859     $separator = " & \n";
2860     $column =
2861       sub { my ($d,$a,$s,$w) = @_;
2862             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2863           };
2864     $money_char = '\\dollar';
2865   }elsif ( $format eq 'html' ) {
2866     $prefix = '"><td align="center"></td>';
2867     $suffix = '';
2868     $separator = '';
2869     $column =
2870       sub { my ($d,$a,$s,$w) = @_;
2871             return qq!<td align="$html_align{$a}">$d</td>!;
2872       };
2873     #$money_char = $conf->config('money_char') || '$';
2874     $money_char = '';  # this is madness
2875   }
2876
2877   sub {
2878     #my @args = @_;
2879     my $href = shift;
2880     my @result = ();
2881
2882     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2883       my $dollar = '';
2884       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2885       push @result,
2886         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2887                     map { $f->{$_}->[$i] } qw(align span width)
2888                   );
2889     }
2890
2891     $prefix. join( $separator, @result ). $suffix;
2892   };
2893
2894 }
2895
2896 sub _condensed_total_generator {
2897   my ( $self, $format ) = ( shift, shift );
2898
2899   my ( $f, $prefix, $suffix, $separator, $column ) =
2900     _condensed_generator_defaults($format);
2901   my $style = '';
2902
2903   if ($format eq 'latex') {
2904     $prefix = "& ";
2905     $suffix = "\\\\\n";
2906     $separator = " & \n";
2907     $column =
2908       sub { my ($d,$a,$s,$w) = @_;
2909             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2910           };
2911   }elsif ( $format eq 'html' ) {
2912     $prefix = '';
2913     $suffix = '';
2914     $separator = '';
2915     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2916     $column =
2917       sub { my ($d,$a,$s,$w) = @_;
2918             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2919       };
2920   }
2921
2922
2923   sub {
2924     my @args = @_;
2925     my @result = ();
2926
2927     #  my $r = &{$f->{fields}->[$i]}(@args);
2928     #  $r .= ' Total' unless $i;
2929
2930     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2931       push @result,
2932         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2933                     map { $f->{$_}->[$i] } qw(align span width)
2934                   );
2935     }
2936
2937     $prefix. join( $separator, @result ). $suffix;
2938   };
2939
2940 }
2941
2942 =item total_line_generator FORMAT
2943
2944 Returns a coderef used for generation of invoice total line items for this
2945 usage_class.  FORMAT is either html or latex
2946
2947 =cut
2948
2949 # should not be used: will have issues with hash element names (description vs
2950 # total_item and amount vs total_amount -- another array of functions?
2951
2952 sub _condensed_total_line_generator {
2953   my ( $self, $format ) = ( shift, shift );
2954
2955   my ( $f, $prefix, $suffix, $separator, $column ) =
2956     _condensed_generator_defaults($format);
2957   my $style = '';
2958
2959   if ($format eq 'latex') {
2960     $prefix = "& ";
2961     $suffix = "\\\\\n";
2962     $separator = " & \n";
2963     $column =
2964       sub { my ($d,$a,$s,$w) = @_;
2965             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2966           };
2967   }elsif ( $format eq 'html' ) {
2968     $prefix = '';
2969     $suffix = '';
2970     $separator = '';
2971     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2972     $column =
2973       sub { my ($d,$a,$s,$w) = @_;
2974             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2975       };
2976   }
2977
2978
2979   sub {
2980     my @args = @_;
2981     my @result = ();
2982
2983     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2984       push @result,
2985         &{$column}( &{$f->{fields}->[$i]}(@args),
2986                     map { $f->{$_}->[$i] } qw(align span width)
2987                   );
2988     }
2989
2990     $prefix. join( $separator, @result ). $suffix;
2991   };
2992
2993 }
2994
2995 =item _items_pkg [ OPTIONS ]
2996
2997 Return line item hashes for each package item on this invoice. Nearly
2998 equivalent to
2999
3000 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
3001
3002 OPTIONS are passed through to _items_cust_bill_pkg, and should include
3003 'format' and 'escape_function' at minimum.
3004
3005 To produce items for a specific invoice section, OPTIONS should include
3006 'section', a hashref containing 'category' and/or 'locationnum' keys.
3007
3008 'section' may also contain a key named 'condensed'. If this is present
3009 and has a true value, _items_pkg will try to merge identical items into items
3010 with 'quantity' equal to the number of items (not the sum of their separate
3011 quantities, for some reason).
3012
3013 =cut
3014
3015 sub _items_nontax {
3016   my $self = shift;
3017   # The order of these is important.  Bundled line items will be merged into
3018   # the most recent non-hidden item, so it needs to be the one with:
3019   # - the same pkgnum
3020   # - the same start date
3021   # - no pkgpart_override
3022   #
3023   # So: sort by pkgnum,
3024   # then by sdate
3025   # then sort the base line item before any overrides
3026   # then sort hidden before non-hidden add-ons
3027   # then sort by override pkgpart (for consistency)
3028   sort { $a->pkgnum <=> $b->pkgnum        or
3029          $a->sdate  <=> $b->sdate         or
3030          ($a->pkgpart_override ? 0 : -1)  or
3031          ($b->pkgpart_override ? 0 : 1)   or
3032          $b->hidden cmp $a->hidden        or
3033          $a->pkgpart_override <=> $b->pkgpart_override
3034        }
3035   # and of course exclude taxes and fees
3036   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
3037 }
3038
3039 sub _items_fee {
3040   my $self = shift;
3041   my %options = @_;
3042   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
3043   my $escape_function = $options{escape_function};
3044
3045   my @items;
3046   foreach my $cust_bill_pkg (@cust_bill_pkg) {
3047     # cache this, so we don't look it up again in every section
3048     my $part_fee = $cust_bill_pkg->get('part_fee')
3049        || $cust_bill_pkg->part_fee;
3050     $cust_bill_pkg->set('part_fee', $part_fee);
3051     if (!$part_fee) {
3052       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
3053       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
3054       next;
3055     }
3056     if ( exists($options{section}) and exists($options{section}{category}) )
3057     {
3058       my $categoryname = $options{section}{category};
3059       # then filter for items that have that section
3060       if ( $part_fee->categoryname ne $categoryname ) {
3061         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
3062         next;
3063       }
3064     } # otherwise include them all in the main section
3065     # XXX what to do when sectioning by location?
3066
3067     my @ext_desc;
3068     my %base_invnums; # invnum => invoice date
3069     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
3070       if ($_->base_invnum) {
3071         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
3072         my $base_date = $self->time2str_local('short', $base_bill->_date)
3073           if $base_bill;
3074         $base_invnums{$_->base_invnum} = $base_date || '';
3075       }
3076     }
3077     foreach (sort keys(%base_invnums)) {
3078       next if $_ == $self->invnum;
3079       # per convention, we must escape ext_description lines
3080       push @ext_desc,
3081         &{$escape_function}(
3082           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
3083         );
3084     }
3085     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
3086     # but not escape the base description line
3087
3088     push @items,
3089       { feepart     => $cust_bill_pkg->feepart,
3090         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
3091         description => $desc,
3092         ext_description => \@ext_desc
3093         # sdate/edate?
3094       };
3095   }
3096   @items;
3097 }
3098
3099 sub _items_pkg {
3100   my $self = shift;
3101   my %options = @_;
3102
3103   warn "$me _items_pkg searching for all package line items\n"
3104     if $DEBUG > 1;
3105
3106   my @cust_bill_pkg = $self->_items_nontax;
3107
3108   warn "$me _items_pkg filtering line items\n"
3109     if $DEBUG > 1;
3110   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3111
3112   if ($options{section} && $options{section}->{condensed}) {
3113
3114     warn "$me _items_pkg condensing section\n"
3115       if $DEBUG > 1;
3116
3117     my %itemshash = ();
3118     local $Storable::canonical = 1;
3119     foreach ( @items ) {
3120       my $item = { %$_ };
3121       delete $item->{ref};
3122       delete $item->{ext_description};
3123       my $key = freeze($item);
3124       $itemshash{$key} ||= 0;
3125       $itemshash{$key} ++; # += $item->{quantity};
3126     }
3127     @items = sort { $a->{description} cmp $b->{description} }
3128              map { my $i = thaw($_);
3129                    $i->{quantity} = $itemshash{$_};
3130                    $i->{amount} =
3131                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
3132                    $i;
3133                  }
3134              keys %itemshash;
3135   }
3136
3137   warn "$me _items_pkg returning ". scalar(@items). " items\n"
3138     if $DEBUG > 1;
3139
3140   @items;
3141 }
3142
3143 sub _taxsort {
3144   return 0 unless $a->itemdesc cmp $b->itemdesc;
3145   return -1 if $b->itemdesc eq 'Tax';
3146   return 1 if $a->itemdesc eq 'Tax';
3147   return -1 if $b->itemdesc eq 'Other surcharges';
3148   return 1 if $a->itemdesc eq 'Other surcharges';
3149   $a->itemdesc cmp $b->itemdesc;
3150 }
3151
3152 sub _items_tax {
3153   my $self = shift;
3154   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
3155     $self->cust_bill_pkg;
3156   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
3157
3158   if ( $self->conf->exists('always_show_tax') ) {
3159     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
3160     if (0 == grep { $_->{description} eq $itemdesc } @items) {
3161       push @items,
3162         { 'description' => $itemdesc,
3163           'amount'      => 0.00 };
3164     }
3165   }
3166   @items;
3167 }
3168
3169 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
3170
3171 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
3172 list of hashrefs describing the line items they generate on the invoice.
3173
3174 OPTIONS may include:
3175
3176 format: the invoice format.
3177
3178 escape_function: the function used to escape strings.
3179
3180 DEPRECATED? (expensive, mostly unused?)
3181 format_function: the function used to format CDRs.
3182
3183 section: a hashref containing 'category' and/or 'locationnum'; if this
3184 is present, only returns line items that belong to that category and/or
3185 location (whichever is defined).
3186
3187 multisection: a flag indicating that this is a multisection invoice,
3188 which does something complicated.
3189
3190 Returns a list of hashrefs, each of which may contain:
3191
3192 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
3193 ext_description, which is an arrayref of detail lines to show below
3194 the package line.
3195
3196 =cut
3197
3198 sub _items_cust_bill_pkg {
3199   my $self = shift;
3200   my $conf = $self->conf;
3201   my $cust_bill_pkgs = shift;
3202   my %opt = @_;
3203
3204   my $format = $opt{format} || '';
3205   my $escape_function = $opt{escape_function} || sub { shift };
3206   my $format_function = $opt{format_function} || '';
3207   my $no_usage = $opt{no_usage} || '';
3208   my $unsquelched = $opt{unsquelched} || ''; #unused
3209   my ($section, $locationnum, $category);
3210   if ( $opt{section} ) {
3211     $category = $opt{section}->{category};
3212     $locationnum = $opt{section}->{locationnum};
3213   }
3214   my $summary_page = $opt{summary_page} || ''; #unused
3215   my $multisection = defined($category) || defined($locationnum);
3216   # this variable is the value of the config setting, not whether it applies
3217   # to this particular line item.
3218   my $discount_show_always = $conf->exists('discount-show-always');
3219
3220   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3221
3222   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3223
3224   # for location labels: use default location on the invoice date
3225   my $default_locationnum;
3226   if ( $conf->exists('invoice-all_pkg_addresses') ) {
3227     $default_locationnum = 0; # treat them all as non-default
3228   } elsif ( $self->custnum ) {
3229     my $h_cust_main;
3230     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3231     $h_cust_main = qsearchs({
3232         'table'     => 'h_cust_main',
3233         'hashref'   => { custnum => $self->custnum },
3234         'extra_sql' => $h_search[1],
3235         'addl_from' => $h_search[3],
3236     }) || $cust_main;
3237     $default_locationnum = $h_cust_main->ship_locationnum;
3238   } elsif ( $self->prospectnum ) {
3239     my $cust_location = qsearchs('cust_location',
3240       { prospectnum => $self->prospectnum,
3241         disabled => '' });
3242     $default_locationnum = $cust_location->locationnum if $cust_location;
3243   }
3244
3245   my @b = (); # accumulator for the line item hashes that we'll return
3246   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3247             # the 'current' line item hashes for setup, recur, usage, discount
3248   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3249   {
3250     # if the current line item is waiting to go out, and the one we're about
3251     # to start is not bundled, then push out the current one and start a new
3252     # one.
3253     if ( $d ) {
3254       $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3255     }
3256     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3257       if ( $_ && !$cust_bill_pkg->hidden ) {
3258         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3259         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3260         if (exists($_->{unit_amount})) {
3261           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3262         }
3263         push @b, { %$_ };
3264         # we already decided to create this display line; don't reconsider it
3265         # now.
3266         #  if $_->{amount} != 0
3267         #  || $discount_show_always
3268         #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3269         #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3270         ;
3271         $_ = undef;
3272       }
3273     }
3274
3275     if ( $locationnum ) {
3276       # this is a location section; skip packages that aren't at this
3277       # service location.
3278       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3279       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3280               != $locationnum;
3281     }
3282
3283     # Consider display records for this item to determine if it belongs
3284     # in this section.  Note that if there are no display records, there
3285     # will be a default pseudo-record that includes all charge types
3286     # and has no section name.
3287     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3288                                   ? $cust_bill_pkg->cust_bill_pkg_display
3289                                   : ( $cust_bill_pkg );
3290
3291     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3292          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3293       if $DEBUG > 1;
3294
3295     if ( defined($category) ) {
3296       # then this is a package category section; process all display records
3297       # that belong to this section.
3298       @cust_bill_pkg_display = grep { $_->section eq $category }
3299                                 @cust_bill_pkg_display;
3300     } else {
3301       # otherwise, process all display records that aren't usage summaries
3302       # (I don't think there should be usage summaries if you aren't using
3303       # category sections, but this is the historical behavior)
3304       @cust_bill_pkg_display = grep { !$_->summary }
3305                                 @cust_bill_pkg_display;
3306     }
3307
3308     my $classname = ''; # package class name, will fill in later
3309
3310     foreach my $display (@cust_bill_pkg_display) {
3311
3312       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3313            $display->billpkgdisplaynum. "\n"
3314         if $DEBUG > 1;
3315
3316       my $type = $display->type;
3317
3318       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3319       $desc = substr($desc, 0, $maxlength). '...'
3320         if $format eq 'latex' && length($desc) > $maxlength;
3321
3322       my %details_opt = ( 'format'          => $format,
3323                           'escape_function' => $escape_function,
3324                           'format_function' => $format_function,
3325                           'no_usage'        => $opt{'no_usage'},
3326                         );
3327
3328       if ( $cust_bill_pkg->pkgnum > 0 ) {
3329         # a "normal" package line item (not a quotation, not a fee, not a tax)
3330
3331         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3332           if $DEBUG > 1;
3333
3334         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3335         my $part_pkg = $cust_pkg->part_pkg;
3336
3337         # which pkgpart to show for display purposes?
3338         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3339
3340         # start/end dates for invoice formats that do nonstandard
3341         # things with them
3342         my %item_dates = ();
3343         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3344           unless $part_pkg->option('disable_line_item_date_ranges',1);
3345
3346         # not normally used, but pass this to the template anyway
3347         $classname = $part_pkg->classname;
3348
3349         if (    (!$type || $type eq 'S')
3350              && (    $cust_bill_pkg->setup != 0
3351                   || $cust_bill_pkg->setup_show_zero
3352                   || ($discount_show_always and $cust_bill_pkg->unitsetup > 0)
3353                 )
3354            )
3355          {
3356
3357           warn "$me _items_cust_bill_pkg adding setup\n"
3358             if $DEBUG > 1;
3359
3360           # append the word 'Setup' to the setup line if there's going to be
3361           # a recur line for the same package (i.e. not a one-time charge)
3362           # XXX localization
3363           my $description = $desc;
3364           $description .= ' Setup'
3365             if $cust_bill_pkg->recur != 0
3366             || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3367             || $cust_bill_pkg->recur_show_zero;
3368
3369           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3370                                                               $self->agentnum )
3371             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3372                                      # triggered by the recurring charge freq
3373                                      # (RT#26274)
3374             && $cust_bill_pkg->recur == 0
3375             && ! $cust_bill_pkg->recur_show_zero;
3376
3377           my @d = ();
3378           my @svc_labels = ();
3379           my $svc_label = '';
3380
3381           unless ( $part_pkg->hide_svc_detail ) {
3382
3383             # still pass the svc_label through to the template, even if
3384             # not displaying it as an ext_description
3385             @svc_labels = map &{$escape_function}($_),
3386               $cust_pkg->h_labels_short($self->_date,
3387                                         undef,
3388                                         'I',
3389                                         $self->conf->{locale},
3390                                        );
3391             $svc_label = $svc_labels[0];
3392
3393           }
3394
3395           unless ( $part_pkg->hide_svc_detail
3396                 || $cust_bill_pkg->hidden )
3397           {
3398
3399             push @d, @svc_labels
3400               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3401             # show the location label if it's not the customer's default
3402             # location, and we're not grouping items by location already
3403             if ( $cust_pkg->locationnum != $default_locationnum
3404                   and !defined($locationnum) ) {
3405               my $loc = $cust_pkg->location_label;
3406               $loc = substr($loc, 0, $maxlength). '...'
3407                 if $format eq 'latex' && length($loc) > $maxlength;
3408               push @d, &{$escape_function}($loc);
3409             }
3410
3411           } #unless hiding service details
3412
3413           push @d, $cust_bill_pkg->details(%details_opt)
3414             if $cust_bill_pkg->recur == 0;
3415
3416           if ( $cust_bill_pkg->hidden ) {
3417             $s->{amount}      += $cust_bill_pkg->setup;
3418             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3419             push @{ $s->{ext_description} }, @d;
3420           } else {
3421             $s = {
3422               _is_setup       => 1,
3423               description     => $description,
3424               pkgpart         => $pkgpart,
3425               pkgnum          => $cust_bill_pkg->pkgnum,
3426               amount          => $cust_bill_pkg->setup,
3427               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3428               unit_amount     => $cust_bill_pkg->unitsetup,
3429               quantity        => $cust_bill_pkg->quantity,
3430               ext_description => \@d,
3431               svc_label       => ($svc_label || ''),
3432               locationnum     => $cust_pkg->locationnum, # sure, why not?
3433             };
3434           };
3435
3436         }
3437
3438         # should we show a recur line?
3439         # if type eq 'S', then NO, because we've been told not to.
3440         # otherwise, show the recur line if:
3441         # - there's a recurring charge
3442         # - or recur_show_zero is on
3443         # - or there's a positive unitrecur (so it's been discounted to zero)
3444         #   and discount-show-always is on
3445         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3446              && (
3447                      $cust_bill_pkg->recur != 0
3448                   || !defined($s)
3449                   || ($discount_show_always and $cust_bill_pkg->unitrecur > 0)
3450                   || $cust_bill_pkg->recur_show_zero
3451                 )
3452            )
3453         {
3454
3455           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3456             if $DEBUG > 1;
3457
3458           my $is_summary = $display->summary;
3459           my $description = $desc;
3460           if ( $type eq 'U' and defined($r) ) {
3461             # don't just show the same description as the recur line
3462             $description = $self->mt('Usage charges');
3463           }
3464
3465           my $part_pkg = $cust_pkg->part_pkg;
3466
3467           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3468                                                               $self->agentnum );
3469
3470           my @d = ();
3471           my @seconds = (); # for display of usage info
3472           my @svc_labels = ();
3473           my $svc_label = '';
3474
3475           #at least until cust_bill_pkg has "past" ranges in addition to
3476           #the "future" sdate/edate ones... see #3032
3477           my @dates = ( $self->_date );
3478           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3479           push @dates, $prev->sdate if $prev;
3480           push @dates, undef if !$prev;
3481
3482           unless ( $part_pkg->hide_svc_detail ) {
3483             @svc_labels = map &{$escape_function}($_),
3484               $cust_pkg->h_labels_short(@dates,
3485                                         'I',
3486                                         $self->conf->{locale});
3487             $svc_label = $svc_labels[0];
3488           }
3489
3490           # show service labels, unless...
3491                     # the package is set not to display them
3492           unless ( $part_pkg->hide_svc_detail
3493                     # or this is a tax-like line item
3494                 || $cust_bill_pkg->itemdesc
3495                     # or this is a hidden (bundled) line item
3496                 || $cust_bill_pkg->hidden
3497                     # or this is a usage summary line
3498                 || $is_summary && $type && $type eq 'U'
3499                     # or this is a usage line and there's a recurring line
3500                     # for the package in the same section (which will
3501                     # have service labels already)
3502                 || ($type eq 'U' and defined($r))
3503               )
3504           {
3505
3506             warn "$me _items_cust_bill_pkg adding service details\n"
3507               if $DEBUG > 1;
3508
3509             push @d, @svc_labels
3510               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3511             warn "$me _items_cust_bill_pkg done adding service details\n"
3512               if $DEBUG > 1;
3513
3514             # show the location label if it's not the customer's default
3515             # location, and we're not grouping items by location already
3516             if ( $cust_pkg->locationnum != $default_locationnum
3517                   and !defined($locationnum) ) {
3518               my $loc = $cust_pkg->location_label;
3519               $loc = substr($loc, 0, $maxlength). '...'
3520                 if $format eq 'latex' && length($loc) > $maxlength;
3521               push @d, &{$escape_function}($loc);
3522             }
3523
3524             # Display of seconds_since_sqlradacct:
3525             # On the invoice, when processing @detail_items, look for a field
3526             # named 'seconds'.  This will contain total seconds for each
3527             # service, in the same order as @ext_description.  For services
3528             # that don't support this it will show undef.
3529             if ( $conf->exists('svc_acct-usage_seconds')
3530                  and ! $cust_bill_pkg->pkgpart_override ) {
3531               foreach my $cust_svc (
3532                   $cust_pkg->h_cust_svc(@dates, 'I')
3533                 ) {
3534
3535                 # eval because not having any part_export_usage exports
3536                 # is a fatal error, last_bill/_date because that's how
3537                 # sqlradius_hour billing does it
3538                 my $sec = eval {
3539                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3540                 };
3541                 push @seconds, $sec;
3542               }
3543             } #if svc_acct-usage_seconds
3544
3545           } # if we are showing service labels
3546
3547           unless ( $is_summary ) {
3548             warn "$me _items_cust_bill_pkg adding details\n"
3549               if $DEBUG > 1;
3550
3551             #instead of omitting details entirely in this case (unwanted side
3552             # effects), just omit CDRs
3553             $details_opt{'no_usage'} = 1
3554               if $type && $type eq 'R';
3555
3556             push @d, $cust_bill_pkg->details(%details_opt);
3557           }
3558
3559           warn "$me _items_cust_bill_pkg calculating amount\n"
3560             if $DEBUG > 1;
3561
3562           my $amount = 0;
3563           if (!$type) {
3564             $amount = $cust_bill_pkg->recur;
3565           } elsif ($type eq 'R') {
3566             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3567           } elsif ($type eq 'U') {
3568             $amount = $cust_bill_pkg->usage;
3569           }
3570
3571           if ( !$type || $type eq 'R' ) {
3572
3573             warn "$me _items_cust_bill_pkg adding recur\n"
3574               if $DEBUG > 1;
3575
3576             my $unit_amount =
3577               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3578                                                 : $amount;
3579
3580             if ( $cust_bill_pkg->hidden ) {
3581               $r->{amount}      += $amount;
3582               $r->{unit_amount} += $unit_amount;
3583               push @{ $r->{ext_description} }, @d;
3584             } else {
3585               $r = {
3586                 description     => $description,
3587                 pkgpart         => $pkgpart,
3588                 pkgnum          => $cust_bill_pkg->pkgnum,
3589                 amount          => $amount,
3590                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3591                 unit_amount     => $unit_amount,
3592                 quantity        => $cust_bill_pkg->quantity,
3593                 %item_dates,
3594                 ext_description => \@d,
3595                 svc_label       => ($svc_label || ''),
3596                 locationnum     => $cust_pkg->locationnum,
3597               };
3598               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3599             }
3600
3601           } else {  # $type eq 'U'
3602
3603             warn "$me _items_cust_bill_pkg adding usage\n"
3604               if $DEBUG > 1;
3605
3606             if ( $cust_bill_pkg->hidden and defined($u) ) {
3607               # if this is a hidden package and there's already a usage
3608               # line for the bundle, add this package's total amount and
3609               # usage details to it
3610               $u->{amount}      += $amount;
3611               push @{ $u->{ext_description} }, @d;
3612             } elsif ( $amount ) {
3613               # create a new usage line
3614               $u = {
3615                 description     => $description,
3616                 pkgpart         => $pkgpart,
3617                 pkgnum          => $cust_bill_pkg->pkgnum,
3618                 amount          => $amount,
3619                 usage_item      => 1,
3620                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3621                 %item_dates,
3622                 ext_description => \@d,
3623                 locationnum     => $cust_pkg->locationnum,
3624               };
3625             } # else this has no usage, so don't create a usage section
3626           }
3627
3628         } # recurring or usage with recurring charge
3629
3630       } else { # taxes and fees
3631
3632         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3633           if $DEBUG > 1;
3634
3635         # items of this kind should normally not have sdate/edate.
3636         push @b, {
3637           'description' => $desc,
3638           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3639                                            + $cust_bill_pkg->recur)
3640         };
3641
3642       } # if package line item / other line item
3643
3644       # decide whether to show active discounts here
3645       if (
3646           # case 1: we are showing a single line for the package
3647           ( !$type )
3648           # case 2: we are showing a setup line for a package that has
3649           # no base recurring fee
3650           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3651           # case 3: we are showing a recur line for a package that has
3652           # a base recurring fee
3653           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3654       ) {
3655
3656         my $item_discount = $cust_bill_pkg->_item_discount;
3657         if ( $item_discount ) {
3658           # $item_discount->{amount} is negative
3659
3660           if ( $d and $cust_bill_pkg->hidden ) {
3661             $d->{setup_amount} += $item_discount->{setup_amount};
3662             $d->{recur_amount} += $item_discount->{recur_amount};
3663           } else {
3664             $d = $item_discount;
3665             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3666           }
3667
3668           # update the active line (before the discount) to show the
3669           # original price (whether this is a hidden line or not)
3670
3671           $s->{amount} -= $item_discount->{setup_amount} if $s;
3672           $r->{amount} -= $item_discount->{recur_amount} if $r;
3673
3674         } # if there are any discounts
3675       } # if this is an appropriate place to show discounts
3676
3677     } # foreach $display
3678
3679   }
3680
3681   # discount amount is internally split up
3682   if ( $d ) {
3683     $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
3684   }
3685
3686   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3687     if ( $_  ) {
3688       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3689         if exists($_->{amount});
3690       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3691       if (exists($_->{unit_amount})) {
3692         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3693       }
3694
3695       push @b, { %$_ };
3696       #if $_->{amount} != 0
3697       #  || $discount_show_always
3698       #  || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3699       #  || (   $_->{_is_setup} && $_->{setup_show_zero} )
3700     }
3701   }
3702
3703   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3704     if $DEBUG > 1;
3705
3706   @b;
3707
3708 }
3709
3710 =item _items_discounts_avail
3711
3712 Returns an array of line item hashrefs representing available term discounts
3713 for this invoice.  This makes the same assumptions that apply to term
3714 discounts in general: that the package is billed monthly, at a flat rate,
3715 with no usage charges.  A prorated first month will be handled, as will
3716 a setup fee if the discount is allowed to apply to setup fees.
3717
3718 =cut
3719
3720 sub _items_discounts_avail {
3721   my $self = shift;
3722
3723   #maybe move this method from cust_bill when quotations support discount_plans
3724   return () unless $self->can('discount_plans');
3725   my %plans = $self->discount_plans;
3726
3727   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3728   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3729
3730   map {
3731     my $months = $_;
3732     my $plan = $plans{$months};
3733
3734     my $term_total = sprintf('%.2f', $plan->discounted_total);
3735     my $percent = sprintf('%.0f',
3736                           100 * (1 - $term_total / $plan->base_total) );
3737     my $permonth = sprintf('%.2f', $term_total / $months);
3738     my $detail = $self->mt('discount on item'). ' '.
3739                  join(', ', map { "#$_" } $plan->pkgnums)
3740       if $list_pkgnums;
3741
3742     # discounts for non-integer months don't work anyway
3743     $months = sprintf("%d", $months);
3744
3745     +{
3746       description => $self->mt('Save [_1]% by paying for [_2] months',
3747                                 $percent, $months),
3748       amount      => $self->mt('[_1] ([_2] per month)',
3749                                 $term_total, $money_char.$permonth),
3750       ext_description => ($detail || ''),
3751     }
3752   } #map
3753   sort { $b <=> $a } keys %plans;
3754
3755 }
3756
3757 1;