FS/FS/Cron/tax_rate_update.pm

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 FS::Cron::tax_rate_update
   6
   7 =head1 DESCRIPTION
   8
   9 Cron routine to update city/district sales tax rates in I<cust_main_county>.
  10 Currently supports sales tax in the state of Washington.
  11
  12 =head2 wa_sales
  13
  14 =item Tax Rate Download
  15
  16 Once each month, update the tax tables from the WA DOR website.
  17
  18 =item Customer Address Rate Classification
  19
  20 Find cust_location rows in WA with no tax district.  Try to determine
  21 a tax district.  Otherwise, generate a log error that address needs
  22 to be correctd.
  23
  24 =cut
  25
  26 use strict;
  27 use warnings;
  28 use feature 'state';
  29
  30 use Exporter;
  31 our @EXPORT_OK = qw(
  32   tax_rate_update
  33   wa_sales_update_tax_table
  34   wa_sales_log_customer_without_tax_district
  35 );
  36
  37 use Carp qw(croak);
  38 use DateTime;
  39 use File::Temp 'tempdir';
  40 use File::Slurp qw(read_file write_file);
  41 use LWP::UserAgent;
  42 use Spreadsheet::XLSX;
  43 use Text::CSV;
  44
  45 use FS::Conf;
  46 use FS::cust_main;
  47 use FS::cust_main_county;
  48 use FS::geocode_Mixin;
  49 use FS::Log;
  50 use FS::part_pkg_taxclass;
  51 use FS::Record qw(qsearch qsearchs dbh);
  52 use FS::upgrade_journal;
  53
  54 our $DEBUG = 0;
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 tax_rate_update
  59
  60 Cron routine for freeside_daily.
  61
  62 Run one of the available cron functions based on conf value tax_district_method
  63
  64 =cut
  65
  66 sub tax_rate_update {
  67
  68   # Currently only wa_sales is supported
  69   my $tax_district_method = conf_tax_district_method();
  70
  71   return unless $tax_district_method;
  72
  73   if ( exists &{$tax_district_method} ) {
  74     my $func = \&{$tax_district_method};
  75     $func->();
  76   } else {
  77     my $log = FS::Log->new('tax_rate_update');
  78     $log->error( "Unhandled tax_district_method($tax_district_method)" );
  79   }
  80
  81 }
  82
  83 =head2 wa_sales
  84
  85 Monthly:   Update the complete WA state tax tables
  86 Every Run: Log errors for cust_location records without a district
  87
  88 =cut
  89
  90 sub wa_sales {
  91
  92   return
  93     unless conf_tax_district_method()
  94         && conf_tax_district_method() eq 'wa_sales';
  95
  96   my $dt_now  = DateTime->now;
  97   my $year    = $dt_now->year;
  98   my $quarter = $dt_now->quarter;
  99
 100   my $journal_label =
 101     sprintf 'wa_sales_update_tax_table_%sQ%s', $year, $quarter;
 102
 103   unless ( FS::upgrade_journal->is_done( $journal_label ) ) {
 104     local $@;
 105
 106     eval{ wa_sales_update_tax_table(); };
 107     log_error_and_die( "Error updating tax tables: $@" )
 108       if $@;
 109     FS::upgrade_journal->set_done( $journal_label );
 110   }
 111
 112   wa_sales_log_customer_without_tax_district();
 113
 114   '';
 115
 116 }
 117
 118 =head2 wa_sales_log_customer_without_tax_district
 119
 120 For any cust_location records
 121 * In WA state
 122 * Attached to non cancelled packages
 123 * With no tax district
 124
 125 Classify the tax district for the record using the WA State Dept of
 126 Revenue API.  If this fails, generate an error into system log so
 127 address can be corrected
 128
 129 =cut
 130
 131 sub wa_sales_log_customer_without_tax_district {
 132
 133   return
 134     unless conf_tax_district_method()
 135         && conf_tax_district_method() eq 'wa_sales';
 136
 137   my %qsearch_cust_location = (
 138     table => 'cust_location',
 139     select => '
 140       cust_location.locationnum,
 141       cust_location.custnum,
 142       cust_location.address1,
 143       cust_location.city,
 144       cust_location.state,
 145       cust_location.zip
 146     ',
 147     addl_from => '
 148       LEFT JOIN cust_main USING (custnum)
 149       LEFT JOIN cust_pkg ON cust_location.locationnum = cust_pkg.locationnum
 150     ',
 151     extra_sql => sprintf(q{
 152         WHERE cust_location.state = 'WA'
 153         AND (
 154              cust_location.district IS NULL
 155           or cust_location.district = ''
 156         )
 157         AND cust_pkg.pkgnum IS NOT NULL
 158         AND (
 159              cust_pkg.cancel > %s
 160           OR cust_pkg.cancel IS NULL
 161         )
 162       }, time()
 163     ),
 164   );
 165
 166   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 167     local $@;
 168     log_info_and_warn(
 169       sprintf
 170         'Attempting to classify district for cust_location ' .
 171         'locationnum(%s) address(%s)',
 172           $cust_location->locationnum,
 173           $cust_location->address1,
 174     );
 175
 176     eval {
 177       FS::geocode_Mixin::process_district_update(
 178         'FS::cust_location',
 179         $cust_location->locationnum
 180       );
 181     };
 182
 183     if ( $@ ) {
 184       # Error indicates a crash, not an error looking up district
 185       # process_district_udpate will generate log messages for those errors
 186       log_error_and_warn(
 187         sprintf "Classify district error for cust_location(%s): %s",
 188           $cust_location->locationnum,
 189           $@
 190       );
 191     }
 192
 193     sleep 1; # Be polite to WA DOR API
 194   }
 195
 196   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 197     log_error_and_warn(
 198       sprintf
 199         "Customer address in WA lacking tax district classification. ".
 200         "custnum(%s) ".
 201         "locationnum(%s) ".
 202         "address(%s, %s %s, %s) ".
 203         "[https://webgis.dor.wa.gov/taxratelookup/SalesTax.aspx]",
 204           map { $cust_location->$_ }
 205           qw( custnum locationnum address1 city state zip )
 206     );
 207   }
 208
 209 }
 210
 211
 212 =head2 wa_sales_update_tax_table \%args
 213
 214 Update city/district sales tax rates in L<FS::cust_main_county> from the
 215 Washington State Department of Revenue published data files.
 216
 217 Creates, or updates, a L<FS::cust_main_county> row for every tax district
 218 in Washington state. Some cities have different tax rates based on the
 219 address, within the city.  Because of this, some cities have multiple
 220 districts.
 221
 222 If tax classes are enabled, a row is created in every tax class for
 223 every district.
 224
 225 Customer addresses aren't classified into districts here.  Instead,
 226 when a Washington state address is inserted or changed in L<FS::cust_location>,
 227 a job is queued for FS::geocode_Mixin::process_district_update, to ask the
 228 Washington state API which tax district to use for this address.
 229
 230 All arguments are optional:
 231
 232   filename: Skip file download, and process the specified filename instead
 233
 234   taxname:  Updated or created records will be set to the given tax name.
 235             If not specified, conf value 'tax_district_taxname' is used
 236
 237   year:     Specify year for tax table download.  Defaults to current year
 238
 239   quarter:  Specify quarter for tax table download.  Defaults to current quarter
 240
 241 =head3 Washington State Department of Revenue Resources
 242
 243 The state of Washington makes data files available via their public website.
 244 It's possible the availability or format of these files may change.  As of now,
 245 the only data file that contains both city and county names is published in
 246 XLSX format.
 247
 248 =over 4
 249
 250 =item WA Dept of Revenue
 251
 252 https://dor.wa.gov
 253
 254 =item Data file downloads
 255
 256 https://dor.wa.gov/find-taxes-rates/sales-and-use-tax-rates/downloadable-database
 257
 258 =item XLSX file example
 259
 260 https://dor.wa.gov/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx/ExcelLocalSlsUserates_19_Q1.xlsx
 261
 262 =item CSV file example
 263
 264 https://dor.wa.gov/sites/default/files/legacy/downloads/Add_DataRates2018Q4.zip
 265
 266
 267 =item Address lookup API tool
 268
 269 http://webgis.dor.wa.gov/webapi/AddressRates.aspx?output=xml&addr=410 Terry Ave. North&city=&zip=98100
 270
 271 =back
 272
 273 =cut
 274
 275 sub wa_sales_update_tax_table {
 276   my $args = shift;
 277
 278   croak 'wa_sales_update_tax_table requires \$args hashref'
 279     if $args && !ref $args;
 280
 281   return
 282     unless conf_tax_district_method()
 283         && conf_tax_district_method() eq 'wa_sales';
 284
 285   $args->{taxname} ||= FS::Conf->new->config('tax_district_taxname');
 286   $args->{year}    ||= DateTime->now->year;
 287   $args->{quarter} ||= DateTime->now->quarter;
 288
 289   log_info_and_warn(
 290     "Begin wa_sales_update_tax_table() ".
 291     join ', ' => (
 292       map{ "$_ => ". ( $args->{$_} || 'undef' ) }
 293       sort keys %$args
 294     )
 295   );
 296
 297   unless ( wa_sales_update_tax_table_sanity_check() ) {
 298     log_error_and_die(
 299       'Duplicate district rows exist in the Washington state sales tax table. '.
 300       'These must be resolved before updating the tax tables. '.
 301       'See "freeside-wa-tax-table-resolve --check" to repair the tax tables. '
 302     );
 303   }
 304
 305   $args->{temp_dir} ||= tempdir();
 306
 307   $args->{filename} ||= wa_sales_fetch_xlsx_file( $args );
 308
 309   $args->{tax_districts} = wa_sales_parse_xlsx_file( $args );
 310
 311   wa_sales_update_cust_main_county( $args );
 312
 313   log_info_and_warn( 'Finished wa_sales_update_tax_table()' );
 314 }
 315
 316 =head2 wa_sales_update_cust_main_county \%args
 317
 318 Create or update the L<FS::cust_main_county> records with new data
 319
 320 =cut
 321
 322 sub wa_sales_update_cust_main_county {
 323   my $args = shift;
 324
 325   return
 326     unless conf_tax_district_method()
 327         && conf_tax_district_method() eq 'wa_sales';
 328
 329   croak 'wa_sales_update_cust_main_county requires $args hashref'
 330     unless ref $args
 331         && ref $args->{tax_districts};
 332
 333   my $insert_count = 0;
 334   my $update_count = 0;
 335   my $same_count   = 0;
 336
 337   # Work within a SQL transaction
 338   local $FS::UID::AutoCommit = 0;
 339
 340   for my $taxclass ( FS::part_pkg_taxclass->taxclass_names ) {
 341     $taxclass ||= undef; # trap empty string when taxclasses are disabled
 342
 343     # Dupe detection/remediation:
 344     #
 345     # Previous code for washington state tax district was creating
 346     # duplicate entries for tax districts.  This could lead to customers
 347     # being double-taxed
 348     #
 349     # The following code detects and eliminates duplicates that
 350     # were created by wa_sales district code (source=wa_sales)
 351     # before updating the tax table with the newly downloaded
 352     # data
 353
 354     my %cust_main_county;
 355     my %cust_main_county_dupe;
 356
 357     for my $row (
 358       qsearch(
 359         cust_main_county => {
 360           source    => 'wa_sales',
 361           district  => { op => '!=', value => undef },
 362           taxclass => $taxclass,
 363         }
 364       )
 365     ) {
 366       my $district = $row->district;
 367
 368       # Row belongs to a known dupe group of districts
 369       if ( $cust_main_county_dupe{$district} ) {
 370         push @{ $cust_main_county_dupe{$district} }, $row;
 371         next;
 372       }
 373
 374       # Row is the first seen dupe for the given district
 375       if ( $cust_main_county{$district} ) {
 376         $cust_main_county_dupe{$district} = [
 377           delete $cust_main_county{$district},
 378           $row
 379         ];
 380         next;
 381       }
 382
 383       # Row is the first seen with this district
 384       $cust_main_county{$district} = $row;
 385     }
 386
 387     # # Merge any dupes, place resulting non-dupe row in %cust_main_county
 388     # #  Merge, even if one of the dupes has a $0 tax, or some other
 389     # #  variation on tax row data.  Data for this row will get corrected
 390     # #  during the following tax import
 391     # for my $dupe_district_aref ( values %cust_main_county_dupe ) {
 392     #   my $row_to_keep = shift @$dupe_district_aref;
 393     #   while ( my $row_to_merge = shift @$dupe_district_aref ) {
 394     #     $row_to_merge->_merge_into(
 395     #       $row_to_keep,
 396     #       { identical_record_check => 0 },
 397     #     );
 398     #   }
 399     #   $cust_main_county{$row_to_keep->district} = $row_to_keep;
 400     # }
 401
 402     # If there are duplicate rows, it may be unsafe to auto-resolve them
 403     if ( %cust_main_county_dupe ) {
 404       warn "Unable to continue!";
 405       log_error_and_die( sprintf(
 406         'Tax district duplicate rows detected(%s) - '.
 407         'WA Sales tax tables cannot be updated without resolving duplicates - '.
 408         'Please use tool freeside-wa-tax-table-resolve for tax table repair',
 409             join( ',', keys %cust_main_county_dupe )
 410       ));
 411     }
 412
 413     for my $district ( @{ $args->{tax_districts} } ) {
 414       if ( my $row = $cust_main_county{ $district->{district} } ) {
 415
 416         # District already exists in this taxclass, update if necessary
 417         #
 418         # If admin updates value of conf tax_district_taxname, instead of
 419         # creating an entire separate set of tax rows with
 420         # the new taxname, update the taxname on existing records
 421
 422         {
 423           # Supress warning on taxname comparison, when taxname is undef
 424           no warnings 'uninitialized';
 425
 426           if (
 427             $row->tax == ( $district->{tax_combined} * 100 )
 428             &&    $row->taxname eq    $args->{taxname}
 429             && uc $row->county  eq uc $district->{county}
 430             && uc $row->city    eq uc $district->{city}
 431           ) {
 432             $same_count++;
 433             next;
 434           }
 435         }
 436
 437         $row->city( uc $district->{city} );
 438         $row->county( uc $district->{county} );
 439         $row->taxclass( $taxclass );
 440         $row->taxname( $args->{taxname} || undef );
 441         $row->tax( $district->{tax_combined} * 100 );
 442
 443         if ( my $error = $row->replace ) {
 444           dbh->rollback;
 445           local $FS::UID::AutoCommit = 1;
 446           log_error_and_die(
 447             sprintf
 448               "Error updating cust_main_county row %s for district %s: %s",
 449               $row->taxnum,
 450               $district->{district},
 451               $error
 452           );
 453         }
 454
 455         $update_count++;
 456
 457       } else {
 458
 459         # District doesn't exist, create row
 460
 461         my $row = FS::cust_main_county->new({
 462           district => $district->{district},
 463           city     => uc $district->{city},
 464           county   => uc $district->{county},
 465           state    => 'WA',
 466           country  => 'US',
 467           taxclass => $taxclass,
 468           taxname  => $args->{taxname} || undef,
 469           tax      => $district->{tax_combined} * 100,
 470           source   => 'wa_sales',
 471         });
 472
 473         if ( my $error = $row->insert ) {
 474           dbh->rollback;
 475           local $FS::UID::AutoCommit = 1;
 476           log_error_and_die(
 477             sprintf
 478               "Error inserting cust_main_county row for district %s: %s",
 479               $district->{district},
 480               $error
 481           );
 482         }
 483
 484         $cust_main_county{ $district->{district} } = $row;
 485         $insert_count++;
 486       }
 487
 488     } # /foreach $district
 489   } # /foreach $taxclass
 490
 491   dbh->commit;
 492
 493   local $FS::UID::AutoCommit = 1;
 494   log_info_and_warn(
 495     sprintf
 496       "WA tax table update completed. ".
 497       "Inserted %s rows, updated %s rows, identical %s rows",
 498       $insert_count,
 499       $update_count,
 500       $same_count
 501   );
 502
 503 }
 504
 505 =head2 wa_sales_parse_xlsx_file \%args
 506
 507 Parse given XLSX file for tax district information
 508 Return an arrayref of district information hashrefs
 509
 510 =cut
 511
 512 sub wa_sales_parse_xlsx_file {
 513   my $args = shift;
 514
 515   croak 'wa_sales_parse_xlsx_file requires $args hashref containing a filename'
 516     unless ref $args
 517         && $args->{filename};
 518
 519   # About the file format:
 520   #
 521   # The current spreadsheet contains the following @columns.
 522   # Rows 1 and 2 are a marquee header
 523   # Row 3 is the column labels.  We will test these to detect
 524   #   changes in the data format
 525   # Rows 4+ are the tax district data
 526   #
 527   # The "city" column is being parsed from "Location"
 528
 529   my @columns = qw( city county district tax_local tax_state tax_combined );
 530
 531   log_error_and_die( "Unable to access XLSX file: $args->{filename}" )
 532     unless -r $args->{filename};
 533
 534   my $xls_parser = Spreadsheet::XLSX->new( $args->{filename} )
 535     or log_error_and_die( "Error parsing XLSX file: $!" );
 536
 537   my $sheet = $xls_parser->{Worksheet}->[0]
 538     or log_error_and_die(" Unable to access worksheet 1 in XLSX file" );
 539
 540   my $cells = $sheet->{Cells}
 541     or log_error_and_die( "Unable to read cells in XLSX file" );
 542
 543   # Read the column labels and verify
 544   my %labels =
 545     map{ $columns[$_] => $cells->[2][$_]->{Val} }
 546     0 .. scalar(@columns)-1;
 547
 548   my %expected_labels = (
 549     city         => 'Location',
 550     county       => 'County',
 551     district     => 'Location Code',
 552     tax_local    => 'Local Rate',
 553     tax_state    => 'State Rate',
 554     tax_combined => 'Combined Sales Tax',
 555   );
 556
 557   if (
 558     my @error_labels =
 559       grep { lc $labels{$_} ne lc $expected_labels{$_} }
 560       @columns
 561   ) {
 562     my $error = "Error parsing XLS file - ".
 563                 "Data format may have been updated with WA DOR! ";
 564     $error .= "Expected column $expected_labels{$_}, found $labels{$_}! "
 565       for @error_labels;
 566     log_error_and_die( $error );
 567   }
 568
 569   # Parse the rows into an array of hashes
 570   my @districts;
 571   for my $row ( 3..$sheet->{MaxRow} ) {
 572     my %district = (
 573       map { $columns[$_] => $cells->[$row][$_]->{Val} }
 574       0 .. scalar(@columns)-1
 575     );
 576
 577     if (
 578          $district{city}
 579       && $district{county}
 580       && $district{district}     =~ /^\d+$/
 581       && $district{tax_local}    =~ /^\d?\.\d+$/
 582       && $district{tax_state}    =~ /^\d?\.\d+$/
 583       && $district{tax_combined} =~ /^\d?\.\d+$/
 584     ) {
 585
 586       # For some reason, city may contain line breaks!
 587       $district{city} =~ s/[\r\n]//g;
 588
 589       push @districts, \%district;
 590     } else {
 591       log_warn_and_warn(
 592         "Non-usable row found in spreadsheet:\n" . Dumper( \%district )
 593       );
 594     }
 595
 596   }
 597
 598   log_error_and_die( "No \@districts found in data file!" )
 599     unless @districts;
 600
 601   log_info_and_warn(
 602     sprintf "Parsed %s districts from data file", scalar @districts
 603   );
 604
 605   \@districts;
 606
 607 }
 608
 609 =head2 wa_sales_fetch_xlsx_file \%args
 610
 611 Download data file from WA state DOR to temporary storage,
 612 return filename
 613
 614 =cut
 615
 616 sub wa_sales_fetch_xlsx_file {
 617   my $args = shift;
 618
 619   return
 620     unless conf_tax_district_method()
 621         && conf_tax_district_method() eq 'wa_sales';
 622
 623   croak 'wa_sales_fetch_xlsx_file requires \$args hashref'
 624     unless ref $args
 625         && $args->{temp_dir};
 626
 627   my $url_base = 'https://dor.wa.gov'.
 628                  '/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx';
 629
 630   my $year    = $args->{year}    || DateTime->now->year;
 631   my $quarter = $args->{quarter} || DateTime->now->quarter;
 632   $year = substr( $year, 2, 2 ) if $year >= 1000;
 633
 634   my $fn = sprintf( 'ExcelLocalSlsUserates_%s_Q%s.xlsx', $year, $quarter );
 635   my $url = "$url_base/$fn";
 636
 637   my $write_fn = "$args->{temp_dir}/$fn";
 638
 639   log_info_and_warn( "Begin download from url: $url" );
 640
 641   my $ua = LWP::UserAgent->new;
 642   my $res = $ua->get( $url );
 643
 644   log_error_and_die( "Download error: ".$res->status_line )
 645     unless $res->is_success;
 646
 647   local $@;
 648   eval { write_file( $write_fn, $res->decoded_content ); };
 649   log_error_and_die( "Problem writing download to disk: $@" )
 650     if $@;
 651
 652   log_info_and_warn( "Temporary file: $write_fn" );
 653   $write_fn;
 654
 655 }
 656
 657 =head2 wa_sales_update_tax_table_sanity_check
 658
 659 There should be no duplicate tax table entries in the tax table,
 660 with the same district value, within a tax class, where source=wa_sales.
 661
 662 If there are, custome taxes may have been user-entered in the
 663 freeside UI, and incorrectly labelled as source=wa_sales.  Or, the
 664 dupe record may have been created by issues with older wa_sales code.
 665
 666 If these dupes exist, the sysadmin must solve the problem by hand
 667 with the freeeside-wa-tax-table-resolve script
 668
 669 Returns 1 unless problem sales tax entries are detected
 670
 671 =cut
 672
 673 sub wa_sales_update_tax_table_sanity_check {
 674   FS::cust_main_county->find_wa_tax_dupes ? 0 : 1;
 675 }
 676
 677 sub log {
 678   state $log = FS::Log->new('tax_rate_update');
 679   $log;
 680 }
 681
 682 sub log_info_and_warn {
 683   my $log_message = shift;
 684   warn "$log_message\n";
 685   &log()->info( $log_message );
 686 }
 687
 688 sub log_warn_and_warn {
 689   my $log_message = shift;
 690   warn "$log_message\n";
 691   &log()->warn( $log_message );
 692 }
 693
 694 sub log_error_and_die {
 695   my $log_message = shift;
 696   &log()->error( $log_message );
 697   warn( "$log_message\n" );
 698   die( "$log_message\n" );
 699 }
 700
 701 sub log_error_and_warn {
 702   my $log_message = shift;
 703   warn "$log_message\n";
 704   &log()->error( $log_message );
 705 }
 706
 707 sub conf_tax_district_method {
 708   state $tax_district_method = FS::Conf->new->config('tax_district_method');
 709   $tax_district_method;
 710 }
 711
 712
 713 1;