FS/FS/Cron/tax_rate_update.pm

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 FS::Cron::tax_rate_update
   6
   7 =head1 DESCRIPTION
   8
   9 Cron routine to update city/district sales tax rates in I<cust_main_county>.
  10 Currently supports sales tax in the state of Washington.
  11
  12 =head2 wa_sales
  13
  14 =item Tax Rate Download
  15
  16 Once each month, update the tax tables from the WA DOR website.
  17
  18 =item Customer Address Rate Classification
  19
  20 Find cust_location rows in WA with no tax district.  Try to determine
  21 a tax district.  Otherwise, generate a log error that address needs
  22 to be correctd.
  23
  24 =cut
  25
  26 use strict;
  27 use warnings;
  28 use feature 'state';
  29
  30 use Exporter;
  31 our @EXPORT_OK = qw(
  32   tax_rate_update
  33   wa_sales_update_tax_table
  34   wa_sales_log_customer_without_tax_district
  35 );
  36
  37 use Carp qw(croak);
  38 use DateTime;
  39 use File::Temp 'tempdir';
  40 use File::Slurp qw(read_file write_file);
  41 use LWP::UserAgent;
  42 use Spreadsheet::XLSX;
  43 use Text::CSV;
  44
  45 use FS::Conf;
  46 use FS::cust_main;
  47 use FS::cust_main_county;
  48 use FS::geocode_Mixin;
  49 use FS::Log;
  50 use FS::part_pkg_taxclass;
  51 use FS::Record qw(qsearch qsearchs dbh);
  52 use FS::upgrade_journal;
  53
  54 our $DEBUG = 0;
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 tax_rate_update
  59
  60 Cron routine for freeside_daily.
  61
  62 Run one of the available cron functions based on conf value tax_district_method
  63
  64 =cut
  65
  66 sub tax_rate_update {
  67
  68   # Currently only wa_sales is supported
  69   my $tax_district_method = conf_tax_district_method();
  70
  71   return unless $tax_district_method;
  72
  73   if ( exists &{$tax_district_method} ) {
  74     my $func = \&{$tax_district_method};
  75     $func->();
  76   } else {
  77     my $log = FS::Log->new('tax_rate_update');
  78     $log->error( "Unhandled tax_district_method($tax_district_method)" );
  79   }
  80
  81 }
  82
  83 =head2 wa_sales
  84
  85 Monthly:   Update the complete WA state tax tables
  86 Every Run: Log errors for cust_location records without a district
  87
  88 =cut
  89
  90 sub wa_sales {
  91
  92   return
  93     unless conf_tax_district_method()
  94         && conf_tax_district_method() eq 'wa_sales';
  95
  96   my $dt_now  = DateTime->now;
  97   my $year    = $dt_now->year;
  98   my $quarter = $dt_now->quarter;
  99
 100   my $journal_label =
 101     sprintf 'wa_sales_update_tax_table_%sQ%s', $year, $quarter;
 102
 103   unless ( FS::upgrade_journal->is_done( $journal_label ) ) {
 104     local $@;
 105
 106     eval{ wa_sales_update_tax_table(); };
 107     log_error_and_die( "Error updating tax tables: $@" )
 108       if $@;
 109     FS::upgrade_journal->set_done( $journal_label );
 110   }
 111
 112   wa_sales_log_customer_without_tax_district();
 113
 114   '';
 115
 116 }
 117
 118 =head2 wa_sales_log_customer_without_tax_district
 119
 120 For any cust_location records
 121 * In WA state
 122 * Attached to non cancelled packages
 123 * With no tax district
 124
 125 Classify the tax district for the record using the WA State Dept of
 126 Revenue API.  If this fails, generate an error into system log so
 127 address can be corrected
 128
 129 =cut
 130
 131 sub wa_sales_log_customer_without_tax_district {
 132
 133   return
 134     unless conf_tax_district_method()
 135         && conf_tax_district_method() eq 'wa_sales';
 136
 137   my %qsearch_cust_location = (
 138     table => 'cust_location',
 139     select => '
 140       cust_location.locationnum,
 141       cust_location.custnum,
 142       cust_location.address1,
 143       cust_location.city,
 144       cust_location.state,
 145       cust_location.zip
 146     ',
 147     addl_from => '
 148       LEFT JOIN cust_main USING (custnum)
 149       LEFT JOIN cust_pkg ON cust_location.locationnum = cust_pkg.locationnum
 150     ',
 151     extra_sql => sprintf(q{
 152         WHERE cust_location.state = 'WA'
 153         AND (
 154              cust_location.district IS NULL
 155           or cust_location.district = ''
 156         )
 157         AND cust_pkg.pkgnum IS NOT NULL
 158         AND (
 159              cust_pkg.cancel > %s
 160           OR cust_pkg.cancel IS NULL
 161         )
 162       }, time()
 163     ),
 164   );
 165
 166   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 167     local $@;
 168     log_info_and_warn(
 169       sprintf
 170         'Attempting to classify district for cust_location ' .
 171         'locationnum(%s) address(%s)',
 172           $cust_location->locationnum,
 173           $cust_location->address1,
 174     );
 175
 176     eval {
 177       FS::geocode_Mixin::process_district_update(
 178         'FS::cust_location',
 179         $cust_location->locationnum
 180       );
 181     };
 182
 183     if ( $@ ) {
 184       # Error indicates a crash, not an error looking up district
 185       # process_district_udpate will generate log messages for those errors
 186       log_error_and_warn(
 187         sprintf "Classify district error for cust_location(%s): %s",
 188           $cust_location->locationnum,
 189           $@
 190       );
 191     }
 192
 193     sleep 1; # Be polite to WA DOR API
 194   }
 195
 196   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 197     log_error_and_warn(
 198       sprintf
 199         "Customer address in WA lacking tax district classification. ".
 200         "custnum(%s) ".
 201         "locationnum(%s) ".
 202         "address(%s, %s %s, %s) ".
 203         "[https://webgis.dor.wa.gov/taxratelookup/SalesTax.aspx]",
 204           map { $cust_location->$_ }
 205           qw( custnum locationnum address1 city state zip )
 206     );
 207   }
 208
 209 }
 210
 211
 212 =head2 wa_sales_update_tax_table \%args
 213
 214 Update city/district sales tax rates in L<FS::cust_main_county> from the
 215 Washington State Department of Revenue published data files.
 216
 217 Creates, or updates, a L<FS::cust_main_county> row for every tax district
 218 in Washington state. Some cities have different tax rates based on the
 219 address, within the city.  Because of this, some cities have multiple
 220 districts.
 221
 222 If tax classes are enabled, a row is created in every tax class for
 223 every district.
 224
 225 Customer addresses aren't classified into districts here.  Instead,
 226 when a Washington state address is inserted or changed in L<FS::cust_location>,
 227 a job is queued for FS::geocode_Mixin::process_district_update, to ask the
 228 Washington state API which tax district to use for this address.
 229
 230 All arguments are optional:
 231
 232   filename: Skip file download, and process the specified filename instead
 233
 234   taxname:  Updated or created records will be set to the given tax name.
 235             If not specified, conf value 'tax_district_taxname' is used
 236
 237   year:     Specify year for tax table download.  Defaults to current year
 238
 239   quarter:  Specify quarter for tax table download.  Defaults to current quarter
 240
 241 =head3 Washington State Department of Revenue Resources
 242
 243 The state of Washington makes data files available via their public website.
 244 It's possible the availability or format of these files may change.  As of now,
 245 the only data file that contains both city and county names is published in
 246 XLSX format.
 247
 248 =over 4
 249
 250 =item WA Dept of Revenue
 251
 252 https://dor.wa.gov
 253
 254 =item Data file downloads
 255
 256 https://dor.wa.gov/find-taxes-rates/sales-and-use-tax-rates/downloadable-database
 257
 258 =item XLSX file example
 259
 260 https://dor.wa.gov/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx/ExcelLocalSlsUserates_19_Q1.xlsx
 261
 262 =item CSV file example
 263
 264 https://dor.wa.gov/sites/default/files/legacy/downloads/Add_DataRates2018Q4.zip
 265
 266
 267 =item Address lookup API tool
 268
 269 http://webgis.dor.wa.gov/webapi/AddressRates.aspx?output=xml&addr=410 Terry Ave. North&city=&zip=98100
 270
 271 =back
 272
 273 =cut
 274
 275 sub wa_sales_update_tax_table {
 276   my $args = shift;
 277
 278   croak 'wa_sales_update_tax_table requires \$args hashref'
 279     if $args && !ref $args;
 280
 281   return
 282     unless conf_tax_district_method()
 283         && conf_tax_district_method() eq 'wa_sales';
 284
 285   $args->{taxname} ||= FS::Conf->new->config('tax_district_taxname');
 286   $args->{year}    ||= DateTime->now->year;
 287   $args->{quarter} ||= DateTime->now->quarter;
 288
 289   log_info_and_warn(
 290     "Begin wa_sales_update_tax_table() ".
 291     join ', ' => (
 292       map{ "$_ => ". ( $args->{$_} || 'undef' ) }
 293       sort keys %$args
 294     )
 295   );
 296
 297   $args->{temp_dir} ||= tempdir();
 298
 299   $args->{filename} ||= wa_sales_fetch_xlsx_file( $args );
 300
 301   $args->{tax_districts} = wa_sales_parse_xlsx_file( $args );
 302
 303   wa_sales_update_cust_main_county( $args );
 304
 305   log_info_and_warn( 'Finished wa_sales_update_tax_table()' );
 306 }
 307
 308 =head2 wa_sales_update_cust_main_county \%args
 309
 310 Create or update the L<FS::cust_main_county> records with new data
 311
 312 =cut
 313
 314 sub wa_sales_update_cust_main_county {
 315   my $args = shift;
 316
 317   return
 318     unless conf_tax_district_method()
 319         && conf_tax_district_method() eq 'wa_sales';
 320
 321   croak 'wa_sales_update_cust_main_county requires $args hashref'
 322     unless ref $args
 323         && ref $args->{tax_districts};
 324
 325   my $insert_count = 0;
 326   my $update_count = 0;
 327   my $same_count   = 0;
 328
 329   # Work within a SQL transaction
 330   local $FS::UID::AutoCommit = 0;
 331
 332   for my $taxclass ( FS::part_pkg_taxclass->taxclass_names ) {
 333     $taxclass ||= undef; # trap empty string when taxclasses are disabled
 334
 335     # Dupe detection/remediation:
 336     #
 337     # Previous code for washington state tax district was creating
 338     # duplicate entries for tax districts.  This could lead to customers
 339     # being double-taxed
 340     #
 341     # The following code detects and eliminates duplicates that
 342     # were created by wa_sales district code (source=wa_sales)
 343     # before updating the tax table with the newly downloaded
 344     # data
 345
 346     my %cust_main_county;
 347     my %cust_main_county_dupe;
 348
 349     for my $row (
 350       qsearch(
 351         cust_main_county => {
 352           source    => 'wa_sales',
 353           district  => { op => '!=', value => undef },
 354           tax_class => $taxclass,
 355         }
 356       )
 357     ) {
 358       my $district = $row->district;
 359
 360       # Row belongs to a known dupe group of districts
 361       if ( $cust_main_county_dupe{$district} ) {
 362         push @{ $cust_main_county_dupe{$district} }, $row;
 363         next;
 364       }
 365
 366       # Row is the first seen dupe for the given district
 367       if ( $cust_main_county{$district} ) {
 368         $cust_main_county_dupe{$district} = [
 369           delete $cust_main_county{$district},
 370           $row
 371         ];
 372         next;
 373       }
 374
 375       # Row is the first seen with this district
 376       $cust_main_county{$district} = $row;
 377     }
 378
 379     # Merge any dupes, place resulting non-dupe row in %cust_main_county
 380     #  Merge, even if one of the dupes has a $0 tax, or some other
 381     #  variation on tax row data.  Data for this row will get corrected
 382     #  during the following tax import
 383     for my $dupe_district_aref ( values %cust_main_county_dupe ) {
 384       my $row_to_keep = shift @$dupe_district_aref;
 385       while ( my $row_to_merge = shift @$dupe_district_aref ) {
 386         $row_to_merge->_merge_into(
 387           $row_to_keep,
 388           { identical_record_check => 0 },
 389         );
 390       }
 391       $cust_main_county{$row_to_keep->district} = $row_to_keep;
 392     }
 393
 394     for my $district ( @{ $args->{tax_districts} } ) {
 395       if ( my $row = $cust_main_county{ $district->{district} } ) {
 396
 397         # District already exists in this taxclass, update if necessary
 398         #
 399         # If admin updates value of conf tax_district_taxname, instead of
 400         # creating an entire separate set of tax rows with
 401         # the new taxname, update the taxname on existing records
 402
 403         {
 404           # Supress warning on taxname comparison, when taxname is undef
 405           no warnings 'uninitialized';
 406
 407           if (
 408             $row->tax == ( $district->{tax_combined} * 100 )
 409             &&    $row->taxname eq    $args->{taxname}
 410             && uc $row->county  eq uc $district->{county}
 411             && uc $row->city    eq uc $district->{city}
 412           ) {
 413             $same_count++;
 414             next;
 415           }
 416         }
 417
 418         $row->city( uc $district->{city} );
 419         $row->county( uc $district->{county} );
 420         $row->taxclass( $taxclass );
 421         $row->taxname( $args->{taxname} || undef );
 422         $row->tax( $district->{tax_combined} * 100 );
 423
 424         if ( my $error = $row->replace ) {
 425           dbh->rollback;
 426           local $FS::UID::AutoCommit = 1;
 427           log_error_and_die(
 428             sprintf
 429               "Error updating cust_main_county row %s for district %s: %s",
 430               $row->taxnum,
 431               $district->{district},
 432               $error
 433           );
 434         }
 435
 436         $update_count++;
 437
 438       } else {
 439
 440         # District doesn't exist, create row
 441
 442         my $row = FS::cust_main_county->new({
 443           district => $district->{district},
 444           city     => uc $district->{city},
 445           county   => uc $district->{county},
 446           state    => 'WA',
 447           country  => 'US',
 448           taxclass => $taxclass,
 449           taxname  => $args->{taxname} || undef,
 450           tax      => $district->{tax_combined} * 100,
 451           source   => 'wa_sales',
 452         });
 453
 454         if ( my $error = $row->insert ) {
 455           dbh->rollback;
 456           local $FS::UID::AutoCommit = 1;
 457           log_error_and_die(
 458             sprintf
 459               "Error inserting cust_main_county row for district %s: %s",
 460               $district->{district},
 461               $error
 462           );
 463         }
 464
 465         $cust_main_county{ $district->{district} } = $row;
 466         $insert_count++;
 467       }
 468
 469     } # /foreach $district
 470   } # /foreach $taxclass
 471
 472   dbh->commit;
 473
 474   local $FS::UID::AutoCommit = 1;
 475   log_info_and_warn(
 476     sprintf
 477       "WA tax table update completed. ".
 478       "Inserted %s rows, updated %s rows, identical %s rows",
 479       $insert_count,
 480       $update_count,
 481       $same_count
 482   );
 483
 484 }
 485
 486 =head2 wa_sales_parse_xlsx_file \%args
 487
 488 Parse given XLSX file for tax district information
 489 Return an arrayref of district information hashrefs
 490
 491 =cut
 492
 493 sub wa_sales_parse_xlsx_file {
 494   my $args = shift;
 495
 496   croak 'wa_sales_parse_xlsx_file requires $args hashref containing a filename'
 497     unless ref $args
 498         && $args->{filename};
 499
 500   # About the file format:
 501   #
 502   # The current spreadsheet contains the following @columns.
 503   # Rows 1 and 2 are a marquee header
 504   # Row 3 is the column labels.  We will test these to detect
 505   #   changes in the data format
 506   # Rows 4+ are the tax district data
 507   #
 508   # The "city" column is being parsed from "Location"
 509
 510   my @columns = qw( city county district tax_local tax_state tax_combined );
 511
 512   log_error_and_die( "Unable to access XLSX file: $args->{filename}" )
 513     unless -r $args->{filename};
 514
 515   my $xls_parser = Spreadsheet::XLSX->new( $args->{filename} )
 516     or log_error_and_die( "Error parsing XLSX file: $!" );
 517
 518   my $sheet = $xls_parser->{Worksheet}->[0]
 519     or log_error_and_die(" Unable to access worksheet 1 in XLSX file" );
 520
 521   my $cells = $sheet->{Cells}
 522     or log_error_and_die( "Unable to read cells in XLSX file" );
 523
 524   # Read the column labels and verify
 525   my %labels =
 526     map{ $columns[$_] => $cells->[2][$_]->{Val} }
 527     0 .. scalar(@columns)-1;
 528
 529   my %expected_labels = (
 530     city         => 'Location',
 531     county       => 'County',
 532     district     => 'Location Code',
 533     tax_local    => 'Local Rate',
 534     tax_state    => 'State Rate',
 535     tax_combined => 'Combined Sales Tax',
 536   );
 537
 538   if (
 539     my @error_labels =
 540       grep { lc $labels{$_} ne lc $expected_labels{$_} }
 541       @columns
 542   ) {
 543     my $error = "Error parsing XLS file - ".
 544                 "Data format may have been updated with WA DOR! ";
 545     $error .= "Expected column $expected_labels{$_}, found $labels{$_}! "
 546       for @error_labels;
 547     log_error_and_die( $error );
 548   }
 549
 550   # Parse the rows into an array of hashes
 551   my @districts;
 552   for my $row ( 3..$sheet->{MaxRow} ) {
 553     my %district = (
 554       map { $columns[$_] => $cells->[$row][$_]->{Val} }
 555       0 .. scalar(@columns)-1
 556     );
 557
 558     if (
 559          $district{city}
 560       && $district{county}
 561       && $district{district}     =~ /^\d+$/
 562       && $district{tax_local}    =~ /^\d?\.\d+$/
 563       && $district{tax_state}    =~ /^\d?\.\d+$/
 564       && $district{tax_combined} =~ /^\d?\.\d+$/
 565     ) {
 566
 567       # For some reason, city may contain line breaks!
 568       $district{city} =~ s/[\r\n]//g;
 569
 570       push @districts, \%district;
 571     } else {
 572       log_warn_and_warn(
 573         "Non-usable row found in spreadsheet:\n" . Dumper( \%district )
 574       );
 575     }
 576
 577   }
 578
 579   log_error_and_die( "No \@districts found in data file!" )
 580     unless @districts;
 581
 582   log_info_and_warn(
 583     sprintf "Parsed %s districts from data file", scalar @districts
 584   );
 585
 586   \@districts;
 587
 588 }
 589
 590 =head2 wa_sales_fetch_xlsx_file \%args
 591
 592 Download data file from WA state DOR to temporary storage,
 593 return filename
 594
 595 =cut
 596
 597 sub wa_sales_fetch_xlsx_file {
 598   my $args = shift;
 599
 600   return
 601     unless conf_tax_district_method()
 602         && conf_tax_district_method() eq 'wa_sales';
 603
 604   croak 'wa_sales_fetch_xlsx_file requires \$args hashref'
 605     unless ref $args
 606         && $args->{temp_dir};
 607
 608   my $url_base = 'https://dor.wa.gov'.
 609                  '/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx';
 610
 611   my $year    = $args->{year}    || DateTime->now->year;
 612   my $quarter = $args->{quarter} || DateTime->now->quarter;
 613   $year = substr( $year, 2, 2 ) if $year >= 1000;
 614
 615   my $fn = sprintf( 'ExcelLocalSlsUserates_%s_Q%s.xlsx', $year, $quarter );
 616   my $url = "$url_base/$fn";
 617
 618   my $write_fn = "$args->{temp_dir}/$fn";
 619
 620   log_info_and_warn( "Begin download from url: $url" );
 621
 622   my $ua = LWP::UserAgent->new;
 623   my $res = $ua->get( $url );
 624
 625   log_error_and_die( "Download error: ".$res->status_line )
 626     unless $res->is_success;
 627
 628   local $@;
 629   eval { write_file( $write_fn, $res->decoded_content ); };
 630   log_error_and_die( "Problem writing download to disk: $@" )
 631     if $@;
 632
 633   log_info_and_warn( "Temporary file: $write_fn" );
 634   $write_fn;
 635
 636 }
 637
 638 sub log {
 639   state $log = FS::Log->new('tax_rate_update');
 640   $log;
 641 }
 642
 643 sub log_info_and_warn {
 644   my $log_message = shift;
 645   warn "$log_message\n";
 646   &log()->info( $log_message );
 647 }
 648
 649 sub log_warn_and_warn {
 650   my $log_message = shift;
 651   warn "$log_message\n";
 652   &log()->warn( $log_message );
 653 }
 654
 655 sub log_error_and_die {
 656   my $log_message = shift;
 657   &log()->error( $log_message );
 658   die( "$log_message\n" );
 659 }
 660
 661 sub log_error_and_warn {
 662   my $log_message = shift;
 663   warn "$log_message\n";
 664   &log()->error( $log_message );
 665 }
 666
 667 sub conf_tax_district_method {
 668   state $tax_district_method = FS::Conf->new->config('tax_district_method');
 669   $tax_district_method;
 670 }
 671
 672
 673 1;