FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $dbdef_file $dbdef $setup_hack $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $me );
   6 use subs qw(reload_dbdef);
   7 use Exporter;
   8 use Carp qw(carp cluck croak confess);
   9 use File::CounterFile;
  10 use Locale::Country;
  11 use DBI qw(:sql_types);
  12 use DBIx::DBSchema 0.19;
  13 use FS::UID qw(dbh checkruid getotaker datasrc driver_name);
  14 use FS::SearchCache;
  15
  16 @ISA = qw(Exporter);
  17 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch);
  18
  19 $DEBUG = 0;
  20 $me = '[FS::Record]';
  21
  22 #ask FS::UID to run this stuff for us later
  23 $FS::UID::callback{'FS::Record'} = sub {
  24   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  25   $dbdef_file = "/usr/local/etc/freeside/dbdef.". datasrc;
  26   &reload_dbdef unless $setup_hack; #$setup_hack needed now?
  27 };
  28
  29 =head1 NAME
  30
  31 FS::Record - Database record objects
  32
  33 =head1 SYNOPSIS
  34
  35     use FS::Record;
  36     use FS::Record qw(dbh fields qsearch qsearchs dbdef);
  37
  38     $record = new FS::Record 'table', \%hash;
  39     $record = new FS::Record 'table', { 'column' => 'value', ... };
  40
  41     $record  = qsearchs FS::Record 'table', \%hash;
  42     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  43     @records = qsearch  FS::Record 'table', \%hash;
  44     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  45
  46     $table = $record->table;
  47     $dbdef_table = $record->dbdef_table;
  48
  49     $value = $record->get('column');
  50     $value = $record->getfield('column');
  51     $value = $record->column;
  52
  53     $record->set( 'column' => 'value' );
  54     $record->setfield( 'column' => 'value' );
  55     $record->column('value');
  56
  57     %hash = $record->hash;
  58
  59     $hashref = $record->hashref;
  60
  61     $error = $record->insert;
  62     #$error = $record->add; #deprecated
  63
  64     $error = $record->delete;
  65     #$error = $record->del; #deprecated
  66
  67     $error = $new_record->replace($old_record);
  68     #$error = $new_record->rep($old_record); #deprecated
  69
  70     $value = $record->unique('column');
  71
  72     $error = $record->ut_float('column');
  73     $error = $record->ut_number('column');
  74     $error = $record->ut_numbern('column');
  75     $error = $record->ut_money('column');
  76     $error = $record->ut_text('column');
  77     $error = $record->ut_textn('column');
  78     $error = $record->ut_alpha('column');
  79     $error = $record->ut_alphan('column');
  80     $error = $record->ut_phonen('column');
  81     $error = $record->ut_anything('column');
  82     $error = $record->ut_name('column');
  83
  84     $dbdef = reload_dbdef;
  85     $dbdef = reload_dbdef "/non/standard/filename";
  86     $dbdef = dbdef;
  87
  88     $quoted_value = _quote($value,'table','field');
  89
  90     #depriciated
  91     $fields = hfields('table');
  92     if ( $fields->{Field} ) { # etc.
  93
  94     @fields = fields 'table'; #as a subroutine
  95     @fields = $record->fields; #as a method call
  96
  97
  98 =head1 DESCRIPTION
  99
 100 (Mostly) object-oriented interface to database records.  Records are currently
 101 implemented on top of DBI.  FS::Record is intended as a base class for
 102 table-specific classes to inherit from, i.e. FS::cust_main.
 103
 104 =head1 CONSTRUCTORS
 105
 106 =over 4
 107
 108 =item new [ TABLE, ] HASHREF
 109
 110 Creates a new record.  It doesn't store it in the database, though.  See
 111 L<"insert"> for that.
 112
 113 Note that the object stores this hash reference, not a distinct copy of the
 114 hash it points to.  You can ask the object for a copy with the I<hash>
 115 method.
 116
 117 TABLE can only be omitted when a dervived class overrides the table method.
 118
 119 =cut
 120
 121 sub new {
 122   my $proto = shift;
 123   my $class = ref($proto) || $proto;
 124   my $self = {};
 125   bless ($self, $class);
 126
 127   unless ( defined ( $self->table ) ) {
 128     $self->{'Table'} = shift;
 129     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 130   }
 131
 132   my $hashref = $self->{'Hash'} = shift;
 133
 134   foreach my $field ( $self->fields ) {
 135     $hashref->{$field}='' unless defined $hashref->{$field};
 136     #trim the '$' and ',' from money fields for Pg (belong HERE?)
 137     #(what about Pg i18n?)
 138     if ( driver_name =~ /^Pg$/i
 139          && $self->dbdef_table->column($field)->type eq 'money' ) {
 140       ${$hashref}{$field} =~ s/^\$//;
 141       ${$hashref}{$field} =~ s/\,//;
 142     }
 143   }
 144
 145   $self->_cache($hashref, shift) if $self->can('_cache') && @_;
 146
 147   $self;
 148 }
 149
 150 sub new_or_cached {
 151   my $proto = shift;
 152   my $class = ref($proto) || $proto;
 153   my $self = {};
 154   bless ($self, $class);
 155
 156   $self->{'Table'} = shift unless defined ( $self->table );
 157
 158   my $hashref = $self->{'Hash'} = shift;
 159   my $cache = shift;
 160   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 161     my $obj = $cache->cache->{$hashref->{$cache->key}};
 162     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 163     $obj;
 164   } else {
 165     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 166   }
 167
 168 }
 169
 170 sub create {
 171   my $proto = shift;
 172   my $class = ref($proto) || $proto;
 173   my $self = {};
 174   bless ($self, $class);
 175   if ( defined $self->table ) {
 176     cluck "create constructor is depriciated, use new!";
 177     $self->new(@_);
 178   } else {
 179     croak "FS::Record::create called (not from a subclass)!";
 180   }
 181 }
 182
 183 =item qsearch TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ
 184
 185 Searches the database for all records matching (at least) the key/value pairs
 186 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 187 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 188 objects.
 189
 190 ###oops, argh, FS::Record::new only lets us create database fields.
 191 #Normal behaviour if SELECT is not specified is `*', as in
 192 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 193 #feature where you can specify SELECT - remember, the objects returned,
 194 #although blessed into the appropriate `FS::TABLE' package, will only have the
 195 #fields you specify.  This might have unwanted results if you then go calling
 196 #regular FS::TABLE methods
 197 #on it.
 198
 199 =cut
 200
 201 sub qsearch {
 202   my($stable, $record, $select, $extra_sql, $cache ) = @_;
 203   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 204   #for jsearch
 205   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 206   $stable = $1;
 207   $select ||= '*';
 208   my $dbh = dbh;
 209
 210   my $table = $cache ? $cache->table : $stable;
 211
 212   my @fields = grep exists($record->{$_}), fields($table);
 213
 214   my $statement = "SELECT $select FROM $stable";
 215   if ( @fields ) {
 216     $statement .= ' WHERE '. join(' AND ', map {
 217
 218       my $op = '=';
 219       if ( ref($record->{$_}) ) {
 220         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 221         $op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name !~ /^Pg$/i;
 222         $record->{$_} = $record->{$_}{'value'}
 223       }
 224
 225       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 226         if ( driver_name =~ /^Pg$/i ) {
 227           qq-( $_ IS NULL OR $_ = '' )-;
 228         } else {
 229           qq-( $_ IS NULL OR $_ = "" )-;
 230         }
 231       } else {
 232         "$_ $op ?";
 233       }
 234     } @fields );
 235   }
 236   $statement .= " $extra_sql" if defined($extra_sql);
 237
 238   warn "[debug]$me $statement\n" if $DEBUG;
 239   my $sth = $dbh->prepare($statement)
 240     or croak "$dbh->errstr doing $statement";
 241
 242   my $bind = 1;
 243
 244   foreach my $field (
 245     grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 246   ) {
 247     if ( $record->{$field} =~ /^\d+(\.\d+)?$/
 248          && $dbdef->table($table)->column($field)->type =~ /(int)/i
 249     ) {
 250       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_INTEGER } );
 251     } else {
 252       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_VARCHAR } );
 253     }
 254   }
 255
 256 #  $sth->execute( map $record->{$_},
 257 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 258 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 259
 260   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 261
 262   $dbh->commit or croak $dbh->errstr if $FS::UID::AutoCommit;
 263
 264   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 265     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 266       #derivied class didn't override new method, so this optimization is safe
 267       if ( $cache ) {
 268         map {
 269           new_or_cached( "FS::$table", { %{$_} }, $cache )
 270         } @{$sth->fetchall_arrayref( {} )};
 271       } else {
 272         map {
 273           new( "FS::$table", { %{$_} } )
 274         } @{$sth->fetchall_arrayref( {} )};
 275       }
 276     } else {
 277       warn "untested code (class FS::$table uses custom new method)";
 278       map {
 279         eval 'FS::'. $table. '->new( { %{$_} } )';
 280       } @{$sth->fetchall_arrayref( {} )};
 281     }
 282   } else {
 283     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 284     map {
 285       FS::Record->new( $table, { %{$_} } );
 286     } @{$sth->fetchall_arrayref( {} )};
 287   }
 288
 289 }
 290
 291 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 292
 293 Experimental JOINed search method.  Using this method, you can execute a
 294 single SELECT spanning multiple tables, and cache the results for subsequent
 295 method calls.  Interface will almost definately change in an incompatible
 296 fashion.
 297
 298 Arguments:
 299
 300 =cut
 301
 302 sub jsearch {
 303   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 304   my $cache = FS::SearchCache->new( $ptable, $pkey );
 305   my %saw;
 306   ( $cache,
 307     grep { !$saw{$_->getfield($pkey)}++ }
 308       qsearch($table, $record, $select, $extra_sql, $cache )
 309   );
 310 }
 311
 312 =item qsearchs TABLE, HASHREF
 313
 314 Same as qsearch, except that if more than one record matches, it B<carp>s but
 315 returns the first.  If this happens, you either made a logic error in asking
 316 for a single item, or your data is corrupted.
 317
 318 =cut
 319
 320 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 321   my(@result) = qsearch(@_);
 322   carp "warning: Multiple records in scalar search!" if scalar(@result) > 1;
 323     #should warn more vehemently if the search was on a primary key?
 324   scalar(@result) ? ($result[0]) : ();
 325 }
 326
 327 =back
 328
 329 =head1 METHODS
 330
 331 =over 4
 332
 333 =item table
 334
 335 Returns the table name.
 336
 337 =cut
 338
 339 sub table {
 340 #  cluck "warning: FS::Record::table depriciated; supply one in subclass!";
 341   my $self = shift;
 342   $self -> {'Table'};
 343 }
 344
 345 =item dbdef_table
 346
 347 Returns the DBIx::DBSchema::Table object for the table.
 348
 349 =cut
 350
 351 sub dbdef_table {
 352   my($self)=@_;
 353   my($table)=$self->table;
 354   $dbdef->table($table);
 355 }
 356
 357 =item get, getfield COLUMN
 358
 359 Returns the value of the column/field/key COLUMN.
 360
 361 =cut
 362
 363 sub get {
 364   my($self,$field) = @_;
 365   # to avoid "Use of unitialized value" errors
 366   if ( defined ( $self->{Hash}->{$field} ) ) {
 367     $self->{Hash}->{$field};
 368   } else {
 369     '';
 370   }
 371 }
 372 sub getfield {
 373   my $self = shift;
 374   $self->get(@_);
 375 }
 376
 377 =item set, setfield COLUMN, VALUE
 378
 379 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 380
 381 =cut
 382
 383 sub set {
 384   my($self,$field,$value) = @_;
 385   $self->{'Hash'}->{$field} = $value;
 386 }
 387 sub setfield {
 388   my $self = shift;
 389   $self->set(@_);
 390 }
 391
 392 =item AUTLOADED METHODS
 393
 394 $record->column is a synonym for $record->get('column');
 395
 396 $record->column('value') is a synonym for $record->set('column','value');
 397
 398 =cut
 399
 400 # readable/safe
 401 #sub AUTOLOAD {
 402 #  my($self,$value)=@_;
 403 #  my($field)=$AUTOLOAD;
 404 #  $field =~ s/.*://;
 405 #  if ( defined($value) ) {
 406 #    confess "errant AUTOLOAD $field for $self (arg $value)"
 407 #      unless $self->can('setfield');
 408 #    $self->setfield($field,$value);
 409 #  } else {
 410 #    confess "errant AUTOLOAD $field for $self (no args)"
 411 #      unless $self->can('getfield');
 412 #    $self->getfield($field);
 413 #  }
 414 #}
 415
 416 # efficient
 417 sub AUTOLOAD {
 418   my $field = $AUTOLOAD;
 419   $field =~ s/.*://;
 420   if ( defined($_[1]) ) {
 421     $_[0]->setfield($field, $_[1]);
 422   } else {
 423     $_[0]->getfield($field);
 424   }
 425 }
 426
 427 =item hash
 428
 429 Returns a list of the column/value pairs, usually for assigning to a new hash.
 430
 431 To make a distinct duplicate of an FS::Record object, you can do:
 432
 433     $new = new FS::Record ( $old->table, { $old->hash } );
 434
 435 =cut
 436
 437 sub hash {
 438   my($self) = @_;
 439   %{ $self->{'Hash'} };
 440 }
 441
 442 =item hashref
 443
 444 Returns a reference to the column/value hash.
 445
 446 =cut
 447
 448 sub hashref {
 449   my($self) = @_;
 450   $self->{'Hash'};
 451 }
 452
 453 =item insert
 454
 455 Inserts this record to the database.  If there is an error, returns the error,
 456 otherwise returns false.
 457
 458 =cut
 459
 460 sub insert {
 461   my $self = shift;
 462
 463   my $error = $self->check;
 464   return $error if $error;
 465
 466   #single-field unique keys are given a value if false
 467   #(like MySQL's AUTO_INCREMENT)
 468   foreach ( $self->dbdef_table->unique->singles ) {
 469     $self->unique($_) unless $self->getfield($_);
 470   }
 471   #and also the primary key
 472   my $primary_key = $self->dbdef_table->primary_key;
 473   $self->unique($primary_key)
 474     if $primary_key && ! $self->getfield($primary_key);
 475
 476   #false laziness w/delete
 477   my @fields =
 478     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 479     $self->fields
 480   ;
 481   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
 482   #eslaf
 483
 484   my $statement = "INSERT INTO ". $self->table. " ( ".
 485       join( ', ', @fields ).
 486     ") VALUES (".
 487       join( ', ', @values ).
 488     ")"
 489   ;
 490   warn "[debug]$me $statement\n" if $DEBUG;
 491   my $sth = dbh->prepare($statement) or return dbh->errstr;
 492
 493   my $h_statement = $self->_h_statement('insert');
 494   warn "[debug]$me $h_statement\n" if $DEBUG;
 495   my $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 496
 497   local $SIG{HUP} = 'IGNORE';
 498   local $SIG{INT} = 'IGNORE';
 499   local $SIG{QUIT} = 'IGNORE';
 500   local $SIG{TERM} = 'IGNORE';
 501   local $SIG{TSTP} = 'IGNORE';
 502   local $SIG{PIPE} = 'IGNORE';
 503
 504   $sth->execute or return $sth->errstr;
 505   $h_sth->execute or return $h_sth->errstr;
 506   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 507
 508   '';
 509 }
 510
 511 =item add
 512
 513 Depriciated (use insert instead).
 514
 515 =cut
 516
 517 sub add {
 518   cluck "warning: FS::Record::add depriciated!";
 519   insert @_; #call method in this scope
 520 }
 521
 522 =item delete
 523
 524 Delete this record from the database.  If there is an error, returns the error,
 525 otherwise returns false.
 526
 527 =cut
 528
 529 sub delete {
 530   my $self = shift;
 531
 532   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 533     map {
 534       $self->getfield($_) eq ''
 535         #? "( $_ IS NULL OR $_ = \"\" )"
 536         ? ( driver_name =~ /^Pg$/i
 537               ? "$_ IS NULL"
 538               : "( $_ IS NULL OR $_ = \"\" )"
 539           )
 540         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 541     } ( $self->dbdef_table->primary_key )
 542           ? ( $self->dbdef_table->primary_key)
 543           : $self->fields
 544   );
 545   warn "[debug]$me $statement\n" if $DEBUG;
 546   my $sth = dbh->prepare($statement) or return dbh->errstr;
 547
 548   my $h_statement = $self->_h_statement('delete');
 549   warn "[debug]$me $h_statement\n" if $DEBUG;
 550   my $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 551
 552   local $SIG{HUP} = 'IGNORE';
 553   local $SIG{INT} = 'IGNORE';
 554   local $SIG{QUIT} = 'IGNORE';
 555   local $SIG{TERM} = 'IGNORE';
 556   local $SIG{TSTP} = 'IGNORE';
 557   local $SIG{PIPE} = 'IGNORE';
 558
 559   my $rc = $sth->execute or return $sth->errstr;
 560   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 561   $h_sth->execute or return $h_sth->errstr;
 562   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 563
 564   undef $self; #no need to keep object!
 565
 566   '';
 567 }
 568
 569 =item del
 570
 571 Depriciated (use delete instead).
 572
 573 =cut
 574
 575 sub del {
 576   cluck "warning: FS::Record::del depriciated!";
 577   &delete(@_); #call method in this scope
 578 }
 579
 580 =item replace OLD_RECORD
 581
 582 Replace the OLD_RECORD with this one in the database.  If there is an error,
 583 returns the error, otherwise returns false.
 584
 585 =cut
 586
 587 sub replace {
 588   my ( $new, $old ) = ( shift, shift );
 589   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
 590
 591   return "Records not in same table!" unless $new->table eq $old->table;
 592
 593   my $primary_key = $old->dbdef_table->primary_key;
 594   return "Can't change $primary_key"
 595     if $primary_key
 596        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 597
 598   my $error = $new->check;
 599   return $error if $error;
 600
 601   my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 602   unless ( @diff ) {
 603     carp "[warning]$me $new -> replace $old: records identical";
 604     return '';
 605   }
 606
 607   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 608     map {
 609       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 610     } @diff
 611   ). ' WHERE '.
 612     join(' AND ',
 613       map {
 614         $old->getfield($_) eq ''
 615           #? "( $_ IS NULL OR $_ = \"\" )"
 616           ? ( driver_name =~ /^Pg$/i
 617                 ? "$_ IS NULL"
 618                 : "( $_ IS NULL OR $_ = \"\" )"
 619             )
 620           : "$_ = ". _quote($old->getfield($_),$old->table,$_)
 621       } ( $primary_key ? ( $primary_key ) : $old->fields )
 622     )
 623   ;
 624   warn "[debug]$me $statement\n" if $DEBUG;
 625   my $sth = dbh->prepare($statement) or return dbh->errstr;
 626
 627   my $h_old_statement = $old->_h_statement('replace_old');
 628   warn "[debug]$me $h_old_statement\n" if $DEBUG;
 629   my $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
 630
 631   my $h_new_statement = $new->_h_statement('replace_new');
 632   warn "[debug]$me $h_new_statement\n" if $DEBUG;
 633   my $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
 634
 635   local $SIG{HUP} = 'IGNORE';
 636   local $SIG{INT} = 'IGNORE';
 637   local $SIG{QUIT} = 'IGNORE';
 638   local $SIG{TERM} = 'IGNORE';
 639   local $SIG{TSTP} = 'IGNORE';
 640   local $SIG{PIPE} = 'IGNORE';
 641
 642   my $rc = $sth->execute or return $sth->errstr;
 643   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
 644   $h_old_sth->execute or return $h_old_sth->errstr;
 645   $h_new_sth->execute or return $h_new_sth->errstr;
 646   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 647
 648   '';
 649
 650 }
 651
 652 =item rep
 653
 654 Depriciated (use replace instead).
 655
 656 =cut
 657
 658 sub rep {
 659   cluck "warning: FS::Record::rep depriciated!";
 660   replace @_; #call method in this scope
 661 }
 662
 663 =item check
 664
 665 Not yet implemented, croaks.  Derived classes should provide a check method.
 666
 667 =cut
 668
 669 sub check {
 670   confess "FS::Record::check not implemented; supply one in subclass!";
 671 }
 672
 673 sub _h_statement {
 674   my( $self, $action ) = @_;
 675
 676   my @fields =
 677     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 678     $self->fields
 679   ;
 680   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
 681
 682   "INSERT INTO h_". $self->table. " ( ".
 683       join(', ', qw(history_date history_user history_action), @fields ).
 684     ") VALUES (".
 685       join(', ', time, dbh->quote(getotaker()), dbh->quote($action), @values).
 686     ")"
 687   ;
 688 }
 689
 690 =item unique COLUMN
 691
 692 Replaces COLUMN in record with a unique number.  Called by the B<add> method
 693 on primary keys and single-field unique columns (see L<DBIx::DBSchema::Table>).
 694 Returns the new value.
 695
 696 =cut
 697
 698 sub unique {
 699   my($self,$field) = @_;
 700   my($table)=$self->table;
 701
 702   croak("&FS::UID::checkruid failed") unless &checkruid;
 703
 704   croak "Unique called on field $field, but it is ",
 705         $self->getfield($field),
 706         ", not null!"
 707     if $self->getfield($field);
 708
 709   #warn "table $table is tainted" if is_tainted($table);
 710   #warn "field $field is tainted" if is_tainted($field);
 711
 712   my($counter) = new File::CounterFile "$table.$field",0;
 713 # hack for web demo
 714 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
 715 #  my($user)=$1;
 716 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
 717 # endhack
 718
 719   my($index)=$counter->inc;
 720   $index=$counter->inc
 721     while qsearchs($table,{$field=>$index}); #just in case
 722
 723   $index =~ /^(\d*)$/;
 724   $index=$1;
 725
 726   $self->setfield($field,$index);
 727
 728 }
 729
 730 =item ut_float COLUMN
 731
 732 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
 733 null.  If there is an error, returns the error, otherwise returns false.
 734
 735 =cut
 736
 737 sub ut_float {
 738   my($self,$field)=@_ ;
 739   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
 740    $self->getfield($field) =~ /^(\d+)$/ ||
 741    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
 742    $self->getfield($field) =~ /^(\d+e\d+)$/)
 743     or return "Illegal or empty (float) $field: ". $self->getfield($field);
 744   $self->setfield($field,$1);
 745   '';
 746 }
 747
 748 =item ut_number COLUMN
 749
 750 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
 751 is an error, returns the error, otherwise returns false.
 752
 753 =cut
 754
 755 sub ut_number {
 756   my($self,$field)=@_;
 757   $self->getfield($field) =~ /^(\d+)$/
 758     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
 759   $self->setfield($field,$1);
 760   '';
 761 }
 762
 763 =item ut_numbern COLUMN
 764
 765 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
 766 an error, returns the error, otherwise returns false.
 767
 768 =cut
 769
 770 sub ut_numbern {
 771   my($self,$field)=@_;
 772   $self->getfield($field) =~ /^(\d*)$/
 773     or return "Illegal (numeric) $field: ". $self->getfield($field);
 774   $self->setfield($field,$1);
 775   '';
 776 }
 777
 778 =item ut_money COLUMN
 779
 780 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
 781 is an error, returns the error, otherwise returns false.
 782
 783 =cut
 784
 785 sub ut_money {
 786   my($self,$field)=@_;
 787   $self->setfield($field, 0) if $self->getfield($field) eq '';
 788   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
 789     or return "Illegal (money) $field: ". $self->getfield($field);
 790   #$self->setfield($field, "$1$2$3" || 0);
 791   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
 792   '';
 793 }
 794
 795 =item ut_text COLUMN
 796
 797 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 798 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 799 May not be null.  If there is an error, returns the error, otherwise returns
 800 false.
 801
 802 =cut
 803
 804 sub ut_text {
 805   my($self,$field)=@_;
 806   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]+)$/
 807     or return "Illegal or empty (text) $field: ". $self->getfield($field);
 808   $self->setfield($field,$1);
 809   '';
 810 }
 811
 812 =item ut_textn COLUMN
 813
 814 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
 815 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
 816 May be null.  If there is an error, returns the error, otherwise returns false.
 817
 818 =cut
 819
 820 sub ut_textn {
 821   my($self,$field)=@_;
 822   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/]*)$/
 823     or return "Illegal (text) $field: ". $self->getfield($field);
 824   $self->setfield($field,$1);
 825   '';
 826 }
 827
 828 =item ut_alpha COLUMN
 829
 830 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
 831 an error, returns the error, otherwise returns false.
 832
 833 =cut
 834
 835 sub ut_alpha {
 836   my($self,$field)=@_;
 837   $self->getfield($field) =~ /^(\w+)$/
 838     or return "Illegal or empty (alphanumeric) $field: ".
 839               $self->getfield($field);
 840   $self->setfield($field,$1);
 841   '';
 842 }
 843
 844 =item ut_alpha COLUMN
 845
 846 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
 847 error, returns the error, otherwise returns false.
 848
 849 =cut
 850
 851 sub ut_alphan {
 852   my($self,$field)=@_;
 853   $self->getfield($field) =~ /^(\w*)$/
 854     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
 855   $self->setfield($field,$1);
 856   '';
 857 }
 858
 859 =item ut_phonen COLUMN [ COUNTRY ]
 860
 861 Check/untaint phone numbers.  May be null.  If there is an error, returns
 862 the error, otherwise returns false.
 863
 864 Takes an optional two-letter ISO country code; without it or with unsupported
 865 countries, ut_phonen simply calls ut_alphan.
 866
 867 =cut
 868
 869 sub ut_phonen {
 870   my( $self, $field, $country ) = @_;
 871   return $self->ut_alphan($field) unless defined $country;
 872   my $phonen = $self->getfield($field);
 873   if ( $phonen eq '' ) {
 874     $self->setfield($field,'');
 875   } elsif ( $country eq 'US' || $country eq 'CA' ) {
 876     $phonen =~ s/\D//g;
 877     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
 878       or return "Illegal (phone) $field: ". $self->getfield($field);
 879     $phonen = "$1-$2-$3";
 880     $phonen .= " x$4" if $4;
 881     $self->setfield($field,$phonen);
 882   } else {
 883     warn "warning: don't know how to check phone numbers for country $country";
 884     return $self->ut_textn($field);
 885   }
 886   '';
 887 }
 888
 889 =item ut_ip COLUMN
 890
 891 Check/untaint ip addresses.  IPv4 only for now.
 892
 893 =cut
 894
 895 sub ut_ip {
 896   my( $self, $field ) = @_;
 897   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
 898     or return "Illegal (IP address) $field: ". $self->getfield($field);
 899   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
 900   $self->setfield($field, "$1.$2.$3.$3");
 901   '';
 902 }
 903
 904 =item ut_ipn COLUMN
 905
 906 Check/untaint ip addresses.  IPv4 only for now.  May be null.
 907
 908 =cut
 909
 910 sub ut_ipn {
 911   my( $self, $field ) = @_;
 912   if ( $self->getfield($field) =~ /^()$/ ) {
 913     $self->setfield($field,'');
 914     '';
 915   } else {
 916     $self->ut_ip($field);
 917   }
 918 }
 919
 920 =item ut_domain COLUMN
 921
 922 Check/untaint host and domain names.
 923
 924 =cut
 925
 926 sub ut_domain {
 927   my( $self, $field ) = @_;
 928   #$self->getfield($field) =~/^(\w+\.)*\w+$/
 929   $self->getfield($field) =~/^(\w+\.)*\w+$/
 930     or return "Illegal (domain) $field: ". $self->getfield($field);
 931   $self->setfield($field,$1);
 932   '';
 933 }
 934
 935 =item ut_name COLUMN
 936
 937 Check/untaint proper names; allows alphanumerics, spaces and the following
 938 punctuation: , . - '
 939
 940 May not be null.
 941
 942 =cut
 943
 944 sub ut_name {
 945   my( $self, $field ) = @_;
 946   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
 947     or return "Illegal (name) $field: ". $self->getfield($field);
 948   $self->setfield($field,$1);
 949   '';
 950 }
 951
 952 =item ut_zip COLUMN
 953
 954 Check/untaint zip codes.
 955
 956 =cut
 957
 958 sub ut_zip {
 959   my( $self, $field, $country ) = @_;
 960   if ( $country eq 'US' ) {
 961     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
 962       or return "Illegal (zip) $field for country $country: ".
 963                 $self->getfield($field);
 964     $self->setfield($field,$1);
 965   } else {
 966     $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
 967       or return "Illegal (zip) $field: ". $self->getfield($field);
 968     $self->setfield($field,$1);
 969   }
 970   '';
 971 }
 972
 973 =item ut_country COLUMN
 974
 975 Check/untaint country codes.  Country names are changed to codes, if possible -
 976 see L<Locale::Country>.
 977
 978 =cut
 979
 980 sub ut_country {
 981   my( $self, $field ) = @_;
 982   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
 983     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
 984          && country2code($1) ) {
 985       $self->setfield($field,uc(country2code($1)));
 986     }
 987   }
 988   $self->getfield($field) =~ /^(\w\w)$/
 989     or return "Illegal (country) $field: ". $self->getfield($field);
 990   $self->setfield($field,uc($1));
 991   '';
 992 }
 993
 994 =item ut_anything COLUMN
 995
 996 Untaints arbitrary data.  Be careful.
 997
 998 =cut
 999
