FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw($dbdef_file $dbdef $setup_hack $AUTOLOAD @ISA @EXPORT_OK $DEBUG);
   5 use subs qw(reload_dbdef);
   6 use Exporter;
   7 use Carp qw(carp cluck croak confess);
   8 use File::CounterFile;
   9 use Locale::Country;
  10 use DBIx::DBSchema;
  11 use FS::UID qw(dbh checkruid getotaker datasrc driver_name);
  12
  13 @ISA = qw(Exporter);
  14 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef);
  15
  16 $DEBUG = 0;
  17
  18 #ask FS::UID to run this stuff for us later
  19 $FS::UID::callback{'FS::Record'} = sub {
  20   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  21   $dbdef_file = "/usr/local/etc/freeside/dbdef.". datasrc;
  22   &reload_dbdef unless $setup_hack; #$setup_hack needed now?
  23 };
  24
  25 =head1 NAME
  26
  27 FS::Record - Database record objects
  28
  29 =head1 SYNOPSIS
  30
  31     use FS::Record;
  32     use FS::Record qw(dbh fields qsearch qsearchs dbdef);
  33
  34     $record = new FS::Record 'table', \%hash;
  35     $record = new FS::Record 'table', { 'column' => 'value', ... };
  36
  37     $record  = qsearchs FS::Record 'table', \%hash;
  38     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  39     @records = qsearch  FS::Record 'table', \%hash;
  40     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  41
  42     $table = $record->table;
  43     $dbdef_table = $record->dbdef_table;
  44
  45     $value = $record->get('column');
  46     $value = $record->getfield('column');
  47     $value = $record->column;
  48
  49     $record->set( 'column' => 'value' );
  50     $record->setfield( 'column' => 'value' );
  51     $record->column('value');
  52
  53     %hash = $record->hash;
  54
  55     $hashref = $record->hashref;
  56
  57     $error = $record->insert;
  58     #$error = $record->add; #depriciated
  59
  60     $error = $record->delete;
  61     #$error = $record->del; #depriciated
  62
  63     $error = $new_record->replace($old_record);
  64     #$error = $new_record->rep($old_record); #depriciated
  65
  66     $value = $record->unique('column');
  67
  68     $value = $record->ut_float('column');
  69     $value = $record->ut_number('column');
  70     $value = $record->ut_numbern('column');
  71     $value = $record->ut_money('column');
  72     $value = $record->ut_text('column');
  73     $value = $record->ut_textn('column');
  74     $value = $record->ut_alpha('column');
  75     $value = $record->ut_alphan('column');
  76     $value = $record->ut_phonen('column');
  77     $value = $record->ut_anything('column');
  78     $value = $record->ut_name('column');
  79
  80     $dbdef = reload_dbdef;
  81     $dbdef = reload_dbdef "/non/standard/filename";
  82     $dbdef = dbdef;
  83
  84     $quoted_value = _quote($value,'table','field');
  85
  86     #depriciated
  87     $fields = hfields('table');
  88     if ( $fields->{Field} ) { # etc.
  89
  90     @fields = fields 'table'; #as a subroutine
  91     @fields = $record->fields; #as a method call
  92
  93
  94 =head1 DESCRIPTION
  95
  96 (Mostly) object-oriented interface to database records.  Records are currently
  97 implemented on top of DBI.  FS::Record is intended as a base class for
  98 table-specific classes to inherit from, i.e. FS::cust_main.
  99
 100 =head1 CONSTRUCTORS
 101
 102 =over 4
 103
 104 =item new [ TABLE, ] HASHREF
 105
 106 Creates a new record.  It doesn't store it in the database, though.  See
 107 L<"insert"> for that.
 108
 109 Note that the object stores this hash reference, not a distinct copy of the
 110 hash it points to.  You can ask the object for a copy with the I<hash>
 111 method.
 112
 113 TABLE can only be omitted when a dervived class overrides the table method.
 114
 115 =cut
 116
 117 sub new {
 118   my $proto = shift;
 119   my $class = ref($proto) || $proto;
 120   my $self = {};
 121   bless ($self, $class);
 122
 123   $self->{'Table'} = shift unless defined ( $self->table );
 124
 125   my $hashref = $self->{'Hash'} = shift;
 126
 127   foreach my $field ( $self->fields ) {
 128     $hashref->{$field}='' unless defined $hashref->{$field};
 129     #trim the '$' and ',' from money fields for Pg (belong HERE?)
 130     #(what about Pg i18n?)
 131     if ( driver_name =~ /^Pg$/i
 132          && $self->dbdef_table->column($field)->type eq 'money' ) {
 133       ${$hashref}{$field} =~ s/^\$//;
 134       ${$hashref}{$field} =~ s/\,//;
 135     }
 136   }
 137
 138   $self;
 139 }
 140
 141 sub create {
 142   my $proto = shift;
 143   my $class = ref($proto) || $proto;
 144   my $self = {};
 145   bless ($self, $class);
 146   if ( defined $self->table ) {
 147     cluck "create constructor is depriciated, use new!";
 148     $self->new(@_);
 149   } else {
 150     croak "FS::Record::create called (not from a subclass)!";
 151   }
 152 }
 153
 154 =item qsearch TABLE, HASHREF, SELECT, EXTRA_SQL
 155
 156 Searches the database for all records matching (at least) the key/value pairs
 157 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 158 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 159 objects.
 160
 161 ###oops, argh, FS::Record::new only lets us create database fields.
 162 #Normal behaviour if SELECT is not specified is `*', as in
 163 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 164 #feature where you can specify SELECT - remember, the objects returned,
 165 #although blessed into the appropriate `FS::TABLE' package, will only have the
 166 #fields you specify.  This might have unwanted results if you then go calling
 167 #regular FS::TABLE methods
 168 #on it.
 169
 170 =cut
 171
 172 sub qsearch {
 173   my($table, $record, $select, $extra_sql ) = @_;
 174   $table =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 175   $table = $1;
 176   $select ||= '*';
 177   my $dbh = dbh;
 178
 179   my @fields = grep exists($record->{$_}), fields($table);
 180
 181   my $statement = "SELECT $select FROM $table";
 182   if ( @fields ) {
 183     $statement .= ' WHERE '. join(' AND ', map {
 184       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 185         if ( driver_name =~ /^Pg$/i ) {
 186           "$_ IS NULL";
 187         } else {
 188           qq-( $_ IS NULL OR $_ = "" )-;
 189         }
 190       } else {
 191         "$_ = ?";
 192       }
 193     } @fields );
 194   }
 195   $statement .= " $extra_sql" if defined($extra_sql);
 196
 197   warn $statement if $DEBUG;
 198   my $sth = $dbh->prepare($statement)
 199     or croak "$dbh->errstr doing $statement";
 200
 201   $sth->execute( map $record->{$_},
 202     grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 203   ) or croak "Error executing \"$statement\": ". $dbh->errstr;
 204   $dbh->commit or croak $dbh->errstr if $FS::UID::AutoCommit;
 205
 206   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 207     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 208       #derivied class didn't override new method, so this optimization is safe
 209       map {
 210         new( "FS::$table", { %{$_} } )
 211       } @{$sth->fetchall_arrayref( {} )};
 212     } else {
 213       warn "untested code (class FS::$table uses custom new method)";
 214       map {
 215         eval 'FS::'. $table. '->new( { %{$_} } )';
 216       } @{$sth->fetchall_arrayref( {} )};
 217     }
 218   } else {
 219     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 220     map {
 221       FS::Record->new( $table, { %{$_} } );
 222     } @{$sth->fetchall_arrayref( {} )};
 223   }
 224
 225 }
 226
 227 =item qsearchs TABLE, HASHREF
 228
 229 Same as qsearch, except that if more than one record matches, it B<carp>s but
 230 returns the first.  If this happens, you either made a logic error in asking
 231 for a single item, or your data is corrupted.
 232
 233 =cut
 234
 235 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 236   my(@result) = qsearch(@_);
 237   carp "warning: Multiple records in scalar search!" if scalar(@result) > 1;
 238     #should warn more vehemently if the search was on a primary key?
 239   scalar(@result) ? ($result[0]) : ();
 240 }
 241
 242 =back
 243
 244 =head1 METHODS
 245
 246 =over 4
 247
 248 =item table
 249
 250 Returns the table name.
 251
 252 =cut
 253
 254 sub table {
 255 #  cluck "warning: FS::Record::table depriciated; supply one in subclass!";
 256   my $self = shift;
 257   $self -> {'Table'};
 258 }
 259
 260 =item dbdef_table
 261
 262 Returns the FS::dbdef_table object for the table.
 263
 264 =cut
 265
 266 sub dbdef_table {
 267   my($self)=@_;
 268   my($table)=$self->table;
 269   $dbdef->table($table);
 270 }
 271
 272 =item get, getfield COLUMN
 273
 274 Returns the value of the column/field/key COLUMN.
 275
 276 =cut
 277
 278 sub get {
 279   my($self,$field) = @_;
 280   # to avoid "Use of unitialized value" errors
 281   if ( defined ( $self->{Hash}->{$field} ) ) {
 282     $self->{Hash}->{$field};
 283   } else {
 284     '';
 285   }
 286 }
 287 sub getfield {
 288   my $self = shift;
 289   $self->get(@_);
 290 }
 291
 292 =item set, setfield COLUMN, VALUE
 293
 294 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 295
 296 =cut
 297
 298 sub set {
 299   my($self,$field,$value) = @_;
 300   $self->{'Hash'}->{$field} = $value;
 301 }
 302 sub setfield {
 303   my $self = shift;
 304   $self->set(@_);
 305 }
 306
 307 =item AUTLOADED METHODS
 308
 309 $record->column is a synonym for $record->get('column');
 310
 311 $record->column('value') is a synonym for $record->set('column','value');
 312
 313 =cut
 314
 315 sub AUTOLOAD {
 316   my($self,$value)=@_;
 317   my($field)=$AUTOLOAD;
 318   $field =~ s/.*://;
 319   if ( defined($value) ) {
 320     confess "errant AUTOLOAD $field for $self (arg $value)"
 321       unless $self->can('setfield');
 322     $self->setfield($field,$value);
 323   } else {
 324     $self->getfield($field);
 325   }
 326 }
 327
 328 =item hash
 329
 330 Returns a list of the column/value pairs, usually for assigning to a new hash.
 331
 332 To make a distinct duplicate of an FS::Record object, you can do:
 333
 334     $new = new FS::Record ( $old->table, { $old->hash } );
 335
 336 =cut
 337
 338 sub hash {
 339   my($self) = @_;
 340   %{ $self->{'Hash'} };
 341 }
 342
 343 =item hashref
 344
 345 Returns a reference to the column/value hash.
 346
 347 =cut
 348
 349 sub hashref {
 350   my($self) = @_;
 351   $self->{'Hash'};
 352 }
 353
 354 =item insert
 355
 356 Inserts this record to the database.  If there is an error, returns the error,
 357 otherwise returns false.
 358
 359 =cut
 360
 361 sub insert {
 362   my $self = shift;
 363
 364   my $error = $self->check;
 365   return $error if $error;
 366
 367   #single-field unique keys are given a value if false
 368   #(like MySQL's AUTO_INCREMENT)
 369   foreach ( $self->dbdef_table->unique->singles ) {
 370     $self->unique($_) unless $self->getfield($_);
 371   }
 372   #and also the primary key
 373   my $primary_key = $self->dbdef_table->primary_key;
 374   $self->unique($primary_key)
 375     if $primary_key && ! $self->getfield($primary_key);
 376
 377   my @fields =
 378     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 379     $self->fields
 380   ;
 381
 382   my $statement = "INSERT INTO ". $self->table. " ( ".
 383       join(', ',@fields ).
 384     ") VALUES (".
 385       join(', ',map(_quote($self->getfield($_),$self->table,$_), @fields)).
 386     ")"
 387   ;
 388   my $sth = dbh->prepare($statement) or return dbh->errstr;
 389
 390   local $SIG{HUP} = 'IGNORE';
 391   local $SIG{INT} = 'IGNORE';
 392   local $SIG{QUIT} = 'IGNORE';
 393   local $SIG{TERM} = 'IGNORE';
 394   local $SIG{TSTP} = 'IGNORE';
 395   local $SIG{PIPE} = 'IGNORE';
 396
 397   $sth->execute or return $sth->errstr;
 398   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 399
 400   '';
 401 }
 402
 403 =item add
 404
 405 Depriciated (use insert instead).
 406
 407 =cut
 408
 409 sub add {
 410   cluck "warning: FS::Record::add depriciated!";
 411   insert @_; #call method in this scope
 412 }
 413
 414 =item delete
 415
 416 Delete this record from the database.  If there is an error, returns the error,
 417 otherwise returns false.
 418
 419 =cut
 420
 421 sub delete {
 422   my $self = shift;
 423
 424   my($statement)="DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 425     map {
 426       $self->getfield($_) eq ''
 427         #? "( $_ IS NULL OR $_ = \"\" )"
 428         ? ( driver_name =~ /^Pg$/i
 429               ? "$_ IS NULL"
 430               : "( $_ IS NULL OR $_ = \"\" )"
 431           )
 432         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 433     } ( $self->dbdef_table->primary_key )
 434           ? ( $self->dbdef_table->primary_key)
 435           : $self->fields
 436   );
 437   my $sth = dbh->prepare($statement) or return dbh->errstr;
 438
 439   local $SIG{HUP} = 'IGNORE';
 440   local $SIG{INT} = 'IGNORE';
 441   local $SIG{QUIT} = 'IGNORE';
 442   local $SIG{TERM} = 'IGNORE';
 443   local $SIG{TSTP} = 'IGNORE';
 444   local $SIG{PIPE} = 'IGNORE';
 445
 446   my $rc = $sth->execute or return $sth->errstr;
 447   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 448   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 449
 450   undef $self; #no need to keep object!
 451
 452   '';
 453 }
 454
 455 =item del
 456
 457 Depriciated (use delete instead).
 458
 459 =cut
 460
 461 sub del {
 462   cluck "warning: FS::Record::del depriciated!";
 463   &delete(@_); #call method in this scope
 464 }
 465
 466 =item replace OLD_RECORD
 467
 468 Replace the OLD_RECORD with this one in the database.  If there is an error,
 469 returns the error, otherwise returns false.
 470
 471 =cut
 472
 473 sub replace {
 474   my ( $new, $old ) = ( shift, shift );
 475
 476   my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 477   unless ( @diff ) {
 478     carp "warning: records identical";
 479     return '';
 480   }
 481
 482   return "Records not in same table!" unless $new->table eq $old->table;
 483
 484   my $primary_key = $old->dbdef_table->primary_key;
 485   return "Can't change $primary_key"
 486     if $primary_key
 487        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 488
 489   my $error = $new->check;
 490   return $error if $error;
 491
 492   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 493     map {
 494       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 495     } @diff
 496   ). ' WHERE '.
 497     join(' AND ',
 498       map {
 499         $old->getfield($_) eq ''
 500           #? "( $_ IS NULL OR $_ = \"\" )"
 501           ? ( driver_name =~ /^Pg$/i
 502                 ? "$_ IS NULL"
 503                 : "( $_ IS NULL OR $_ = \"\" )"
 504             )
 505           : "$_ = ". _quote($old->getfield($_),$old->table,$_)
 506       } ( $primary_key ? ( $primary_key ) : $old->fields )
 507     )
 508   ;
 509   my $sth = dbh->prepare($statement) or return dbh->errstr;
 510
 511   local $SIG{HUP} = 'IGNORE';
 512   local $SIG{INT} = 'IGNORE';
 513   local $SIG{QUIT} = 'IGNORE';
 514   local $SIG{TERM} = 'IGNORE';
 515   local $SIG{TSTP} = 'IGNORE';
 516   local $SIG{PIPE} = 'IGNORE';
 517
 518   my $rc = $sth->execute or return $sth->errstr;
 519   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
 520   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 521
 522   '';
 523
 524 }
 525
 526 =item rep
 527
 528 Depriciated (use replace instead).
 529
 530 =cut
 531
 532 sub rep {
 533   cluck "warning: FS::Record::rep depriciated!";
 534   replace @_; #call method in this scope
 535 }
 536
 537 =item check
 538
 539 Not yet implemented, croaks.  Derived classes should provide a check method.
 540
 541 =cut
 542
 543 sub check {
 544   confess "FS::Record::check not implemented; supply one in subclass!";
 545 }
 546
 547 =item unique COLUMN
 548
 549 Replaces COLUMN in record with a unique number.  Called by the B<add> method
 550 on primary keys and single-field unique columns (see L<DBIx::DBSchema::Table>).
 551 Returns the new value.
 552
 553 =cut
 554
 555 sub unique {
 556   my($self,$field) = @_;
 557   my($table)=$self->table;
 558
 559   croak("&FS::UID::checkruid failed") unless &checkruid;
 560
 561   croak "Unique called on field $field, but it is ",
 562         $self->getfield($field),
 563         ", not null!"
 564     if $self->getfield($field);
 565
 566   #warn "table $table is tainted" if is_tainted($table);
 567   #warn "field $field is tainted" if is_tainted($field);
 568
 569   my($counter) = new File::CounterFile "$table.$field",0;
 570 # hack for web demo
 571 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
 572 #  my($user)=$1;
 573 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
 574 # endhack
 575
 576   my($index)=$counter->inc;
 577   $index=$counter->inc
 578     while qsearchs($table,{$field=>$index}); #just in case
 579
 580   $index =~ /^(\d*)$/;
 581   $index=$1;
 582
 583   $self->setfield($field,$index);
 584
 585 }
 586
 587 =item ut_float COLUMN
 588
 589 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
 590 null.  If there is an error, returns the error, otherwise returns false.
 591
 592 =cut
 593
 594 sub ut_float {
 595   my($self,$field)=@_ ;
 596   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
 597    $self->getfield($field) =~ /^(\d+)$/ ||
 598    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
 599    $self->getfield($field) =~ /^(\d+e\d+)$/)
 600     or return "Illegal or empty (float) $field: ". $self->getfield($field);
 601   $self->setfield($field,$1);
 602   '';
 603 }
 604
 605 =item ut_number COLUMN
 606
 607 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
 608 is an error, returns the error, otherwise returns false.
 609
 610 =cut
 611
 612 sub ut_number {
 613   my($self,$field)=@_;
 614   $self->getfield($field) =~ /^(\d+)$/
 615     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
 616   $self->setfield($field,$1);
 617   '';
 618 }
 619
 620 =item ut_numbern COLUMN
 621
 622 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
 623 an error, returns the error, otherwise returns false.
 624
 625 =cut
 626
 627 sub ut_numbern {
 628   my($self,$field)=@_;
 629   $self->getfield($field) =~ /^(\d*)$/
 630     or return "Illegal (numeric) $field: ". $self->getfield($field);
 631   $self->setfield($field,$1);
 632   '';
 633 }
 634
 635 =item ut_money COLUMN
 636
 637 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
 638 is an error, returns the error, otherwise returns false.
 639
 640 =cut
 641
 642 sub ut_money {
 643   my($self,$field)=@_;
 644   $self->setfield($field, 0) if $self->getfield($field) eq '';
 645   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
 646     or return "Illegal (money) $field: ". $self->getfield($field);
 647   #$self->setfield($field, "$1$2$3" || 0);
 648   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
 649   '';
 650 }
 651
 652 =item ut_text COLUMN
 653
 654 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 655 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 656 May not be null.  If there is an error, returns the error, otherwise returns
 657 false.
 658
 659 =cut
 660
 661 sub ut_text {
 662   my($self,$field)=@_;
 663   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]+)$/
 664     or return "Illegal or empty (text) $field: ". $self->getfield($field);
 665   $self->setfield($field,$1);
 666   '';
 667 }
 668
 669 =item ut_textn COLUMN
 670
 671 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 672 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 673 May be null.  If there is an error, returns the error, otherwise returns false.
 674
 675 =cut
 676
 677 sub ut_textn {
 678   my($self,$field)=@_;
 679   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]*)$/
 680     or return "Illegal (text) $field: ". $self->getfield($field);
 681   $self->setfield($field,$1);
 682   '';
 683 }
 684
 685 =item ut_alpha COLUMN
 686
 687 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
 688 an error, returns the error, otherwise returns false.
 689
 690 =cut
 691
 692 sub ut_alpha {
 693   my($self,$field)=@_;
 694   $self->getfield($field) =~ /^(\w+)$/
 695     or return "Illegal or empty (alphanumeric) $field: ".
 696               $self->getfield($field);
 697   $self->setfield($field,$1);
 698   '';
 699 }
 700
 701 =item ut_alpha COLUMN
 702
 703 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
 704 error, returns the error, otherwise returns false.
 705
 706 =cut
 707
 708 sub ut_alphan {
 709   my($self,$field)=@_;
 710   $self->getfield($field) =~ /^(\w*)$/
 711     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
 712   $self->setfield($field,$1);
 713   '';
 714 }
 715
 716 =item ut_phonen COLUMN [ COUNTRY ]
 717
 718 Check/untaint phone numbers.  May be null.  If there is an error, returns
 719 the error, otherwise returns false.
 720
 721 Takes an optional two-letter ISO country code; without it or with unsupported
 722 countries, ut_phonen simply calls ut_alphan.
 723
 724 =cut
 725
 726 sub ut_phonen {
 727   my( $self, $field, $country ) = @_;
 728   return $self->ut_alphan($field) unless defined $country;
 729   my $phonen = $self->getfield($field);
 730   if ( $phonen eq '' ) {
 731     $self->setfield($field,'');
 732   } elsif ( $country eq 'US' || $country eq 'CA' ) {
 733     $phonen =~ s/\D//g;
 734     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
 735       or return "Illegal (phone) $field: ". $self->getfield($field);
 736     $phonen = "$1-$2-$3";
 737     $phonen .= " x$4" if $4;
 738     $self->setfield($field,$phonen);
 739   } else {
 740     warn "don't know how to check phone numbers for country $country";
 741     return $self->ut_textn($field);
 742   }
 743   '';
 744 }
 745
 746 =item ut_ip COLUMN
 747
 748 Check/untaint ip addresses.  IPv4 only for now.
 749
 750 =cut
 751
 752 sub ut_ip {
 753   my( $self, $field ) = @_;
 754   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
 755     or return "Illegal (IP address) $field: ". $self->getfield($field);
 756   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
 757   $self->setfield($field, "$1.$2.$3.$3");
 758   '';
 759 }
 760
 761 =item ut_ipn COLUMN
 762
 763 Check/untaint ip addresses.  IPv4 only for now.  May be null.
 764
 765 =cut
 766
 767 sub ut_ipn {
 768   my( $self, $field ) = @_;
 769   if ( $self->getfield($field) =~ /^()$/ ) {
 770     $self->setfield($field,'');
 771     '';
 772   } else {
 773     $self->ut_ip($field);
 774   }
 775 }
 776
 777 =item ut_domain COLUMN
 778
 779 Check/untaint host and domain names.
 780
 781 =cut
 782
 783 sub ut_domain {
 784   my( $self, $field ) = @_;
 785   #$self->getfield($field) =~/^(\w+\.)*\w+$/
 786   $self->getfield($field) =~/^(\w+\.)*\w+$/
 787     or return "Illegal (domain) $field: ". $self->getfield($field);
 788   $self->setfield($field,$1);
 789   '';
 790 }
 791
 792 =item ut_name COLUMN
 793
 794 Check/untaint proper names; allows alphanumerics, spaces and the following
 795 punctuation: , . - '
 796
 797 May not be null.
 798
 799 =cut
 800
 801 sub ut_name {
 802   my( $self, $field ) = @_;
 803   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
 804     or return "Illegal (name) $field: ". $self->getfield($field);
 805   $self->setfield($field,$1);
 806   '';
 807 }
 808
 809 =item ut_zip COLUMN
 810
 811 Check/untaint zip codes.
 812
 813 =cut
 814
 815 sub ut_zip {
 816   my( $self, $field, $country ) = @_;
 817   if ( $country eq 'US' ) {
 818     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
 819       or return "Illegal (zip) $field for country $country: ".
 820                 $self->getfield($field);
 821     $self->setfield($field,$1);
 822   } else {
 823     $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
 824       or return "Illegal (zip) $field: ". $self->getfield($field);
 825     $self->setfield($field,$1);
 826   }
 827   '';
 828 }
 829
 830 =item ut_country COLUMN
 831
 832 Check/untaint country codes.  Country names are changed to codes, if possible -
 833 see L<Locale::Country>.
 834
 835 =cut
 836
 837 sub ut_country {
 838   my( $self, $field ) = @_;
 839   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
 840     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
 841          && country2code($1) ) {
 842       $self->setfield($field,uc(country2code($1)));
 843     }
 844   }
 845   $self->getfield($field) =~ /^(\w\w)$/
 846     or return "Illegal (country) $field: ". $self->getfield($field);
 847   $self->setfield($field,uc($1));
 848   '';
 849 }
 850
 851 =item ut_anything COLUMN
 852
 853 Untaints arbitrary data.  Be careful.
 854
 855 =cut
 856
 857 sub ut_anything {
 858   my( $self, $field ) = @_;
 859   $self->getfield($field) =~ /^(.*)$/s
 860     or return "Illegal $field: ". $self->getfield($field);
 861   $self->setfield($field,$1);
 862   '';
 863 }
 864
 865 =item ut_enum COLUMN CHOICES_ARRAYREF
 866
 867 Check/untaint a column, supplying all possible choices, like the "enum" type.
 868
 869 =cut
 870
 871 sub ut_enum {
 872   my( $self, $field, $choices ) = @_;
 873   foreach my $choice ( @$choices ) {
 874     if ( $self->getfield($field) eq $choice ) {
 875       $self->setfield($choice);
 876       return '';
 877     }
 878   }
 879   return "Illegal (enum) field $field: ". $self->getfield($field);
 880 }
 881
 882 =item fields [ TABLE ]
 883
 884 This can be used as both a subroutine and a method call.  It returns a list
 885 of the columns in this record's table, or an explicitly specified table.
 886 (See L<DBIx::DBSchema::Table>).
 887
 888 =cut
 889
 890 # Usage: @fields = fields($table);
 891 #        @fields = $record->fields;
 892 sub fields {
 893   my $something = shift;
 894   my $table;
 895   if ( ref($something) ) {
 896     $table = $something->table;
 897   } else {
 898     $table = $something;
 899   }
 900   #croak "Usage: \@fields = fields(\$table)\n   or: \@fields = \$record->fields" unless $table;
 901   my($table_obj) = $dbdef->table($table);
 902   croak "Unknown table $table" unless $table_obj;
 903   $table_obj->columns;
 904 }
 905
 906 =back
 907
 908 =head1 SUBROUTINES
 909
 910 =over 4
 911
 912 =item reload_dbdef([FILENAME])
 913
 914 Load a database definition (see L<DBIx::DBSchema>), optionally from a
 915 non-default filename.  This command is executed at startup unless
 916 I<$FS::Record::setup_hack> is true.  Returns a DBIx::DBSchema object.
 917
 918 =cut
 919
 920 sub reload_dbdef {
 921   my $file = shift || $dbdef_file;
 922   $dbdef = load DBIx::DBSchema $file;
 923 }
 924
 925 =item dbdef
 926
 927 Returns the current database definition.  See L<FS::dbdef>.
 928
 929 =cut
 930
 931 sub dbdef { $dbdef; }
 932
 933 =item _quote VALUE, TABLE, COLUMN
 934
 935 This is an internal function used to construct SQL statements.  It returns
 936 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
 937 type (see L<FS::dbdef_column>) does not end in `char' or `binary'.
 938
 939 =cut
 940
 941 sub _quote {
 942   my($value,$table,$field)=@_;
 943   my($dbh)=dbh;
 944   if ( $value =~ /^\d+(\.\d+)?$/ &&
 945 #       ! ( datatype($table,$field) =~ /^char/ )
 946        ! ( $dbdef->table($table)->column($field)->type =~ /(char|binary)$/i )
 947   ) {
 948     $value;
 949   } else {
 950     $dbh->quote($value);
 951   }
 952 }
 953
 954 =item hfields TABLE
 955
 956 This is depriciated.  Don't use it.
 957
 958 It returns a hash-type list with the fields of this record's table set true.
 959
 960 =cut
 961
 962 sub hfields {
 963   carp "warning: hfields is depriciated";
 964   my($table)=@_;
 965   my(%hash);
 966   foreach (fields($table)) {
 967     $hash{$_}=1;
 968   }
 969   \%hash;
 970 }
 971
 972 #sub _dump {
 973 #  my($self)=@_;
 974 #  join("\n", map {
 975 #    "$_: ". $self->getfield($_). "|"
 976 #  } (fields($self->table)) );
 977 #}
 978
 979 sub DESTROY { return; }
 980
 981 #sub DESTROY {
 982 #  my $self = shift;
 983 #  #use Carp qw(cluck);
 984 #  #cluck "DESTROYING $self";
 985 #  warn "DESTROYING $self";
 986 #}
 987
 988 #sub is_tainted {
 989 #             return ! eval { join('',@_), kill 0; 1; };
 990 #         }
 991
 992 =back
 993
 994 =head1 VERSION
 995
 996 $Id: Record.pm,v 1.27 2001-09-11 00:08:18 ivan Exp $
 997
 998 =head1 BUGS
 999
