FS/FS/Record.pm

   1 package FS::Record;
   2
   3 use strict;
   4 use vars qw( $dbdef_file $dbdef $setup_hack $AUTOLOAD @ISA @EXPORT_OK $DEBUG
   5              $me %dbdef_cache %virtual_fields_cache );
   6 use subs qw(reload_dbdef);
   7 use Exporter;
   8 use Carp qw(carp cluck croak confess);
   9 use File::CounterFile;
  10 use Locale::Country;
  11 use DBI qw(:sql_types);
  12 use DBIx::DBSchema 0.21;
  13 use FS::UID qw(dbh getotaker datasrc driver_name);
  14 use FS::SearchCache;
  15 use FS::Msgcat qw(gettext);
  16
  17 use FS::part_virtual_field;
  18
  19 use Tie::IxHash;
  20
  21 @ISA = qw(Exporter);
  22 @EXPORT_OK = qw(dbh fields hfields qsearch qsearchs dbdef jsearch);
  23
  24 $DEBUG = 0;
  25 $me = '[FS::Record]';
  26
  27 #ask FS::UID to run this stuff for us later
  28 $FS::UID::callback{'FS::Record'} = sub {
  29   $File::CounterFile::DEFAULT_DIR = "/usr/local/etc/freeside/counters.". datasrc;
  30   $dbdef_file = "/usr/local/etc/freeside/dbdef.". datasrc;
  31   &reload_dbdef unless $setup_hack; #$setup_hack needed now?
  32 };
  33
  34 =head1 NAME
  35
  36 FS::Record - Database record objects
  37
  38 =head1 SYNOPSIS
  39
  40     use FS::Record;
  41     use FS::Record qw(dbh fields qsearch qsearchs dbdef);
  42
  43     $record = new FS::Record 'table', \%hash;
  44     $record = new FS::Record 'table', { 'column' => 'value', ... };
  45
  46     $record  = qsearchs FS::Record 'table', \%hash;
  47     $record  = qsearchs FS::Record 'table', { 'column' => 'value', ... };
  48     @records = qsearch  FS::Record 'table', \%hash;
  49     @records = qsearch  FS::Record 'table', { 'column' => 'value', ... };
  50
  51     $table = $record->table;
  52     $dbdef_table = $record->dbdef_table;
  53
  54     $value = $record->get('column');
  55     $value = $record->getfield('column');
  56     $value = $record->column;
  57
  58     $record->set( 'column' => 'value' );
  59     $record->setfield( 'column' => 'value' );
  60     $record->column('value');
  61
  62     %hash = $record->hash;
  63
  64     $hashref = $record->hashref;
  65
  66     $error = $record->insert;
  67
  68     $error = $record->delete;
  69
  70     $error = $new_record->replace($old_record);
  71
  72     # external use deprecated - handled by the database (at least for Pg, mysql)
  73     $value = $record->unique('column');
  74
  75     $error = $record->ut_float('column');
  76     $error = $record->ut_number('column');
  77     $error = $record->ut_numbern('column');
  78     $error = $record->ut_money('column');
  79     $error = $record->ut_text('column');
  80     $error = $record->ut_textn('column');
  81     $error = $record->ut_alpha('column');
  82     $error = $record->ut_alphan('column');
  83     $error = $record->ut_phonen('column');
  84     $error = $record->ut_anything('column');
  85     $error = $record->ut_name('column');
  86
  87     $dbdef = reload_dbdef;
  88     $dbdef = reload_dbdef "/non/standard/filename";
  89     $dbdef = dbdef;
  90
  91     $quoted_value = _quote($value,'table','field');
  92
  93     #deprecated
  94     $fields = hfields('table');
  95     if ( $fields->{Field} ) { # etc.
  96
  97     @fields = fields 'table'; #as a subroutine
  98     @fields = $record->fields; #as a method call
  99
 100
 101 =head1 DESCRIPTION
 102
 103 (Mostly) object-oriented interface to database records.  Records are currently
 104 implemented on top of DBI.  FS::Record is intended as a base class for
 105 table-specific classes to inherit from, i.e. FS::cust_main.
 106
 107 =head1 CONSTRUCTORS
 108
 109 =over 4
 110
 111 =item new [ TABLE, ] HASHREF
 112
 113 Creates a new record.  It doesn't store it in the database, though.  See
 114 L<"insert"> for that.
 115
 116 Note that the object stores this hash reference, not a distinct copy of the
 117 hash it points to.  You can ask the object for a copy with the I<hash>
 118 method.
 119
 120 TABLE can only be omitted when a dervived class overrides the table method.
 121
 122 =cut
 123
 124 sub new {
 125   my $proto = shift;
 126   my $class = ref($proto) || $proto;
 127   my $self = {};
 128   bless ($self, $class);
 129
 130   unless ( defined ( $self->table ) ) {
 131     $self->{'Table'} = shift;
 132     carp "warning: FS::Record::new called with table name ". $self->{'Table'};
 133   }
 134
 135   my $hashref = $self->{'Hash'} = shift;
 136
 137   foreach my $field ( grep !defined($hashref->{$_}), $self->fields ) {
 138     $hashref->{$field}='';
 139   }
 140
 141   $self->_cache($hashref, shift) if $self->can('_cache') && @_;
 142
 143   $self;
 144 }
 145
 146 sub new_or_cached {
 147   my $proto = shift;
 148   my $class = ref($proto) || $proto;
 149   my $self = {};
 150   bless ($self, $class);
 151
 152   $self->{'Table'} = shift unless defined ( $self->table );
 153
 154   my $hashref = $self->{'Hash'} = shift;
 155   my $cache = shift;
 156   if ( defined( $cache->cache->{$hashref->{$cache->key}} ) ) {
 157     my $obj = $cache->cache->{$hashref->{$cache->key}};
 158     $obj->_cache($hashref, $cache) if $obj->can('_cache');
 159     $obj;
 160   } else {
 161     $cache->cache->{$hashref->{$cache->key}} = $self->new($hashref, $cache);
 162   }
 163
 164 }
 165
 166 sub create {
 167   my $proto = shift;
 168   my $class = ref($proto) || $proto;
 169   my $self = {};
 170   bless ($self, $class);
 171   if ( defined $self->table ) {
 172     cluck "create constructor is deprecated, use new!";
 173     $self->new(@_);
 174   } else {
 175     croak "FS::Record::create called (not from a subclass)!";
 176   }
 177 }
 178
 179 =item qsearch TABLE, HASHREF, SELECT, EXTRA_SQL, CACHE_OBJ
 180
 181 Searches the database for all records matching (at least) the key/value pairs
 182 in HASHREF.  Returns all the records found as `FS::TABLE' objects if that
 183 module is loaded (i.e. via `use FS::cust_main;'), otherwise returns FS::Record
 184 objects.
 185
 186 ###oops, argh, FS::Record::new only lets us create database fields.
 187 #Normal behaviour if SELECT is not specified is `*', as in
 188 #C<SELECT * FROM table WHERE ...>.  However, there is an experimental new
 189 #feature where you can specify SELECT - remember, the objects returned,
 190 #although blessed into the appropriate `FS::TABLE' package, will only have the
 191 #fields you specify.  This might have unwanted results if you then go calling
 192 #regular FS::TABLE methods
 193 #on it.
 194
 195 =cut
 196
 197 sub qsearch {
 198   my($stable, $record, $select, $extra_sql, $cache ) = @_;
 199   #$stable =~ /^([\w\_]+)$/ or die "Illegal table: $table";
 200   #for jsearch
 201   $stable =~ /^([\w\s\(\)\.\,\=]+)$/ or die "Illegal table: $stable";
 202   $stable = $1;
 203   $select ||= '*';
 204   my $dbh = dbh;
 205
 206   my $table = $cache ? $cache->table : $stable;
 207   my $pkey = $dbdef->table($table)->primary_key;
 208
 209   my @real_fields = grep exists($record->{$_}), real_fields($table);
 210   my @virtual_fields = grep exists($record->{$_}), "FS::$table"->virtual_fields;
 211
 212   my $statement = "SELECT $select FROM $stable";
 213   if ( @real_fields or @virtual_fields ) {
 214     $statement .= ' WHERE '. join(' AND ',
 215       ( map {
 216
 217       my $op = '=';
 218       my $column = $_;
 219       if ( ref($record->{$_}) ) {
 220         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 221         #$op = 'LIKE' if $op =~ /^ILIKE$/i && driver_name ne 'Pg';
 222         if ( uc($op) eq 'ILIKE' ) {
 223           $op = 'LIKE';
 224           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 225           $column = "LOWER($_)";
 226         }
 227         $record->{$_} = $record->{$_}{'value'}
 228       }
 229
 230       if ( ! defined( $record->{$_} ) || $record->{$_} eq '' ) {
 231         if ( $op eq '=' ) {
 232           if ( driver_name eq 'Pg' ) {
 233             my $type = $dbdef->table($table)->column($column)->type;
 234             if ( $type =~ /(int|serial)/i ) {
 235               qq-( $column IS NULL )-;
 236             } else {
 237               qq-( $column IS NULL OR $column = '' )-;
 238             }
 239           } else {
 240             qq-( $column IS NULL OR $column = "" )-;
 241           }
 242         } elsif ( $op eq '!=' ) {
 243           if ( driver_name eq 'Pg' ) {
 244             my $type = $dbdef->table($table)->column($column)->type;
 245             if ( $type =~ /(int|serial)/i ) {
 246               qq-( $column IS NOT NULL )-;
 247             } else {
 248               qq-( $column IS NOT NULL AND $column != '' )-;
 249             }
 250           } else {
 251             qq-( $column IS NOT NULL AND $column != "" )-;
 252           }
 253         } else {
 254           if ( driver_name eq 'Pg' ) {
 255             qq-( $column $op '' )-;
 256           } else {
 257             qq-( $column $op "" )-;
 258           }
 259         }
 260       } else {
 261         "$column $op ?";
 262       }
 263     } @real_fields ),
 264     ( map {
 265       my $op = '=';
 266       my $column = $_;
 267       if ( ref($record->{$_}) ) {
 268         $op = $record->{$_}{'op'} if $record->{$_}{'op'};
 269         if ( uc($op) eq 'ILIKE' ) {
 270           $op = 'LIKE';
 271           $record->{$_}{'value'} = lc($record->{$_}{'value'});
 272           $column = "LOWER($_)";
 273         }
 274         $record->{$_} = $record->{$_}{'value'};
 275       }
 276
 277       # ... EXISTS ( SELECT name, value FROM part_virtual_field
 278       #              JOIN virtual_field
 279       #              ON part_virtual_field.vfieldpart = virtual_field.vfieldpart
 280       #              WHERE recnum = svc_acct.svcnum
 281       #              AND (name, value) = ('egad', 'brain') )
 282
 283       my $value = $record->{$_};
 284
 285       my $subq;
 286
 287       $subq = ($value ? 'EXISTS ' : 'NOT EXISTS ') .
 288       "( SELECT part_virtual_field.name, virtual_field.value ".
 289       "FROM part_virtual_field JOIN virtual_field ".
 290       "ON part_virtual_field.vfieldpart = virtual_field.vfieldpart ".
 291       "WHERE virtual_field.recnum = ${table}.${pkey} ".
 292       "AND part_virtual_field.name = '${column}'".
 293       ($value ?
 294         " AND virtual_field.value ${op} '${value}'"
 295       : "") . ")";
 296       $subq;
 297
 298     } @virtual_fields ) );
 299
 300   }
 301
 302   $statement .= " $extra_sql" if defined($extra_sql);
 303
 304   warn "[debug]$me $statement\n" if $DEBUG > 1;
 305   my $sth = $dbh->prepare($statement)
 306     or croak "$dbh->errstr doing $statement";
 307
 308   my $bind = 1;
 309
 310   foreach my $field (
 311     grep defined( $record->{$_} ) && $record->{$_} ne '', @real_fields
 312   ) {
 313     if ( $record->{$field} =~ /^\d+(\.\d+)?$/
 314          && $dbdef->table($table)->column($field)->type =~ /(int|serial)/i
 315     ) {
 316       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_INTEGER } );
 317     } else {
 318       $sth->bind_param($bind++, $record->{$field}, { TYPE => SQL_VARCHAR } );
 319     }
 320   }
 321
 322 #  $sth->execute( map $record->{$_},
 323 #    grep defined( $record->{$_} ) && $record->{$_} ne '', @fields
 324 #  ) or croak "Error executing \"$statement\": ". $sth->errstr;
 325
 326   $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 327
 328   my %result;
 329   tie %result, "Tie::IxHash";
 330   @virtual_fields = "FS::$table"->virtual_fields;
 331
 332   my @stuff = @{ $sth->fetchall_arrayref( {} ) };
 333   if($pkey) {
 334     %result = map { $_->{$pkey}, $_ } @stuff;
 335   } else {
 336     @result{@stuff} = @stuff;
 337   }
 338
 339   $sth->finish;
 340   if ( keys(%result) and @virtual_fields ) {
 341     $statement =
 342       "SELECT virtual_field.recnum, part_virtual_field.name, ".
 343              "virtual_field.value ".
 344       "FROM part_virtual_field JOIN virtual_field USING (vfieldpart) ".
 345       "WHERE part_virtual_field.dbtable = '$table' AND ".
 346       "virtual_field.recnum IN (".
 347       join(',', keys(%result)). ") AND part_virtual_field.name IN ('".
 348       join(q!', '!, @virtual_fields) . "')";
 349     warn "[debug]$me $statement\n" if $DEBUG > 1;
 350     $sth = $dbh->prepare($statement) or croak "$dbh->errstr doing $statement";
 351     $sth->execute or croak "Error executing \"$statement\": ". $sth->errstr;
 352
 353     foreach (@{ $sth->fetchall_arrayref({}) }) {
 354       my $recnum = $_->{recnum};
 355       my $name = $_->{name};
 356       my $value = $_->{value};
 357       if (exists($result{$recnum})) {
 358         $result{$recnum}->{$name} = $value;
 359       }
 360     }
 361   }
 362
 363   if ( eval 'scalar(@FS::'. $table. '::ISA);' ) {
 364     if ( eval 'FS::'. $table. '->can(\'new\')' eq \&new ) {
 365       #derivied class didn't override new method, so this optimization is safe
 366       if ( $cache ) {
 367         map {
 368           new_or_cached( "FS::$table", { %{$_} }, $cache )
 369         } values(%result);
 370       } else {
 371         map {
 372           new( "FS::$table", { %{$_} } )
 373         } values(%result);
 374       }
 375     } else {
 376       warn "untested code (class FS::$table uses custom new method)";
 377       map {
 378         eval 'FS::'. $table. '->new( { %{$_} } )';
 379       } values(%result);
 380     }
 381   } else {
 382     cluck "warning: FS::$table not loaded; returning FS::Record objects";
 383     map {
 384       FS::Record->new( $table, { %{$_} } );
 385     } values(%result);
 386   }
 387
 388 }
 389
 390 =item jsearch TABLE, HASHREF, SELECT, EXTRA_SQL, PRIMARY_TABLE, PRIMARY_KEY
 391
 392 Experimental JOINed search method.  Using this method, you can execute a
 393 single SELECT spanning multiple tables, and cache the results for subsequent
 394 method calls.  Interface will almost definately change in an incompatible
 395 fashion.
 396
 397 Arguments:
 398
 399 =cut
 400
 401 sub jsearch {
 402   my($table, $record, $select, $extra_sql, $ptable, $pkey ) = @_;
 403   my $cache = FS::SearchCache->new( $ptable, $pkey );
 404   my %saw;
 405   ( $cache,
 406     grep { !$saw{$_->getfield($pkey)}++ }
 407       qsearch($table, $record, $select, $extra_sql, $cache )
 408   );
 409 }
 410
 411 =item qsearchs TABLE, HASHREF
 412
 413 Same as qsearch, except that if more than one record matches, it B<carp>s but
 414 returns the first.  If this happens, you either made a logic error in asking
 415 for a single item, or your data is corrupted.
 416
 417 =cut
 418
 419 sub qsearchs { # $result_record = &FS::Record:qsearchs('table',\%hash);
 420   my $table = $_[0];
 421   my(@result) = qsearch(@_);
 422   carp "warning: Multiple records in scalar search ($table)"
 423     if scalar(@result) > 1;
 424   #should warn more vehemently if the search was on a primary key?
 425   scalar(@result) ? ($result[0]) : ();
 426 }
 427
 428 =back
 429
 430 =head1 METHODS
 431
 432 =over 4
 433
 434 =item table
 435
 436 Returns the table name.
 437
 438 =cut
 439
 440 sub table {
 441 #  cluck "warning: FS::Record::table deprecated; supply one in subclass!";
 442   my $self = shift;
 443   $self -> {'Table'};
 444 }
 445
 446 =item dbdef_table
 447
 448 Returns the DBIx::DBSchema::Table object for the table.
 449
 450 =cut
 451
 452 sub dbdef_table {
 453   my($self)=@_;
 454   my($table)=$self->table;
 455   $dbdef->table($table);
 456 }
 457
 458 =item get, getfield COLUMN
 459
 460 Returns the value of the column/field/key COLUMN.
 461
 462 =cut
 463
 464 sub get {
 465   my($self,$field) = @_;
 466   # to avoid "Use of unitialized value" errors
 467   if ( defined ( $self->{Hash}->{$field} ) ) {
 468     $self->{Hash}->{$field};
 469   } else {
 470     '';
 471   }
 472 }
 473 sub getfield {
 474   my $self = shift;
 475   $self->get(@_);
 476 }
 477
 478 =item set, setfield COLUMN, VALUE
 479
 480 Sets the value of the column/field/key COLUMN to VALUE.  Returns VALUE.
 481
 482 =cut
 483
 484 sub set {
 485   my($self,$field,$value) = @_;
 486   $self->{'Hash'}->{$field} = $value;
 487 }
 488 sub setfield {
 489   my $self = shift;
 490   $self->set(@_);
 491 }
 492
 493 =item AUTLOADED METHODS
 494
 495 $record->column is a synonym for $record->get('column');
 496
 497 $record->column('value') is a synonym for $record->set('column','value');
 498
 499 =cut
 500
 501 # readable/safe
 502 sub AUTOLOAD {
 503   my($self,$value)=@_;
 504   my($field)=$AUTOLOAD;
 505   $field =~ s/.*://;
 506   if ( defined($value) ) {
 507     confess "errant AUTOLOAD $field for $self (arg $value)"
 508       unless ref($self) && $self->can('setfield');
 509     $self->setfield($field,$value);
 510   } else {
 511     confess "errant AUTOLOAD $field for $self (no args)"
 512       unless ref($self) && $self->can('getfield');
 513     $self->getfield($field);
 514   }
 515 }
 516
 517 # efficient
 518 #sub AUTOLOAD {
 519 #  my $field = $AUTOLOAD;
 520 #  $field =~ s/.*://;
 521 #  if ( defined($_[1]) ) {
 522 #    $_[0]->setfield($field, $_[1]);
 523 #  } else {
 524 #    $_[0]->getfield($field);
 525 #  }
 526 #}
 527
 528 =item hash
 529
 530 Returns a list of the column/value pairs, usually for assigning to a new hash.
 531
 532 To make a distinct duplicate of an FS::Record object, you can do:
 533
 534     $new = new FS::Record ( $old->table, { $old->hash } );
 535
 536 =cut
 537
 538 sub hash {
 539   my($self) = @_;
 540   %{ $self->{'Hash'} };
 541 }
 542
 543 =item hashref
 544
 545 Returns a reference to the column/value hash.
 546
 547 =cut
 548
 549 sub hashref {
 550   my($self) = @_;
 551   $self->{'Hash'};
 552 }
 553
 554 =item insert
 555
 556 Inserts this record to the database.  If there is an error, returns the error,
 557 otherwise returns false.
 558
 559 =cut
 560
 561 sub insert {
 562   my $self = shift;
 563
 564   my $error = $self->check;
 565   return $error if $error;
 566
 567   #single-field unique keys are given a value if false
 568   #(like MySQL's AUTO_INCREMENT or Pg SERIAL)
 569   foreach ( $self->dbdef_table->unique->singles ) {
 570     $self->unique($_) unless $self->getfield($_);
 571   }
 572
 573   #and also the primary key, if the database isn't going to
 574   my $primary_key = $self->dbdef_table->primary_key;
 575   my $db_seq = 0;
 576   if ( $primary_key ) {
 577     my $col = $self->dbdef_table->column($primary_key);
 578
 579     $db_seq =
 580       uc($col->type) eq 'SERIAL'
 581       || ( driver_name eq 'Pg'
 582              && defined($col->default)
 583              && $col->default =~ /^nextval\(/i
 584          )
 585       || ( driver_name eq 'mysql'
 586              && defined($col->local)
 587              && $col->local =~ /AUTO_INCREMENT/i
 588          );
 589     $self->unique($primary_key) unless $self->getfield($primary_key) || $db_seq;
 590   }
 591
 592   my $table = $self->table;
 593   #false laziness w/delete
 594   my @real_fields =
 595     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 596     real_fields($table)
 597   ;
 598   my @values = map { _quote( $self->getfield($_), $table, $_) } @real_fields;
 599   #eslaf
 600
 601   my $statement = "INSERT INTO $table ( ".
 602       join( ', ', @real_fields ).
 603     ") VALUES (".
 604       join( ', ', @values ).
 605     ")"
 606   ;
 607   warn "[debug]$me $statement\n" if $DEBUG > 1;
 608   my $sth = dbh->prepare($statement) or return dbh->errstr;
 609
 610   local $SIG{HUP} = 'IGNORE';
 611   local $SIG{INT} = 'IGNORE';
 612   local $SIG{QUIT} = 'IGNORE';
 613   local $SIG{TERM} = 'IGNORE';
 614   local $SIG{TSTP} = 'IGNORE';
 615   local $SIG{PIPE} = 'IGNORE';
 616
 617   $sth->execute or return $sth->errstr;
 618
 619   my $insertid = '';
 620   if ( $db_seq ) { # get inserted id from the database, if applicable
 621     warn "[debug]$me retreiving sequence from database\n" if $DEBUG;
 622     if ( driver_name eq 'Pg' ) {
 623
 624       my $oid = $sth->{'pg_oid_status'};
 625       my $i_sql = "SELECT $primary_key FROM $table WHERE oid = ?";
 626       my $i_sth = dbh->prepare($i_sql) or do {
 627         dbh->rollback if $FS::UID::AutoCommit;
 628         return dbh->errstr;
 629       };
 630       $i_sth->execute($oid) or do {
 631         dbh->rollback if $FS::UID::AutoCommit;
 632         return $i_sth->errstr;
 633       };
 634       $insertid = $i_sth->fetchrow_arrayref->[0];
 635
 636     } elsif ( driver_name eq 'mysql' ) {
 637
 638       $insertid = dbh->{'mysql_insertid'};
 639       # work around mysql_insertid being null some of the time, ala RT :/
 640       unless ( $insertid ) {
 641         warn "WARNING: DBD::mysql didn't return mysql_insertid; ".
 642              "using SELECT LAST_INSERT_ID();";
 643         my $i_sql = "SELECT LAST_INSERT_ID()";
 644         my $i_sth = dbh->prepare($i_sql) or do {
 645           dbh->rollback if $FS::UID::AutoCommit;
 646           return dbh->errstr;
 647         };
 648         $i_sth->execute or do {
 649           dbh->rollback if $FS::UID::AutoCommit;
 650           return $i_sth->errstr;
 651         };
 652         $insertid = $i_sth->fetchrow_arrayref->[0];
 653       }
 654
 655     } else {
 656       dbh->rollback if $FS::UID::AutoCommit;
 657       return "don't know how to retreive inserted ids from ". driver_name.
 658              ", try using counterfiles (maybe run dbdef-create?)";
 659     }
 660     $self->setfield($primary_key, $insertid);
 661   }
 662
 663   my @virtual_fields =
 664       grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 665           $self->virtual_fields;
 666   if (@virtual_fields) {
 667     my %v_values = map { $_, $self->getfield($_) } @virtual_fields;
 668
 669     my $vfieldpart = $self->vfieldpart_hashref;
 670
 671     my $v_statement = "INSERT INTO virtual_field(recnum, vfieldpart, value) ".
 672                     "VALUES (?, ?, ?)";
 673
 674     my $v_sth = dbh->prepare($v_statement) or do {
 675       dbh->rollback if $FS::UID::AutoCommit;
 676       return dbh->errstr;
 677     };
 678
 679     foreach (keys(%v_values)) {
 680       $v_sth->execute($self->getfield($primary_key),
 681                       $vfieldpart->{$_},
 682                       $v_values{$_})
 683       or do {
 684         dbh->rollback if $FS::UID::AutoCommit;
 685         return $v_sth->errstr;
 686       };
 687     }
 688   }
 689
 690
 691   my $h_sth;
 692   if ( defined $dbdef->table('h_'. $table) ) {
 693     my $h_statement = $self->_h_statement('insert');
 694     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 695     $h_sth = dbh->prepare($h_statement) or do {
 696       dbh->rollback if $FS::UID::AutoCommit;
 697       return dbh->errstr;
 698     };
 699   } else {
 700     $h_sth = '';
 701   }
 702   $h_sth->execute or return $h_sth->errstr if $h_sth;
 703
 704   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 705
 706   '';
 707 }
 708
 709 =item add
 710
 711 Depriciated (use insert instead).
 712
 713 =cut
 714
 715 sub add {
 716   cluck "warning: FS::Record::add deprecated!";
 717   insert @_; #call method in this scope
 718 }
 719
 720 =item delete
 721
 722 Delete this record from the database.  If there is an error, returns the error,
 723 otherwise returns false.
 724
 725 =cut
 726
 727 sub delete {
 728   my $self = shift;
 729
 730   my $statement = "DELETE FROM ". $self->table. " WHERE ". join(' AND ',
 731     map {
 732       $self->getfield($_) eq ''
 733         #? "( $_ IS NULL OR $_ = \"\" )"
 734         ? ( driver_name eq 'Pg'
 735               ? "$_ IS NULL"
 736               : "( $_ IS NULL OR $_ = \"\" )"
 737           )
 738         : "$_ = ". _quote($self->getfield($_),$self->table,$_)
 739     } ( $self->dbdef_table->primary_key )
 740           ? ( $self->dbdef_table->primary_key)
 741           : real_fields($self->table)
 742   );
 743   warn "[debug]$me $statement\n" if $DEBUG > 1;
 744   my $sth = dbh->prepare($statement) or return dbh->errstr;
 745
 746   my $h_sth;
 747   if ( defined $dbdef->table('h_'. $self->table) ) {
 748     my $h_statement = $self->_h_statement('delete');
 749     warn "[debug]$me $h_statement\n" if $DEBUG > 2;
 750     $h_sth = dbh->prepare($h_statement) or return dbh->errstr;
 751   } else {
 752     $h_sth = '';
 753   }
 754
 755   my $primary_key = $self->dbdef_table->primary_key;
 756   my $v_sth;
 757   my @del_vfields;
 758   my $vfp = $self->vfieldpart_hashref;
 759   foreach($self->virtual_fields) {
 760     next if $self->getfield($_) eq '';
 761     unless(@del_vfields) {
 762       my $st = "DELETE FROM virtual_field WHERE recnum = ? AND vfieldpart = ?";
 763       $v_sth = dbh->prepare($st) or return dbh->errstr;
 764     }
 765     push @del_vfields, $_;
 766   }
 767
 768   local $SIG{HUP} = 'IGNORE';
 769   local $SIG{INT} = 'IGNORE';
 770   local $SIG{QUIT} = 'IGNORE';
 771   local $SIG{TERM} = 'IGNORE';
 772   local $SIG{TSTP} = 'IGNORE';
 773   local $SIG{PIPE} = 'IGNORE';
 774
 775   my $rc = $sth->execute or return $sth->errstr;
 776   #not portable #return "Record not found, statement:\n$statement" if $rc eq "0E0";
 777   $h_sth->execute or return $h_sth->errstr if $h_sth;
 778   $v_sth->execute($self->getfield($primary_key), $vfp->{$_})
 779     or return $v_sth->errstr
 780         foreach (@del_vfields);
 781
 782   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 783
 784   #no need to needlessly destoy the data either (causes problems actually)
 785   #undef $self; #no need to keep object!
 786
 787   '';
 788 }
 789
 790 =item del
 791
 792 Depriciated (use delete instead).
 793
 794 =cut
 795
 796 sub del {
 797   cluck "warning: FS::Record::del deprecated!";
 798   &delete(@_); #call method in this scope
 799 }
 800
 801 =item replace OLD_RECORD
 802
 803 Replace the OLD_RECORD with this one in the database.  If there is an error,
 804 returns the error, otherwise returns false.
 805
 806 =cut
 807
 808 sub replace {
 809   my ( $new, $old ) = ( shift, shift );
 810   warn "[debug]$me $new ->replace $old\n" if $DEBUG;
 811
 812   return "Records not in same table!" unless $new->table eq $old->table;
 813
 814   my $primary_key = $old->dbdef_table->primary_key;
 815   return "Can't change $primary_key"
 816     if $primary_key
 817        && ( $old->getfield($primary_key) ne $new->getfield($primary_key) );
 818
 819   my $error = $new->check;
 820   return $error if $error;
 821
 822   #my @diff = grep $new->getfield($_) ne $old->getfield($_), $old->fields;
 823   my %diff = map { ($new->getfield($_) ne $old->getfield($_))
 824                    ? ($_, $new->getfield($_)) : () } $old->fields;
 825
 826   unless ( keys(%diff) ) {
 827     carp "[warning]$me $new -> replace $old: records identical";
 828     return '';
 829   }
 830
 831   my $statement = "UPDATE ". $old->table. " SET ". join(', ',
 832     map {
 833       "$_ = ". _quote($new->getfield($_),$old->table,$_)
 834     } real_fields($old->table)
 835   ). ' WHERE '.
 836     join(' AND ',
 837       map {
 838         $old->getfield($_) eq ''
 839           #? "( $_ IS NULL OR $_ = \"\" )"
 840           ? ( driver_name eq 'Pg'
 841                 ? "( $_ IS NULL OR $_ = '' )"
 842                 : "( $_ IS NULL OR $_ = \"\" )"
 843             )
 844           : "$_ = ". _quote($old->getfield($_),$old->table,$_)
 845       } ( $primary_key ? ( $primary_key ) : real_fields($old->table) )
 846     )
 847   ;
 848   warn "[debug]$me $statement\n" if $DEBUG > 1;
 849   my $sth = dbh->prepare($statement) or return dbh->errstr;
 850
 851   my $h_old_sth;
 852   if ( defined $dbdef->table('h_'. $old->table) ) {
 853     my $h_old_statement = $old->_h_statement('replace_old');
 854     warn "[debug]$me $h_old_statement\n" if $DEBUG > 2;
 855     $h_old_sth = dbh->prepare($h_old_statement) or return dbh->errstr;
 856   } else {
 857     $h_old_sth = '';
 858   }
 859
 860   my $h_new_sth;
 861   if ( defined $dbdef->table('h_'. $new->table) ) {
 862     my $h_new_statement = $new->_h_statement('replace_new');
 863     warn "[debug]$me $h_new_statement\n" if $DEBUG > 2;
 864     $h_new_sth = dbh->prepare($h_new_statement) or return dbh->errstr;
 865   } else {
 866     $h_new_sth = '';
 867   }
 868
 869   # For virtual fields we have three cases with different SQL
 870   # statements: add, replace, delete
 871   my $v_add_sth;
 872   my $v_rep_sth;
 873   my $v_del_sth;
 874   my (@add_vfields, @rep_vfields, @del_vfields);
 875   my $vfp = $old->vfieldpart_hashref;
 876   foreach(grep { exists($diff{$_}) } $new->virtual_fields) {
 877     if($diff{$_} eq '') {
 878       # Delete
 879       unless(@del_vfields) {
 880         my $st = "DELETE FROM virtual_field WHERE recnum = ? ".
 881                  "AND vfieldpart = ?";
 882         warn "[debug]$me $st\n" if $DEBUG > 2;
 883         $v_del_sth = dbh->prepare($st) or return dbh->errstr;
 884       }
 885       push @del_vfields, $_;
 886     } elsif($old->getfield($_) eq '') {
 887       # Add
 888       unless(@add_vfields) {
 889         my $st = "INSERT INTO virtual_field (value, recnum, vfieldpart) ".
 890                  "VALUES (?, ?, ?)";
 891         warn "[debug]$me $st\n" if $DEBUG > 2;
 892         $v_add_sth = dbh->prepare($st) or return dbh->errstr;
 893       }
 894       push @add_vfields, $_;
 895     } else {
 896       # Replace
 897       unless(@rep_vfields) {
 898         my $st = "UPDATE virtual_field SET value = ? ".
 899                  "WHERE recnum = ? AND vfieldpart = ?";
 900         warn "[debug]$me $st\n" if $DEBUG > 2;
 901         $v_rep_sth = dbh->prepare($st) or return dbh->errstr;
 902       }
 903       push @rep_vfields, $_;
 904     }
 905   }
 906
 907   local $SIG{HUP} = 'IGNORE';
 908   local $SIG{INT} = 'IGNORE';
 909   local $SIG{QUIT} = 'IGNORE';
 910   local $SIG{TERM} = 'IGNORE';
 911   local $SIG{TSTP} = 'IGNORE';
 912   local $SIG{PIPE} = 'IGNORE';
 913
 914   my $rc = $sth->execute or return $sth->errstr;
 915   #not portable #return "Record not found (or records identical)." if $rc eq "0E0";
 916   $h_old_sth->execute or return $h_old_sth->errstr if $h_old_sth;
 917   $h_new_sth->execute or return $h_new_sth->errstr if $h_new_sth;
 918
 919   $v_del_sth->execute($old->getfield($primary_key),
 920                       $vfp->{$_})
 921         or return $v_del_sth->errstr
 922       foreach(@del_vfields);
 923
 924   $v_add_sth->execute($new->getfield($_),
 925                       $old->getfield($primary_key),
 926                       $vfp->{$_})
 927         or return $v_add_sth->errstr
 928       foreach(@add_vfields);
 929
 930   $v_rep_sth->execute($new->getfield($_),
 931                       $old->getfield($primary_key),
 932                       $vfp->{$_})
 933         or return $v_rep_sth->errstr
 934       foreach(@rep_vfields);
 935
 936   dbh->commit or croak dbh->errstr if $FS::UID::AutoCommit;
 937
 938   '';
 939
 940 }
 941
 942 =item rep
 943
 944 Depriciated (use replace instead).
 945
 946 =cut
 947
 948 sub rep {
 949   cluck "warning: FS::Record::rep deprecated!";
 950   replace @_; #call method in this scope
 951 }
 952
 953 =item check
 954
 955 Checks virtual fields (using check_blocks).  Subclasses should still provide
 956 a check method to validate real fields, foreign keys, etc., and call this
 957 method via $self->SUPER::check.
 958
 959 (FIXME: Should this method try to make sure that it I<is> being called from
 960 a subclass's check method, to keep the current semantics as far as possible?)
 961
 962 =cut
 963
 964 sub check {
 965   #confess "FS::Record::check not implemented; supply one in subclass!";
 966   my $self = shift;
 967
 968   foreach my $field ($self->virtual_fields) {
 969     for ($self->getfield($field)) {
 970       # See notes on check_block in FS::part_virtual_field.
 971       eval $self->pvf($field)->check_block;
 972       return $@ if $@;
 973       $self->setfield($field, $_);
 974     }
 975   }
 976   '';
 977 }
 978
 979 sub _h_statement {
 980   my( $self, $action ) = @_;
 981
 982   my @fields =
 983     grep defined($self->getfield($_)) && $self->getfield($_) ne "",
 984     real_fields($self->table);
 985   ;
 986   my @values = map { _quote( $self->getfield($_), $self->table, $_) } @fields;
 987
 988   "INSERT INTO h_". $self->table. " ( ".
 989       join(', ', qw(history_date history_user history_action), @fields ).
 990     ") VALUES (".
 991       join(', ', time, dbh->quote(getotaker()), dbh->quote($action), @values).
 992     ")"
 993   ;
 994 }
 995
 996 =item unique COLUMN
 997
 998 B<Warning>: External use is B<deprecated>.
 999
1000 Replaces COLUMN in record with a unique number, using counters in the
1001 filesystem.  Used by the B<insert> method on single-field unique columns
1002 (see L<DBIx::DBSchema::Table>) and also as a fallback for primary keys
1003 that aren't SERIAL (Pg) or AUTO_INCREMENT (mysql).
1004
1005 Returns the new value.
1006
1007 =cut
1008
1009 sub unique {
1010   my($self,$field) = @_;
1011   my($table)=$self->table;
1012
1013   croak "Unique called on field $field, but it is ",
1014         $self->getfield($field),
1015         ", not null!"
1016     if $self->getfield($field);
1017
1018   #warn "table $table is tainted" if is_tainted($table);
1019   #warn "field $field is tainted" if is_tainted($field);
1020
1021   my($counter) = new File::CounterFile "$table.$field",0;
1022 # hack for web demo
1023 #  getotaker() =~ /^([\w\-]{1,16})$/ or die "Illegal CGI REMOTE_USER!";
1024 #  my($user)=$1;
1025 #  my($counter) = new File::CounterFile "$user/$table.$field",0;
1026 # endhack
1027
1028   my $index = $counter->inc;
1029   $index = $counter->inc while qsearchs($table, { $field=>$index } );
1030
1031   $index =~ /^(\d*)$/;
1032   $index=$1;
1033
1034   $self->setfield($field,$index);
1035
1036 }
1037
1038 =item ut_float COLUMN
1039
1040 Check/untaint floating point numeric data: 1.1, 1, 1.1e10, 1e10.  May not be
1041 null.  If there is an error, returns the error, otherwise returns false.
1042
1043 =cut
1044
1045 sub ut_float {
1046   my($self,$field)=@_ ;
1047   ($self->getfield($field) =~ /^(\d+\.\d+)$/ ||
1048    $self->getfield($field) =~ /^(\d+)$/ ||
1049    $self->getfield($field) =~ /^(\d+\.\d+e\d+)$/ ||
1050    $self->getfield($field) =~ /^(\d+e\d+)$/)
1051     or return "Illegal or empty (float) $field: ". $self->getfield($field);
1052   $self->setfield($field,$1);
1053   '';
1054 }
1055
1056 =item ut_snumber COLUMN
1057
1058 Check/untaint signed numeric data (whole numbers).  May not be null.  If there
1059 is an error, returns the error, otherwise returns false.
1060
1061 =cut
1062
1063 sub ut_snumber {
1064   my($self, $field) = @_;
1065   $self->getfield($field) =~ /^(-?)\s*(\d+)$/
1066     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1067   $self->setfield($field, "$1$2");
1068   '';
1069 }
1070
1071 =item ut_number COLUMN
1072
1073 Check/untaint simple numeric data (whole numbers).  May not be null.  If there
1074 is an error, returns the error, otherwise returns false.
1075
1076 =cut
1077
1078 sub ut_number {
1079   my($self,$field)=@_;
1080   $self->getfield($field) =~ /^(\d+)$/
1081     or return "Illegal or empty (numeric) $field: ". $self->getfield($field);
1082   $self->setfield($field,$1);
1083   '';
1084 }
1085
1086 =item ut_numbern COLUMN
1087
1088 Check/untaint simple numeric data (whole numbers).  May be null.  If there is
1089 an error, returns the error, otherwise returns false.
1090
1091 =cut
1092
1093 sub ut_numbern {
1094   my($self,$field)=@_;
1095   $self->getfield($field) =~ /^(\d*)$/
1096     or return "Illegal (numeric) $field: ". $self->getfield($field);
1097   $self->setfield($field,$1);
1098   '';
1099 }
1100
1101 =item ut_money COLUMN
1102
1103 Check/untaint monetary numbers.  May be negative.  Set to 0 if null.  If there
1104 is an error, returns the error, otherwise returns false.
1105
1106 =cut
1107
1108 sub ut_money {
1109   my($self,$field)=@_;
1110   $self->setfield($field, 0) if $self->getfield($field) eq '';
1111   $self->getfield($field) =~ /^(\-)? ?(\d*)(\.\d{2})?$/
1112     or return "Illegal (money) $field: ". $self->getfield($field);
1113   #$self->setfield($field, "$1$2$3" || 0);
1114   $self->setfield($field, ( ($1||''). ($2||''). ($3||'') ) || 0);
1115   '';
1116 }
1117
1118 =item ut_text COLUMN
1119
1120 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1121 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? / =
1122 May not be null.  If there is an error, returns the error, otherwise returns
1123 false.
1124
1125 =cut
1126
1127 sub ut_text {
1128   my($self,$field)=@_;
1129   #warn "msgcat ". \&msgcat. "\n";
1130   #warn "notexist ". \&notexist. "\n";
1131   #warn "AUTOLOAD ". \&AUTOLOAD. "\n";
1132   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]+)$/
1133     or return gettext('illegal_or_empty_text'). " $field: ".
1134                $self->getfield($field);
1135   $self->setfield($field,$1);
1136   '';
1137 }
1138
1139 =item ut_textn COLUMN
1140
1141 Check/untaint text.  Alphanumerics, spaces, and the following punctuation
1142 symbols are currently permitted: ! @ # $ % & ( ) - + ; : ' " , . ? /
1143 May be null.  If there is an error, returns the error, otherwise returns false.
1144
1145 =cut
1146
1147 sub ut_textn {
1148   my($self,$field)=@_;
1149   $self->getfield($field) =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
1150     or return gettext('illegal_text'). " $field: ". $self->getfield($field);
1151   $self->setfield($field,$1);
1152   '';
1153 }
1154
1155 =item ut_alpha COLUMN
1156
1157 Check/untaint alphanumeric strings (no spaces).  May not be null.  If there is
1158 an error, returns the error, otherwise returns false.
1159
1160 =cut
1161
1162 sub ut_alpha {
1163   my($self,$field)=@_;
1164   $self->getfield($field) =~ /^(\w+)$/
1165     or return "Illegal or empty (alphanumeric) $field: ".
1166               $self->getfield($field);
1167   $self->setfield($field,$1);
1168   '';
1169 }
1170
1171 =item ut_alpha COLUMN
1172
1173 Check/untaint alphanumeric strings (no spaces).  May be null.  If there is an
1174 error, returns the error, otherwise returns false.
1175
1176 =cut
1177
1178 sub ut_alphan {
1179   my($self,$field)=@_;
1180   $self->getfield($field) =~ /^(\w*)$/
1181     or return "Illegal (alphanumeric) $field: ". $self->getfield($field);
1182   $self->setfield($field,$1);
1183   '';
1184 }
1185
1186 =item ut_phonen COLUMN [ COUNTRY ]
1187
1188 Check/untaint phone numbers.  May be null.  If there is an error, returns
1189 the error, otherwise returns false.
1190
1191 Takes an optional two-letter ISO country code; without it or with unsupported
1192 countries, ut_phonen simply calls ut_alphan.
1193
1194 =cut
1195
1196 sub ut_phonen {
1197   my( $self, $field, $country ) = @_;
1198   return $self->ut_alphan($field) unless defined $country;
1199   my $phonen = $self->getfield($field);
1200   if ( $phonen eq '' ) {
1201     $self->setfield($field,'');
1202   } elsif ( $country eq 'US' || $country eq 'CA' ) {
1203     $phonen =~ s/\D//g;
1204     $phonen =~ /^(\d{3})(\d{3})(\d{4})(\d*)$/
1205       or return gettext('illegal_phone'). " $field: ". $self->getfield($field);
1206     $phonen = "$1-$2-$3";
1207     $phonen .= " x$4" if $4;
1208     $self->setfield($field,$phonen);
1209   } else {
1210     warn "warning: don't know how to check phone numbers for country $country";
1211     return $self->ut_textn($field);
1212   }
1213   '';
1214 }
1215
1216 =item ut_ip COLUMN
1217
1218 Check/untaint ip addresses.  IPv4 only for now.
1219
1220 =cut
1221
1222 sub ut_ip {
1223   my( $self, $field ) = @_;
1224   $self->getfield($field) =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)$/
1225     or return "Illegal (IP address) $field: ". $self->getfield($field);
1226   for ( $1, $2, $3, $4 ) { return "Illegal (IP address) $field" if $_ > 255; }
1227   $self->setfield($field, "$1.$2.$3.$4");
1228   '';
1229 }
1230
1231 =item ut_ipn COLUMN
1232
1233 Check/untaint ip addresses.  IPv4 only for now.  May be null.
1234
1235 =cut
1236
1237 sub ut_ipn {
1238   my( $self, $field ) = @_;
1239   if ( $self->getfield($field) =~ /^()$/ ) {
1240     $self->setfield($field,'');
1241     '';
1242   } else {
1243     $self->ut_ip($field);
1244   }
1245 }
1246
1247 =item ut_domain COLUMN
1248
1249 Check/untaint host and domain names.
1250
1251 =cut
1252
1253 sub ut_domain {
1254   my( $self, $field ) = @_;
1255   #$self->getfield($field) =~/^(\w+\.)*\w+$/
1256   $self->getfield($field) =~/^(([\w\-]+\.)*\w+)$/
1257     or return "Illegal (domain) $field: ". $self->getfield($field);
1258   $self->setfield($field,$1);
1259   '';
1260 }
1261
1262 =item ut_name COLUMN
1263
1264 Check/untaint proper names; allows alphanumerics, spaces and the following
1265 punctuation: , . - '
1266
1267 May not be null.
1268
1269 =cut
1270
1271 sub ut_name {
1272   my( $self, $field ) = @_;
1273   $self->getfield($field) =~ /^([\w \,\.\-\']+)$/
1274     or return gettext('illegal_name'). " $field: ". $self->getfield($field);
1275   $self->setfield($field,$1);
1276   '';
1277 }
1278
1279 =item ut_zip COLUMN
1280
1281 Check/untaint zip codes.
1282
1283 =cut
1284
1285 sub ut_zip {
1286   my( $self, $field, $country ) = @_;
1287   if ( $country eq 'US' ) {
1288     $self->getfield($field) =~ /\s*(\d{5}(\-\d{4})?)\s*$/
1289       or return gettext('illegal_zip'). " $field for country $country: ".
1290                 $self->getfield($field);
1291     $self->setfield($field,$1);
1292   } else {
1293     $self->getfield($field) =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
1294       or return gettext('illegal_zip'). " $field: ". $self->getfield($field);
1295     $self->setfield($field,$1);
1296   }
1297   '';
1298 }
1299
1300 =item ut_country COLUMN
1301
1302 Check/untaint country codes.  Country names are changed to codes, if possible -
1303 see L<Locale::Country>.
1304
1305 =cut
1306
1307 sub ut_country {
1308   my( $self, $field ) = @_;
1309   unless ( $self->getfield($field) =~ /^(\w\w)$/ ) {
1310     if ( $self->getfield($field) =~ /^([\w \,\.\(\)\']+)$/
1311          && country2code($1) ) {
1312       $self->setfield($field,uc(country2code($1)));
1313     }
1314   }
1315   $self->getfield($field) =~ /^(\w\w)$/
1316     or return "Illegal (country) $field: ". $self->getfield($field);
1317   $self->setfield($field,uc($1));
1318   '';
1319 }
1320
1321 =item ut_anything COLUMN
1322
1323 Untaints arbitrary data.  Be careful.
1324
1325 =cut
1326
1327 sub ut_anything {
1328   my( $self, $field ) = @_;
1329   $self->getfield($field) =~ /^(.*)$/s
1330     or return "Illegal $field: ". $self->getfield($field);
1331   $self->setfield($field,$1);
1332   '';
1333 }
1334
1335 =item ut_enum COLUMN CHOICES_ARRAYREF
1336
1337 Check/untaint a column, supplying all possible choices, like the "enum" type.
1338
1339 =cut
1340
1341 sub ut_enum {
1342   my( $self, $field, $choices ) = @_;
1343   foreach my $choice ( @$choices ) {
1344     if ( $self->getfield($field) eq $choice ) {
1345       $self->setfield($choice);
1346       return '';
1347     }
1348   }
1349   return "Illegal (enum) field $field: ". $self->getfield($field);
1350 }
1351
1352 =item ut_foreign_key COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1353
1354 Check/untaint a foreign column key.  Call a regular ut_ method (like ut_number)
1355 on the column first.
1356
1357 =cut
1358
1359 sub ut_foreign_key {
1360   my( $self, $field, $table, $foreign ) = @_;
1361   qsearchs($table, { $foreign => $self->getfield($field) })
1362     or return "Can't find $field ". $self->getfield($field).
1363               " in $table.$foreign";
1364   '';
1365 }
1366
1367 =item ut_foreign_keyn COLUMN FOREIGN_TABLE FOREIGN_COLUMN
1368
1369 Like ut_foreign_key, except the null value is also allowed.
1370
1371 =cut
1372
1373 sub ut_foreign_keyn {
1374   my( $self, $field, $table, $foreign ) = @_;
1375   $self->getfield($field)
1376     ? $self->ut_foreign_key($field, $table, $foreign)
1377     : '';
1378 }
1379
1380
1381 =item virtual_fields [ TABLE ]
1382
1383 Returns a list of virtual fields defined for the table.  This should not
1384 be exported, and should only be called as an instance or class method.
1385
1386 =cut
1387
1388 sub virtual_fields {
1389   my $self = shift;
1390   my $table;
1391   $table = $self->table or confess "virtual_fields called on non-table";
1392
1393   confess "Unknown table $table" unless $dbdef->table($table);
1394
1395   return () unless $self->dbdef->table('part_virtual_field');
1396
1397   unless ( $virtual_fields_cache{$table} ) {
1398     my $query = 'SELECT name from part_virtual_field ' .
1399                 "WHERE dbtable = '$table'";
1400     my $dbh = dbh;
1401     my $result = $dbh->selectcol_arrayref($query);
1402     confess $dbh->errstr if $dbh->err;
1403     $virtual_fields_cache{$table} = $result;
1404   }
1405
1406   @{$virtual_fields_cache{$table}};
1407
1408 }
1409
1410
1411 =item fields [ TABLE ]
1412
1413 This is a wrapper for real_fields and virtual_fields.  Code that called
1414 fields before should probably continue to call fields.
1415
1416 =cut
1417
1418 sub fields {
1419   my $something = shift;
1420   my $table;
1421   if($something->isa('FS::Record')) {
1422     $table = $something->table;
1423   } else {
1424     $table = $something;
1425     $something = "FS::$table";
1426   }
1427   return (real_fields($table), $something->virtual_fields());
1428 }
1429
1430 =back
1431
1432 =item pvf FIELD_NAME
1433
1434 Returns the FS::part_virtual_field object corresponding to a field in the
1435 record (specified by FIELD_NAME).
1436
1437 =cut
1438
1439 sub pvf {
1440   my ($self, $name) = (shift, shift);
1441
1442   if(grep /^$name$/, $self->virtual_fields) {
1443     return qsearchs('part_virtual_field', { dbtable => $self->table,
1444                                             name    => $name } );
1445   }
1446   ''
1447 }
1448
1449 =head1 SUBROUTINES
1450
1451 =over 4
1452
1453 =item real_fields [ TABLE ]
1454
1455 Returns a list of the real columns in the specified table.  Called only by
1456 fields() and other subroutines elsewhere in FS::Record.
1457
1458 =cut
1459
1460 sub real_fields {
1461   my $table = shift;
1462
1463   my($table_obj) = $dbdef->table($table);
1464   confess "Unknown table $table" unless $table_obj;
1465   $table_obj->columns;
1466 }
1467
1468 =item reload_dbdef([FILENAME])
1469
1470 Load a database definition (see L<DBIx::DBSchema>), optionally from a
1471 non-default filename.  This command is executed at startup unless
1472 I<$FS::Record::setup_hack> is true.  Returns a DBIx::DBSchema object.
1473
1474 =cut
1475
1476 sub reload_dbdef {
1477   my $file = shift || $dbdef_file;
1478
1479   unless ( exists $dbdef_cache{$file} ) {
1480     warn "[debug]$me loading dbdef for $file\n" if $DEBUG;
1481     $dbdef_cache{$file} = DBIx::DBSchema->load( $file )
1482                             or die "can't load database schema from $file";
1483   } else {
1484     warn "[debug]$me re-using cached dbdef for $file\n" if $DEBUG;
1485   }
1486   $dbdef = $dbdef_cache{$file};
1487 }
1488
1489 =item dbdef
1490
1491 Returns the current database definition.  See L<DBIx::DBSchema>.
1492
1493 =cut
1494
1495 sub dbdef { $dbdef; }
1496
1497 =item _quote VALUE, TABLE, COLUMN
1498
1499 This is an internal function used to construct SQL statements.  It returns
1500 VALUE DBI-quoted (see L<DBI/"quote">) unless VALUE is a number and the column
1501 type (see L<DBIx::DBSchema::Column>) does not end in `char' or `binary'.
1502
1503 =cut
1504
1505 sub _quote {
1506   my($value, $table, $column) = @_;
1507   my $column_obj = $dbdef->table($table)->column($column);
1508   my $column_type = $column_obj->type;
1509
1510   if ( $value eq '' && $column_type =~ /^int/ ) {
1511     if ( $column_obj->null ) {
1512       'NULL';
1513     } else {
1514       cluck "WARNING: Attempting to set non-null integer $table.$column null; ".
1515             "using 0 instead";
1516       0;
1517     }
1518   } elsif ( $value =~ /^\d+(\.\d+)?$/ &&
1519             ! $column_type =~ /(char|binary|text)$/i ) {
1520     $value;
1521   } else {
1522     dbh->quote($value);
1523   }
1524 }
1525
1526 =item vfieldpart_hashref TABLE
1527
1528 Returns a hashref of virtual field names and vfieldparts applicable to the given
1529 TABLE.
1530
1531 =cut
1532
1533 sub vfieldpart_hashref {
1534   my $self = shift;
1535   my $table = $self->table;
1536
1537   return {} unless $self->dbdef->table('part_virtual_field');
1538
1539   my $dbh = dbh;
1540   my $statement = "SELECT vfieldpart, name FROM part_virtual_field WHERE ".
1541                   "dbtable = '$table'";
1542   my $sth = $dbh->prepare($statement);
1543   $sth->execute or croak "Execution of '$statement' failed: ".$dbh->errstr;
1544   return { map { $_->{name}, $_->{vfieldpart} }
1545     @{$sth->fetchall_arrayref({})} };
1546
1547 }
1548
1549
1550 =item hfields TABLE
1551
1552 This is deprecated.  Don't use it.
1553
1554 It returns a hash-type list with the fields of this record's table set true.
1555
1556 =cut
1557
1558 sub hfields {
1559   carp "warning: hfields is deprecated";
1560   my($table)=@_;
1561   my(%hash);
1562   foreach (fields($table)) {
1563     $hash{$_}=1;
1564   }
1565   \%hash;
1566 }
1567
1568 sub _dump {
1569   my($self)=@_;
1570   join("\n", map {
1571     "$_: ". $self->getfield($_). "|"
1572   } (fields($self->table)) );
1573 }
1574
1575 sub DESTROY { return; }
1576
1577 #sub DESTROY {
1578 #  my $self = shift;
1579 #  #use Carp qw(cluck);
1580 #  #cluck "DESTROYING $self";
1581 #  warn "DESTROYING $self";
1582 #}
1583
1584 #sub is_tainted {
1585 #             return ! eval { join('',@_), kill 0; 1; };
1586 #         }
1587
1588 =back
1589
1590 =head1 BUGS
1591
1592 This module should probably be renamed, since much of the functionality is
1593 of general use.  It is not completely unlike Adapter::DBI (see below).
1594
1595 Exported qsearch and qsearchs should be deprecated in favor of method calls
1596 (against an FS::Record object like the old search and searchs that qsearch
1597 and qsearchs were on top of.)
1598
1599 The whole fields / hfields mess should be removed.
1600
1601 The various WHERE clauses should be subroutined.
1602
1603 table string should be deprecated in favor of DBIx::DBSchema::Table.
1604
1605 No doubt we could benefit from a Tied hash.  Documenting how exists / defined
1606 true maps to the database (and WHERE clauses) would also help.
1607
1608 The ut_ methods should ask the dbdef for a default length.
1609
1610 ut_sqltype (like ut_varchar) should all be defined
1611
1612 A fallback check method should be provided which uses the dbdef.
1613
1614 The ut_money method assumes money has two decimal digits.
1615
1616 The Pg money kludge in the new method only strips `$'.
1617
1618 The ut_phonen method only checks US-style phone numbers.
1619
1620 The _quote function should probably use ut_float instead of a regex.
1621
1622 All the subroutines probably should be methods, here or elsewhere.
1623
1624 Probably should borrow/use some dbdef methods where appropriate (like sub
1625 fields)
1626
1627 As of 1.14, DBI fetchall_hashref( {} ) doesn't set fetchrow_hashref NAME_lc,
1628 or allow it to be set.  Working around it is ugly any way around - DBI should
1629 be fixed.  (only affects RDBMS which return uppercase column names)
1630
1631 ut_zip should take an optional country like ut_phone.
1632
1633 =head1 SEE ALSO
1634
1635 L<DBIx::DBSchema>, L<FS::UID>, L<DBI>
1636
1637 Adapter::DBI from Ch. 11 of Advanced Perl Programming by Sriram Srinivasan.
1638
1639 =cut
1640
1641 1;
1642