1000 sub ut_anything {
1001   my( $self, $field ) = @_;
1002   $self->getfield($field) =~ /^(.*)$/s
1003     or return "Illegal $field: ". $self->getfield($field);
1004   $self->setfield($field,$1);
1005   '';
1006 }
1007
1008 =item ut_enum COLUMN CHOICES_ARRAYREF
1009
1010 Check/untaint a column, supplying all possible choices, like the "enum" type.
1011
1012 =cut
1013
1014 sub ut_enum {
1015   my( $self, $field, $choices ) = @_;
1016   foreach my $choice ( @$choices ) {
1017     if ( $self->getfield($field) eq $choice ) {
1018       $self->setfield($choice);
1019       return '';
1020     }
1021   }
1022   return "Illegal (enum) field $field: ". $self->getfield($field);
1023 }
1024
1025 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1026
1027 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
1028 on the column first.
1029
1030 =cut
1031
1032 sub ut_foreign_key {
1033   my( $self, $field, $table, $foreign ) = @_;
1034   qsearchs($table, { $foreign => $self->getfield($field) })
1035     or return "Can't find $field ". $self->getfield($field).
1036               " in $table.$foreign";
1037   '';
1038 }
1039
1040 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1041
1042 Like ut_foreign_key, except the null value is also allowed.
1043
1044 =cut
1045
1046 sub ut_foreign_keyn {
1047   my( $self, $field, $table, $foreign ) = @_;
1048   $self->getfield($field)
1049     ? $self->ut_foreign_key($field, $table, $foreign)
1050     : '';
1051 }
1052
1053 =item fields [ TABLE ]
1054
1055 This can be used as both a subroutine and a method call.  It returns a list
1056 of the columns in this record's table, or an explicitly specified table.
1057 (See L<DBIx::DBSchema::Table>).
1058
1059 =cut
1060
1061 # Usage: @fields = fields($table);
1062 #        @fields = $record->fields;
1063 sub fields {
1064   my $something = shift;
1065   my $table;
1066   if ( ref($something) ) {
1067     $table = $something->table;
1068   } else {
1069     $table = $something;
1070   }
1071   #croak "Usage: \@fields = fields(\$table)\n   or: \@fields = \$record->fields" unless $table;
1072   my($table_obj) = $dbdef->table($table);
1073   confess "Unknown table $table" unless $table_obj;
1074   $table_obj->columns;
1075 }
1076
1077 =back
1078
1079 =head1 SUBROUTINES
1080
1081 =over 4
1082
1083 =item reload_dbdef([FILENAME])
1084
1085 Load a database definition (see L<DBIx::DBSchema>), optionally from a
1086 non-default filename.  This command is executed at startup unless
1087 I<$FS::Record::setup_hack> is true.  Returns a DBIx::DBSchema object.
1088
1089 =cut
1090
1091 sub reload_dbdef {
1092   my $file = shift || $dbdef_file;
1093   $dbdef = load DBIx::DBSchema $file
1094     or die "can't load database schema from $file";
1095 }
1096
1097 =item dbdef
1098
1099 Returns the current database definition.  See L<DBIx::DBSchema>.
1100
1101 =cut
1102
1103 sub dbdef { $dbdef; }
1104
1105 =item _quote VALUE, TABLE, COLUMN
1106
1107 This is an internal function used to construct SQL statements.  It returns
1108 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
1109 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
1110
1111 =cut
1112
1113 sub _quote {
1114   my($value,$table,$field)=@_;
1115   my($dbh)=dbh;
1116   if ( $value =~ /^\d+(\.\d+)?$/ &&
1117 #       ! ( datatype($table,$field) =~ /^char/ )
1118        ! ( $dbdef->table($table)->column($field)->type =~ /(char|binary)$/i )
1119   ) {
1120     $value;
1121   } else {
1122     $dbh->quote($value);
1123   }
1124 }
1125
1126 =item hfields TABLE
1127
1128 This is depriciated.  Don't use it.
1129
1130 It returns a hash-type list with the fields of this record's table set true.
1131
1132 =cut
1133
1134 sub hfields {
1135   carp "warning: hfields is depriciated";
1136   my($table)=@_;
1137   my(%hash);
1138   foreach (fields($table)) {
1139     $hash{$_}=1;
1140   }
1141   \%hash;
1142 }
1143
1144 sub _dump {
1145   my($self)=@_;
1146   join("\n", map {
1147     "$_: ". $self->getfield($_). "|"
1148   } (fields($self->table)) );
1149 }
1150
1151 sub DESTROY { return; }
1152
1153 #sub DESTROY {
1154 #  my $self = shift;
1155 #  #use Carp qw(cluck);
1156 #  #cluck "DESTROYING $self";
1157 #  warn "DESTROYING $self";
1158 #}
1159
1160 #sub is_tainted {
1161 #             return ! eval { join('',@_), kill 0; 1; };
1162 #         }
1163
1164 =back
1165
1166 =head1 BUGS
1167
1168 This module should probably be renamed, since much of the functionality is
1169 of general use.  It is not completely unlike Adapter::DBI (see below).
1170
1171 Exported qsearch and qsearchs should be depriciated in favor of method calls
1172 (against an FS::Record object like the old search and searchs that qsearch
1173 and qsearchs were on top of.)
1174
1175 The whole fields / hfields mess should be removed.
1176
1177 The various WHERE clauses should be subroutined.
1178
1179 table string should be depriciated in favor of DBIx::DBSchema::Table.
1180
1181 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1182 true maps to the database (and WHERE clauses) would also help.
1183
1184 The ut_ methods should ask the dbdef for a default length.
1185
1186 ut_sqltype (like ut_varchar) should all be defined
1187
1188 A fallback check method should be provided which uses the dbdef.
1189
1190 The ut_money method assumes money has two decimal digits.
1191
1192 The Pg money kludge in the new method only strips `$'.
1193
1194 The ut_phonen method only checks US-style phone numbers.
1195
1196 The _quote function should probably use ut_float instead of a regex.
1197
1198 All the subroutines probably should be methods, here or elsewhere.
1199
1200 Probably should borrow/use some dbdef methods where appropriate (like sub
1201 fields)
1202
1203 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1204 or allow it to be set.  Working around it is ugly any way around - DBI should
1205 be fixed.  (only affects RDBMS which return uppercase column names)
1206
1207 ut_zip should take an optional country like ut_phone.
1208
1209 =head1 SEE ALSO
1210
1211 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1212
1213 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1214
1215 =cut
1216
1217 1;
1218