FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $dbdef_file $dbdef $setup_hack $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $me );
   6 use subs qw(reload_dbdef);
   7 use Exporter;
   8 use Carp qw(carp cluck croak confess);
   9 use File::CounterFile;
  10 use Locale::Country;
  11 use DBI qw(:sql_types);
  12 use DBIx::DBSchema 0.19;
  13 use FS::UID qw(dbh checkruid getotaker datasrc driver_name);
  14 use FS::SearchCache;
  15
  16 @ISA = qw(Exporter);
  17 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch);
  18
  19 $DEBUG = 0;
  20 $me = '[FS::Record]';
  21
  22 #ask FS::UID to run this stuff for us later
  23 $FS::UID::callback{'FS::Record'} = sub {
  24   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  25   $dbdef_file = "/usr/local/etc/freeside/dbdef.". datasrc;
  26   &reload_dbdef unless $setup_hack; #$setup_hack needed now?
  27 };
  28
  29 =head1 NAME
  30
  31 FS::Record - Database record objects
  32
  33 =head1 SYNOPSIS
  34
  35     use FS::Record;
  36     use FS::Record qw(dbh fields qsearch qsearchs dbdef);
  37
  38     $record = new FS::Record 'table', \%hash;
  39     $record = new FS::Record 'table', { 'column' => 'value', ... };
  40
  41     $record  = qsearchs FS::Record 'table', \%hash;
  42     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  43     @records = qsearch  FS::Record 'table', \%hash;
  44     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  45
  46     $table = $record->table;
  47     $dbdef_table = $record->dbdef_table;
  48
  49     $value = $record->get('column');
  50     $value = $record->getfield('column');
  51     $value = $record->column;
  52
  53     $record->set( 'column' => 'value' );
  54     $record->setfield( 'column' => 'value' );
  55     $record->column('value');
  56
  57     %hash = $record->hash;
  58
  59     $hashref = $record->hashref;
  60
  61     $error = $record->insert;
  62     #$error = $record->add; #deprecated
  63
  64     $error = $record->delete;
  65     #$error = $record->del; #deprecated
  66
  67     $error = $new_record->replace($old_record);
  68     #$error = $new_record->rep($old_record); #deprecated
  69
  70     $value = $record->unique('column');
  71
  72     $error = $record->ut_float('column');
  73     $error = $record->ut_number('column');
  74     $error = $record->ut_numbern('column');
  75     $error = $record->ut_money('column');
  76     $error = $record->ut_text('column');
  77     $error = $record->ut_textn('column');
  78     $error = $record->ut_alpha('column');
  79     $error = $record->ut_alphan('column');
  80     $error = $record->ut_phonen('column');
  81     $error = $record->ut_anything('column');
  82     $error = $record->ut_name('column');
  83
  84     $dbdef = reload_dbdef;
  85     $dbdef = reload_dbdef "/non/standard/filename";
  86     $dbdef = dbdef;
  87
  88     $quoted_value = _quote($value,'table','field');
  89
  90     #depriciated
  91     $fields = hfields('table');
  92     if ( $fields->{Field} ) { # etc.
  93
  94     @fields = fields 'table'; #as a subroutine
  95     @fields = $record->fields; #as a method call
  96
  97
  98 =head1 DESCRIPTION
  99
 100 (Mostly) object-oriented interface to database records.  Records are currently
 101 implemented on top of DBI.  FS::Record is intended as a base class for
 102 table-specific classes to inherit from, i.e. FS::cust_main.
 103
 104 =head1 CONSTRUCTORS
 105
 106 =over 4
 107
 108 =item new [ TABLE, ] HASHREF
 109
 110 Creates a new record.  It doesn't store it in the database, though.  See
 111 L<"insert"> for that.
 112
 113 Note that the object stores this hash reference, not a distinct copy of the
 114 hash it points to.  You can ask the object for a copy with the I<hash>
 115 method.
 116
 117 TABLE can only be omitted when a dervived class overrides the table method.
 118
 119 =cut
 120
 121 sub new {
 122   my $proto = shift;
 123   my $class = ref($proto) || $proto;
 124   my $self = {};
 125   bless ($self, $class);
 126
 127   unless ( defined ( $self->table ) ) {
 128     $self->{'Table'} = shift;
 129     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 130   }
 131
 132   my $hashref = $self->{'Hash'} = shift;
 133
 134   foreach my $field ( $self->fields ) {
 135     $hashref->{$field}='' unless defined $hashref->{$field};
 136     #trim the '$' and ',' from money fields for Pg (belong HERE?)
 137     #(what about Pg i18n?)
 138     if ( driver_name =~ /^Pg$/i
 139          && $self->dbdef_table->column($field)->type eq 'money' ) {
 140       ${$hashref}{$field} =~ s/^\$//;
 141       ${$hashref}{$field} =~ s/\,//;
 142     }
 143   }
 144
 145   $self->_cache($hashref, shift) if $self->can('_cache') && @_;
 146
 147   $self;
 148 }
 149
 150 sub new_or_cached {
 151   my $proto = shift;
 152   my $class = ref($proto) || $proto;
 153   my $self = {};
 154   bless ($self, $class);
 155
 156   $self->{'Table'} = shift unless defined ( $self->table );
 157
 158   my $hashref = $self->{'Hash'} = shift;
 159   my $cache = shift;
 160   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 161     my $obj = $cache->cache->{$hashref->{$cache->key}};
 162     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 163     $obj;
 164   } else {
 165     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 166   }
 167
 168 }
 169
 170 sub create {
 171   my $proto = shift;
 172   my $class = ref($proto) || $proto;
 173   my $self = {};
 174   bless ($self, $class);
 175   if ( defined $self->table ) {
 176     cluck "create constructor is depriciated, use new!";
 177     $self->new(@_);
 178   } else {
 179     croak "FS::Record::create called (not from a subclass)!";
 180   }
 181 }
 182
 183 =item qsearch TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ
 184
 185 Searches the database for all records matching (at least) the key/value pairs
 186 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 187 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 188 objects.
 189
 190 ###oops, argh, FS::Record::new only lets us create database fields.
 191 #Normal behaviour if SELECT is not specified is `*', as in
 192 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 193 #feature where you can specify SELECT - remember, the objects returned,
 194 #although blessed into the appropriate `FS::TABLE' package, will only have the
 195 #fields you specify.  This might have unwanted results if you then go calling
 196 #regular FS::TABLE methods
 197 #on it.
 198
 199 =cut
 200
 201 sub qsearch {
 202   my($stable, $record, $select, $extra_sql, $cache ) = @_;
 203   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 204   #for jsearch
 205   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 206   $stable = $1;
 207   $select ||= '*';
 208   my $dbh = dbh;
 209
 210   my $table = $cache ? $cache->table : $stable;
 211
 212   my @fields = grep exists($record->{$_}), fields($table);
 213
 214   my $statement = "SELECT $select FROM $stable";
 215   if ( @fields ) {
 216     $statement .= ' WHERE '. join(' AND ', map {
 217
 218       my $op = '=';
 219       if ( ref($record->{$_}) ) {
 220         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 221         $op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name !~ /^Pg$/i;
 222         $record->{$_} = $record->{$_}{'value'}
 223       }
 224
 225       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 226         if ( driver_name =~ /^Pg$/i ) {
 227           qq-( $_ IS NULL OR $_ = '' )-;
 228         } else {
 229           qq-( $_ IS NULL OR $_ = "" )-;
 230         }
 231       } else {
 232         "$_ $op ?";
 233       }
 234     } @fields );
 235   }
 236   $statement .= " $extra_sql" if defined($extra_sql);
 237
 238   warn "[debug]$me $statement\n" if $DEBUG;
 239   my $sth = $dbh->prepare($statement)
 240     or croak "$dbh->errstr doing $statement";
 241
 242   my $bind = 1;
 243
 244   foreach my $field (
 245     grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 246   ) {
 247     if ( $record->{$field} =~ /^\d+(\.\d+)?$/
 248          && $dbdef->table($table)->column($field)->type =~ /(int)/i
 249     ) {
 250       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_INTEGER } );
 251     } else {
 252       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_VARCHAR } );
 253     }
 254   }
 255
 256 #  $sth->execute( map $record->{$_},
 257 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 258 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 259
 260   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 261
 262   $dbh->commit or croak $dbh->errstr if $FS::UID::AutoCommit;
 263
 264   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 265     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 266       #derivied class didn't override new method, so this optimization is safe
 267       if ( $cache ) {
 268         map {
 269           new_or_cached( "FS::$table", { %{$_} }, $cache )
 270         } @{$sth->fetchall_arrayref( {} )};
 271       } else {
 272         map {
 273           new( "FS::$table", { %{$_} } )
 274         } @{$sth->fetchall_arrayref( {} )};
 275       }
 276     } else {
 277       warn "untested code (class FS::$table uses custom new method)";
 278       map {
 279         eval 'FS::'. $table. '->new( { %{$_} } )';
 280       } @{$sth->fetchall_arrayref( {} )};
 281     }
 282   } else {
 283     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 284     map {
 285       FS::Record->new( $table, { %{$_} } );
 286     } @{$sth->fetchall_arrayref( {} )};
 287   }
 288
 289 }
 290
 291 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 292
 293 Experimental JOINed search method.  Using this method, you can execute a
 294 single SELECT spanning multiple tables, and cache the results for subsequent
 295 method calls.  Interface will almost definately change in an incompatible
 296 fashion.
 297
 298 Arguments:
 299
 300 =cut
 301
 302 sub jsearch {
 303   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 304   my $cache = FS::SearchCache->new( $ptable, $pkey );
 305   my %saw;
 306   ( $cache,
 307     grep { !$saw{$_->getfield($pkey)}++ }
 308       qsearch($table, $record, $select, $extra_sql, $cache )
 309   );
 310 }
 311
 312 =item qsearchs TABLE, HASHREF
 313
 314 Same as qsearch, except that if more than one record matches, it B<carp>s but
 315 returns the first.  If this happens, you either made a logic error in asking
 316 for a single item, or your data is corrupted.
 317
 318 =cut
 319
 320 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 321   my(@result) = qsearch(@_);
 322   carp "warning: Multiple records in scalar search!" if scalar(@result) > 1;
 323     #should warn more vehemently if the search was on a primary key?
 324   scalar(@result) ? ($result[0]) : ();
 325 }
 326
 327 =back
 328
 329 =head1 METHODS
 330
 331 =over 4
 332
 333 =item table
 334
 335 Returns the table name.
 336
 337 =cut
 338
 339 sub table {
 340 #  cluck "warning: FS::Record::table depriciated; supply one in subclass!";
 341   my $self = shift;
 342   $self -> {'Table'};
 343 }
 344
 345 =item dbdef_table
 346
 347 Returns the FS::dbdef_table object for the table.
 348
 349 =cut
 350
 351 sub dbdef_table {
 352   my($self)=@_;
 353   my($table)=$self->table;
 354   $dbdef->table($table);
 355 }
 356
 357 =item get, getfield COLUMN
 358
 359 Returns the value of the column/field/key COLUMN.
 360
 361 =cut
 362
 363 sub get {
 364   my($self,$field) = @_;
 365   # to avoid "Use of unitialized value" errors
 366   if ( defined ( $self->{Hash}->{$field} ) ) {
 367     $self->{Hash}->{$field};
 368   } else {
 369     '';
 370   }
 371 }
 372 sub getfield {
 373   my $self = shift;
 374   $self->get(@_);
 375 }
 376
 377 =item set, setfield COLUMN, VALUE
 378
 379 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 380
 381 =cut
 382
 383 sub set {
 384   my($self,$field,$value) = @_;
 385   $self->{'Hash'}->{$field} = $value;
 386 }
 387 sub setfield {
 388   my $self = shift;
 389   $self->set(@_);
 390 }
 391
 392 =item AUTLOADED METHODS
 393
 394 $record->column is a synonym for $record->get('column');
 395
 396 $record->column('value') is a synonym for $record->set('column','value');
 397
 398 =cut
 399
 400 # readable/safe
 401 #sub AUTOLOAD {
 402 #  my($self,$value)=@_;
 403 #  my($field)=$AUTOLOAD;
 404 #  $field =~ s/.*://;
 405 #  if ( defined($value) ) {
 406 #    confess "errant AUTOLOAD $field for $self (arg $value)"
 407 #      unless $self->can('setfield');
 408 #    $self->setfield($field,$value);
 409 #  } else {
 410 #    confess "errant AUTOLOAD $field for $self (no args)"
 411 #      unless $self->can('getfield');
 412 #    $self->getfield($field);
 413 #  }
 414 #}
 415
 416 # efficient
 417 sub AUTOLOAD {
 418   my $field = $AUTOLOAD;
 419   $field =~ s/.*://;
 420   if ( defined($_[1]) ) {
 421     $_[0]->setfield($field, $_[1]);
 422   } else {
 423     $_[0]->getfield($field);
 424   }
 425 }
 426
 427 =item hash
 428
 429 Returns a list of the column/value pairs, usually for assigning to a new hash.
 430
 431 To make a distinct duplicate of an FS::Record object, you can do:
 432
 433     $new = new FS::Record ( $old->table, { $old->hash } );
 434
 435 =cut
 436
 437 sub hash {
 438   my($self) = @_;
 439   %{ $self->{'Hash'} };
 440 }
 441
 442 =item hashref
 443
 444 Returns a reference to the column/value hash.
 445
 446 =cut
 447
 448 sub hashref {
 449   my($self) = @_;
 450   $self->{'Hash'};
 451 }
 452
 453 =item insert
 454
 455 Inserts this record to the database.  If there is an error, returns the error,
 456 otherwise returns false.
 457
 458 =cut
 459
 460 sub insert {
 461   my $self = shift;
 462
 463   my $error = $self->check;
 464   return $error if $error;
 465
 466   #single-field unique keys are given a value if false
 467   #(like MySQL's AUTO_INCREMENT)
 468   foreach ( $self->dbdef_table->unique->singles ) {
 469     $self->unique($_) unless $self->getfield($_);
 470   }
 471   #and also the primary key
 472   my $primary_key = $self->dbdef_table->primary_key;
 473   $self->unique($primary_key)
 474     if $primary_key && ! $self->getfield($primary_key);
 475
 476   my @fields =
 477     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 478     $self->fields
 479   ;
 480
 481   my $statement = "INSERT INTO ". $self->table. " ( ".
 482       join(', ',@fields ).
 483     ") VALUES (".
 484       join(', ',map(_quote($self->getfield($_),$self->table,$_), @fields)).
 485     ")"
 486   ;
 487   warn "[debug]$me $statement\n" if $DEBUG;
 488   my $sth = dbh->prepare($statement) or return dbh->errstr;
 489
 490   local $SIG{HUP} = 'IGNORE';
 491   local $SIG{INT} = 'IGNORE';
 492   local $SIG{QUIT} = 'IGNORE';
 493   local $SIG{TERM} = 'IGNORE';
 494   local $SIG{TSTP} = 'IGNORE';
 495   local $SIG{PIPE} = 'IGNORE';
 496
 497   $sth->execute or return $sth->errstr;
 498   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 499
 500   '';
 501 }
 502
 503 =item add
 504
 505 Depriciated (use insert instead).
 506
 507 =cut
 508
 509 sub add {
 510   cluck "warning: FS::Record::add depriciated!";
 511   insert @_; #call method in this scope
 512 }
 513
 514 =item delete
 515
 516 Delete this record from the database.  If there is an error, returns the error,
 517 otherwise returns false.
 518
 519 =cut
 520
 521 sub delete {
 522   my $self = shift;
 523
 524   my($statement)="DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 525     map {
 526       $self->getfield($_) eq ''
 527         #? "( $_ IS NULL OR $_ = \"\" )"
 528         ? ( driver_name =~ /^Pg$/i
 529               ? "$_ IS NULL"
 530               : "( $_ IS NULL OR $_ = \"\" )"
 531           )
 532         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 533     } ( $self->dbdef_table->primary_key )
 534           ? ( $self->dbdef_table->primary_key)
 535           : $self->fields
 536   );
 537   warn "[debug]$me $statement\n" if $DEBUG;
 538   my $sth = dbh->prepare($statement) or return dbh->errstr;
 539
 540   local $SIG{HUP} = 'IGNORE';
 541   local $SIG{INT} = 'IGNORE';
 542   local $SIG{QUIT} = 'IGNORE';
 543   local $SIG{TERM} = 'IGNORE';
 544   local $SIG{TSTP} = 'IGNORE';
 545   local $SIG{PIPE} = 'IGNORE';
 546
 547   my $rc = $sth->execute or return $sth->errstr;
 548   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 549   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 550
 551   undef $self; #no need to keep object!
 552
 553   '';
 554 }
 555
 556 =item del
 557
 558 Depriciated (use delete instead).
 559
 560 =cut
 561
 562 sub del {
 563   cluck "warning: FS::Record::del depriciated!";
 564   &delete(@_); #call method in this scope
 565 }
 566
 567 =item replace OLD_RECORD
 568
 569 Replace the OLD_RECORD with this one in the database.  If there is an error,
 570 returns the error, otherwise returns false.
 571
 572 =cut
 573
 574 sub replace {
 575   my ( $new, $old ) = ( shift, shift );
 576   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
 577
 578   my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 579   unless ( @diff ) {
 580     carp "[warning]$me $new -> replace $old: records identical";
 581     return '';
 582   }
 583
 584   return "Records not in same table!" unless $new->table eq $old->table;
 585
 586   my $primary_key = $old->dbdef_table->primary_key;
 587   return "Can't change $primary_key"
 588     if $primary_key
 589        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 590
 591   my $error = $new->check;
 592   return $error if $error;
 593
 594   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 595     map {
 596       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 597     } @diff
 598   ). ' WHERE '.
 599     join(' AND ',
 600       map {
 601         $old->getfield($_) eq ''
 602           #? "( $_ IS NULL OR $_ = \"\" )"
 603           ? ( driver_name =~ /^Pg$/i
 604                 ? "$_ IS NULL"
 605                 : "( $_ IS NULL OR $_ = \"\" )"
 606             )
 607           : "$_ = ". _quote($old->getfield($_),$old->table,$_)
 608       } ( $primary_key ? ( $primary_key ) : $old->fields )
 609     )
 610   ;
 611   warn "[debug]$me $statement\n" if $DEBUG;
 612   my $sth = dbh->prepare($statement) or return dbh->errstr;
 613
 614   local $SIG{HUP} = 'IGNORE';
 615   local $SIG{INT} = 'IGNORE';
 616   local $SIG{QUIT} = 'IGNORE';
 617   local $SIG{TERM} = 'IGNORE';
 618   local $SIG{TSTP} = 'IGNORE';
 619   local $SIG{PIPE} = 'IGNORE';
 620
 621   my $rc = $sth->execute or return $sth->errstr;
 622   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
 623   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 624
 625   '';
 626
 627 }
 628
 629 =item rep
 630
 631 Depriciated (use replace instead).
 632
 633 =cut
 634
 635 sub rep {
 636   cluck "warning: FS::Record::rep depriciated!";
 637   replace @_; #call method in this scope
 638 }
 639
 640 =item check
 641
 642 Not yet implemented, croaks.  Derived classes should provide a check method.
 643
 644 =cut
 645
 646 sub check {
 647   confess "FS::Record::check not implemented; supply one in subclass!";
 648 }
 649
 650 =item unique COLUMN
 651
 652 Replaces COLUMN in record with a unique number.  Called by the B<add> method
 653 on primary keys and single-field unique columns (see L<DBIx::DBSchema::Table>).
 654 Returns the new value.
 655
 656 =cut
 657
 658 sub unique {
 659   my($self,$field) = @_;
 660   my($table)=$self->table;
 661
 662   croak("&FS::UID::checkruid failed") unless &checkruid;
 663
 664   croak "Unique called on field $field, but it is ",
 665         $self->getfield($field),
 666         ", not null!"
 667     if $self->getfield($field);
 668
 669   #warn "table $table is tainted" if is_tainted($table);
 670   #warn "field $field is tainted" if is_tainted($field);
 671
 672   my($counter) = new File::CounterFile "$table.$field",0;
 673 # hack for web demo
 674 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
 675 #  my($user)=$1;
 676 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
 677 # endhack
 678
 679   my($index)=$counter->inc;
 680   $index=$counter->inc
 681     while qsearchs($table,{$field=>$index}); #just in case
 682
 683   $index =~ /^(\d*)$/;
 684   $index=$1;
 685
 686   $self->setfield($field,$index);
 687
 688 }
 689
 690 =item ut_float COLUMN
 691
 692 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
 693 null.  If there is an error, returns the error, otherwise returns false.
 694
 695 =cut
 696
 697 sub ut_float {
 698   my($self,$field)=@_ ;
 699   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
 700    $self->getfield($field) =~ /^(\d+)$/ ||
 701    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
 702    $self->getfield($field) =~ /^(\d+e\d+)$/)
 703     or return "Illegal or empty (float) $field: ". $self->getfield($field);
 704   $self->setfield($field,$1);
 705   '';
 706 }
 707
 708 =item ut_number COLUMN
 709
 710 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
 711 is an error, returns the error, otherwise returns false.
 712
 713 =cut
 714
 715 sub ut_number {
 716   my($self,$field)=@_;
 717   $self->getfield($field) =~ /^(\d+)$/
 718     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
 719   $self->setfield($field,$1);
 720   '';
 721 }
 722
 723 =item ut_numbern COLUMN
 724
 725 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
 726 an error, returns the error, otherwise returns false.
 727
 728 =cut
 729
 730 sub ut_numbern {
 731   my($self,$field)=@_;
 732   $self->getfield($field) =~ /^(\d*)$/
 733     or return "Illegal (numeric) $field: ". $self->getfield($field);
 734   $self->setfield($field,$1);
 735   '';
 736 }
 737
 738 =item ut_money COLUMN
 739
 740 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
 741 is an error, returns the error, otherwise returns false.
 742
 743 =cut
 744
 745 sub ut_money {
 746   my($self,$field)=@_;
 747   $self->setfield($field, 0) if $self->getfield($field) eq '';
 748   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
 749     or return "Illegal (money) $field: ". $self->getfield($field);
 750   #$self->setfield($field, "$1$2$3" || 0);
 751   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
 752   '';
 753 }
 754
 755 =item ut_text COLUMN
 756
 757 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 758 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 759 May not be null.  If there is an error, returns the error, otherwise returns
 760 false.
 761
 762 =cut
 763
 764 sub ut_text {
 765   my($self,$field)=@_;
 766   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]+)$/
 767     or return "Illegal or empty (text) $field: ". $self->getfield($field);
 768   $self->setfield($field,$1);
 769   '';
 770 }
 771
 772 =item ut_textn COLUMN
 773
 774 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 775 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 776 May be null.  If there is an error, returns the error, otherwise returns false.
 777
 778 =cut
 779
 780 sub ut_textn {
 781   my($self,$field)=@_;
 782   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]*)$/
 783     or return "Illegal (text) $field: ". $self->getfield($field);
 784   $self->setfield($field,$1);
 785   '';
 786 }
 787
 788 =item ut_alpha COLUMN
 789
 790 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
 791 an error, returns the error, otherwise returns false.
 792
 793 =cut
 794
 795 sub ut_alpha {
 796   my($self,$field)=@_;
 797   $self->getfield($field) =~ /^(\w+)$/
 798     or return "Illegal or empty (alphanumeric) $field: ".
 799               $self->getfield($field);
 800   $self->setfield($field,$1);
 801   '';
 802 }
 803
 804 =item ut_alpha COLUMN
 805
 806 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
 807 error, returns the error, otherwise returns false.
 808
 809 =cut
 810
 811 sub ut_alphan {
 812   my($self,$field)=@_;
 813   $self->getfield($field) =~ /^(\w*)$/
 814     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
 815   $self->setfield($field,$1);
 816   '';
 817 }
 818
 819 =item ut_phonen COLUMN [ COUNTRY ]
 820
 821 Check/untaint phone numbers.  May be null.  If there is an error, returns
 822 the error, otherwise returns false.
 823
 824 Takes an optional two-letter ISO country code; without it or with unsupported
 825 countries, ut_phonen simply calls ut_alphan.
 826
 827 =cut
 828
 829 sub ut_phonen {
 830   my( $self, $field, $country ) = @_;
 831   return $self->ut_alphan($field) unless defined $country;
 832   my $phonen = $self->getfield($field);
 833   if ( $phonen eq '' ) {
 834     $self->setfield($field,'');
 835   } elsif ( $country eq 'US' || $country eq 'CA' ) {
 836     $phonen =~ s/\D//g;
 837     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
 838       or return "Illegal (phone) $field: ". $self->getfield($field);
 839     $phonen = "$1-$2-$3";
 840     $phonen .= " x$4" if $4;
 841     $self->setfield($field,$phonen);
 842   } else {
 843     warn "warning: don't know how to check phone numbers for country $country";
 844     return $self->ut_textn($field);
 845   }
 846   '';
 847 }
 848
 849 =item ut_ip COLUMN
 850
 851 Check/untaint ip addresses.  IPv4 only for now.
 852
 853 =cut
 854
 855 sub ut_ip {
 856   my( $self, $field ) = @_;
 857   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
 858     or return "Illegal (IP address) $field: ". $self->getfield($field);
 859   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
 860   $self->setfield($field, "$1.$2.$3.$3");
 861   '';
 862 }
 863
 864 =item ut_ipn COLUMN
 865
 866 Check/untaint ip addresses.  IPv4 only for now.  May be null.
 867
 868 =cut
 869
 870 sub ut_ipn {
 871   my( $self, $field ) = @_;
 872   if ( $self->getfield($field) =~ /^()$/ ) {
 873     $self->setfield($field,'');
 874     '';
 875   } else {
 876     $self->ut_ip($field);
 877   }
 878 }
 879
 880 =item ut_domain COLUMN
 881
 882 Check/untaint host and domain names.
 883
 884 =cut
 885
 886 sub ut_domain {
 887   my( $self, $field ) = @_;
 888   #$self->getfield($field) =~/^(\w+\.)*\w+$/
 889   $self->getfield($field) =~/^(\w+\.)*\w+$/
 890     or return "Illegal (domain) $field: ". $self->getfield($field);
 891   $self->setfield($field,$1);
 892   '';
 893 }
 894
 895 =item ut_name COLUMN
 896
 897 Check/untaint proper names; allows alphanumerics, spaces and the following
 898 punctuation: , . - '
 899
 900 May not be null.
 901
 902 =cut
 903
 904 sub ut_name {
 905   my( $self, $field ) = @_;
 906   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
 907     or return "Illegal (name) $field: ". $self->getfield($field);
 908   $self->setfield($field,$1);
 909   '';
 910 }
 911
 912 =item ut_zip COLUMN
 913
 914 Check/untaint zip codes.
 915
 916 =cut
 917
 918 sub ut_zip {
 919   my( $self, $field, $country ) = @_;
 920   if ( $country eq 'US' ) {
 921     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
 922       or return "Illegal (zip) $field for country $country: ".
 923                 $self->getfield($field);
 924     $self->setfield($field,$1);
 925   } else {
 926     $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
 927       or return "Illegal (zip) $field: ". $self->getfield($field);
 928     $self->setfield($field,$1);
 929   }
 930   '';
 931 }
 932
 933 =item ut_country COLUMN
 934
 935 Check/untaint country codes.  Country names are changed to codes, if possible -
 936 see L<Locale::Country>.
 937
 938 =cut
 939
 940 sub ut_country {
 941   my( $self, $field ) = @_;
 942   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
 943     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
 944          && country2code($1) ) {
 945       $self->setfield($field,uc(country2code($1)));
 946     }
 947   }
 948   $self->getfield($field) =~ /^(\w\w)$/
 949     or return "Illegal (country) $field: ". $self->getfield($field);
 950   $self->setfield($field,uc($1));
 951   '';
 952 }
 953
 954 =item ut_anything COLUMN
 955
 956 Untaints arbitrary data.  Be careful.
 957
 958 =cut
 959
 960 sub ut_anything {
 961   my( $self, $field ) = @_;
 962   $self->getfield($field) =~ /^(.*)$/s
 963     or return "Illegal $field: ". $self->getfield($field);
 964   $self->setfield($field,$1);
 965   '';
 966 }
 967
 968 =item ut_enum COLUMN CHOICES_ARRAYREF
 969
 970 Check/untaint a column, supplying all possible choices, like the "enum" type.
 971
 972 =cut
 973
 974 sub ut_enum {
 975   my( $self, $field, $choices ) = @_;
 976   foreach my $choice ( @$choices ) {
 977     if ( $self->getfield($field) eq $choice ) {
 978       $self->setfield($choice);
 979       return '';
 980     }
 981   }
 982   return "Illegal (enum) field $field: ". $self->getfield($field);
 983 }
 984
 985 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
 986
 987 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
 988 on the column first.
 989
 990 =cut
 991
 992 sub ut_foreign_key {
 993   my( $self, $field, $table, $foreign ) = @_;
 994   qsearchs($table, { $foreign => $self->getfield($field) })
 995     or return "Can't find $field ". $self->getfield($field).
 996               " in $table.$foreign";
 997   '';
 998 }
 999
