FS/FS/Cron/tax_rate_update.pm

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 FS::Cron::tax_rate_update
   6
   7 =head1 DESCRIPTION
   8
   9 Cron routine to update city/district sales tax rates in I<cust_main_county>.
  10 Currently supports sales tax in the state of Washington.
  11
  12 =head2 wa_sales
  13
  14 =item Tax Rate Download
  15
  16 Once each month, update the tax tables from the WA DOR website.
  17
  18 =item Customer Address Rate Classification
  19
  20 Find cust_location rows in WA with no tax district.  Try to determine
  21 a tax district.  Otherwise, generate a log error that address needs
  22 to be correctd.
  23
  24 =cut
  25
  26 use strict;
  27 use warnings;
  28 use feature 'state';
  29
  30 use Exporter;
  31 our @EXPORT_OK = qw(
  32   tax_rate_update
  33   wa_sales_update_tax_table
  34   wa_sales_log_customer_without_tax_district
  35 );
  36
  37 use Carp qw(croak);
  38 use DateTime;
  39 use File::Temp 'tempdir';
  40 use File::Slurp qw(read_file write_file);
  41 use LWP::UserAgent;
  42 use Spreadsheet::XLSX;
  43 use Text::CSV;
  44
  45 use FS::Conf;
  46 use FS::cust_main;
  47 use FS::cust_main_county;
  48 use FS::geocode_Mixin;
  49 use FS::Log;
  50 use FS::part_pkg_taxclass;
  51 use FS::Record qw(qsearch qsearchs dbh);
  52 use FS::upgrade_journal;
  53
  54 our $DEBUG = 0;
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 tax_rate_update
  59
  60 Cron routine for freeside_daily.
  61
  62 Run one of the available cron functions based on conf value tax_district_method
  63
  64 =cut
  65
  66 sub tax_rate_update {
  67
  68   # Currently only wa_sales is supported
  69   my $tax_district_method = conf_tax_district_method();
  70
  71   return unless $tax_district_method;
  72
  73   if ( exists &{$tax_district_method} ) {
  74     my $func = \&{$tax_district_method};
  75     $func->();
  76   } else {
  77     my $log = FS::Log->new('tax_rate_update');
  78     $log->error( "Unhandled tax_district_method($tax_district_method)" );
  79   }
  80
  81 }
  82
  83 =head2 wa_sales
  84
  85 Monthly:   Update the complete WA state tax tables
  86 Every Run: Log errors for cust_location records without a district
  87
  88 =cut
  89
  90 sub wa_sales {
  91
  92   return
  93     unless conf_tax_district_method()
  94         && conf_tax_district_method() eq 'wa_sales';
  95
  96   my $dt_now  = DateTime->now;
  97   my $year    = $dt_now->year;
  98   my $quarter = $dt_now->quarter;
  99
 100   my $journal_label =
 101     sprintf 'wa_sales_update_tax_table_%sQ%s', $year, $quarter;
 102
 103   unless ( FS::upgrade_journal->is_done( $journal_label ) ) {
 104     local $@;
 105
 106     eval{ wa_sales_update_tax_table(); };
 107     log_error_and_die( "Error updating tax tables: $@" )
 108       if $@;
 109     FS::upgrade_journal->set_done( $journal_label );
 110   }
 111
 112   wa_sales_log_customer_without_tax_district();
 113
 114   '';
 115
 116 }
 117
 118 =head2 wa_sales_log_customer_without_tax_district
 119
 120 For any cust_location records
 121 * In WA state
 122 * Attached to non cancelled packages
 123 * With no tax district
 124
 125 Classify the tax district for the record using the WA State Dept of
 126 Revenue API.  If this fails, generate an error into system log so
 127 address can be corrected
 128
 129 =cut
 130
 131 sub wa_sales_log_customer_without_tax_district {
 132
 133   return
 134     unless conf_tax_district_method()
 135         && conf_tax_district_method() eq 'wa_sales';
 136
 137   my %qsearch_cust_location = (
 138     table => 'cust_location',
 139     select => '
 140       cust_location.locationnum,
 141       cust_location.custnum,
 142       cust_location.address1,
 143       cust_location.city,
 144       cust_location.state,
 145       cust_location.zip
 146     ',
 147     addl_from => '
 148       LEFT JOIN cust_main USING (custnum)
 149       LEFT JOIN cust_pkg ON cust_location.locationnum = cust_pkg.locationnum
 150     ',
 151     extra_sql => sprintf(q{
 152         WHERE cust_location.state = 'WA'
 153         AND (
 154              cust_location.district IS NULL
 155           or cust_location.district = ''
 156         )
 157         AND cust_pkg.pkgnum IS NOT NULL
 158         AND (
 159              cust_pkg.cancel > %s
 160           OR cust_pkg.cancel IS NULL
 161         )
 162       }, time()
 163     ),
 164   );
 165
 166   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 167     local $@;
 168     log_info_and_warn(
 169       sprintf
 170         'Attempting to classify district for cust_location ' .
 171         'locationnum(%s) address(%s)',
 172           $cust_location->locationnum,
 173           $cust_location->address1,
 174     );
 175
 176     eval {
 177       FS::geocode_Mixin::process_district_update(
 178         'FS::cust_location',
 179         $cust_location->locationnum
 180       );
 181     };
 182
 183     if ( $@ ) {
 184       # Error indicates a crash, not an error looking up district
 185       # process_district_udpate will generate log messages for those errors
 186       log_error_and_warn(
 187         sprintf "Classify district error for cust_location(%s): %s",
 188           $cust_location->locationnum,
 189           $@
 190       );
 191     }
 192
 193     sleep 1; # Be polite to WA DOR API
 194   }
 195
 196   for my $cust_location ( qsearch( \%qsearch_cust_location )) {
 197     log_error_and_warn(
 198       sprintf
 199         "Customer address in WA lacking tax district classification. ".
 200         "custnum(%s) ".
 201         "locationnum(%s) ".
 202         "address(%s, %s %s, %s) ".
 203         "[https://webgis.dor.wa.gov/taxratelookup/SalesTax.aspx]",
 204           map { $cust_location->$_ }
 205           qw( custnum locationnum address1 city state zip )
 206     );
 207   }
 208
 209 }
 210
 211
 212 =head2 wa_sales_update_tax_table \%args
 213
 214 Update city/district sales tax rates in L<FS::cust_main_county> from the
 215 Washington State Department of Revenue published data files.
 216
 217 Creates, or updates, a L<FS::cust_main_county> row for every tax district
 218 in Washington state. Some cities have different tax rates based on the
 219 address, within the city.  Because of this, some cities have multiple
 220 districts.
 221
 222 If tax classes are enabled, a row is created in every tax class for
 223 every district.
 224
 225 Customer addresses aren't classified into districts here.  Instead,
 226 when a Washington state address is inserted or changed in L<FS::cust_location>,
 227 a job is queued for FS::geocode_Mixin::process_district_update, to ask the
 228 Washington state API which tax district to use for this address.
 229
 230 All arguments are optional:
 231
 232   filename: Skip file download, and process the specified filename instead
 233
 234   taxname:  Updated or created records will be set to the given tax name.
 235             If not specified, conf value 'tax_district_taxname' is used
 236
 237   year:     Specify year for tax table download.  Defaults to current year
 238
 239   quarter:  Specify quarter for tax table download.  Defaults to current quarter
 240
 241 =head3 Washington State Department of Revenue Resources
 242
 243 The state of Washington makes data files available via their public website.
 244 It's possible the availability or format of these files may change.  As of now,
 245 the only data file that contains both city and county names is published in
 246 XLSX format.
 247
 248 =over 4
 249
 250 =item WA Dept of Revenue
 251
 252 https://dor.wa.gov
 253
 254 =item Data file downloads
 255
 256 https://dor.wa.gov/find-taxes-rates/sales-and-use-tax-rates/downloadable-database
 257
 258 =item XLSX file example
 259
 260 https://dor.wa.gov/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx/ExcelLocalSlsUserates_19_Q1.xlsx
 261
 262 =item CSV file example
 263
 264 https://dor.wa.gov/sites/default/files/legacy/downloads/Add_DataRates2018Q4.zip
 265
 266
 267 =item Address lookup API tool
 268
 269 http://webgis.dor.wa.gov/webapi/AddressRates.aspx?output=xml&addr=410 Terry Ave. North&city=&zip=98100
 270
 271 =back
 272
 273 =cut
 274
 275 sub wa_sales_update_tax_table {
 276   my $args = shift;
 277
 278   croak 'wa_sales_update_tax_table requires \$args hashref'
 279     if $args && !ref $args;
 280
 281   return
 282     unless conf_tax_district_method()
 283         && conf_tax_district_method() eq 'wa_sales';
 284
 285   $args->{taxname} ||= FS::Conf->new->config('tax_district_taxname');
 286   $args->{year}    ||= DateTime->now->year;
 287   $args->{quarter} ||= DateTime->now->quarter;
 288
 289   log_info_and_warn(
 290     "Begin wa_sales_update_tax_table() ".
 291     join ', ' => (
 292       map{ "$_ => ". ( $args->{$_} || 'undef' ) }
 293       sort keys %$args
 294     )
 295   );
 296
 297   # The checks themselves will fully log details about the problem,
 298   # so simple error message is sufficient here
 299   log_error_and_die('abort tax table update, sanity checks failed')
 300     unless wa_sales_update_tax_table_sanity_check();
 301
 302   $args->{temp_dir} ||= tempdir();
 303
 304   $args->{filename} ||= wa_sales_fetch_xlsx_file( $args );
 305
 306   $args->{tax_districts} = wa_sales_parse_xlsx_file( $args );
 307
 308   wa_sales_update_cust_main_county( $args );
 309
 310   log_info_and_warn( 'Finished wa_sales_update_tax_table()' );
 311 }
 312
 313 =head2 wa_sales_update_cust_main_county \%args
 314
 315 Create or update the L<FS::cust_main_county> records with new data
 316
 317 =cut
 318
 319 sub wa_sales_update_cust_main_county {
 320   my $args = shift;
 321
 322   return
 323     unless conf_tax_district_method()
 324         && conf_tax_district_method() eq 'wa_sales';
 325
 326   croak 'wa_sales_update_cust_main_county requires $args hashref'
 327     unless ref $args
 328         && ref $args->{tax_districts};
 329
 330   my $insert_count = 0;
 331   my $update_count = 0;
 332   my $same_count   = 0;
 333
 334   # Work within a SQL transaction
 335   local $FS::UID::AutoCommit = 0;
 336
 337   for my $taxclass ( FS::part_pkg_taxclass->taxclass_names ) {
 338     $taxclass ||= undef; # trap empty string when taxclasses are disabled
 339
 340     # Dupe detection/remediation:
 341     #
 342     # Previous code for washington state tax district was creating
 343     # duplicate entries for tax districts.  This could lead to customers
 344     # being double-taxed
 345     #
 346     # The following code detects and eliminates duplicates that
 347     # were created by wa_sales district code (source=wa_sales)
 348     # before updating the tax table with the newly downloaded
 349     # data
 350
 351     my %cust_main_county;
 352     my %cust_main_county_dupe;
 353
 354     for my $row (
 355       qsearch(
 356         cust_main_county => {
 357           source    => 'wa_sales',
 358           district  => { op => '!=', value => undef },
 359           tax_class => $taxclass,
 360         }
 361       )
 362     ) {
 363       my $district = $row->district;
 364
 365       # Row belongs to a known dupe group of districts
 366       if ( $cust_main_county_dupe{$district} ) {
 367         push @{ $cust_main_county_dupe{$district} }, $row;
 368         next;
 369       }
 370
 371       # Row is the first seen dupe for the given district
 372       if ( $cust_main_county{$district} ) {
 373         $cust_main_county_dupe{$district} = [
 374           delete $cust_main_county{$district},
 375           $row
 376         ];
 377         next;
 378       }
 379
 380       # Row is the first seen with this district
 381       $cust_main_county{$district} = $row;
 382     }
 383
 384     # Merge any dupes, place resulting non-dupe row in %cust_main_county
 385     #  Merge, even if one of the dupes has a $0 tax, or some other
 386     #  variation on tax row data.  Data for this row will get corrected
 387     #  during the following tax import
 388     for my $dupe_district_aref ( values %cust_main_county_dupe ) {
 389       my $row_to_keep = shift @$dupe_district_aref;
 390       while ( my $row_to_merge = shift @$dupe_district_aref ) {
 391         $row_to_merge->_merge_into(
 392           $row_to_keep,
 393           { identical_record_check => 0 },
 394         );
 395       }
 396       $cust_main_county{$row_to_keep->district} = $row_to_keep;
 397     }
 398
 399     for my $district ( @{ $args->{tax_districts} } ) {
 400       if ( my $row = $cust_main_county{ $district->{district} } ) {
 401
 402         # District already exists in this taxclass, update if necessary
 403         #
 404         # If admin updates value of conf tax_district_taxname, instead of
 405         # creating an entire separate set of tax rows with
 406         # the new taxname, update the taxname on existing records
 407
 408         {
 409           # Supress warning on taxname comparison, when taxname is undef
 410           no warnings 'uninitialized';
 411
 412           if (
 413             $row->tax == ( $district->{tax_combined} * 100 )
 414             &&    $row->taxname eq    $args->{taxname}
 415             && uc $row->county  eq uc $district->{county}
 416             && uc $row->city    eq uc $district->{city}
 417           ) {
 418             $same_count++;
 419             next;
 420           }
 421         }
 422
 423         $row->city( uc $district->{city} );
 424         $row->county( uc $district->{county} );
 425         $row->taxclass( $taxclass );
 426         $row->taxname( $args->{taxname} || undef );
 427         $row->tax( $district->{tax_combined} * 100 );
 428
 429         if ( my $error = $row->replace ) {
 430           dbh->rollback;
 431           local $FS::UID::AutoCommit = 1;
 432           log_error_and_die(
 433             sprintf
 434               "Error updating cust_main_county row %s for district %s: %s",
 435               $row->taxnum,
 436               $district->{district},
 437               $error
 438           );
 439         }
 440
 441         $update_count++;
 442
 443       } else {
 444
 445         # District doesn't exist, create row
 446
 447         my $row = FS::cust_main_county->new({
 448           district => $district->{district},
 449           city     => uc $district->{city},
 450           county   => uc $district->{county},
 451           state    => 'WA',
 452           country  => 'US',
 453           taxclass => $taxclass,
 454           taxname  => $args->{taxname} || undef,
 455           tax      => $district->{tax_combined} * 100,
 456           source   => 'wa_sales',
 457         });
 458
 459         if ( my $error = $row->insert ) {
 460           dbh->rollback;
 461           local $FS::UID::AutoCommit = 1;
 462           log_error_and_die(
 463             sprintf
 464               "Error inserting cust_main_county row for district %s: %s",
 465               $district->{district},
 466               $error
 467           );
 468         }
 469
 470         $cust_main_county{ $district->{district} } = $row;
 471         $insert_count++;
 472       }
 473
 474     } # /foreach $district
 475   } # /foreach $taxclass
 476
 477   dbh->commit;
 478
 479   local $FS::UID::AutoCommit = 1;
 480   log_info_and_warn(
 481     sprintf
 482       "WA tax table update completed. ".
 483       "Inserted %s rows, updated %s rows, identical %s rows",
 484       $insert_count,
 485       $update_count,
 486       $same_count
 487   );
 488
 489 }
 490
 491 =head2 wa_sales_parse_xlsx_file \%args
 492
 493 Parse given XLSX file for tax district information
 494 Return an arrayref of district information hashrefs
 495
 496 =cut
 497
 498 sub wa_sales_parse_xlsx_file {
 499   my $args = shift;
 500
 501   croak 'wa_sales_parse_xlsx_file requires $args hashref containing a filename'
 502     unless ref $args
 503         && $args->{filename};
 504
 505   # About the file format:
 506   #
 507   # The current spreadsheet contains the following @columns.
 508   # Rows 1 and 2 are a marquee header
 509   # Row 3 is the column labels.  We will test these to detect
 510   #   changes in the data format
 511   # Rows 4+ are the tax district data
 512   #
 513   # The "city" column is being parsed from "Location"
 514
 515   my @columns = qw( city county district tax_local tax_state tax_combined );
 516
 517   log_error_and_die( "Unable to access XLSX file: $args->{filename}" )
 518     unless -r $args->{filename};
 519
 520   my $xls_parser = Spreadsheet::XLSX->new( $args->{filename} )
 521     or log_error_and_die( "Error parsing XLSX file: $!" );
 522
 523   my $sheet = $xls_parser->{Worksheet}->[0]
 524     or log_error_and_die(" Unable to access worksheet 1 in XLSX file" );
 525
 526   my $cells = $sheet->{Cells}
 527     or log_error_and_die( "Unable to read cells in XLSX file" );
 528
 529   # Read the column labels and verify
 530   my %labels =
 531     map{ $columns[$_] => $cells->[2][$_]->{Val} }
 532     0 .. scalar(@columns)-1;
 533
 534   my %expected_labels = (
 535     city         => 'Location',
 536     county       => 'County',
 537     district     => 'Location Code',
 538     tax_local    => 'Local Rate',
 539     tax_state    => 'State Rate',
 540     tax_combined => 'Combined Sales Tax',
 541   );
 542
 543   if (
 544     my @error_labels =
 545       grep { lc $labels{$_} ne lc $expected_labels{$_} }
 546       @columns
 547   ) {
 548     my $error = "Error parsing XLS file - ".
 549                 "Data format may have been updated with WA DOR! ";
 550     $error .= "Expected column $expected_labels{$_}, found $labels{$_}! "
 551       for @error_labels;
 552     log_error_and_die( $error );
 553   }
 554
 555   # Parse the rows into an array of hashes
 556   my @districts;
 557   for my $row ( 3..$sheet->{MaxRow} ) {
 558     my %district = (
 559       map { $columns[$_] => $cells->[$row][$_]->{Val} }
 560       0 .. scalar(@columns)-1
 561     );
 562
 563     if (
 564          $district{city}
 565       && $district{county}
 566       && $district{district}     =~ /^\d+$/
 567       && $district{tax_local}    =~ /^\d?\.\d+$/
 568       && $district{tax_state}    =~ /^\d?\.\d+$/
 569       && $district{tax_combined} =~ /^\d?\.\d+$/
 570     ) {
 571
 572       # For some reason, city may contain line breaks!
 573       $district{city} =~ s/[\r\n]//g;
 574
 575       push @districts, \%district;
 576     } else {
 577       log_warn_and_warn(
 578         "Non-usable row found in spreadsheet:\n" . Dumper( \%district )
 579       );
 580     }
 581
 582   }
 583
 584   log_error_and_die( "No \@districts found in data file!" )
 585     unless @districts;
 586
 587   log_info_and_warn(
 588     sprintf "Parsed %s districts from data file", scalar @districts
 589   );
 590
 591   \@districts;
 592
 593 }
 594
 595 =head2 wa_sales_fetch_xlsx_file \%args
 596
 597 Download data file from WA state DOR to temporary storage,
 598 return filename
 599
 600 =cut
 601
 602 sub wa_sales_fetch_xlsx_file {
 603   my $args = shift;
 604
 605   return
 606     unless conf_tax_district_method()
 607         && conf_tax_district_method() eq 'wa_sales';
 608
 609   croak 'wa_sales_fetch_xlsx_file requires \$args hashref'
 610     unless ref $args
 611         && $args->{temp_dir};
 612
 613   my $url_base = 'https://dor.wa.gov'.
 614                  '/sites/default/files/legacy/Docs/forms/ExcsTx/LocSalUseTx';
 615
 616   my $year    = $args->{year}    || DateTime->now->year;
 617   my $quarter = $args->{quarter} || DateTime->now->quarter;
 618   $year = substr( $year, 2, 2 ) if $year >= 1000;
 619
 620   my $fn = sprintf( 'ExcelLocalSlsUserates_%s_Q%s.xlsx', $year, $quarter );
 621   my $url = "$url_base/$fn";
 622
 623   my $write_fn = "$args->{temp_dir}/$fn";
 624
 625   log_info_and_warn( "Begin download from url: $url" );
 626
 627   my $ua = LWP::UserAgent->new;
 628   my $res = $ua->get( $url );
 629
 630   log_error_and_die( "Download error: ".$res->status_line )
 631     unless $res->is_success;
 632
 633   local $@;
 634   eval { write_file( $write_fn, $res->decoded_content ); };
 635   log_error_and_die( "Problem writing download to disk: $@" )
 636     if $@;
 637
 638   log_info_and_warn( "Temporary file: $write_fn" );
 639   $write_fn;
 640
 641 }
 642
 643 =head2 wa_sales_update_tax_table_sanity_check
 644
 645 There should be no duplicate tax table entries in the tax table,
 646 with the same district value, within a tax class, where source=wa_sales.
 647
 648 If there are, custome taxes may have been user-entered in the
 649 freeside UI, and incorrectly labelled as source=wa_sales.  Or, the
 650 dupe record may have been created by issues with older wa_sales code.
 651
 652 If these dupes exist, the sysadmin must solve the problem by hand
 653 with the freeeside-wa-tax-table-resolve script
 654
 655 Returns 1 unless problem sales tax entries are detected
 656
 657 =cut
 658
 659 sub wa_sales_update_tax_table_sanity_check {
 660   FS::cust_main_county->find_wa_tax_dupes ? 0 : 1;
 661 }
 662
 663 sub log {
 664   state $log = FS::Log->new('tax_rate_update');
 665   $log;
 666 }
 667
 668 sub log_info_and_warn {
 669   my $log_message = shift;
 670   warn "$log_message\n";
 671   &log()->info( $log_message );
 672 }
 673
 674 sub log_warn_and_warn {
 675   my $log_message = shift;
 676   warn "$log_message\n";
 677   &log()->warn( $log_message );
 678 }
 679
 680 sub log_error_and_die {
 681   my $log_message = shift;
 682   &log()->error( $log_message );
 683   warn( "$log_message\n" );
 684   die( "$log_message\n" );
 685 }
 686
 687 sub log_error_and_warn {
 688   my $log_message = shift;
 689   warn "$log_message\n";
 690   &log()->error( $log_message );
 691 }
 692
 693 sub conf_tax_district_method {
 694   state $tax_district_method = FS::Conf->new->config('tax_district_method');
 695   $tax_district_method;
 696 }
 697
 698
 699 1;