FS/FS/TaxEngine/internal.pm

   1 package FS::TaxEngine::internal;
   2
   3 use strict;
   4 use base 'FS::TaxEngine';
   5 use FS::Record qw(dbh qsearch qsearchs);
   6 use FS::Conf;
   7 use vars qw( $conf );
   8
   9 FS::UID->install_callback(sub {
  10     $conf = FS::Conf->new;
  11 });
  12
  13 =head1 SUMMARY
  14
  15 FS::TaxEngine::internal: the classic Freeside "internal tax engine".
  16 Uses tax rates and localities defined in L<FS::cust_main_county>.
  17
  18 =cut
  19
  20 my %part_pkg_cache;
  21
  22 sub add_sale {
  23   my ($self, $cust_bill_pkg) = @_;
  24
  25   my $part_item = $cust_bill_pkg->part_X;
  26   my $location = $cust_bill_pkg->tax_location;
  27   my $custnum = $self->{cust_main}->custnum;
  28
  29   push @{ $self->{items} }, $cust_bill_pkg;
  30
  31   my %taxhash = map { $_ => $location->get($_) }
  32                 qw( district county state country );
  33   # city names in cust_main_county are uppercase
  34   $taxhash{'city'} = uc($location->get('city'));
  35
  36   $taxhash{'taxclass'} = $part_item->taxclass;
  37
  38   my @taxes = (); # entries are cust_main_county objects
  39   my %taxhash_elim = %taxhash;
  40   my @elim = qw( district city county state );
  41   do {
  42
  43     #first try a match with taxclass
  44     @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
  45
  46     if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
  47       #then try a match without taxclass
  48       my %no_taxclass = %taxhash_elim;
  49       $no_taxclass{ 'taxclass' } = '';
  50       @taxes = qsearch( 'cust_main_county', \%no_taxclass );
  51     }
  52
  53     $taxhash_elim{ shift(@elim) } = '';
  54   } while ( !scalar(@taxes) && scalar(@elim) );
  55
  56   foreach my $tax (@taxes) {
  57     my $taxnum = $tax->taxnum;
  58     $self->{taxes}->{$taxnum} ||= [ $tax ];
  59     $cust_bill_pkg->set_exemptions( $tax, 'custnum' => $custnum );
  60     push @{ $self->{taxes}->{$taxnum} }, $cust_bill_pkg;
  61   }
  62 }
  63
  64 sub taxline {
  65   my ($self, %opt) = @_;
  66   my $tax_object = $opt{tax};
  67   my $taxables = $opt{sales};
  68   my $taxnum = $tax_object->taxnum;
  69   my $exemptions = $self->{exemptions}->{$taxnum} ||= [];
  70
  71   my $taxable_total = 0;
  72   my $tax_cents = 0;
  73
  74   my $round_per_line_item = $conf->exists('tax-round_per_line_item');
  75
  76   my $cust_main = $self->{cust_main};
  77   my $custnum   = $cust_main->custnum;
  78   my $invoice_time = $self->{invoice_time};
  79
  80   # set a flag if the customer is tax-exempt
  81   my $exempt_cust;
  82   my $conf = FS::Conf->new;
  83   if ( $conf->exists('cust_class-tax_exempt') ) {
  84     my $cust_class = $cust_main->cust_class;
  85     $exempt_cust = $cust_class->tax if $cust_class;
  86   } else {
  87     $exempt_cust = $cust_main->tax;
  88   }
  89   # set a flag if the customer is exempt from this tax here
  90   my $exempt_cust_taxname = $cust_main->tax_exemption($tax_object->taxname)
  91     if $tax_object->taxname;
  92
  93   # Gather any exemptions that are already attached to these cust_bill_pkgs
  94   # so that we can deduct them from the customer's monthly limit.
  95   my @existing_exemptions = @{ $exemptions };
  96   push @existing_exemptions, @{ $_->cust_tax_exempt_pkg }
  97     foreach @$taxables;
  98
  99   my @tax_links;
 100
 101   foreach my $cust_bill_pkg (@$taxables) {
 102
 103     my $cust_pkg  = $cust_bill_pkg->cust_pkg;
 104     my $part_pkg  = $cust_bill_pkg->part_pkg;
 105     my @new_exemptions;
 106     my $taxable_charged = $cust_bill_pkg->setup + $cust_bill_pkg->recur
 107       or next; # don't create zero-amount exemptions
 108
 109     # XXX the following procedure should probably be in cust_bill_pkg
 110
 111     if ( $exempt_cust ) {
 112
 113       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 114           amount => $taxable_charged,
 115           exempt_cust => 'Y',
 116         });
 117       $taxable_charged = 0;
 118
 119     } elsif ( $exempt_cust_taxname ) {
 120
 121       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 122           amount => $taxable_charged,
 123           exempt_cust_taxname => 'Y',
 124         });
 125       $taxable_charged = 0;
 126
 127     }
 128
 129     if ( ($part_pkg->setuptax eq 'Y' or $tax_object->setuptax eq 'Y')
 130         and $cust_bill_pkg->setup > 0 and $taxable_charged > 0 ) {
 131
 132       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 133           amount => $cust_bill_pkg->setup,
 134           exempt_setup => 'Y'
 135       });
 136       $taxable_charged -= $cust_bill_pkg->setup;
 137
 138     }
 139     if ( ($part_pkg->recurtax eq 'Y' or $tax_object->recurtax eq 'Y')
 140         and $cust_bill_pkg->recur > 0 and $taxable_charged > 0 ) {
 141
 142       push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 143           amount => $cust_bill_pkg->recur,
 144           exempt_recur => 'Y'
 145       });
 146        $taxable_charged -= $cust_bill_pkg->recur;
 147
 148     }
 149
 150     if ( $tax_object->exempt_amount && $tax_object->exempt_amount > 0
 151       and $taxable_charged > 0 ) {
 152       # If the billing period extends across multiple calendar months,
 153       # there may be several months of exemption available.
 154       my $sdate = $cust_bill_pkg->sdate || $invoice_time;
 155       my $start_month = (localtime($sdate))[4] + 1;
 156       my $start_year  = (localtime($sdate))[5] + 1900;
 157       my $edate = $cust_bill_pkg->edate || $invoice_time;
 158       my $end_month   = (localtime($edate))[4] + 1;
 159       my $end_year    = (localtime($edate))[5] + 1900;
 160
 161       # If the partial last month + partial first month <= one month,
 162       # don't use the exemption in the last month
 163       # (unless the last month is also the first month, e.g. one-time
 164       # charges)
 165       if ( (localtime($sdate))[3] >= (localtime($edate))[3]
 166            and ($start_month != $end_month or $start_year != $end_year)
 167      ) {
 168         $end_month--;
 169         if ( $end_month == 0 ) {
 170           $end_year--;
 171           $end_month = 12;
 172         }
 173       }
 174
 175       # number of months of exemption available
 176       my $freq = ($end_month - $start_month) +
 177                  ($end_year  - $start_year) * 12 +
 178                  1;
 179
 180       # divide equally among all of them
 181       my $permonth = sprintf('%.2f', $taxable_charged / $freq);
 182
 183       #call the whole thing off if this customer has any old
 184       #exemption records...
 185       my @cust_tax_exempt =
 186         qsearch( 'cust_tax_exempt' => { custnum=> $custnum } );
 187       if ( @cust_tax_exempt ) {
 188         return
 189           'this customer still has old-style tax exemption records; '.
 190           'run bin/fs-migrate-cust_tax_exempt?';
 191       }
 192
 193       my ($mon, $year) = ($start_month, $start_year);
 194       while ($taxable_charged > 0.005 and
 195              ($year < $end_year or
 196                ($year == $end_year and $mon <= $end_month)
 197              )
 198       ) {
 199
 200         # find the sum of the exemption used by this customer, for this tax,
 201         # in this month
 202         my $sql = "
 203           SELECT SUM(amount)
 204             FROM cust_tax_exempt_pkg
 205               LEFT JOIN cust_bill_pkg USING ( billpkgnum )
 206               LEFT JOIN cust_bill     USING ( invnum     )
 207             WHERE custnum = ?
 208              AND taxnum  = ?
 209               AND year    = ?
 210               AND month   = ?
 211               AND exempt_monthly = 'Y'
 212         ";
 213         my $sth = dbh->prepare($sql) or
 214           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 215         $sth->execute(
 216           $custnum,
 217           $tax_object->taxnum,
 218           $year,
 219           $mon,
 220         ) or
 221           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 222         my $existing_exemption = $sth->fetchrow_arrayref->[0] || 0;
 223
 224         # add any exemption we're already using for another line item
 225        foreach ( grep { $_->taxnum == $tax_object->taxnum &&
 226                          $_->exempt_monthly eq 'Y'   &&
 227                          $_->month  == $mon          &&
 228                          $_->year   == $year
 229                        } @existing_exemptions
 230                 )
 231         {
 232           $existing_exemption += $_->amount;
 233         }
 234
 235         my $remaining_exemption =
 236           $tax_object->exempt_amount - $existing_exemption;
 237         if ( $remaining_exemption > 0 ) {
 238           my $addl = $remaining_exemption > $permonth
 239             ? $permonth
 240             : $remaining_exemption;
 241           $addl = $taxable_charged if $addl > $taxable_charged;
 242
 243           push @new_exemptions, FS::cust_tax_exempt_pkg->new({
 244               amount          => sprintf('%.2f', $addl),
 245               exempt_monthly  => 'Y',
 246               year            => $year,
 247               month           => $mon,
 248             });
 249
 250           $taxable_charged -= $addl;
 251         }
 252         # if they're using multiple months of exemption for a multi-month
 253         # package, then record the exemptions in separate months
 254         $mon++;
 255         if ( $mon > 12 ) {
 256           $mon -= 12;
 257           $year++;
 258         }
 259
 260       }
 261     } # if exempt_amount
 262
 263     # attach them to the line item
 264     foreach my $ex (@new_exemptions) {
 265
 266       $ex->set('taxnum', $taxnum);
 267
 268       if ( $cust_bill_pkg->billpkgnum ) {
 269         # the exempted item is already inserted (it should be, these days) so
 270         # insert the exemption record now:
 271         $ex->set('billpkgnum', $cust_bill_pkg->billpkgnum);
 272         my $error = $ex->insert;
 273         return "inserting tax exemption record: $error" if $error;
 274
 275       } else {
 276         # defer it until the item is inserted
 277         push @{ $cust_bill_pkg->cust_tax_exempt_pkg }, $ex;
 278       }
 279     }
 280
 281     # and remember we've used the exemption
 282     push @existing_exemptions, @new_exemptions;
 283
 284     $taxable_charged = sprintf( "%.2f", $taxable_charged);
 285     next if $taxable_charged == 0;
 286
 287     my $this_tax_cents = $taxable_charged * $tax_object->tax;
 288     if ( $round_per_line_item ) {
 289       # Round the tax to the nearest cent for each line item, instead of
 290       # across the whole invoice.
 291       $this_tax_cents = sprintf('%.0f', $this_tax_cents);
 292     } else {
 293       # Otherwise truncate it so that rounding error is always positive.
 294       $this_tax_cents = int($this_tax_cents);
 295     }
 296
 297     my $location = FS::cust_bill_pkg_tax_location->new({
 298         'taxnum'      => $tax_object->taxnum,
 299         'taxtype'     => ref($tax_object),
 300         'cents'       => $this_tax_cents,
 301         'pkgnum'      => $cust_bill_pkg->pkgnum,
 302         'locationnum' => $cust_bill_pkg->cust_pkg->tax_locationnum,
 303         'taxable_cust_bill_pkg' => $cust_bill_pkg,
 304     });
 305     push @tax_links, $location;
 306
 307     $taxable_total += $taxable_charged;
 308     $tax_cents += $this_tax_cents;
 309   } #foreach $cust_bill_pkg
 310
 311   # calculate tax and rounding error for the whole group: total taxable
 312   # amount times tax rate (as cents per dollar), minus the tax already
 313   # charged
 314   # and force 0.5 to round up
 315   my $extra_cents = sprintf('%.0f',
 316     ($taxable_total * $tax_object->tax) - $tax_cents + 0.00000001
 317   );
 318
 319   # if we're rounding per item, then ignore that and don't distribute any
 320   # extra cents.
 321   if ( $round_per_line_item ) {
 322     $extra_cents = 0;
 323   }
 324
 325   if ( $extra_cents < 0 ) {
 326     die "nonsense extra_cents value $extra_cents";
 327   }
 328   $tax_cents += $extra_cents;
 329   my $i = 0;
 330   foreach (@tax_links) { # can never require more than a single pass, yes?
 331     my $cents = $_->get('cents');
 332     if ( $extra_cents > 0 ) {
 333       $cents++;
 334       $extra_cents--;
 335     }
 336     $_->set('amount', sprintf('%.2f', $cents/100));
 337   }
 338
 339   return @tax_links;
 340 }
 341
 342 sub info {
 343  +{
 344     batch       => 0,
 345     override    => 0,
 346     rate_table  => 'cust_main_county',
 347     link_table  => 'cust_bill_pkg_tax_location',
 348   }
 349 }
 350
 351 1;