1000 This module should probably be renamed, since much of the functionality is
1001 of general use.  It is not completely unlike Adapter::DBI (see below).
1002
1003 Exported qsearch and qsearchs should be depriciated in favor of method calls
1004 (against an FS::Record object like the old search and searchs that qsearch
1005 and qsearchs were on top of.)
1006
1007 The whole fields / hfields mess should be removed.
1008
1009 The various WHERE clauses should be subroutined.
1010
1011 table string should be depriciated in favor of FS::dbdef_table.
1012
1013 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1014 true maps to the database (and WHERE clauses) would also help.
1015
1016 The ut_ methods should ask the dbdef for a default length.
1017
1018 ut_sqltype (like ut_varchar) should all be defined
1019
1020 A fallback check method should be provided which uses the dbdef.
1021
1022 The ut_money method assumes money has two decimal digits.
1023
1024 The Pg money kludge in the new method only strips `$'.
1025
1026 The ut_phonen method only checks US-style phone numbers.
1027
1028 The _quote function should probably use ut_float instead of a regex.
1029
1030 All the subroutines probably should be methods, here or elsewhere.
1031
1032 Probably should borrow/use some dbdef methods where appropriate (like sub
1033 fields)
1034
1035 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1036 or allow it to be set.  Working around it is ugly any way around - DBI should
1037 be fixed.  (only affects RDBMS which return uppercase column names)
1038
1039 ut_zip should take an optional country like ut_phone.
1040
1041 =head1 SEE ALSO
1042
1043 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1044
1045 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1046
1047 =cut
1048
1049 1;
1050