FS/FS/TemplateItem_Mixin.pm

   1 package FS::TemplateItem_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me $conf $date_format );
   5 use Carp;
   6 use Date::Format;
   7 use FS::UID;
   8 use FS::Record qw( qsearch qsearchs dbh );
   9 use FS::Conf;
  10 use FS::part_pkg;
  11 use FS::cust_pkg;
  12
  13 $DEBUG = 0;
  14 $me = '[FS::TemplateItem_Mixin]';
  15 FS::UID->install_callback( sub {
  16   $conf = new FS::Conf;
  17   $date_format      = $conf->config('date_format')      || '%x'; #/YY
  18 } );
  19
  20 =item cust_pkg
  21
  22 Returns the package (see L<FS::cust_pkg>) for this invoice line item.
  23
  24 =cut
  25
  26 sub cust_pkg {
  27   my $self = shift;
  28   carp "$me $self -> cust_pkg" if $DEBUG;
  29   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
  30 }
  31
  32 =item part_pkg
  33
  34 Returns the package definition for this invoice line item.
  35
  36 =cut
  37
  38 sub part_pkg {
  39   my $self = shift;
  40   if ( $self->pkgpart_override ) {
  41     qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart_override } );
  42   } else {
  43     my $part_pkg;
  44     my $cust_pkg = $self->cust_pkg;
  45     $part_pkg = $cust_pkg->part_pkg if $cust_pkg;
  46     $part_pkg;
  47   }
  48 }
  49
  50 =item part_fee
  51
  52 Returns the fee definition for this line item, if there is one.
  53
  54 =cut
  55
  56 sub part_fee {
  57   my $self = shift;
  58   $self->feepart
  59     ? FS::part_fee->by_key($self->feepart)
  60     : '';
  61 }
  62
  63 =item part_X
  64
  65 Returns L</part_pkg> or L</part_fee>, whichever is applicable (or nothing,
  66 if called on a tax line item).
  67
  68 =cut
  69
  70 sub part_X {
  71   my $self = shift;
  72   $self->part_pkg || $self->part_fee;
  73 }
  74
  75 =item desc LOCALE
  76
  77 Returns a description for this line item.  For typical line items, this is the
  78 I<pkg> field of the corresponding B<FS::part_pkg> object (see L<FS::part_pkg>).
  79 For one-shot line items and named taxes, it is the I<itemdesc> field of this
  80 line item, and for generic taxes, simply returns "Tax".
  81
  82 =cut
  83
  84 sub desc {
  85   my( $self, $locale ) = @_;
  86
  87   if ( $self->pkgnum > 0 ) {
  88     return $self->itemdesc if $self->itemdesc;
  89     my $part_pkg = $self->part_pkg or return 'UNKNOWN';
  90     return $part_pkg->pkg_locale($locale);
  91
  92   } elsif ( $self->feepart ) {
  93     return $self->part_fee->itemdesc_locale($locale);
  94
  95   } else { # by the process of elimination it must be a tax
  96     my $desc = $self->itemdesc || 'Tax';
  97     $desc .= ' '. $self->itemcomment if $self->itemcomment =~ /\S/;
  98     return $desc;
  99   }
 100
 101 }
 102
 103 =item time_period_pretty PART_PKG, AGENTNUM
 104
 105 Returns a formatted time period for this line item.
 106
 107 =cut
 108
 109 sub time_period_pretty {
 110   my( $self, $part_pkg, $agentnum ) = @_;
 111
 112   #more efficient to look some of this conf stuff up outside the
 113   # invoice/template display loop we're called from
 114   # (Template_Mixin::_invoice_cust_bill_pkg) and pass them in as options
 115
 116   return '' if $conf->exists('disable_line_item_date_ranges')
 117             || $part_pkg->option('disable_line_item_date_ranges',1)
 118             || ! $self->sdate
 119             || ! $self->edate;
 120
 121   my $date_style = '';
 122   $date_style = $conf->config( 'cust_bill-line_item-date_style-non_monhtly',
 123                                $agentnum
 124                              )
 125     if $part_pkg && $part_pkg->freq !~ /^1m?$/;
 126   $date_style ||= $conf->config( 'cust_bill-line_item-date_style',
 127                                   $agentnum
 128                                );
 129
 130   my $time_period;
 131   if ( defined($date_style) && $date_style eq 'month_of' ) {
 132     # (now watch, someone's going to make us do Chinese)
 133     $time_period = $self->mt('The month of [_1]',
 134                       $self->time2str_local('%B', $self->sdate)
 135                    );
 136   } elsif ( defined($date_style) && $date_style eq 'X_month' ) {
 137     my $desc = $conf->config( 'cust_bill-line_item-date_description',
 138                                $agentnum
 139                             );
 140     $desc .= ' ' unless $desc =~ /\s$/;
 141     $time_period = $desc. $self->time2str_local('%B', $self->sdate);
 142   } else {
 143     $time_period =      $self->time2str_local($date_format, $self->sdate).
 144                  " - ". $self->time2str_local($date_format, $self->edate);
 145   }
 146
 147   " ($time_period)";
 148
 149 }
 150
 151 =item details [ OPTION => VALUE ... ]
 152
 153 Returns an array of detail information for the invoice line item.
 154
 155 Options may include:
 156
 157 I<format>: set to 'html' or 'latex' to have the detail lines formatted for
 158 inclusion in an HTML table (wrapped in <tr> and <td> elements) or LaTeX table
 159 (delimited with & and \\ operators).
 160
 161 I<escape_function>: if present, then the array elements are processed by this
 162 function before being returned.
 163
 164 I<format_function>: overrides the normal HTML or LaTeX function for returning
 165 formatted CDRs.
 166
 167 I<no_usage>: excludes call detail records.  The method will still return
 168 some special-case records like prorate details, and manually created package
 169 details.
 170
 171 =cut
 172
 173 sub details {
 174   my ( $self, %opt ) = @_;
 175   my $escape_function = $opt{escape_function} || sub { shift };
 176
 177   my $csv = new Text::CSV_XS;
 178
 179   if ( $opt{format_function} ) {
 180
 181     #this still expects to be passed a cust_bill_pkg_detail object as the
 182     #second argument, which is expensive
 183     carp "deprecated format_function passed to cust_bill_pkg->details";
 184     my $format_sub = $opt{format_function} if $opt{format_function};
 185
 186     map { ( $_->format eq 'C'
 187               ? &{$format_sub}( $_->detail, $_ )
 188               : &{$escape_function}( $_->detail )
 189           )
 190         }
 191       qsearch ({ 'table'    => $self->detail_table,
 192                  'hashref'  => { 'billpkgnum' => $self->billpkgnum },
 193                  'order_by' => 'ORDER BY detailnum',
 194               });
 195
 196   } elsif ( $opt{'no_usage'} ) {
 197
 198     my $sql = "SELECT detail FROM ". $self->detail_table.
 199               "  WHERE billpkgnum = ". $self->billpkgnum.
 200               "    AND ( format IS NULL OR format != 'C' ) ".
 201               "  ORDER BY detailnum";
 202     my $sth = dbh->prepare($sql) or die dbh->errstr;
 203     $sth->execute or die $sth->errstr;
 204
 205     map &{$escape_function}( $_->[0] ), @{ $sth->fetchall_arrayref };
 206
 207   } else {
 208
 209     my $format_sub;
 210     my $format = $opt{format} || '';
 211     if ( $format eq 'html' ) {
 212
 213       $format_sub = sub { my $detail = shift;
 214                           $csv->parse($detail) or return "can't parse $detail";
 215                           join('</TD><TD>', map { &$escape_function($_) }
 216                                             $csv->fields
 217                               );
 218                         };
 219
 220     } elsif ( $format eq 'latex' ) {
 221
 222       $format_sub = sub {
 223         my $detail = shift;
 224         $csv->parse($detail) or return "can't parse $detail";
 225         #join(' & ', map { '\small{'. &$escape_function($_). '}' }
 226         #            $csv->fields );
 227         my $result = '';
 228         my $column = 1;
 229         foreach ($csv->fields) {
 230           $result .= ' & ' if $column > 1;
 231           if ($column > 6) {                     # KLUDGE ALERT!
 232             $result .= '\multicolumn{1}{l}{\scriptsize{'.
 233                        &$escape_function($_). '}}';
 234           }else{
 235             $result .= '\scriptsize{'.  &$escape_function($_). '}';
 236           }
 237           $column++;
 238         }
 239         $result;
 240       };
 241
 242     } else {
 243
 244       $format_sub = sub { my $detail = shift;
 245                           $csv->parse($detail) or return "can't parse $detail";
 246                           join(' - ', map { &$escape_function($_) }
 247                                       $csv->fields
 248                               );
 249                         };
 250
 251     }
 252
 253     my $sql = "SELECT format, detail FROM ". $self->detail_table.
 254               "  WHERE billpkgnum = ". $self->billpkgnum.
 255               "  ORDER BY detailnum";
 256     my $sth = dbh->prepare($sql) or die dbh->errstr;
 257     $sth->execute or die $sth->errstr;
 258
 259     #avoid the fetchall_arrayref and loop for less memory usage?
 260
 261     map { (defined($_->[0]) && $_->[0] eq 'C')
 262             ? &{$format_sub}(      $_->[1] )
 263             : &{$escape_function}( $_->[1] );
 264         }
 265       @{ $sth->fetchall_arrayref };
 266
 267   }
 268
 269 }
 270
 271 =item details_header [ OPTION => VALUE ... ]
 272
 273 Returns a list representing an invoice line item detail header, if any.
 274 This relies on the behavior of voip_cdr in that it expects the header
 275 to be the first CSV formatted detail (as is expected by invoice generation
 276 routines).  Returns the empty list otherwise.
 277
 278 =cut
 279
 280 sub details_header {
 281   my $self = shift;
 282
 283   my $csv = new Text::CSV_XS;
 284
 285   my @detail =
 286     qsearch ({ 'table'    => $self->detail_table,
 287                'hashref'  => { 'billpkgnum' => $self->billpkgnum,
 288                                'format'     => 'C',
 289                              },
 290                'order_by' => 'ORDER BY detailnum LIMIT 1',
 291             });
 292   return() unless scalar(@detail);
 293   $csv->parse($detail[0]->detail) or return ();
 294   $csv->fields;
 295 }
 296
 297 =item quantity
 298
 299 =cut
 300
 301 sub quantity {
 302   my( $self, $value ) = @_;
 303   if ( defined($value) ) {
 304     $self->setfield('quantity', $value);
 305   }
 306   $self->getfield('quantity') || 1;
 307 }
 308
 309 =item unitsetup
 310
 311 =cut
 312
 313 sub unitsetup {
 314   my( $self, $value ) = @_;
 315   if ( defined($value) ) {
 316     $self->setfield('unitsetup', $value);
 317   }
 318   $self->getfield('unitsetup') eq ''
 319     ? $self->getfield('setup')
 320     : $self->getfield('unitsetup');
 321 }
 322
 323 =item unitrecur
 324
 325 =cut
 326
 327 sub unitrecur {
 328   my( $self, $value ) = @_;
 329   if ( defined($value) ) {
 330     $self->setfield('unitrecur', $value);
 331   }
 332   $self->getfield('unitrecur') eq ''
 333     ? $self->getfield('recur')
 334     : $self->getfield('unitrecur');
 335 }
 336
 337 =item cust_bill_pkg_display [ type => TYPE ]
 338
 339 Returns an array of display information for the invoice line item optionally
 340 limited to 'TYPE'.
 341
 342 =cut
 343
 344 sub cust_bill_pkg_display {
 345   my ( $self, %opt ) = @_;
 346
 347   my $class = 'FS::'. $self->display_table;
 348
 349   my $default = $class->new( { billpkgnum =>$self->billpkgnum } );
 350
 351   my $type = $opt{type} if exists $opt{type};
 352   my @result;
 353
 354   if ( $self->get('display') ) {
 355     @result = grep { defined($type) ? ($type eq $_->type) : 1 }
 356               @{ $self->get('display') };
 357   } else {
 358     my $hashref = { 'billpkgnum' => $self->billpkgnum };
 359     $hashref->{type} = $type if defined($type);
 360
 361     my $order_by = $self->display_table_orderby || 'billpkgdisplaynum';
 362
 363     @result = qsearch ({ 'table'    => $self->display_table,
 364                          'hashref'  => $hashref,
 365                          'order_by' => "ORDER BY $order_by",
 366                       });
 367   }
 368
 369   push @result, $default unless ( scalar(@result) || $type );
 370
 371   @result;
 372
 373 }
 374
 375 =item cust_bill_pkg_detail [ CLASSNUM ]
 376
 377 Returns the list of associated cust_bill_pkg_detail objects
 378 The optional CLASSNUM argument will limit the details to the specified usage
 379 class.
 380
 381 =cut
 382
 383 sub cust_bill_pkg_detail {
 384   my $self = shift;
 385   my $classnum = shift || '';
 386
 387   my %hash = ( 'billpkgnum' => $self->billpkgnum );
 388   $hash{classnum} = $classnum if $classnum;
 389
 390   qsearch( $self->detail_table, \%hash ),
 391
 392 }
 393
 394 =item pkg_discount
 395
 396 Returns the list of associated cust_bill_pkg_discount or
 397 quotation_pkg_discount objects.
 398
 399 =cut
 400
 401 sub pkg_discount {
 402   my $self = shift;
 403   my $pkey = $self->primary_key;
 404   qsearch( $self->discount_table, { $pkey => $self->get($pkey) } );
 405 }
 406
 407 1;