FS/FS/Msgcat.pm

   1 package FS::Msgcat;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $conf $locale $debug );
   5 use Exporter;
   6 use FS::UID;
   7 #use FS::Record qw( qsearchs ); # wtf?  won't import...
   8 use FS::Record;
   9 #use FS::Conf; #wtf?  causes dependency loops too.
  10 use FS::msgcat;
  11
  12 @ISA = qw(Exporter);
  13 @EXPORT_OK = qw( gettext geterror );
  14
  15 FS::UID->install_callback( sub {
  16   eval "use FS::Conf;";
  17   die $@ if $@;
  18   $conf = new FS::Conf;
  19   $locale = $conf->config('locale') || 'en_US';
  20   $debug = $conf->exists('show-msgcat-codes')
  21 });
  22
  23 =head1 NAME
  24
  25 FS::Msgcat - Message catalog functions
  26
  27 =head1 SYNOPSIS
  28
  29   use FS::Msgcat qw(gettext geterror);
  30
  31   #simple interface for retreiving messages...
  32   $message = gettext('msgcode');
  33   #or errors (includes the error code)
  34   $message = geterror('msgcode');
  35
  36 =head1 DESCRIPTION
  37
  38 FS::Msgcat provides functions to use the message catalog.  If you want to
  39 maintain the message catalog database, see L<FS::msgcat> instead.
  40
  41 =head1 SUBROUTINES
  42
  43 =over 4
  44
  45 =item gettext MSGCODE
  46
  47 Returns the full message for the supplied message code.
  48
  49 =cut
  50
  51 sub gettext {
  52   $debug ? geterror(@_) : _gettext(@_);
  53 }
  54
  55 sub _gettext {
  56   my $msgcode = shift;
  57   my $msgcat = FS::Record::qsearchs('msgcat', {
  58     'msgcode' => $msgcode,
  59     'locale' => $locale
  60   } );
  61   if ( $msgcat ) {
  62     $msgcat->msg;
  63   } else {
  64     warn "WARNING: message for msgcode $msgcode in locale $locale not found";
  65     $msgcode;
  66   }
  67
  68 }
  69
  70 =item geterror MSGCODE
  71
  72 Returns the full message for the supplied message code, including the message
  73 code.
  74
  75 =cut
  76
  77 sub geterror {
  78   my $msgcode = shift;
  79   my $msg = _gettext($msgcode);
  80   if ( $msg eq $msgcode ) {
  81     "Error code $msgcode (message for locale $locale not found)";
  82   } else {
  83     "$msg (error code $msgcode)";
  84   }
  85 }
  86
  87 =back
  88
  89 =head1 BUGS
  90
  91 i18n/l10n, eek
  92
  93 =head1 SEE ALSO
  94
  95 L<FS::msgcat>, L<FS::Record>, schema.html from the base documentation.
  96
  97 =cut
  98
  99 1;
 100