FS/FS/Msgcat.pm

   1 package FS::Msgcat;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $conf $def_locale $debug );
   5 use Exporter;
   6 use FS::UID;
   7 #use FS::Record qw( qsearchs ); # wtf?  won't import...
   8 use FS::Record;
   9 #use FS::Conf; #wtf?  causes dependency loops too.
  10 use FS::msgcat;
  11
  12 @ISA = qw(Exporter);
  13 @EXPORT_OK = qw( gettext geterror );
  14
  15 FS::UID->install_callback( sub {
  16   eval "use FS::Conf;";
  17   die $@ if $@;
  18   $conf = new FS::Conf;
  19   $def_locale = $conf->config('locale') || 'en_US';
  20   $debug = $conf->exists('show-msgcat-codes')
  21 });
  22
  23 =head1 NAME
  24
  25 FS::Msgcat - Message catalog functions
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Msgcat qw(gettext geterror);
  30
  31   #simple interface for retreiving messages...
  32   $message = gettext('msgcode');
  33   #or errors (includes the error code)
  34   $message = geterror('msgcode');
  35
  36 =head1 DESCRIPTION
  37
  38 FS::Msgcat provides functions to use the message catalog.  If you want to
  39 maintain the message catalog database, see L<FS::msgcat> instead.
  40
  41 =head1 SUBROUTINES
  42
  43 =over 4
  44
  45 =item gettext MSGCODE
  46
  47 Returns the full message for the supplied message code.
  48
  49 =cut
  50
  51 sub gettext {
  52   $debug ? geterror(@_) : _gettext(@_);
  53 }
  54
  55 #though i guess we don't really have to cache here since we do it in
  56 # FS::L10N::DBI
  57 our %cache;
  58
  59 sub _gettext {
  60   my $msgcode = shift;
  61   return '' unless defined($msgcode) && length($msgcode) > 0;
  62
  63   my $locale =  (@_ && shift)
  64              || $FS::CurrentUser::CurrentUser->locale
  65              || $def_locale;
  66
  67   return $cache{$locale}->{$msgcode} if exists $cache{$locale}->{$msgcode};
  68
  69   my $msgcat = FS::Record::qsearchs('msgcat', {
  70     'msgcode' => $msgcode,
  71     'locale'  => $locale,
  72   } );
  73   if ( $msgcat ) {
  74     $cache{$locale}->{$msgcode} = $msgcat->msg;
  75   } else {
  76     warn "WARNING: message for msgcode $msgcode in locale $locale not found"
  77       unless $locale eq 'en_US';
  78     $cache{$locale}->{$msgcode} = $msgcode;
  79
  80     my @translate_auto_insert = $conf->config('translate-auto-insert');
  81     if ( $locale ne 'en_US' && grep { $_ eq $locale } @translate_auto_insert ) {
  82
  83         # :(
  84         my $newmsgcat = new FS::Record('msgcat', { locale     => $locale,
  85                                          msgcode    => $msgcode,
  86                                          msg        => $msgcode,
  87                                        });
  88         warn "WARNING: auto-inserting message for msgcode $msgcode in locale $locale";
  89         $newmsgcat->insert;
  90     }
  91     return $msgcode;
  92   }
  93
  94 }
  95
  96 =item geterror MSGCODE
  97
  98 Returns the full message for the supplied message code, including the message
  99 code.
 100
 101 =cut
 102
 103 sub geterror {
 104   my $msgcode = shift;
 105   my $msg = _gettext($msgcode);
 106   if ( $msg eq $msgcode ) {
 107     my $locale = $FS::CurrentUser::CurrentUser->option('locale') || $def_locale;
 108     "Error code $msgcode (message for locale $locale not found)";
 109   } else {
 110     "$msg (error code $msgcode)";
 111   }
 112 }
 113
 114 =back
 115
 116 =head1 BUGS
 117
 118 i18n/l10n, eek
 119
 120 =head1 SEE ALSO
 121
 122 L<FS::Locales>, L<FS::msgcat>
 123
 124 =cut
 125
 126 1;
 127