FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              %virtual_fields_cache
   6              $conf $conf_encryption $money_char $lat_lower $lon_upper
   7              $me
   8              $nowarn_identical $nowarn_classload
   9              $no_update_diff $no_check_foreign
  10              @encrypt_payby
  11            );
  12 use Exporter;
  13 use Carp qw(carp cluck croak confess);
  14 use Scalar::Util qw( blessed );
  15 use File::CounterFile;
  16 use Locale::Country;
  17 use Text::CSV_XS;
  18 use File::Slurp qw( slurp );
  19 use DBI qw(:sql_types);
  20 use DBIx::DBSchema 0.38;
  21 use FS::UID qw(dbh getotaker datasrc driver_name);
  22 use FS::CurrentUser;
  23 use FS::Schema qw(dbdef);
  24 use FS::SearchCache;
  25 use FS::Msgcat qw(gettext);
  26 use NetAddr::IP; # for validation
  27 use Data::Dumper;
  28 #use FS::Conf; #dependency loop bs, in install_callback below instead
  29
  30 use FS::part_virtual_field;
  31
  32 use Tie::IxHash;
  33
  34 @ISA = qw(Exporter);
  35
  36 @encrypt_payby = qw( CARD DCRD CHEK DCHK );
  37
  38 #export dbdef for now... everything else expects to find it here
  39 @EXPORT_OK = qw(
  40   dbh fields hfields qsearch qsearchs dbdef jsearch
  41   str2time_sql str2time_sql_closing regexp_sql not_regexp_sql concat_sql
  42   midnight_sql
  43 );
  44
  45 $DEBUG = 0;
  46 $me = '[FS::Record]';
  47
  48 $nowarn_identical = 0;
  49 $nowarn_classload = 0;
  50 $no_update_diff = 0;
  51 $no_check_foreign = 0;
  52
  53 my $rsa_module;
  54 my $rsa_loaded;
  55 my $rsa_encrypt;
  56 my $rsa_decrypt;
  57
  58 $conf = '';
  59 $conf_encryption = '';
  60 FS::UID->install_callback( sub {
  61
  62   eval "use FS::Conf;";
  63   die $@ if $@;
  64   $conf = FS::Conf->new;
  65   $conf_encryption = $conf->exists('encryption');
  66   $money_char = $conf->config('money_char') || '$';
  67   my $nw_coords = $conf->exists('geocode-require_nw_coordinates');
  68   $lat_lower = $nw_coords ? 1 : -90;
  69   $lon_upper = $nw_coords ? -1 : 180;
  70
  71   $File::CounterFile::DEFAULT_DIR = $conf->base_dir . "/counters.". datasrc;
  72
  73   if ( driver_name eq 'Pg' ) {
  74     eval "use DBD::Pg ':pg_types'";
  75     die $@ if $@;
  76   } else {
  77     eval "sub PG_BYTEA { die 'guru meditation #9: calling PG_BYTEA when not running Pg?'; }";
  78   }
  79
  80 } );
  81
  82 =head1 NAME
  83
  84 FS::Record - Database record objects
  85
  86 =head1 SYNOPSIS
  87
  88     use FS::Record;
  89     use FS::Record qw(dbh fields qsearch qsearchs);
  90
  91     $record = new FS::Record 'table', \%hash;
  92     $record = new FS::Record 'table', { 'column' => 'value', ... };
  93
  94     $record  = qsearchs FS::Record 'table', \%hash;
  95     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  96     @records = qsearch  FS::Record 'table', \%hash;
  97     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  98
  99     $table = $record->table;
 100     $dbdef_table = $record->dbdef_table;
 101
 102     $value = $record->get('column');
 103     $value = $record->getfield('column');
 104     $value = $record->column;
 105
 106     $record->set( 'column' => 'value' );
 107     $record->setfield( 'column' => 'value' );
 108     $record->column('value');
 109
 110     %hash = $record->hash;
 111
 112     $hashref = $record->hashref;
 113
 114     $error = $record->insert;
 115
 116     $error = $record->delete;
 117
 118     $error = $new_record->replace($old_record);
 119
 120     # external use deprecated - handled by the database (at least for Pg, mysql)
 121     $value = $record->unique('column');
 122
 123     $error = $record->ut_float('column');
 124     $error = $record->ut_floatn('column');
 125     $error = $record->ut_number('column');
 126     $error = $record->ut_numbern('column');
 127     $error = $record->ut_snumber('column');
 128     $error = $record->ut_snumbern('column');
 129     $error = $record->ut_money('column');
 130     $error = $record->ut_text('column');
 131     $error = $record->ut_textn('column');
 132     $error = $record->ut_alpha('column');
 133     $error = $record->ut_alphan('column');
 134     $error = $record->ut_phonen('column');
 135     $error = $record->ut_anything('column');
 136     $error = $record->ut_name('column');
 137
 138     $quoted_value = _quote($value,'table','field');
 139
 140     #deprecated
 141     $fields = hfields('table');
 142     if ( $fields->{Field} ) { # etc.
 143
 144     @fields = fields 'table'; #as a subroutine
 145     @fields = $record->fields; #as a method call
 146
 147
 148 =head1 DESCRIPTION
 149
 150 (Mostly) object-oriented interface to database records.  Records are currently
 151 implemented on top of DBI.  FS::Record is intended as a base class for
 152 table-specific classes to inherit from, i.e. FS::cust_main.
 153
 154 =head1 CONSTRUCTORS
 155
 156 =over 4
 157
 158 =item new [ TABLE, ] HASHREF
 159
 160 Creates a new record.  It doesn't store it in the database, though.  See
 161 L<"insert"> for that.
 162
 163 Note that the object stores this hash reference, not a distinct copy of the
 164 hash it points to.  You can ask the object for a copy with the I<hash>
 165 method.
 166
 167 TABLE can only be omitted when a dervived class overrides the table method.
 168
 169 =cut
 170
 171 sub new {
 172   my $proto = shift;
 173   my $class = ref($proto) || $proto;
 174   my $self = {};
 175   bless ($self, $class);
 176
 177   unless ( defined ( $self->table ) ) {
 178     $self->{'Table'} = shift;
 179     carp "warning: FS::Record::new called with table name ". $self->{'Table'}
 180       unless $nowarn_classload;
 181   }
 182
 183   $self->{'Hash'} = shift;
 184
 185   foreach my $field ( grep !defined($self->{'Hash'}{$_}), $self->fields ) {
 186     $self->{'Hash'}{$field}='';
 187   }
 188
 189   $self->_rebless if $self->can('_rebless');
 190
 191   $self->{'modified'} = 0;
 192
 193   $self->_cache($self->{'Hash'}, shift) if $self->can('_cache') && @_;
 194
 195   $self;
 196 }
 197
 198 sub new_or_cached {
 199   my $proto = shift;
 200   my $class = ref($proto) || $proto;
 201   my $self = {};
 202   bless ($self, $class);
 203
 204   $self->{'Table'} = shift unless defined ( $self->table );
 205
 206   my $hashref = $self->{'Hash'} = shift;
 207   my $cache = shift;
 208   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 209     my $obj = $cache->cache->{$hashref->{$cache->key}};
 210     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 211     $obj;
 212   } else {
 213     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 214   }
 215
 216 }
 217
 218 sub create {
 219   my $proto = shift;
 220   my $class = ref($proto) || $proto;
 221   my $self = {};
 222   bless ($self, $class);
 223   if ( defined $self->table ) {
 224     cluck "create constructor is deprecated, use new!";
 225     $self->new(@_);
 226   } else {
 227     croak "FS::Record::create called (not from a subclass)!";
 228   }
 229 }
 230
 231 =item qsearch PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 232
 233 Searches the database for all records matching (at least) the key/value pairs
 234 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 235 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 236 objects.
 237
 238 The preferred usage is to pass a hash reference of named parameters:
 239
 240   @records = qsearch( {
 241                         'table'       => 'table_name',
 242                         'hashref'     => { 'field' => 'value'
 243                                            'field' => { 'op'    => '<',
 244                                                         'value' => '420',
 245                                                       },
 246                                          },
 247
 248                         #these are optional...
 249                         'select'      => '*',
 250                         'extra_sql'   => 'AND field = ? AND intfield = ?',
 251                         'extra_param' => [ 'value', [ 5, 'int' ] ],
 252                         'order_by'    => 'ORDER BY something',
 253                         #'cache_obj'   => '', #optional
 254                         'addl_from'   => 'LEFT JOIN othtable USING ( field )',
 255                         'debug'       => 1,
 256                       }
 257                     );
 258
 259 Much code still uses old-style positional parameters, this is also probably
 260 fine in the common case where there are only two parameters:
 261
 262   my @records = qsearch( 'table', { 'field' => 'value' } );
 263
 264 Also possible is an experimental LISTREF of PARAMS_HASHREFs for a UNION of
 265 the individual PARAMS_HASHREF queries
 266
 267 ###oops, argh, FS::Record::new only lets us create database fields.
 268 #Normal behaviour if SELECT is not specified is `*', as in
 269 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 270 #feature where you can specify SELECT - remember, the objects returned,
 271 #although blessed into the appropriate `FS::TABLE' package, will only have the
 272 #fields you specify.  This might have unwanted results if you then go calling
 273 #regular FS::TABLE methods
 274 #on it.
 275
 276 =cut
 277
 278 my %TYPE = (); #for debugging
 279
 280 sub _bind_type {
 281   my($type, $value) = @_;
 282
 283   my $bind_type = { TYPE => SQL_VARCHAR };
 284
 285   if ( $type =~ /(big)?(int|serial)/i && $value =~ /^-?\d+(\.\d+)?$/ ) {
 286
 287     $bind_type = { TYPE => SQL_INTEGER };
 288
 289   } elsif ( $type =~ /^bytea$/i || $type =~ /(blob|varbinary)/i ) {
 290
 291     if ( driver_name eq 'Pg' ) {
 292       no strict 'subs';
 293       $bind_type = { pg_type => PG_BYTEA };
 294     #} else {
 295     #  $bind_type = ? #SQL_VARCHAR could be fine?
 296     }
 297
 298   #DBD::Pg 1.49: Cannot bind ... unknown sql_type 6 with SQL_FLOAT
 299   #fixed by DBD::Pg 2.11.8
 300   #can change back to SQL_FLOAT in early-mid 2010, once everyone's upgraded
 301   #(make a Tron test first)
 302   } elsif ( _is_fs_float( $type, $value ) ) {
 303
 304     $bind_type = { TYPE => SQL_DECIMAL };
 305
 306   }
 307
 308   $bind_type;
 309
 310 }
 311
 312 sub _is_fs_float {
 313   my($type, $value) = @_;
 314   if ( ( $type =~ /(numeric)/i && $value =~ /^[+-]?\d+(\.\d+)?$/ ) ||
 315        ( $type =~ /(real|float4)/i && $value =~ /[-+]?\d*\.?\d+([eE][-+]?\d+)?/)
 316      ) {
 317     return 1;
 318   }
 319   '';
 320 }
 321
 322 sub qsearch {
 323   my( @stable, @record, @cache );
 324   my( @select, @extra_sql, @extra_param, @order_by, @addl_from );
 325   my @debug = ();
 326   my %union_options = ();
 327   if ( ref($_[0]) eq 'ARRAY' ) {
 328     my $optlist = shift;
 329     %union_options = @_;
 330     foreach my $href ( @$optlist ) {
 331       push @stable,      ( $href->{'table'} or die "table name is required" );
 332       push @record,      ( $href->{'hashref'}     || {} );
 333       push @select,      ( $href->{'select'}      || '*' );
 334       push @extra_sql,   ( $href->{'extra_sql'}   || '' );
 335       push @extra_param, ( $href->{'extra_param'} || [] );
 336       push @order_by,    ( $href->{'order_by'}    || '' );
 337       push @cache,       ( $href->{'cache_obj'}   || '' );
 338       push @addl_from,   ( $href->{'addl_from'}   || '' );
 339       push @debug,       ( $href->{'debug'}       || '' );
 340     }
 341     die "at least one hashref is required" unless scalar(@stable);
 342   } elsif ( ref($_[0]) eq 'HASH' ) {
 343     my $opt = shift;
 344     $stable[0]      = $opt->{'table'}       or die "table name is required";
 345     $record[0]      = $opt->{'hashref'}     || {};
 346     $select[0]      = $opt->{'select'}      || '*';
 347     $extra_sql[0]   = $opt->{'extra_sql'}   || '';
 348     $extra_param[0] = $opt->{'extra_param'} || [];
 349     $order_by[0]    = $opt->{'order_by'}    || '';
 350     $cache[0]       = $opt->{'cache_obj'}   || '';
 351     $addl_from[0]   = $opt->{'addl_from'}   || '';
 352     $debug[0]       = $opt->{'debug'}       || '';
 353   } else {
 354     ( $stable[0],
 355       $record[0],
 356       $select[0],
 357       $extra_sql[0],
 358       $cache[0],
 359       $addl_from[0]
 360     ) = @_;
 361     $select[0] ||= '*';
 362   }
 363   my $cache = $cache[0];
 364
 365   my @statement = ();
 366   my @value = ();
 367   my @bind_type = ();
 368   my $dbh = dbh;
 369   foreach my $stable ( @stable ) {
 370     #stop altering the caller's hashref
 371     my $record      = { %{ shift(@record) || {} } };#and be liberal in receipt
 372     my $select      = shift @select;
 373     my $extra_sql   = shift @extra_sql;
 374     my $extra_param = shift @extra_param;
 375     my $order_by    = shift @order_by;
 376     my $cache       = shift @cache;
 377     my $addl_from   = shift @addl_from;
 378     my $debug       = shift @debug;
 379
 380     #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 381     #for jsearch
 382     $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 383     $stable = $1;
 384
 385     my $table = $cache ? $cache->table : $stable;
 386     my $dbdef_table = dbdef->table($table)
 387       or die "No schema for table $table found - ".
 388              "do you need to run freeside-upgrade?";
 389     my $pkey = $dbdef_table->primary_key;
 390
 391     my @real_fields = grep exists($record->{$_}), real_fields($table);
 392
 393     my $statement .= "SELECT $select FROM $stable";
 394     $statement .= " $addl_from" if $addl_from;
 395     if ( @real_fields ) {
 396       $statement .= ' WHERE '. join(' AND ',
 397         get_real_fields($table, $record, \@real_fields));
 398     }
 399
 400     $statement .= " $extra_sql" if defined($extra_sql);
 401     $statement .= " $order_by"  if defined($order_by);
 402
 403     push @statement, $statement;
 404
 405     warn "[debug]$me $statement\n" if $DEBUG > 1 || $debug;
 406
 407
 408     foreach my $field (
 409       grep defined( $record->{$_} ) && $record->{$_} ne '', @real_fields
 410     ) {
 411
 412       my $value = $record->{$field};
 413       my $op = (ref($value) && $value->{op}) ? $value->{op} : '=';
 414       $value = $value->{'value'} if ref($value);
 415       my $type = dbdef->table($table)->column($field)->type;
 416
 417       my $bind_type = _bind_type($type, $value);
 418
 419       #if ( $DEBUG > 2 ) {
 420       #  no strict 'refs';
 421       #  %TYPE = map { &{"DBI::$_"}() => $_ } @{ $DBI::EXPORT_TAGS{sql_types} }
 422       #    unless keys %TYPE;
 423       #  warn "  bind_param $bind (for field $field), $value, TYPE $TYPE{$TYPE}\n";
 424       #}
 425
 426       push @value, $value;
 427       push @bind_type, $bind_type;
 428
 429     }
 430
 431     foreach my $param ( @$extra_param ) {
 432       my $bind_type = { TYPE => SQL_VARCHAR };
 433       my $value = $param;
 434       if ( ref($param) ) {
 435         $value = $param->[0];
 436         my $type = $param->[1];
 437         $bind_type = _bind_type($type, $value);
 438       }
 439       push @value, $value;
 440       push @bind_type, $bind_type;
 441     }
 442   }
 443
 444   my $statement = join( ' ) UNION ( ', @statement );
 445   $statement = "( $statement )" if scalar(@statement) > 1;
 446   $statement .= " $union_options{order_by}" if $union_options{order_by};
 447
 448   my $sth = $dbh->prepare($statement)
 449     or croak "$dbh->errstr doing $statement";
 450
 451   my $bind = 1;
 452   foreach my $value ( @value ) {
 453     my $bind_type = shift @bind_type;
 454     $sth->bind_param($bind++, $value, $bind_type );
 455   }
 456
 457 #  $sth->execute( map $record->{$_},
 458 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 459 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 460
 461   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 462
 463   my $table = $stable[0];
 464   my $pkey = '';
 465   $table = '' if grep { $_ ne $table } @stable;
 466   $pkey = dbdef->table($table)->primary_key if $table;
 467
 468   my %result;
 469   tie %result, "Tie::IxHash";
 470   my @stuff = @{ $sth->fetchall_arrayref( {} ) };
 471   if ( $pkey && scalar(@stuff) && $stuff[0]->{$pkey} ) {
 472     %result = map { $_->{$pkey}, $_ } @stuff;
 473   } else {
 474     @result{@stuff} = @stuff;
 475   }
 476
 477   $sth->finish;
 478
 479   my @return;
 480   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 481     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 482       #derivied class didn't override new method, so this optimization is safe
 483       if ( $cache ) {
 484         @return = map {
 485           new_or_cached( "FS::$table", { %{$_} }, $cache )
 486         } values(%result);
 487       } else {
 488         @return = map {
 489           new( "FS::$table", { %{$_} } )
 490         } values(%result);
 491       }
 492     } else {
 493       #okay, its been tested
 494       # warn "untested code (class FS::$table uses custom new method)";
 495       @return = map {
 496         eval 'FS::'. $table. '->new( { %{$_} } )';
 497       } values(%result);
 498     }
 499
 500     # Check for encrypted fields and decrypt them.
 501    ## only in the local copy, not the cached object
 502     if ( $conf_encryption
 503          && eval 'defined(@FS::'. $table . '::encrypted_fields)' ) {
 504       foreach my $record (@return) {
 505         foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 506           next if $field eq 'payinfo'
 507                     && ($record->isa('FS::payinfo_transaction_Mixin')
 508                         || $record->isa('FS::payinfo_Mixin') )
 509                     && $record->payby
 510                     && !grep { $record->payby eq $_ } @encrypt_payby;
 511           # Set it directly... This may cause a problem in the future...
 512           $record->setfield($field, $record->decrypt($record->getfield($field)));
 513         }
 514       }
 515     }
 516   } else {
 517     cluck "warning: FS::$table not loaded; returning FS::Record objects"
 518       unless $nowarn_classload;
 519     @return = map {
 520       FS::Record->new( $table, { %{$_} } );
 521     } values(%result);
 522   }
 523   return @return;
 524 }
 525
 526 ## makes this easier to read
 527
 528 sub get_real_fields {
 529   my $table = shift;
 530   my $record = shift;
 531   my $real_fields = shift;
 532
 533    ## this huge map was previously inline, just broke it out to help read the qsearch method, should be optimized for readability
 534       return (
 535       map {
 536
 537       my $op = '=';
 538       my $column = $_;
 539       my $type = dbdef->table($table)->column($column)->type;
 540       my $value = $record->{$column};
 541       $value = $value->{'value'} if ref($value);
 542       if ( ref($record->{$_}) ) {
 543         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 544         #$op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name ne 'Pg';
 545         if ( uc($op) eq 'ILIKE' ) {
 546           $op = 'LIKE';
 547           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 548           $column = "LOWER($_)";
 549         }
 550         $record->{$_} = $record->{$_}{'value'}
 551       }
 552
 553       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 554         if ( $op eq '=' ) {
 555           if ( driver_name eq 'Pg' ) {
 556             if ( $type =~ /(int|numeric|real|float4|(big)?serial)/i ) {
 557               qq-( $column IS NULL )-;
 558             } else {
 559               qq-( $column IS NULL OR $column = '' )-;
 560             }
 561           } else {
 562             qq-( $column IS NULL OR $column = "" )-;
 563           }
 564         } elsif ( $op eq '!=' ) {
 565           if ( driver_name eq 'Pg' ) {
 566             if ( $type =~ /(int|numeric|real|float4|(big)?serial)/i ) {
 567               qq-( $column IS NOT NULL )-;
 568             } else {
 569               qq-( $column IS NOT NULL AND $column != '' )-;
 570             }
 571           } else {
 572             qq-( $column IS NOT NULL AND $column != "" )-;
 573           }
 574         } else {
 575           if ( driver_name eq 'Pg' ) {
 576             qq-( $column $op '' )-;
 577           } else {
 578             qq-( $column $op "" )-;
 579           }
 580         }
 581       } elsif ( $op eq '!=' ) {
 582         qq-( $column IS NULL OR $column != ? )-;
 583       #if this needs to be re-enabled, it needs to use a custom op like
 584       #"APPROX=" or something (better name?, not '=', to avoid affecting other
 585       # searches
 586       #} elsif ( $op eq 'APPROX=' && _is_fs_float( $type, $value ) ) {
 587       #  ( "$column <= ?", "$column >= ?" );
 588       } else {
 589         "$column $op ?";
 590       }
 591     } @{ $real_fields } );
 592 }
 593
 594 =item by_key PRIMARY_KEY_VALUE
 595
 596 This is a class method that returns the record with the given primary key
 597 value.  This method is only useful in FS::Record subclasses.  For example:
 598
 599   my $cust_main = FS::cust_main->by_key(1); # retrieve customer with custnum 1
 600
 601 is equivalent to:
 602
 603   my $cust_main = qsearchs('cust_main', { 'custnum' => 1 } );
 604
 605 =cut
 606
 607 sub by_key {
 608   my ($class, $pkey_value) = @_;
 609
 610   my $table = $class->table
 611     or croak "No table for $class found";
 612
 613   my $dbdef_table = dbdef->table($table)
 614     or die "No schema for table $table found - ".
 615            "do you need to create it or run dbdef-create?";
 616   my $pkey = $dbdef_table->primary_key
 617     or die "No primary key for table $table";
 618
 619   return qsearchs($table, { $pkey => $pkey_value });
 620 }
 621
 622 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 623
 624 Experimental JOINed search method.  Using this method, you can execute a
 625 single SELECT spanning multiple tables, and cache the results for subsequent
 626 method calls.  Interface will almost definately change in an incompatible
 627 fashion.
 628
 629 Arguments:
 630
 631 =cut
 632
 633 sub jsearch {
 634   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 635   my $cache = FS::SearchCache->new( $ptable, $pkey );
 636   my %saw;
 637   ( $cache,
 638     grep { !$saw{$_->getfield($pkey)}++ }
 639       qsearch($table, $record, $select, $extra_sql, $cache )
 640   );
 641 }
 642
 643 =item qsearchs PARAMS_HASHREF | TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ, ADDL_FROM
 644
 645 Same as qsearch, except that if more than one record matches, it B<carp>s but
 646 returns the first.  If this happens, you either made a logic error in asking
 647 for a single item, or your data is corrupted.
 648
 649 =cut
 650
 651 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 652   my $table = $_[0];
 653   my(@result) = qsearch(@_);
 654   cluck "warning: Multiple records in scalar search ($table)"
 655     if scalar(@result) > 1;
 656   #should warn more vehemently if the search was on a primary key?
 657   scalar(@result) ? ($result[0]) : ();
 658 }
 659
 660 =back
 661
 662 =head1 METHODS
 663
 664 =over 4
 665
 666 =item table
 667
 668 Returns the table name.
 669
 670 =cut
 671
 672 sub table {
 673 #  cluck "warning: FS::Record::table deprecated; supply one in subclass!";
 674   my $self = shift;
 675   $self -> {'Table'};
 676 }
 677
 678 =item dbdef_table
 679
 680 Returns the DBIx::DBSchema::Table object for the table.
 681
 682 =cut
 683
 684 sub dbdef_table {
 685   my($self)=@_;
 686   my($table)=$self->table;
 687   dbdef->table($table);
 688 }
 689
 690 =item primary_key
 691
 692 Returns the primary key for the table.
 693
 694 =cut
 695
 696 sub primary_key {
 697   my $self = shift;
 698   my $pkey = $self->dbdef_table->primary_key;
 699 }
 700
 701 =item get, getfield COLUMN
 702
 703 Returns the value of the column/field/key COLUMN.
 704
 705 =cut
 706
 707 sub get {
 708   my($self,$field) = @_;
 709   # to avoid "Use of unitialized value" errors
 710   if ( defined ( $self->{Hash}->{$field} ) ) {
 711     $self->{Hash}->{$field};
 712   } else {
 713     '';
 714   }
 715 }
 716 sub getfield {
 717   my $self = shift;
 718   $self->get(@_);
 719 }
 720
 721 =item set, setfield COLUMN, VALUE
 722
 723 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 724
 725 =cut
 726
 727 sub set {
 728   my($self,$field,$value) = @_;
 729   $self->{'modified'} = 1;
 730   $self->{'Hash'}->{$field} = $value;
 731 }
 732 sub setfield {
 733   my $self = shift;
 734   $self->set(@_);
 735 }
 736
 737 =item exists COLUMN
 738
 739 Returns true if the column/field/key COLUMN exists.
 740
 741 =cut
 742
 743 sub exists {
 744   my($self,$field) = @_;
 745   exists($self->{Hash}->{$field});
 746 }
 747
 748 =item AUTLOADED METHODS
 749
 750 $record->column is a synonym for $record->get('column');
 751
 752 $record->column('value') is a synonym for $record->set('column','value');
 753
 754 =cut
 755
 756 # readable/safe
 757 sub AUTOLOAD {
 758   my($self,$value)=@_;
 759   my($field)=$AUTOLOAD;
 760   $field =~ s/.*://;
 761   if ( defined($value) ) {
 762     confess "errant AUTOLOAD $field for $self (arg $value)"
 763       unless blessed($self) && $self->can('setfield');
 764     $self->setfield($field,$value);
 765   } else {
 766     confess "errant AUTOLOAD $field for $self (no args)"
 767       unless blessed($self) && $self->can('getfield');
 768     $self->getfield($field);
 769   }
 770 }
 771
 772 # efficient
 773 #sub AUTOLOAD {
 774 #  my $field = $AUTOLOAD;
 775 #  $field =~ s/.*://;
 776 #  if ( defined($_[1]) ) {
 777 #    $_[0]->setfield($field, $_[1]);
 778 #  } else {
 779 #    $_[0]->getfield($field);
 780 #  }
 781 #}
 782
 783 =item hash
 784
 785 Returns a list of the column/value pairs, usually for assigning to a new hash.
 786
 787 To make a distinct duplicate of an FS::Record object, you can do:
 788
 789     $new = new FS::Record ( $old->table, { $old->hash } );
 790
 791 =cut
 792
 793 sub hash {
 794   my($self) = @_;
 795   confess $self. ' -> hash: Hash attribute is undefined'
 796     unless defined($self->{'Hash'});
 797   %{ $self->{'Hash'} };
 798 }
 799
 800 =item hashref
 801
 802 Returns a reference to the column/value hash.  This may be deprecated in the
 803 future; if there's a reason you can't just use the autoloaded or get/set
 804 methods, speak up.
 805
 806 =cut
 807
 808 sub hashref {
 809   my($self) = @_;
 810   $self->{'Hash'};
 811 }
 812
 813 =item modified
 814
 815 Returns true if any of this object's values have been modified with set (or via
 816 an autoloaded method).  Doesn't yet recognize when you retreive a hashref and
 817 modify that.
 818
 819 =cut
 820
 821 sub modified {
 822   my $self = shift;
 823   $self->{'modified'};
 824 }
 825
 826 =item select_for_update
 827
 828 Selects this record with the SQL "FOR UPDATE" command.  This can be useful as
 829 a mutex.
 830
 831 =cut
 832
 833 sub select_for_update {
 834   my $self = shift;
 835   my $primary_key = $self->primary_key;
 836   qsearchs( {
 837     'select'    => '*',
 838     'table'     => $self->table,
 839     'hashref'   => { $primary_key => $self->$primary_key() },
 840     'extra_sql' => 'FOR UPDATE',
 841   } );
 842 }
 843
 844 =item lock_table
 845
 846 Locks this table with a database-driver specific lock method.  This is used
 847 as a mutex in order to do a duplicate search.
 848
 849 For PostgreSQL, does "LOCK TABLE tablename IN SHARE ROW EXCLUSIVE MODE".
 850
 851 For MySQL, does a SELECT FOR UPDATE on the duplicate_lock table.
 852
 853 Errors are fatal; no useful return value.
 854
 855 Note: To use this method for new tables other than svc_acct and svc_phone,
 856 edit freeside-upgrade and add those tables to the duplicate_lock list.
 857
 858 =cut
 859
 860 sub lock_table {
 861   my $self = shift;
 862   my $table = $self->table;
 863
 864   warn "$me locking $table table\n" if $DEBUG;
 865
 866   if ( driver_name =~ /^Pg/i ) {
 867
 868     dbh->do("LOCK TABLE $table IN SHARE ROW EXCLUSIVE MODE")
 869       or die dbh->errstr;
 870
 871   } elsif ( driver_name =~ /^mysql/i ) {
 872
 873     dbh->do("SELECT * FROM duplicate_lock
 874                WHERE lockname = '$table'
 875                FOR UPDATE"
 876            ) or die dbh->errstr;
 877
 878   } else {
 879
 880     die "unknown database ". driver_name. "; don't know how to lock table";
 881
 882   }
 883
 884   warn "$me acquired $table table lock\n" if $DEBUG;
 885
 886 }
 887
 888 =item insert
 889
 890 Inserts this record to the database.  If there is an error, returns the error,
 891 otherwise returns false.
 892
 893 =cut
 894
 895 sub insert {
 896   my $self = shift;
 897   my $saved = {};
 898
 899   warn "$self -> insert" if $DEBUG;
 900
 901   my $error = $self->check;
 902   return $error if $error;
 903
 904   #single-field non-null unique keys are given a value if empty
 905   #(like MySQL's AUTO_INCREMENT or Pg SERIAL)
 906   foreach ( $self->dbdef_table->unique_singles) {
 907     next if $self->getfield($_);
 908     next if $self->dbdef_table->column($_)->null eq 'NULL';
 909     $self->unique($_);
 910   }
 911
 912   #and also the primary key, if the database isn't going to
 913   my $primary_key = $self->dbdef_table->primary_key;
 914   my $db_seq = 0;
 915   if ( $primary_key ) {
 916     my $col = $self->dbdef_table->column($primary_key);
 917
 918     $db_seq =
 919       uc($col->type) =~ /^(BIG)?SERIAL\d?/
 920       || ( driver_name eq 'Pg'
 921              && defined($col->default)
 922              && $col->quoted_default =~ /^nextval\(/i
 923          )
 924       || ( driver_name eq 'mysql'
 925              && defined($col->local)
 926              && $col->local =~ /AUTO_INCREMENT/i
 927          );
 928     $self->unique($primary_key) unless $self->getfield($primary_key) || $db_seq;
 929   }
 930
 931   my $table = $self->table;
 932
 933   # Encrypt before the database
 934   if (    defined(eval '@FS::'. $table . '::encrypted_fields')
 935        && scalar( eval '@FS::'. $table . '::encrypted_fields')
 936        && $conf->exists('encryption')
 937   ) {
 938     foreach my $field (eval '@FS::'. $table . '::encrypted_fields') {
 939       next if $field eq 'payinfo'
 940                 && ($self->isa('FS::payinfo_transaction_Mixin')
 941                     || $self->isa('FS::payinfo_Mixin') )
 942                 && $self->payby
 943                 && !grep { $self->payby eq $_ } @encrypt_payby;
 944       $saved->{$field} = $self->getfield($field);
 945       $self->setfield($field, $self->encrypt($self->getfield($field)));
 946     }
 947   }
 948
 949   #false laziness w/delete
 950   my @real_fields =
 951     grep { defined($self->getfield($_)) && $self->getfield($_) ne "" }
 952     real_fields($table)
 953   ;
 954   my @values = map { _quote( $self->getfield($_), $table, $_) } @real_fields;
 955   #eslaf
 956
 957   my $statement = "INSERT INTO $table ";
 958   if ( @real_fields ) {
 959     $statement .=
 960       "( ".
 961         join( ', ', @real_fields ).
 962       ") VALUES (".
 963         join( ', ', @values ).
 964        ")"
 965     ;
 966   } else {
 967     $statement .= 'DEFAULT VALUES';
 968   }
 969   warn "[debug]$me $statement\n" if $DEBUG > 1;
 970   my $sth = dbh->prepare($statement) or return dbh->errstr;
 971
 972   local $SIG{HUP} = 'IGNORE';
 973   local $SIG{INT} = 'IGNORE';
 974   local $SIG{QUIT} = 'IGNORE';
 975   local $SIG{TERM} = 'IGNORE';
 976   local $SIG{TSTP} = 'IGNORE';
 977   local $SIG{PIPE} = 'IGNORE';
 978
 979   $sth->execute or return $sth->errstr;
 980
 981   # get inserted id from the database, if applicable & needed
 982   if ( $db_seq && ! $self->getfield($primary_key) ) {
 983     warn "[debug]$me retreiving sequence from database\n" if $DEBUG;
 984
 985     my $insertid = '';
 986
 987     if ( driver_name eq 'Pg' ) {
 988
 989       #my $oid = $sth->{'pg_oid_status'};
 990       #my $i_sql = "SELECT $primary_key FROM $table WHERE oid = ?";
 991
 992       my $default = $self->dbdef_table->column($primary_key)->quoted_default;
 993       unless ( $default =~ /^nextval\(\(?'"?([\w\.]+)"?'/i ) {
 994         dbh->rollback if $FS::UID::AutoCommit;
 995         return "can't parse $table.$primary_key default value".
 996                " for sequence name: $default";
 997       }
 998       my $sequence = $1;
 999
1000       my $i_sql = "SELECT currval('$sequence')";
1001       my $i_sth = dbh->prepare($i_sql) or do {
1002         dbh->rollback if $FS::UID::AutoCommit;
1003         return dbh->errstr;
1004       };
1005       $i_sth->execute() or do { #$i_sth->execute($oid)
1006         dbh->rollback if $FS::UID::AutoCommit;
1007         return $i_sth->errstr;
1008       };
1009       $insertid = $i_sth->fetchrow_arrayref->[0];
1010
1011     } elsif ( driver_name eq 'mysql' ) {
1012
1013       $insertid = dbh->{'mysql_insertid'};
1014       # work around mysql_insertid being null some of the time, ala RT :/
1015       unless ( $insertid ) {
1016         warn "WARNING: DBD::mysql didn't return mysql_insertid; ".
1017              "using SELECT LAST_INSERT_ID();";
1018         my $i_sql = "SELECT LAST_INSERT_ID()";
1019         my $i_sth = dbh->prepare($i_sql) or do {
1020           dbh->rollback if $FS::UID::AutoCommit;
1021           return dbh->errstr;
1022         };
1023         $i_sth->execute or do {
1024           dbh->rollback if $FS::UID::AutoCommit;
1025           return $i_sth->errstr;
1026         };
1027         $insertid = $i_sth->fetchrow_arrayref->[0];
1028       }
1029
1030     } else {
1031
1032       dbh->rollback if $FS::UID::AutoCommit;
1033       return "don't know how to retreive inserted ids from ". driver_name.
1034              ", try using counterfiles (maybe run dbdef-create?)";
1035
1036     }
1037
1038     $self->setfield($primary_key, $insertid);
1039
1040   }
1041
1042   my $h_sth;
1043   if ( defined dbdef->table('h_'. $table) ) {
1044     my $h_statement = $self->_h_statement('insert');
1045     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
1046     $h_sth = dbh->prepare($h_statement) or do {
1047       dbh->rollback if $FS::UID::AutoCommit;
1048       return dbh->errstr;
1049     };
1050   } else {
1051     $h_sth = '';
1052   }
1053   $h_sth->execute or return $h_sth->errstr if $h_sth;
1054
1055   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1056
1057   # Now that it has been saved, reset the encrypted fields so that $new
1058   # can still be used.
1059   foreach my $field (keys %{$saved}) {
1060     $self->setfield($field, $saved->{$field});
1061   }
1062
1063   '';
1064 }
1065
1066 =item add
1067
1068 Depriciated (use insert instead).
1069
1070 =cut
1071
1072 sub add {
1073   cluck "warning: FS::Record::add deprecated!";
1074   insert @_; #call method in this scope
1075 }
1076
1077 =item delete
1078
1079 Delete this record from the database.  If there is an error, returns the error,
1080 otherwise returns false.
1081
1082 =cut
1083
1084 sub delete {
1085   my $self = shift;
1086
1087   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
1088     map {
1089       $self->getfield($_) eq ''
1090         #? "( $_ IS NULL OR $_ = \"\" )"
1091         ? ( driver_name eq 'Pg'
1092               ? "$_ IS NULL"
1093               : "( $_ IS NULL OR $_ = \"\" )"
1094           )
1095         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
1096     } ( $self->dbdef_table->primary_key )
1097           ? ( $self->dbdef_table->primary_key)
1098           : real_fields($self->table)
1099   );
1100   warn "[debug]$me $statement\n" if $DEBUG > 1;
1101   my $sth = dbh->prepare($statement) or return dbh->errstr;
1102
1103   my $h_sth;
1104   if ( defined dbdef->table('h_'. $self->table) ) {
1105     my $h_statement = $self->_h_statement('delete');
1106     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
1107     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
1108   } else {
1109     $h_sth = '';
1110   }
1111
1112   my $primary_key = $self->dbdef_table->primary_key;
1113
1114   local $SIG{HUP} = 'IGNORE';
1115   local $SIG{INT} = 'IGNORE';
1116   local $SIG{QUIT} = 'IGNORE';
1117   local $SIG{TERM} = 'IGNORE';
1118   local $SIG{TSTP} = 'IGNORE';
1119   local $SIG{PIPE} = 'IGNORE';
1120
1121   my $rc = $sth->execute or return $sth->errstr;
1122   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
1123   $h_sth->execute or return $h_sth->errstr if $h_sth;
1124
1125   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1126
1127   #no need to needlessly destoy the data either (causes problems actually)
1128   #undef $self; #no need to keep object!
1129
1130   '';
1131 }
1132
1133 =item del
1134
1135 Depriciated (use delete instead).
1136
1137 =cut
1138
1139 sub del {
1140   cluck "warning: FS::Record::del deprecated!";
1141   &delete(@_); #call method in this scope
1142 }
1143
1144 =item replace OLD_RECORD
1145
1146 Replace the OLD_RECORD with this one in the database.  If there is an error,
1147 returns the error, otherwise returns false.
1148
1149 =cut
1150
1151 sub replace {
1152   my ($new, $old) = (shift, shift);
1153
1154   $old = $new->replace_old unless defined($old);
1155
1156   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
1157
1158   if ( $new->can('replace_check') ) {
1159     my $error = $new->replace_check($old);
1160     return $error if $error;
1161   }
1162
1163   return "Records not in same table!" unless $new->table eq $old->table;
1164
1165   my $primary_key = $old->dbdef_table->primary_key;
1166   return "Can't change primary key $primary_key ".
1167          'from '. $old->getfield($primary_key).
1168          ' to ' . $new->getfield($primary_key)
1169     if $primary_key
1170        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
1171
1172   my $error = $new->check;
1173   return $error if $error;
1174
1175   # Encrypt for replace
1176   my $saved = {};
1177   if (    $conf->exists('encryption')
1178        && defined(eval '@FS::'. $new->table . '::encrypted_fields')
1179        && scalar( eval '@FS::'. $new->table . '::encrypted_fields')
1180   ) {
1181     foreach my $field (eval '@FS::'. $new->table . '::encrypted_fields') {
1182       next if $field eq 'payinfo'
1183                 && ($new->isa('FS::payinfo_transaction_Mixin')
1184                     || $new->isa('FS::payinfo_Mixin') )
1185                 && $new->payby
1186                 && !grep { $new->payby eq $_ } @encrypt_payby;
1187       $saved->{$field} = $new->getfield($field);
1188       $new->setfield($field, $new->encrypt($new->getfield($field)));
1189     }
1190   }
1191
1192   #my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
1193   my %diff = map { ($new->getfield($_) ne $old->getfield($_))
1194                    ? ($_, $new->getfield($_)) : () } $old->fields;
1195
1196   unless (keys(%diff) || $no_update_diff ) {
1197     carp "[warning]$me ". ref($new)."->replace ".
1198            ( $primary_key ? "$primary_key ".$new->get($primary_key) : '' ).
1199          ": records identical"
1200       unless $nowarn_identical;
1201     return '';
1202   }
1203
1204   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
1205     map {
1206       "$_ = ". _quote($new->getfield($_),$old->table,$_)
1207     } real_fields($old->table)
1208   ). ' WHERE '.
1209     join(' AND ',
1210       map {
1211
1212         if ( $old->getfield($_) eq '' ) {
1213
1214          #false laziness w/qsearch
1215          if ( driver_name eq 'Pg' ) {
1216             my $type = $old->dbdef_table->column($_)->type;
1217             if ( $type =~ /(int|(big)?serial)/i ) {
1218               qq-( $_ IS NULL )-;
1219             } else {
1220               qq-( $_ IS NULL OR $_ = '' )-;
1221             }
1222           } else {
1223             qq-( $_ IS NULL OR $_ = "" )-;
1224           }
1225
1226         } else {
1227           "$_ = ". _quote($old->getfield($_),$old->table,$_);
1228         }
1229
1230       } ( $primary_key ? ( $primary_key ) : real_fields($old->table) )
1231     )
1232   ;
1233   warn "[debug]$me $statement\n" if $DEBUG > 1;
1234   my $sth = dbh->prepare($statement) or return dbh->errstr;
1235
1236   my $h_old_sth;
1237   if ( defined dbdef->table('h_'. $old->table) ) {
1238     my $h_old_statement = $old->_h_statement('replace_old');
1239     warn "[debug]$me $h_old_statement\n" if $DEBUG > 2;
1240     $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
1241   } else {
1242     $h_old_sth = '';
1243   }
1244
1245   my $h_new_sth;
1246   if ( defined dbdef->table('h_'. $new->table) ) {
1247     my $h_new_statement = $new->_h_statement('replace_new');
1248     warn "[debug]$me $h_new_statement\n" if $DEBUG > 2;
1249     $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
1250   } else {
1251     $h_new_sth = '';
1252   }
1253
1254   local $SIG{HUP} = 'IGNORE';
1255   local $SIG{INT} = 'IGNORE';
1256   local $SIG{QUIT} = 'IGNORE';
1257   local $SIG{TERM} = 'IGNORE';
1258   local $SIG{TSTP} = 'IGNORE';
1259   local $SIG{PIPE} = 'IGNORE';
1260
1261   my $rc = $sth->execute or return $sth->errstr;
1262   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
1263   $h_old_sth->execute or return $h_old_sth->errstr if $h_old_sth;
1264   $h_new_sth->execute or return $h_new_sth->errstr if $h_new_sth;
1265
1266   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
1267
1268   # Now that it has been saved, reset the encrypted fields so that $new
1269   # can still be used.
1270   foreach my $field (keys %{$saved}) {
1271     $new->setfield($field, $saved->{$field});
1272   }
1273
1274   '';
1275
1276 }
1277
1278 sub replace_old {
1279   my( $self ) = shift;
1280   warn "[$me] replace called with no arguments; autoloading old record\n"
1281     if $DEBUG;
1282
1283   my $primary_key = $self->dbdef_table->primary_key;
1284   if ( $primary_key ) {
1285     $self->by_key( $self->$primary_key() ) #this is what's returned
1286       or croak "can't find ". $self->table. ".$primary_key ".
1287         $self->$primary_key();
1288   } else {
1289     croak $self->table. " has no primary key; pass old record as argument";
1290   }
1291
1292 }
1293
1294 =item rep
1295
1296 Depriciated (use replace instead).
1297
1298 =cut
1299
1300 sub rep {
1301   cluck "warning: FS::Record::rep deprecated!";
1302   replace @_; #call method in this scope
1303 }
1304
1305 =item check
1306
1307 Checks custom fields. Subclasses should still provide a check method to validate
1308 non-custom fields, foreign keys, etc., and call this method via $self->SUPER::check.
1309
1310 =cut
1311
1312 sub check {
1313     my $self = shift;
1314     foreach my $field ($self->virtual_fields) {
1315         my $error = $self->ut_textn($field);
1316         return $error if $error;
1317     }
1318     '';
1319 }
1320
1321 =item virtual_fields [ TABLE ]
1322
1323 Returns a list of virtual fields defined for the table.  This should not
1324 be exported, and should only be called as an instance or class method.
1325
1326 =cut
1327
1328 sub virtual_fields {
1329   my $self = shift;
1330   my $table;
1331   $table = $self->table or confess "virtual_fields called on non-table";
1332
1333   confess "Unknown table $table" unless dbdef->table($table);
1334
1335   return () unless dbdef->table('part_virtual_field');
1336
1337   unless ( $virtual_fields_cache{$table} ) {
1338     my $concat = [ "'cf_'", "name" ];
1339     my $query = "SELECT ".concat_sql($concat).' from part_virtual_field ' .
1340                 "WHERE dbtable = '$table'";
1341     my $dbh = dbh;
1342     my $result = $dbh->selectcol_arrayref($query);
1343     confess "Error executing virtual fields query: $query: ". $dbh->errstr
1344       if $dbh->err;
1345     $virtual_fields_cache{$table} = $result;
1346   }
1347
1348   @{$virtual_fields_cache{$table}};
1349
1350 }
1351
1352 =item process_batch_import JOB OPTIONS_HASHREF PARAMS
1353
1354 Processes a batch import as a queued JSRPC job
1355
1356 JOB is an FS::queue entry.
1357
1358 OPTIONS_HASHREF can have the following keys:
1359
1360 =over 4
1361
1362 =item table
1363
1364 Table name (required).
1365
1366 =item params
1367
1368 Listref of field names for static fields.  They will be given values from the
1369 PARAMS hashref and passed as a "params" hashref to batch_import.
1370
1371 =item formats
1372
1373 Formats hashref.  Keys are field names, values are listrefs that define the
1374 format.
1375
1376 Each listref value can be a column name or a code reference.  Coderefs are run
1377 with the row object, data and a FS::Conf object as the three parameters.
1378 For example, this coderef does the same thing as using the "columnname" string:
1379
1380   sub {
1381     my( $record, $data, $conf ) = @_;
1382     $record->columnname( $data );
1383   },
1384
1385 Coderefs are run after all "column name" fields are assigned.
1386
1387 =item format_types
1388
1389 Optional format hashref of types.  Keys are field names, values are "csv",
1390 "xls" or "fixedlength".  Overrides automatic determination of file type
1391 from extension.
1392
1393 =item format_headers
1394
1395 Optional format hashref of header lines.  Keys are field names, values are 0
1396 for no header, 1 to ignore the first line, or to higher numbers to ignore that
1397 number of lines.
1398
1399 =item format_sep_chars
1400
1401 Optional format hashref of CSV sep_chars.  Keys are field names, values are the
1402 CSV separation character.
1403
1404 =item format_fixedlenth_formats
1405
1406 Optional format hashref of fixed length format defintiions.  Keys are field
1407 names, values Parse::FixedLength listrefs of field definitions.
1408
1409 =item default_csv
1410
1411 Set true to default to CSV file type if the filename does not contain a
1412 recognizable ".csv" or ".xls" extension (and type is not pre-specified by
1413 format_types).
1414
1415 =back
1416
1417 PARAMS is a base64-encoded Storable string containing the POSTed data as
1418 a hash ref.  It normally contains at least one field, "uploaded files",
1419 generated by /elements/file-upload.html and containing the list of uploaded
1420 files.  Currently only supports a single file named "file".
1421
1422 =cut
1423
1424 use Storable qw(thaw);
1425 use Data::Dumper;
1426 use MIME::Base64;
1427 sub process_batch_import {
1428   my($job, $opt) = ( shift, shift );
1429
1430   my $table = $opt->{table};
1431   my @pass_params = $opt->{params} ? @{ $opt->{params} } : ();
1432   my %formats = %{ $opt->{formats} };
1433
1434   my $param = thaw(decode_base64(shift));
1435   warn Dumper($param) if $DEBUG;
1436
1437   my $files = $param->{'uploaded_files'}
1438     or die "No files provided.\n";
1439
1440   my (%files) = map { /^(\w+):([\.\w]+)$/ ? ($1,$2):() } split /,/, $files;
1441
1442   my $dir = '%%%FREESIDE_CACHE%%%/cache.'. $FS::UID::datasrc. '/';
1443   my $file = $dir. $files{'file'};
1444
1445   my %iopt = (
1446     #class-static
1447     table                      => $table,
1448     formats                    => \%formats,
1449     format_types               => $opt->{format_types},
1450     format_headers             => $opt->{format_headers},
1451     format_sep_chars           => $opt->{format_sep_chars},
1452     format_fixedlength_formats => $opt->{format_fixedlength_formats},
1453     format_xml_formats         => $opt->{format_xml_formats},
1454     format_row_callbacks       => $opt->{format_row_callbacks},
1455     #per-import
1456     job                        => $job,
1457     file                       => $file,
1458     #type                       => $type,
1459     format                     => $param->{format},
1460     params                     => { map { $_ => $param->{$_} } @pass_params },
1461     #?
1462     default_csv                => $opt->{default_csv},
1463     postinsert_callback        => $opt->{postinsert_callback},
1464   );
1465
1466   if ( $opt->{'batch_namecol'} ) {
1467     $iopt{'batch_namevalue'} = $param->{ $opt->{'batch_namecol'} };
1468     $iopt{$_} = $opt->{$_} foreach qw( batch_keycol batch_table batch_namecol );
1469   }
1470
1471   my $error = FS::Record::batch_import( \%iopt );
1472
1473   unlink $file;
1474
1475   die "$error\n" if $error;
1476 }
1477
1478 =item batch_import PARAM_HASHREF
1479
1480 Class method for batch imports.  Available params:
1481
1482 =over 4
1483
1484 =item table
1485
1486 =item format - usual way to specify import, with this format string selecting data from the formats and format_* info hashes
1487
1488 =item formats
1489
1490 =item format_types
1491
1492 =item format_headers
1493
1494 =item format_sep_chars
1495
1496 =item format_fixedlength_formats
1497
1498 =item format_row_callbacks
1499
1500 =item fields - Alternate way to specify import, specifying import fields directly as a listref
1501
1502 =item preinsert_callback
1503
1504 =item postinsert_callback
1505
1506 =item params
1507
1508 =item job
1509
1510 FS::queue object, will be updated with progress
1511
1512 =item file
1513
1514 =item type
1515
1516 csv, xls, fixedlength, xml
1517
1518 =item empty_ok
1519
1520 =back
1521
1522 =cut
1523
1524 sub batch_import {
1525   my $param = shift;
1526
1527   warn "$me batch_import call with params: \n". Dumper($param)
1528     if $DEBUG;
1529
1530   my $table   = $param->{table};
1531
1532   my $job     = $param->{job};
1533   my $file    = $param->{file};
1534   my $params  = $param->{params} || {};
1535
1536   my( $type, $header, $sep_char, $fixedlength_format,
1537       $xml_format, $row_callback, @fields );
1538
1539   my $postinsert_callback = '';
1540   $postinsert_callback = $param->{'postinsert_callback'}
1541           if $param->{'postinsert_callback'};
1542   my $preinsert_callback = '';
1543   $preinsert_callback = $param->{'preinsert_callback'}
1544           if $param->{'preinsert_callback'};
1545
1546   if ( $param->{'format'} ) {
1547
1548     my $format  = $param->{'format'};
1549     my $formats = $param->{formats};
1550     die "unknown format $format" unless exists $formats->{ $format };
1551
1552     $type = $param->{'format_types'}
1553             ? $param->{'format_types'}{ $format }
1554             : $param->{type} || 'csv';
1555
1556
1557     $header = $param->{'format_headers'}
1558                ? $param->{'format_headers'}{ $param->{'format'} }
1559                : 0;
1560
1561     $sep_char = $param->{'format_sep_chars'}
1562                   ? $param->{'format_sep_chars'}{ $param->{'format'} }
1563                   : ',';
1564
1565     $fixedlength_format =
1566       $param->{'format_fixedlength_formats'}
1567         ? $param->{'format_fixedlength_formats'}{ $param->{'format'} }
1568         : '';
1569
1570     $xml_format =
1571       $param->{'format_xml_formats'}
1572         ? $param->{'format_xml_formats'}{ $param->{'format'} }
1573         : '';
1574
1575     $row_callback =
1576       $param->{'format_row_callbacks'}
1577         ? $param->{'format_row_callbacks'}{ $param->{'format'} }
1578         : '';
1579
1580     @fields = @{ $formats->{ $format } };
1581
1582   } elsif ( $param->{'fields'} ) {
1583
1584     $type = ''; #infer from filename
1585     $header = 0;
1586     $sep_char = ',';
1587     $fixedlength_format = '';
1588     $row_callback = '';
1589     @fields = @{ $param->{'fields'} };
1590
1591   } else {
1592     die "neither format nor fields specified";
1593   }
1594
1595   #my $file    = $param->{file};
1596
1597   unless ( $type ) {
1598     if ( $file =~ /\.(\w+)$/i ) {
1599       $type = lc($1);
1600     } else {
1601       #or error out???
1602       warn "can't parse file type from filename $file; defaulting to CSV";
1603       $type = 'csv';
1604     }
1605     $type = 'csv'
1606       if $param->{'default_csv'} && $type ne 'xls';
1607   }
1608
1609
1610   my $row = 0;
1611   my $count;
1612   my $parser;
1613   my @buffer = ();
1614   if ( $type eq 'csv' || $type eq 'fixedlength' ) {
1615
1616     if ( $type eq 'csv' ) {
1617
1618       my %attr = ();
1619       $attr{sep_char} = $sep_char if $sep_char;
1620       $parser = new Text::CSV_XS \%attr;
1621
1622     } elsif ( $type eq 'fixedlength' ) {
1623
1624       eval "use Parse::FixedLength;";
1625       die $@ if $@;
1626       $parser = Parse::FixedLength->new($fixedlength_format);
1627
1628     }
1629     else {
1630       die "Unknown file type $type\n";
1631     }
1632
1633     @buffer = split(/\r?\n/, slurp($file) );
1634     splice(@buffer, 0, ($header || 0) );
1635     $count = scalar(@buffer);
1636
1637   } elsif ( $type eq 'xls' ) {
1638
1639     eval "use Spreadsheet::ParseExcel;";
1640     die $@ if $@;
1641
1642     eval "use DateTime::Format::Excel;";
1643     #for now, just let the error be thrown if it is used, since only CDR
1644     # formats bill_west and troop use it, not other excel-parsing things
1645     #die $@ if $@;
1646
1647     my $excel = Spreadsheet::ParseExcel::Workbook->new->Parse($file);
1648
1649     $parser = $excel->{Worksheet}[0]; #first sheet
1650
1651     $count = $parser->{MaxRow} || $parser->{MinRow};
1652     $count++;
1653
1654     $row = $header || 0;
1655   } elsif ( $type eq 'xml' ) {
1656     # FS::pay_batch
1657     eval "use XML::Simple;";
1658     die $@ if $@;
1659     my $xmlrow = $xml_format->{'xmlrow'};
1660     $parser = $xml_format->{'xmlkeys'};
1661     die 'no xmlkeys specified' unless ref $parser eq 'ARRAY';
1662     my $data = XML::Simple::XMLin(
1663       $file,
1664       'SuppressEmpty' => '', #sets empty values to ''
1665       'KeepRoot'      => 1,
1666     );
1667     my $rows = $data;
1668     $rows = $rows->{$_} foreach @$xmlrow;
1669     $rows = [ $rows ] if ref($rows) ne 'ARRAY';
1670     $count = @buffer = @$rows;
1671   } else {
1672     die "Unknown file type $type\n";
1673   }
1674
1675   #my $columns;
1676
1677   local $SIG{HUP} = 'IGNORE';
1678   local $SIG{INT} = 'IGNORE';
1679   local $SIG{QUIT} = 'IGNORE';
1680   local $SIG{TERM} = 'IGNORE';
1681   local $SIG{TSTP} = 'IGNORE';
1682   local $SIG{PIPE} = 'IGNORE';
1683
1684   my $oldAutoCommit = $FS::UID::AutoCommit;
1685   local $FS::UID::AutoCommit = 0;
1686   my $dbh = dbh;
1687
1688   #my $params  = $param->{params} || {};
1689   if ( $param->{'batch_namecol'} && $param->{'batch_namevalue'} ) {
1690     my $batch_col   = $param->{'batch_keycol'};
1691
1692     my $batch_class = 'FS::'. $param->{'batch_table'};
1693     my $batch = $batch_class->new({
1694       $param->{'batch_namecol'} => $param->{'batch_namevalue'}
1695     });
1696     my $error = $batch->insert;
1697     if ( $error ) {
1698       $dbh->rollback if $oldAutoCommit;
1699       return "can't insert batch record: $error";
1700     }
1701     #primary key via dbdef? (so the column names don't have to match)
1702     my $batch_value = $batch->get( $param->{'batch_keycol'} );
1703
1704     $params->{ $batch_col } = $batch_value;
1705   }
1706
1707   #my $job     = $param->{job};
1708   my $line;
1709   my $imported = 0;
1710   my( $last, $min_sec ) = ( time, 5 ); #progressbar foo
1711   while (1) {
1712
1713     my @columns = ();
1714     if ( $type eq 'csv' ) {
1715
1716       last unless scalar(@buffer);
1717       $line = shift(@buffer);
1718
1719       next if $line =~ /^\s*$/; #skip empty lines
1720
1721       $line = &{$row_callback}($line) if $row_callback;
1722
1723       next if $line =~ /^\s*$/; #skip empty lines
1724
1725       $parser->parse($line) or do {
1726         $dbh->rollback if $oldAutoCommit;
1727         return "can't parse: ". $parser->error_input() . " " . $parser->error_diag;
1728       };
1729       @columns = $parser->fields();
1730
1731     } elsif ( $type eq 'fixedlength' ) {
1732
1733       last unless scalar(@buffer);
1734       $line = shift(@buffer);
1735
1736       @columns = $parser->parse($line);
1737
1738     } elsif ( $type eq 'xls' ) {
1739
1740       last if $row > ($parser->{MaxRow} || $parser->{MinRow})
1741            || ! $parser->{Cells}[$row];
1742
1743       my @row = @{ $parser->{Cells}[$row] };
1744       @columns = map $_->{Val}, @row;
1745
1746       #my $z = 'A';
1747       #warn $z++. ": $_\n" for @columns;
1748
1749     } elsif ( $type eq 'xml' ) {
1750       # $parser = [ 'Column0Key', 'Column1Key' ... ]
1751       last unless scalar(@buffer);
1752       my $row = shift @buffer;
1753       @columns = @{ $row }{ @$parser };
1754     } else {
1755       die "Unknown file type $type\n";
1756     }
1757
1758     my @later = ();
1759     my %hash = %$params;
1760
1761     foreach my $field ( @fields ) {
1762
1763       my $value = shift @columns;
1764
1765       if ( ref($field) eq 'CODE' ) {
1766         #&{$field}(\%hash, $value);
1767         push @later, $field, $value;
1768       } else {
1769         #??? $hash{$field} = $value if length($value);
1770         $hash{$field} = $value if defined($value) && length($value);
1771       }
1772
1773     }
1774
1775     #my $table   = $param->{table};
1776     my $class = "FS::$table";
1777
1778     my $record = $class->new( \%hash );
1779
1780     my $param = {};
1781     while ( scalar(@later) ) {
1782       my $sub = shift @later;
1783       my $data = shift @later;
1784       eval {
1785         &{$sub}($record, $data, $conf, $param); # $record->&{$sub}($data, $conf)
1786       };
1787       if ( $@ ) {
1788         $dbh->rollback if $oldAutoCommit;
1789         return "can't insert record". ( $line ? " for $line" : '' ). ": $@";
1790       }
1791       last if exists( $param->{skiprow} );
1792     }
1793     next if exists( $param->{skiprow} );
1794
1795     if ( $preinsert_callback ) {
1796       my $error = &{$preinsert_callback}($record, $param);
1797       if ( $error ) {
1798         $dbh->rollback if $oldAutoCommit;
1799         return "preinsert_callback error". ( $line ? " for $line" : '' ).
1800                ": $error";
1801       }
1802       next if exists $param->{skiprow} && $param->{skiprow};
1803     }
1804
1805     my $error = $record->insert;
1806
1807     if ( $error ) {
1808       $dbh->rollback if $oldAutoCommit;
1809       return "can't insert record". ( $line ? " for $line" : '' ). ": $error";
1810     }
1811
1812     $row++;
1813     $imported++;
1814
1815     if ( $postinsert_callback ) {
1816       my $error = &{$postinsert_callback}($record, $param);
1817       if ( $error ) {
1818         $dbh->rollback if $oldAutoCommit;
1819         return "postinsert_callback error". ( $line ? " for $line" : '' ).
1820                ": $error";
1821       }
1822     }
1823
1824     if ( $job && time - $min_sec > $last ) { #progress bar
1825       $job->update_statustext( int(100 * $imported / $count) );
1826       $last = time;
1827     }
1828
1829   }
1830
1831   unless ( $imported || $param->{empty_ok} ) {
1832     $dbh->rollback if $oldAutoCommit;
1833     return "Empty file!";
1834   }
1835
1836   $dbh->commit or die $dbh->errstr if $oldAutoCommit;;
1837
1838   ''; #no error
1839
1840 }
1841
1842 sub _h_statement {
1843   my( $self, $action, $time ) = @_;
1844
1845   $time ||= time;
1846
1847   my %nohistory = map { $_=>1 } $self->nohistory_fields;
1848
1849   my @fields =
1850     grep { defined($self->get($_)) && $self->get($_) ne "" && ! $nohistory{$_} }
1851     real_fields($self->table);
1852   ;
1853
1854   # If we're encrypting then don't store the payinfo in the history
1855   if ( $conf && $conf->exists('encryption') && $self->table ne 'banned_pay' ) {
1856     @fields = grep { $_ ne 'payinfo' } @fields;
1857   }
1858
1859   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
1860
1861   "INSERT INTO h_". $self->table. " ( ".
1862       join(', ', qw(history_date history_user history_action), @fields ).
1863     ") VALUES (".
1864       join(', ', $time, dbh->quote(getotaker()), dbh->quote($action), @values).
1865     ")"
1866   ;
1867 }
1868
1869 =item unique COLUMN
1870
1871 B<Warning>: External use is B<deprecated>.
1872
1873 Replaces COLUMN in record with a unique number, using counters in the
1874 filesystem.  Used by the B<insert> method on single-field unique columns
1875 (see L<DBIx::DBSchema::Table>) and also as a fallback for primary keys
1876 that aren't SERIAL (Pg) or AUTO_INCREMENT (mysql).
1877
1878 Returns the new value.
1879
1880 =cut
1881
1882 sub unique {
1883   my($self,$field) = @_;
1884   my($table)=$self->table;
1885
1886   croak "Unique called on field $field, but it is ",
1887         $self->getfield($field),
1888         ", not null!"
1889     if $self->getfield($field);
1890
1891   #warn "table $table is tainted" if is_tainted($table);
1892   #warn "field $field is tainted" if is_tainted($field);
1893
1894   my($counter) = new File::CounterFile "$table.$field",0;
1895 # hack for web demo
1896 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
1897 #  my($user)=$1;
1898 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
1899 # endhack
1900
1901   my $index = $counter->inc;
1902   $index = $counter->inc while qsearchs($table, { $field=>$index } );
1903
1904   $index =~ /^(\d*)$/;
1905   $index=$1;
1906
1907   $self->setfield($field,$index);
1908
1909 }
1910
1911 =item ut_float COLUMN
1912
1913 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
1914 null.  If there is an error, returns the error, otherwise returns false.
1915
1916 =cut
1917
1918 sub ut_float {
1919   my($self,$field)=@_ ;
1920   ($self->getfield($field) =~ /^\s*(\d+\.\d+)\s*$/ ||
1921    $self->getfield($field) =~ /^\s*(\d+)\s*$/ ||
1922    $self->getfield($field) =~ /^\s*(\d+\.\d+e\d+)\s*$/ ||
1923    $self->getfield($field) =~ /^\s*(\d+e\d+)\s*$/)
1924     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1925   $self->setfield($field,$1);
1926   '';
1927 }
1928 =item ut_floatn COLUMN
1929
1930 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May be
1931 null.  If there is an error, returns the error, otherwise returns false.
1932
1933 =cut
1934
1935 #false laziness w/ut_ipn
1936 sub ut_floatn {
1937   my( $self, $field ) = @_;
1938   if ( $self->getfield($field) =~ /^()$/ ) {
1939     $self->setfield($field,'');
1940     '';
1941   } else {
1942     $self->ut_float($field);
1943   }
1944 }
1945
1946 =item ut_sfloat COLUMN
1947
1948 Check/untaint signed floating point numeric data: 1.1, 1, 1.1e10, 1e10.
1949 May not be null.  If there is an error, returns the error, otherwise returns
1950 false.
1951
1952 =cut
1953
1954 sub ut_sfloat {
1955   my($self,$field)=@_ ;
1956   ($self->getfield($field) =~ /^\s*(-?\d+\.\d+)\s*$/ ||
1957    $self->getfield($field) =~ /^\s*(-?\d+)\s*$/ ||
1958    $self->getfield($field) =~ /^\s*(-?\d+\.\d+[eE]-?\d+)\s*$/ ||
1959    $self->getfield($field) =~ /^\s*(-?\d+[eE]-?\d+)\s*$/)
1960     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1961   $self->setfield($field,$1);
1962   '';
1963 }
1964 =item ut_sfloatn COLUMN
1965
1966 Check/untaint signed floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May be
1967 null.  If there is an error, returns the error, otherwise returns false.
1968
1969 =cut
1970
1971 sub ut_sfloatn {
1972   my( $self, $field ) = @_;
1973   if ( $self->getfield($field) =~ /^()$/ ) {
1974     $self->setfield($field,'');
1975     '';
1976   } else {
1977     $self->ut_sfloat($field);
1978   }
1979 }
1980
1981 =item ut_snumber COLUMN
1982
1983 Check/untaint signed numeric data (whole numbers).  If there is an error,
1984 returns the error, otherwise returns false.
1985
1986 =cut
1987
1988 sub ut_snumber {
1989   my($self, $field) = @_;
1990   $self->getfield($field) =~ /^\s*(-?)\s*(\d+)\s*$/
1991     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1992   $self->setfield($field, "$1$2");
1993   '';
1994 }
1995
1996 =item ut_snumbern COLUMN
1997
1998 Check/untaint signed numeric data (whole numbers).  If there is an error,
1999 returns the error, otherwise returns false.
2000
2001 =cut
2002
2003 sub ut_snumbern {
2004   my($self, $field) = @_;
2005   $self->getfield($field) =~ /^\s*(-?)\s*(\d*)\s*$/
2006     or return "Illegal (numeric) $field: ". $self->getfield($field);
2007   if ($1) {
2008     return "Illegal (numeric) $field: ". $self->getfield($field)
2009       unless $2;
2010   }
2011   $self->setfield($field, "$1$2");
2012   '';
2013 }
2014
2015 =item ut_number COLUMN
2016
2017 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
2018 is an error, returns the error, otherwise returns false.
2019
2020 =cut
2021
2022 sub ut_number {
2023   my($self,$field)=@_;
2024   $self->getfield($field) =~ /^\s*(\d+)\s*$/
2025     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
2026   $self->setfield($field,$1);
2027   '';
2028 }
2029
2030 =item ut_numbern COLUMN
2031
2032 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
2033 an error, returns the error, otherwise returns false.
2034
2035 =cut
2036
2037 sub ut_numbern {
2038   my($self,$field)=@_;
2039   $self->getfield($field) =~ /^\s*(\d*)\s*$/
2040     or return "Illegal (numeric) $field: ". $self->getfield($field);
2041   $self->setfield($field,$1);
2042   '';
2043 }
2044
2045 =item ut_money COLUMN
2046
2047 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
2048 is an error, returns the error, otherwise returns false.
2049
2050 =cut
2051
2052 sub ut_money {
2053   my($self,$field)=@_;
2054   $self->setfield($field, 0) if $self->getfield($field) eq '';
2055   $self->getfield($field) =~ /^\s*(\-)?\s*(\d*)(\.\d{2})?\s*$/
2056     or return "Illegal (money) $field: ". $self->getfield($field);
2057   #$self->setfield($field, "$1$2$3" || 0);
2058   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
2059   '';
2060 }
2061
2062 =item ut_moneyn COLUMN
2063
2064 Check/untaint monetary numbers.  May be negative.  If there
2065 is an error, returns the error, otherwise returns false.
2066
2067 =cut
2068
2069 sub ut_moneyn {
2070   my($self,$field)=@_;
2071   if ($self->getfield($field) eq '') {
2072     $self->setfield($field, '');
2073     return '';
2074   }
2075   $self->ut_money($field);
2076 }
2077
2078 =item ut_text COLUMN
2079
2080 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
2081 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / = [ ] < >
2082 May not be null.  If there is an error, returns the error, otherwise returns
2083 false.
2084
2085 =cut
2086
2087 sub ut_text {
2088   my($self,$field)=@_;
2089   #warn "msgcat ". \&msgcat. "\n";
2090   #warn "notexist ". \&notexist. "\n";
2091   #warn "AUTOLOAD ". \&AUTOLOAD. "\n";
2092   $self->getfield($field)
2093     =~ /^([\wô \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=\[\]\<\>$money_char]+)$/
2094       or return gettext('illegal_or_empty_text'). " $field: ".
2095                  $self->getfield($field);
2096   $self->setfield($field,$1);
2097   '';
2098 }
2099
2100 =item ut_textn COLUMN
2101
2102 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
2103 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / = [ ] < >
2104 May be null.  If there is an error, returns the error, otherwise returns false.
2105
2106 =cut
2107
2108 sub ut_textn {
2109   my($self,$field)=@_;
2110   return $self->setfield($field, '') if $self->getfield($field) =~ /^$/;
2111   $self->ut_text($field);
2112 }
2113
2114 =item ut_alpha COLUMN
2115
2116 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
2117 an error, returns the error, otherwise returns false.
2118
2119 =cut
2120
2121 sub ut_alpha {
2122   my($self,$field)=@_;
2123   $self->getfield($field) =~ /^(\w+)$/
2124     or return "Illegal or empty (alphanumeric) $field: ".
2125               $self->getfield($field);
2126   $self->setfield($field,$1);
2127   '';
2128 }
2129
2130 =item ut_alphan COLUMN
2131
2132 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
2133 error, returns the error, otherwise returns false.
2134
2135 =cut
2136
2137 sub ut_alphan {
2138   my($self,$field)=@_;
2139   $self->getfield($field) =~ /^(\w*)$/
2140     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
2141   $self->setfield($field,$1);
2142   '';
2143 }
2144
2145 =item ut_alphasn COLUMN
2146
2147 Check/untaint alphanumeric strings, spaces allowed.  May be null.  If there is
2148 an error, returns the error, otherwise returns false.
2149
2150 =cut
2151
2152 sub ut_alphasn {
2153   my($self,$field)=@_;
2154   $self->getfield($field) =~ /^([\w ]*)$/
2155     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
2156   $self->setfield($field,$1);
2157   '';
2158 }
2159
2160
2161 =item ut_alpha_lower COLUMN
2162
2163 Check/untaint lowercase alphanumeric strings (no spaces).  May not be null.  If
2164 there is an error, returns the error, otherwise returns false.
2165
2166 =cut
2167
2168 sub ut_alpha_lower {
2169   my($self,$field)=@_;
2170   $self->getfield($field) =~ /[[:upper:]]/
2171     and return "Uppercase characters are not permitted in $field";
2172   $self->ut_alpha($field);
2173 }
2174
2175 =item ut_phonen COLUMN [ COUNTRY ]
2176
2177 Check/untaint phone numbers.  May be null.  If there is an error, returns
2178 the error, otherwise returns false.
2179
2180 Takes an optional two-letter ISO country code; without it or with unsupported
2181 countries, ut_phonen simply calls ut_alphan.
2182
2183 =cut
2184
2185 sub ut_phonen {
2186   my( $self, $field, $country ) = @_;
2187   return $self->ut_alphan($field) unless defined $country;
2188   my $phonen = $self->getfield($field);
2189   if ( $phonen eq '' ) {
2190     $self->setfield($field,'');
2191   } elsif ( $country eq 'US' || $country eq 'CA' ) {
2192     $phonen =~ s/\D//g;
2193     $phonen = $conf->config('cust_main-default_areacode').$phonen
2194       if length($phonen)==7 && $conf->config('cust_main-default_areacode');
2195     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
2196       or return gettext('illegal_phone'). " $field: ". $self->getfield($field);
2197     $phonen = "$1-$2-$3";
2198     $phonen .= " x$4" if $4;
2199     $self->setfield($field,$phonen);
2200   } else {
2201     warn "warning: don't know how to check phone numbers for country $country";
2202     return $self->ut_textn($field);
2203   }
2204   '';
2205 }
2206
2207 =item ut_hex COLUMN
2208
2209 Check/untaint hexadecimal values.
2210
2211 =cut
2212
2213 sub ut_hex {
2214   my($self, $field) = @_;
2215   $self->getfield($field) =~ /^([\da-fA-F]+)$/
2216     or return "Illegal (hex) $field: ". $self->getfield($field);
2217   $self->setfield($field, uc($1));
2218   '';
2219 }
2220
2221 =item ut_hexn COLUMN
2222
2223 Check/untaint hexadecimal values.  May be null.
2224
2225 =cut
2226
2227 sub ut_hexn {
2228   my($self, $field) = @_;
2229   $self->getfield($field) =~ /^([\da-fA-F]*)$/
2230     or return "Illegal (hex) $field: ". $self->getfield($field);
2231   $self->setfield($field, uc($1));
2232   '';
2233 }
2234
2235 =item ut_mac_addr COLUMN
2236
2237 Check/untaint mac addresses.  May be null.
2238
2239 =cut
2240
2241 sub ut_mac_addr {
2242   my($self, $field) = @_;
2243
2244   my $mac = $self->get($field);
2245   $mac =~ s/\s+//g;
2246   $mac =~ s/://g;
2247   $self->set($field, $mac);
2248
2249   my $e = $self->ut_hex($field);
2250   return $e if $e;
2251
2252   return "Illegal (mac address) $field: ". $self->getfield($field)
2253     unless length($self->getfield($field)) == 12;
2254
2255   '';
2256
2257 }
2258
2259 =item ut_mac_addrn COLUMN
2260
2261 Check/untaint mac addresses.  May be null.
2262
2263 =cut
2264
2265 sub ut_mac_addrn {
2266   my($self, $field) = @_;
2267   ($self->getfield($field) eq '') ? '' : $self->ut_mac_addr($field);
2268 }
2269
2270 =item ut_ip COLUMN
2271
2272 Check/untaint ip addresses.  IPv4 only for now, though ::1 is auto-translated
2273 to 127.0.0.1.
2274
2275 =cut
2276
2277 sub ut_ip {
2278   my( $self, $field ) = @_;
2279   $self->setfield($field, '127.0.0.1') if $self->getfield($field) eq '::1';
2280   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
2281     or return "Illegal (IP address) $field: ". $self->getfield($field);
2282   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
2283   $self->setfield($field, "$1.$2.$3.$4");
2284   '';
2285 }
2286
2287 =item ut_ipn COLUMN
2288
2289 Check/untaint ip addresses.  IPv4 only for now, though ::1 is auto-translated
2290 to 127.0.0.1.  May be null.
2291
2292 =cut
2293
2294 sub ut_ipn {
2295   my( $self, $field ) = @_;
2296   if ( $self->getfield($field) =~ /^()$/ ) {
2297     $self->setfield($field,'');
2298     '';
2299   } else {
2300     $self->ut_ip($field);
2301   }
2302 }
2303
2304 =item ut_ip46 COLUMN
2305
2306 Check/untaint IPv4 or IPv6 address.
2307
2308 =cut
2309
2310 sub ut_ip46 {
2311   my( $self, $field ) = @_;
2312   my $ip = NetAddr::IP->new($self->getfield($field))
2313     or return "Illegal (IP address) $field: ".$self->getfield($field);
2314   $self->setfield($field, lc($ip->addr));
2315   return '';
2316 }
2317
2318 =item ut_ip46n
2319
2320 Check/untaint IPv6 or IPv6 address.  May be null.
2321
2322 =cut
2323
2324 sub ut_ip46n {
2325   my( $self, $field ) = @_;
2326   if ( $self->getfield($field) =~ /^$/ ) {
2327     $self->setfield($field, '');
2328     return '';
2329   }
2330   $self->ut_ip46($field);
2331 }
2332
2333 =item ut_coord COLUMN [ LOWER [ UPPER ] ]
2334
2335 Check/untaint coordinates.
2336 Accepts the following forms:
2337 DDD.DDDDD
2338 -DDD.DDDDD
2339 DDD MM.MMM
2340 -DDD MM.MMM
2341 DDD MM SS
2342 -DDD MM SS
2343 DDD MM MMM
2344 -DDD MM MMM
2345
2346 The "DDD MM SS" and "DDD MM MMM" are potentially ambiguous.
2347 The latter form (that is, the MMM are thousands of minutes) is
2348 assumed if the "MMM" is exactly three digits or two digits > 59.
2349
2350 To be safe, just use the DDD.DDDDD form.
2351
2352 If LOWER or UPPER are specified, then the coordinate is checked
2353 for lower and upper bounds, respectively.
2354
2355 =cut
2356
2357 sub ut_coord {
2358   my ($self, $field) = (shift, shift);
2359
2360   my($lower, $upper);
2361   if ( $field =~ /latitude/ ) {
2362     $lower = $lat_lower;
2363     $upper = 90;
2364   } elsif ( $field =~ /longitude/ ) {
2365     $lower = -180;
2366     $upper = $lon_upper;
2367   }
2368
2369   my $coord = $self->getfield($field);
2370   my $neg = $coord =~ s/^(-)//;
2371
2372   my ($d, $m, $s) = (0, 0, 0);
2373
2374   if (
2375     (($d) = ($coord =~ /^(\s*\d{1,3}(?:\.\d+)?)\s*$/)) ||
2376     (($d, $m) = ($coord =~ /^(\s*\d{1,3})\s+(\d{1,2}(?:\.\d+))\s*$/)) ||
2377     (($d, $m, $s) = ($coord =~ /^(\s*\d{1,3})\s+(\d{1,2})\s+(\d{1,3})\s*$/))
2378   ) {
2379     $s = (((($s =~ /^\d{3}$/) or $s > 59) ? ($s / 1000) : ($s / 60)) / 60);
2380     $m = $m / 60;
2381     if ($m > 59) {
2382       return "Invalid (coordinate with minutes > 59) $field: "
2383              . $self->getfield($field);
2384     }
2385
2386     $coord = ($neg ? -1 : 1) * sprintf('%.8f', $d + $m + $s);
2387
2388     if (defined($lower) and ($coord < $lower)) {
2389       return "Invalid (coordinate < $lower) $field: "
2390              . $self->getfield($field);;
2391     }
2392
2393     if (defined($upper) and ($coord > $upper)) {
2394       return "Invalid (coordinate > $upper) $field: "
2395              . $self->getfield($field);;
2396     }
2397
2398     $self->setfield($field, $coord);
2399     return '';
2400   }
2401
2402   return "Invalid (coordinate) $field: " . $self->getfield($field);
2403
2404 }
2405
2406 =item ut_coordn COLUMN [ LOWER [ UPPER ] ]
2407
2408 Same as ut_coord, except optionally null.
2409
2410 =cut
2411
2412 sub ut_coordn {
2413
2414   my ($self, $field) = (shift, shift);
2415
2416   if ($self->getfield($field) =~ /^\s*$/) {
2417     return '';
2418   } else {
2419     return $self->ut_coord($field, @_);
2420   }
2421
2422 }
2423
2424 =item ut_domain COLUMN
2425
2426 Check/untaint host and domain names.  May not be null.
2427
2428 =cut
2429
2430 sub ut_domain {
2431   my( $self, $field ) = @_;
2432   #$self->getfield($field) =~/^(\w+\.)*\w+$/
2433   $self->getfield($field) =~/^(([\w\-]+\.)*\w+)$/
2434     or return "Illegal (hostname) $field: ". $self->getfield($field);
2435   $self->setfield($field,$1);
2436   '';
2437 }
2438
2439 =item ut_domainn COLUMN
2440
2441 Check/untaint host and domain names.  May be null.
2442
2443 =cut
2444
2445 sub ut_domainn {
2446   my( $self, $field ) = @_;
2447   if ( $self->getfield($field) =~ /^()$/ ) {
2448     $self->setfield($field,'');
2449     '';
2450   } else {
2451     $self->ut_domain($field);
2452   }
2453 }
2454
2455 =item ut_name COLUMN
2456
2457 Check/untaint proper names; allows alphanumerics, spaces and the following
2458 punctuation: , . - '
2459
2460 May not be null.
2461
2462 =cut
2463
2464 sub ut_name {
2465   my( $self, $field ) = @_;
2466 #  warn "ut_name allowed alphanumerics: +(sort grep /\w/, map { chr() } 0..255), "\n";
2467   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
2468     or return gettext('illegal_name'). " $field: ". $self->getfield($field);
2469   $self->setfield($field,$1);
2470   '';
2471 }
2472
2473 =item ut_zip COLUMN
2474
2475 Check/untaint zip codes.
2476
2477 =cut
2478
2479 my @zip_reqd_countries = qw( AU CA US ); #CA, US implicit...
2480
2481 sub ut_zip {
2482   my( $self, $field, $country ) = @_;
2483
2484   if ( $country eq 'US' ) {
2485
2486     $self->getfield($field) =~ /^\s*(\d{5}(\-\d{4})?)\s*$/
2487       or return gettext('illegal_zip'). " $field for country $country: ".
2488                 $self->getfield($field);
2489     $self->setfield($field, $1);
2490
2491   } elsif ( $country eq 'CA' ) {
2492
2493     $self->getfield($field) =~ /^\s*([A-Z]\d[A-Z])\s*(\d[A-Z]\d)\s*$/i
2494       or return gettext('illegal_zip'). " $field for country $country: ".
2495                 $self->getfield($field);
2496     $self->setfield($field, "$1 $2");
2497
2498   } else {
2499
2500     if ( $self->getfield($field) =~ /^\s*$/
2501          && ( !$country || ! grep { $_ eq $country } @zip_reqd_countries )
2502        )
2503     {
2504       $self->setfield($field,'');
2505     } else {
2506       $self->getfield($field) =~ /^\s*(\w[\w\-\s]{0,8}\w)\s*$/
2507         or return gettext('illegal_zip'). " $field: ". $self->getfield($field);
2508       $self->setfield($field,$1);
2509     }
2510
2511   }
2512
2513   '';
2514 }
2515
2516 =item ut_country COLUMN
2517
2518 Check/untaint country codes.  Country names are changed to codes, if possible -
2519 see L<Locale::Country>.
2520
2521 =cut
2522
2523 sub ut_country {
2524   my( $self, $field ) = @_;
2525   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
2526     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
2527          && country2code($1) ) {
2528       $self->setfield($field,uc(country2code($1)));
2529     }
2530   }
2531   $self->getfield($field) =~ /^(\w\w)$/
2532     or return "Illegal (country) $field: ". $self->getfield($field);
2533   $self->setfield($field,uc($1));
2534   '';
2535 }
2536
2537 =item ut_anything COLUMN
2538
2539 Untaints arbitrary data.  Be careful.
2540
2541 =cut
2542
2543 sub ut_anything {
2544   my( $self, $field ) = @_;
2545   $self->getfield($field) =~ /^(.*)$/s
2546     or return "Illegal $field: ". $self->getfield($field);
2547   $self->setfield($field,$1);
2548   '';
2549 }
2550
2551 =item ut_enum COLUMN CHOICES_ARRAYREF
2552
2553 Check/untaint a column, supplying all possible choices, like the "enum" type.
2554
2555 =cut
2556
2557 sub ut_enum {
2558   my( $self, $field, $choices ) = @_;
2559   foreach my $choice ( @$choices ) {
2560     if ( $self->getfield($field) eq $choice ) {
2561       $self->setfield($field, $choice);
2562       return '';
2563     }
2564   }
2565   return "Illegal (enum) field $field: ". $self->getfield($field);
2566 }
2567
2568 =item ut_enumn COLUMN CHOICES_ARRAYREF
2569
2570 Like ut_enum, except the null value is also allowed.
2571
2572 =cut
2573
2574 sub ut_enumn {
2575   my( $self, $field, $choices ) = @_;
2576   $self->getfield($field)
2577     ? $self->ut_enum($field, $choices)
2578     : '';
2579 }
2580
2581 =item ut_flag COLUMN
2582
2583 Check/untaint a column if it contains either an empty string or 'Y'.  This
2584 is the standard form for boolean flags in Freeside.
2585
2586 =cut
2587
2588 sub ut_flag {
2589   my( $self, $field ) = @_;
2590   my $value = uc($self->getfield($field));
2591   if ( $value eq '' or $value eq 'Y' ) {
2592     $self->setfield($field, $value);
2593     return '';
2594   }
2595   return "Illegal (flag) field $field: $value";
2596 }
2597
2598 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
2599
2600 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
2601 on the column first.
2602
2603 =cut
2604
2605 sub ut_foreign_key {
2606   my( $self, $field, $table, $foreign ) = @_;
2607   return '' if $no_check_foreign;
2608   qsearchs($table, { $foreign => $self->getfield($field) })
2609     or return "Can't find ". $self->table. ".$field ". $self->getfield($field).
2610               " in $table.$foreign";
2611   '';
2612 }
2613
2614 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
2615
2616 Like ut_foreign_key, except the null value is also allowed.
2617
2618 =cut
2619
2620 sub ut_foreign_keyn {
2621   my( $self, $field, $table, $foreign ) = @_;
2622   $self->getfield($field)
2623     ? $self->ut_foreign_key($field, $table, $foreign)
2624     : '';
2625 }
2626
2627 =item ut_agentnum_acl COLUMN [ NULL_RIGHT | NULL_RIGHT_LISTREF ]
2628
2629 Checks this column as an agentnum, taking into account the current users's
2630 ACLs.  NULL_RIGHT or NULL_RIGHT_LISTREF, if specified, indicates the access
2631 right or rights allowing no agentnum.
2632
2633 =cut
2634
2635 sub ut_agentnum_acl {
2636   my( $self, $field ) = (shift, shift);
2637   my $null_acl = scalar(@_) ? shift : [];
2638   $null_acl = [ $null_acl ] unless ref($null_acl);
2639
2640   my $error = $self->ut_foreign_keyn($field, 'agent', 'agentnum');
2641   return "Illegal agentnum: $error" if $error;
2642
2643   my $curuser = $FS::CurrentUser::CurrentUser;
2644
2645   if ( $self->$field() ) {
2646
2647     return "Access denied"
2648       unless $curuser->agentnum($self->$field());
2649
2650   } else {
2651
2652     return "Access denied"
2653       unless grep $curuser->access_right($_), @$null_acl;
2654
2655   }
2656
2657   '';
2658
2659 }
2660
2661 =item fields [ TABLE ]
2662
2663 This is a wrapper for real_fields.  Code that called
2664 fields before should probably continue to call fields.
2665
2666 =cut
2667
2668 sub fields {
2669   my $something = shift;
2670   my $table;
2671   if($something->isa('FS::Record')) {
2672     $table = $something->table;
2673   } else {
2674     $table = $something;
2675     $something = "FS::$table";
2676   }
2677   return (real_fields($table));
2678 }
2679
2680
2681 =item encrypt($value)
2682
2683 Encrypts the credit card using a combination of PK to encrypt and uuencode to armour.
2684
2685 Returns the encrypted string.
2686
2687 You should generally not have to worry about calling this, as the system handles this for you.
2688
2689 =cut
2690
2691 sub encrypt {
2692   my ($self, $value) = @_;
2693   my $encrypted;
2694
2695   if ($conf->exists('encryption')) {
2696     if ($self->is_encrypted($value)) {
2697       # Return the original value if it isn't plaintext.
2698       $encrypted = $value;
2699     } else {
2700       $self->loadRSA;
2701       if (ref($rsa_encrypt) =~ /::RSA/) { # We Can Encrypt
2702         # RSA doesn't like the empty string so let's pack it up
2703         # The database doesn't like the RSA data so uuencode it
2704         my $length = length($value)+1;
2705         $encrypted = pack("u*",$rsa_encrypt->encrypt(pack("Z$length",$value)));
2706       } else {
2707         die ("You can't encrypt w/o a valid RSA engine - Check your installation or disable encryption");
2708       }
2709     }
2710   }
2711   return $encrypted;
2712 }
2713
2714 =item is_encrypted($value)
2715
2716 Checks to see if the string is encrypted and returns true or false (1/0) to indicate it's status.
2717
2718 =cut
2719
2720
2721 sub is_encrypted {
2722   my ($self, $value) = @_;
2723   # Possible Bug - Some work may be required here....
2724
2725   if ($value =~ /^M/ && length($value) > 80) {
2726     return 1;
2727   } else {
2728     return 0;
2729   }
2730 }
2731
2732 =item decrypt($value)
2733
2734 Uses the private key to decrypt the string. Returns the decryoted string or undef on failure.
2735
2736 You should generally not have to worry about calling this, as the system handles this for you.
2737
2738 =cut
2739
2740 sub decrypt {
2741   my ($self,$value) = @_;
2742   my $decrypted = $value; # Will return the original value if it isn't encrypted or can't be decrypted.
2743   if ($conf->exists('encryption') && $self->is_encrypted($value)) {
2744     $self->loadRSA;
2745     if (ref($rsa_decrypt) =~ /::RSA/) {
2746       my $encrypted = unpack ("u*", $value);
2747       $decrypted =  unpack("Z*", eval{$rsa_decrypt->decrypt($encrypted)});
2748       if ($@) {warn "Decryption Failed"};
2749     }
2750   }
2751   return $decrypted;
2752 }
2753
2754 sub loadRSA {
2755     my $self = shift;
2756     #Initialize the Module
2757     $rsa_module = 'Crypt::OpenSSL::RSA'; # The Default
2758
2759     if ($conf->exists('encryptionmodule') && $conf->config('encryptionmodule') ne '') {
2760       $rsa_module = $conf->config('encryptionmodule');
2761     }
2762
2763     if (!$rsa_loaded) {
2764         eval ("require $rsa_module"); # No need to import the namespace
2765         $rsa_loaded++;
2766     }
2767     # Initialize Encryption
2768     if ($conf->exists('encryptionpublickey') && $conf->config('encryptionpublickey') ne '') {
2769       my $public_key = join("\n",$conf->config('encryptionpublickey'));
2770       $rsa_encrypt = $rsa_module->new_public_key($public_key);
2771     }
2772
2773     # Intitalize Decryption
2774     if ($conf->exists('encryptionprivatekey') && $conf->config('encryptionprivatekey') ne '') {
2775       my $private_key = join("\n",$conf->config('encryptionprivatekey'));
2776       $rsa_decrypt = $rsa_module->new_private_key($private_key);
2777     }
2778 }
2779
2780 =item h_search ACTION
2781
2782 Given an ACTION, either "insert", or "delete", returns the appropriate history
2783 record corresponding to this record, if any.
2784
2785 =cut
2786
2787 sub h_search {
2788   my( $self, $action ) = @_;
2789
2790   my $table = $self->table;
2791   $table =~ s/^h_//;
2792
2793   my $primary_key = dbdef->table($table)->primary_key;
2794
2795   qsearchs({
2796     'table'   => "h_$table",
2797     'hashref' => { $primary_key     => $self->$primary_key(),
2798                    'history_action' => $action,
2799                  },
2800   });
2801
2802 }
2803
2804 =item h_date ACTION
2805
2806 Given an ACTION, either "insert", or "delete", returns the timestamp of the
2807 appropriate history record corresponding to this record, if any.
2808
2809 =cut
2810
2811 sub h_date {
2812   my($self, $action) = @_;
2813   my $h = $self->h_search($action);
2814   $h ? $h->history_date : '';
2815 }
2816
2817 =item scalar_sql SQL [ PLACEHOLDER, ... ]
2818
2819 A class or object method.  Executes the sql statement represented by SQL and
2820 returns a scalar representing the result: the first column of the first row.
2821
2822 Dies on bogus SQL.  Returns an empty string if no row is returned.
2823
2824 Typically used for statments which return a single value such as "SELECT
2825 COUNT(*) FROM table WHERE something" OR "SELECT column FROM table WHERE key = ?"
2826
2827 =cut
2828
2829 sub scalar_sql {
2830   my($self, $sql) = (shift, shift);
2831   my $sth = dbh->prepare($sql) or die dbh->errstr;
2832   $sth->execute(@_)
2833     or die "Unexpected error executing statement $sql: ". $sth->errstr;
2834   my $row = $sth->fetchrow_arrayref or return '';
2835   my $scalar = $row->[0];
2836   defined($scalar) ? $scalar : '';
2837 }
2838
2839 =item count [ WHERE ]
2840
2841 Convenience method for the common case of "SELECT COUNT(*) FROM table",
2842 with optional WHERE.  Must be called as method on a class with an
2843 associated table.
2844
2845 =cut
2846
2847 sub count {
2848   my($self, $where) = (shift, shift);
2849   my $table = $self->table or die 'count called on object of class '.ref($self);
2850   my $sql = "SELECT COUNT(*) FROM $table";
2851   $sql .= " WHERE $where" if $where;
2852   $self->scalar_sql($sql);
2853 }
2854
2855 =back
2856
2857 =head1 SUBROUTINES
2858
2859 =over 4
2860
2861 =item real_fields [ TABLE ]
2862
2863 Returns a list of the real columns in the specified table.  Called only by
2864 fields() and other subroutines elsewhere in FS::Record.
2865
2866 =cut
2867
2868 sub real_fields {
2869   my $table = shift;
2870
2871   my($table_obj) = dbdef->table($table);
2872   confess "Unknown table $table" unless $table_obj;
2873   $table_obj->columns;
2874 }
2875
2876 =item pvf FIELD_NAME
2877
2878 Returns the FS::part_virtual_field object corresponding to a field in the
2879 record (specified by FIELD_NAME).
2880
2881 =cut
2882
2883 sub pvf {
2884   my ($self, $name) = (shift, shift);
2885
2886   if(grep /^$name$/, $self->virtual_fields) {
2887     $name =~ s/^cf_//;
2888     my $concat = [ "'cf_'", "name" ];
2889     return qsearchs({   table   =>  'part_virtual_field',
2890                         hashref =>  { dbtable => $self->table,
2891                                       name    => $name
2892                                     },
2893                         select  =>  'vfieldpart, dbtable, length, label, '.concat_sql($concat).' as name',
2894                     });
2895   }
2896   ''
2897 }
2898
2899 =item _quote VALUE, TABLE, COLUMN
2900
2901 This is an internal function used to construct SQL statements.  It returns
2902 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
2903 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
2904
2905 =cut
2906
2907 sub _quote {
2908   my($value, $table, $column) = @_;
2909   my $column_obj = dbdef->table($table)->column($column);
2910   my $column_type = $column_obj->type;
2911   my $nullable = $column_obj->null;
2912
2913   warn "  $table.$column: $value ($column_type".
2914        ( $nullable ? ' NULL' : ' NOT NULL' ).
2915        ")\n" if $DEBUG > 2;
2916
2917   if ( $value eq '' && $nullable ) {
2918     'NULL';
2919   } elsif ( $value eq '' && $column_type =~ /^(int|numeric)/ ) {
2920     cluck "WARNING: Attempting to set non-null integer $table.$column null; ".
2921           "using 0 instead";
2922     0;
2923   } elsif ( $value =~ /^\d+(\.\d+)?$/ &&
2924             ! $column_type =~ /(char|binary|text)$/i ) {
2925     $value;
2926   } elsif (( $column_type =~ /^bytea$/i || $column_type =~ /(blob|varbinary)/i )
2927            && driver_name eq 'Pg'
2928           )
2929   {
2930     no strict 'subs';
2931 #    dbh->quote($value, { pg_type => PG_BYTEA() }); # doesn't work right
2932     # Pg binary string quoting: convert each character to 3-digit octal prefixed with \\,
2933     # single-quote the whole mess, and put an "E" in front.
2934     return ("E'" . join('', map { sprintf('\\\\%03o', ord($_)) } split(//, $value) ) . "'");
2935   } else {
2936     dbh->quote($value);
2937   }
2938 }
2939
2940 =item hfields TABLE
2941
2942 This is deprecated.  Don't use it.
2943
2944 It returns a hash-type list with the fields of this record's table set true.
2945
2946 =cut
2947
2948 sub hfields {
2949   carp "warning: hfields is deprecated";
2950   my($table)=@_;
2951   my(%hash);
2952   foreach (fields($table)) {
2953     $hash{$_}=1;
2954   }
2955   \%hash;
2956 }
2957
2958 sub _dump {
2959   my($self)=@_;
2960   join("\n", map {
2961     "$_: ". $self->getfield($_). "|"
2962   } (fields($self->table)) );
2963 }
2964
2965 sub DESTROY { return; }
2966
2967 #sub DESTROY {
2968 #  my $self = shift;
2969 #  #use Carp qw(cluck);
2970 #  #cluck "DESTROYING $self";
2971 #  warn "DESTROYING $self";
2972 #}
2973
2974 #sub is_tainted {
2975 #             return ! eval { join('',@_), kill 0; 1; };
2976 #         }
2977
2978 =item str2time_sql [ DRIVER_NAME ]
2979
2980 Returns a function to convert to unix time based on database type, such as
2981 "EXTRACT( EPOCH FROM" for Pg or "UNIX_TIMESTAMP(" for mysql.  See
2982 the str2time_sql_closing method to return a closing string rather than just
2983 using a closing parenthesis as previously suggested.
2984
2985 You can pass an optional driver name such as "Pg", "mysql" or
2986 $dbh->{Driver}->{Name} to return a function for that database instead of
2987 the current database.
2988
2989 =cut
2990
2991 sub str2time_sql {
2992   my $driver = shift || driver_name;
2993
2994   return 'UNIX_TIMESTAMP('      if $driver =~ /^mysql/i;
2995   return 'EXTRACT( EPOCH FROM ' if $driver =~ /^Pg/i;
2996
2997   warn "warning: unknown database type $driver; guessing how to convert ".
2998        "dates to UNIX timestamps";
2999   return 'EXTRACT(EPOCH FROM ';
3000
3001 }
3002
3003 =item str2time_sql_closing [ DRIVER_NAME ]
3004
3005 Returns the closing suffix of a function to convert to unix time based on
3006 database type, such as ")::integer" for Pg or ")" for mysql.
3007
3008 You can pass an optional driver name such as "Pg", "mysql" or
3009 $dbh->{Driver}->{Name} to return a function for that database instead of
3010 the current database.
3011
3012 =cut
3013
3014 sub str2time_sql_closing {
3015   my $driver = shift || driver_name;
3016
3017   return ' )::INTEGER ' if $driver =~ /^Pg/i;
3018   return ' ) ';
3019 }
3020
3021 =item regexp_sql [ DRIVER_NAME ]
3022
3023 Returns the operator to do a regular expression comparison based on database
3024 type, such as '~' for Pg or 'REGEXP' for mysql.
3025
3026 You can pass an optional driver name such as "Pg", "mysql" or
3027 $dbh->{Driver}->{Name} to return a function for that database instead of
3028 the current database.
3029
3030 =cut
3031
3032 sub regexp_sql {
3033   my $driver = shift || driver_name;
3034
3035   return '~'      if $driver =~ /^Pg/i;
3036   return 'REGEXP' if $driver =~ /^mysql/i;
3037
3038   die "don't know how to use regular expressions in ". driver_name." databases";
3039
3040 }
3041
3042 =item not_regexp_sql [ DRIVER_NAME ]
3043
3044 Returns the operator to do a regular expression negation based on database
3045 type, such as '!~' for Pg or 'NOT REGEXP' for mysql.
3046
3047 You can pass an optional driver name such as "Pg", "mysql" or
3048 $dbh->{Driver}->{Name} to return a function for that database instead of
3049 the current database.
3050
3051 =cut
3052
3053 sub not_regexp_sql {
3054   my $driver = shift || driver_name;
3055
3056   return '!~'         if $driver =~ /^Pg/i;
3057   return 'NOT REGEXP' if $driver =~ /^mysql/i;
3058
3059   die "don't know how to use regular expressions in ". driver_name." databases";
3060
3061 }
3062
3063 =item concat_sql [ DRIVER_NAME ] ITEMS_ARRAYREF
3064
3065 Returns the items concatenated based on database type, using "CONCAT()" for
3066 mysql and " || " for Pg and other databases.
3067
3068 You can pass an optional driver name such as "Pg", "mysql" or
3069 $dbh->{Driver}->{Name} to return a function for that database instead of
3070 the current database.
3071
3072 =cut
3073
3074 sub concat_sql {
3075   my $driver = ref($_[0]) ? driver_name : shift;
3076   my $items = shift;
3077
3078   if ( $driver =~ /^mysql/i ) {
3079     'CONCAT('. join(',', @$items). ')';
3080   } else {
3081     join('||', @$items);
3082   }
3083
3084 }
3085
3086 =item midnight_sql DATE
3087
3088 Returns an SQL expression to convert DATE (a unix timestamp) to midnight
3089 on that day in the system timezone, using the default driver name.
3090
3091 =cut
3092
3093 sub midnight_sql {
3094   my $driver = driver_name;
3095   my $expr = shift;
3096   if ( $driver =~ /^mysql/i ) {
3097     "UNIX_TIMESTAMP(DATE(FROM_UNIXTIME($expr)))";
3098   }
3099   else {
3100     "EXTRACT( EPOCH FROM DATE(TO_TIMESTAMP($expr)) )";
3101   }
3102 }
3103
3104 =back
3105
3106 =head1 BUGS
3107
3108 This module should probably be renamed, since much of the functionality is
3109 of general use.  It is not completely unlike Adapter::DBI (see below).
3110
3111 Exported qsearch and qsearchs should be deprecated in favor of method calls
3112 (against an FS::Record object like the old search and searchs that qsearch
3113 and qsearchs were on top of.)
3114
3115 The whole fields / hfields mess should be removed.
3116
3117 The various WHERE clauses should be subroutined.
3118
3119 table string should be deprecated in favor of DBIx::DBSchema::Table.
3120
3121 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
3122 true maps to the database (and WHERE clauses) would also help.
3123
3124 The ut_ methods should ask the dbdef for a default length.
3125
3126 ut_sqltype (like ut_varchar) should all be defined
3127
3128 A fallback check method should be provided which uses the dbdef.
3129
3130 The ut_money method assumes money has two decimal digits.
3131
3132 The Pg money kludge in the new method only strips `$'.
3133
3134 The ut_phonen method only checks US-style phone numbers.
3135
3136 The _quote function should probably use ut_float instead of a regex.
3137
3138 All the subroutines probably should be methods, here or elsewhere.
3139
3140 Probably should borrow/use some dbdef methods where appropriate (like sub
3141 fields)
3142
3143 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
3144 or allow it to be set.  Working around it is ugly any way around - DBI should
3145 be fixed.  (only affects RDBMS which return uppercase column names)
3146
3147 ut_zip should take an optional country like ut_phone.
3148
3149 =head1 SEE ALSO
3150
3151 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
3152
3153 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
3154
3155 http://poop.sf.net/
3156
3157 =cut
3158
3159 1;
3160