1000 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1001
1002 Like ut_foreign_key, except the null value is also allowed.
1003
1004 =cut
1005
1006 sub ut_foreign_keyn {
1007   my( $self, $field, $table, $foreign ) = @_;
1008   $self->getfield($field)
1009     ? $self->ut_foreign_key($field, $table, $foreign)
1010     : '';
1011 }
1012
1013 =item fields [ TABLE ]
1014
1015 This can be used as both a subroutine and a method call.  It returns a list
1016 of the columns in this record's table, or an explicitly specified table.
1017 (See L<DBIx::DBSchema::Table>).
1018
1019 =cut
1020
1021 # Usage: @fields = fields($table);
1022 #        @fields = $record->fields;
1023 sub fields {
1024   my $something = shift;
1025   my $table;
1026   if ( ref($something) ) {
1027     $table = $something->table;
1028   } else {
1029     $table = $something;
1030   }
1031   #croak "Usage: \@fields = fields(\$table)\n   or: \@fields = \$record->fields" unless $table;
1032   my($table_obj) = $dbdef->table($table);
1033   confess "Unknown table $table" unless $table_obj;
1034   $table_obj->columns;
1035 }
1036
1037 =back
1038
1039 =head1 SUBROUTINES
1040
1041 =over 4
1042
1043 =item reload_dbdef([FILENAME])
1044
1045 Load a database definition (see L<DBIx::DBSchema>), optionally from a
1046 non-default filename.  This command is executed at startup unless
1047 I<$FS::Record::setup_hack> is true.  Returns a DBIx::DBSchema object.
1048
1049 =cut
1050
1051 sub reload_dbdef {
1052   my $file = shift || $dbdef_file;
1053   $dbdef = load DBIx::DBSchema $file
1054     or die "can't load database schema from $file";
1055 }
1056
1057 =item dbdef
1058
1059 Returns the current database definition.  See L<FS::dbdef>.
1060
1061 =cut
1062
1063 sub dbdef { $dbdef; }
1064
1065 =item _quote VALUE, TABLE, COLUMN
1066
1067 This is an internal function used to construct SQL statements.  It returns
1068 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
1069 type (see L<FS::dbdef_column>) does not end in `char' or `binary'.
1070
1071 =cut
1072
1073 sub _quote {
1074   my($value,$table,$field)=@_;
1075   my($dbh)=dbh;
1076   if ( $value =~ /^\d+(\.\d+)?$/ &&
1077 #       ! ( datatype($table,$field) =~ /^char/ )
1078        ! ( $dbdef->table($table)->column($field)->type =~ /(char|binary)$/i )
1079   ) {
1080     $value;
1081   } else {
1082     $dbh->quote($value);
1083   }
1084 }
1085
1086 =item hfields TABLE
1087
1088 This is depriciated.  Don't use it.
1089
1090 It returns a hash-type list with the fields of this record's table set true.
1091
1092 =cut
1093
1094 sub hfields {
1095   carp "warning: hfields is depriciated";
1096   my($table)=@_;
1097   my(%hash);
1098   foreach (fields($table)) {
1099     $hash{$_}=1;
1100   }
1101   \%hash;
1102 }
1103
1104 sub _dump {
1105   my($self)=@_;
1106   join("\n", map {
1107     "$_: ". $self->getfield($_). "|"
1108   } (fields($self->table)) );
1109 }
1110
1111 sub DESTROY { return; }
1112
1113 #sub DESTROY {
1114 #  my $self = shift;
1115 #  #use Carp qw(cluck);
1116 #  #cluck "DESTROYING $self";
1117 #  warn "DESTROYING $self";
1118 #}
1119
1120 #sub is_tainted {
1121 #             return ! eval { join('',@_), kill 0; 1; };
1122 #         }
1123
1124 =back
1125
1126 =head1 BUGS
1127
1128 This module should probably be renamed, since much of the functionality is
1129 of general use.  It is not completely unlike Adapter::DBI (see below).
1130
1131 Exported qsearch and qsearchs should be depriciated in favor of method calls
1132 (against an FS::Record object like the old search and searchs that qsearch
1133 and qsearchs were on top of.)
1134
1135 The whole fields / hfields mess should be removed.
1136
1137 The various WHERE clauses should be subroutined.
1138
1139 table string should be depriciated in favor of FS::dbdef_table.
1140
1141 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1142 true maps to the database (and WHERE clauses) would also help.
1143
1144 The ut_ methods should ask the dbdef for a default length.
1145
1146 ut_sqltype (like ut_varchar) should all be defined
1147
1148 A fallback check method should be provided which uses the dbdef.
1149
1150 The ut_money method assumes money has two decimal digits.
1151
1152 The Pg money kludge in the new method only strips `$'.
1153
1154 The ut_phonen method only checks US-style phone numbers.
1155
1156 The _quote function should probably use ut_float instead of a regex.
1157
1158 All the subroutines probably should be methods, here or elsewhere.
1159
1160 Probably should borrow/use some dbdef methods where appropriate (like sub
1161 fields)
1162
1163 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1164 or allow it to be set.  Working around it is ugly any way around - DBI should
1165 be fixed.  (only affects RDBMS which return uppercase column names)
1166
1167 ut_zip should take an optional country like ut_phone.
1168
1169 =head1 SEE ALSO
1170
1171 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1172
1173 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1174
1175 =cut
1176
1177 1;
1178