FS/FS/Cron/bill.pm

   1 package FS::Cron::bill;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK );
   5 use Exporter;
   6 use Date::Parse;
   7 use DBI 1.33; #The "clone" method was added in DBI 1.33.
   8 use FS::UID qw(dbh);
   9 use FS::Record qw( qsearch qsearchs );
  10 use FS::queue;
  11 use FS::cust_main;
  12 use FS::part_event;
  13 use FS::part_event_condition;
  14
  15 @ISA = qw( Exporter );
  16 @EXPORT_OK = qw ( bill bill_where );
  17
  18 #freeside-daily %opt:
  19 #  -s: re-charge setup fees
  20 #  -v: enable debugging
  21 #  -l: debugging level
  22 #  -m: Experimental multi-process mode uses the job queue for multi-process and/or multi-machine billing.
  23 #  -r: Multi-process mode dry run option
  24 #  -g: Don't bill these pkgparts
  25
  26 sub bill {
  27   my %opt = @_;
  28
  29   my $check_freq = $opt{'check_freq'} || '1d';
  30
  31   my $debug = 0;
  32   $debug = 1 if $opt{'v'};
  33   $debug = $opt{'l'} if $opt{'l'};
  34   $FS::cust_main::DEBUG = $debug;
  35   #$FS::cust_event::DEBUG = $opt{'l'} if $opt{'l'};
  36
  37   my $conf = new FS::Conf;
  38   if ( $conf->exists('disable_cron_billing') ) {
  39     warn "disable_cron_billing set, skipping billing\n" if $debug;
  40     return;
  41   }
  42
  43   #we're at now now (and later).
  44   $opt{'time'} = $opt{'d'} ? str2time($opt{'d'}) : $^T;
  45   $opt{'time'} += $opt{'y'} * 86400 if $opt{'y'};
  46
  47   $opt{'invoice_time'} = $opt{'n'} ? $^T : $opt{'time'};
  48
  49   #hashref here doesn't work with -m
  50   #my $not_pkgpart = $opt{g} ? { map { $_=>1 } split(/,\s*/, $opt{g}) }
  51   #                          : {};
  52
  53   ###
  54   # get a list of custnums
  55   ###
  56
  57   my $cursor_dbh = dbh->clone;
  58
  59   $cursor_dbh->do(
  60     "DECLARE cron_bill_cursor CURSOR FOR ".
  61     "  SELECT custnum FROM cust_main WHERE ". bill_where( %opt )
  62   ) or die $cursor_dbh->errstr;
  63
  64   while ( 1 ) {
  65
  66     my $sth = $cursor_dbh->prepare('FETCH 100 FROM cron_bill_cursor'); #mysql?
  67
  68     $sth->execute or die $sth->errstr;
  69
  70     my @custnums = map { $_->[0] } @{ $sth->fetchall_arrayref };
  71
  72     last unless scalar(@custnums);
  73
  74     ###
  75     # for each custnum, queue or make one customer object and bill
  76     # (one at a time, to reduce memory footprint with large #s of customers)
  77     ###
  78
  79     foreach my $custnum ( @custnums ) {
  80
  81       my %args = (
  82           'time'         => $opt{'time'},
  83           'invoice_time' => $opt{'invoice_time'},
  84           'actual_time'  => $^T, #when freeside-bill was started
  85                                  #(not, when using -m, freeside-queued)
  86           'check_freq'   => $check_freq,
  87           'resetup'      => ( $opt{'s'} ? $opt{'s'} : 0 ),
  88           'not_pkgpart'  => $opt{'g'}, #$not_pkgpart,
  89       );
  90
  91       if ( $opt{'m'} ) {
  92
  93         if ( $opt{'r'} ) {
  94           warn "DRY RUN: would add custnum $custnum for queued_bill\n";
  95         } else {
  96
  97           #avoid queuing another job if there's one still waiting to run
  98           next if qsearch( 'queue', { 'job'     => 'FS::cust_main::queued_bill',
  99                                       'custnum' => $custnum,
 100                                       'status'  => 'new',
 101                                     }
 102                          );
 103
 104           #add job to queue that calls bill_and_collect with options
 105           my $queue = new FS::queue {
 106             'job'      => 'FS::cust_main::queued_bill',
 107             'secure'   => 'Y',
 108             'priority' => 99, #don't get in the way of provisioning jobs
 109           };
 110           my $error = $queue->insert( 'custnum'=>$custnum, %args );
 111
 112         }
 113
 114       } else {
 115
 116         my $cust_main = qsearchs( 'cust_main', { 'custnum' => $custnum } );
 117         $cust_main->bill_and_collect( %args, 'debug' => $debug );
 118
 119       }
 120
 121     }
 122
 123   }
 124
 125   $cursor_dbh->commit or die $cursor_dbh->errstr;
 126
 127 }
 128
 129 # freeside-daily %opt:
 130 #  -d: Pretend it's 'date'.  Date is in any format Date::Parse is happy with,
 131 #      but be careful.
 132 #
 133 #  -y: In addition to -d, which specifies an absolute date, the -y switch
 134 #      specifies an offset, in days.  For example, "-y 15" would increment the
 135 #      "pretend date" 15 days from whatever was specified by the -d switch
 136 #      (or now, if no -d switch was given).
 137 #
 138 #  -n: When used with "-d" and/or "-y", specifies that invoices should be dated
 139 #      with today's date, irregardless of the pretend date used to pre-generate
 140 #      the invoices.
 141 #
 142 #  -p: Only process customers with the specified payby (I<CARD>, I<DCRD>, I<CHEK>, I<DCHK>, I<BILL>, I<COMP>, I<LECB>)
 143 #
 144 #  -a: Only process customers with the specified agentnum
 145 #
 146 #  -v: enable debugging
 147 #
 148 #  -l: debugging level
 149
 150 sub bill_where {
 151   my( %opt ) = @_;
 152
 153   my $time = $opt{'time'};
 154   my $invoice_time = $opt{'invoice_time'};
 155
 156   my $check_freq = $opt{'check_freq'} || '1d';
 157
 158   my @search = ();
 159
 160   push @search, "( cust_main.archived != 'Y' OR archived IS NULL )"; #disable?
 161
 162   push @search, "cust_main.payby    = '". $opt{'p'}. "'"
 163     if $opt{'p'};
 164   push @search, "cust_main.agentnum IN ( ". $opt{'a'}. " ) "
 165     if $opt{'a'};
 166
 167   #it would be useful if i recognized $opt{g} / $not_pkgpart...
 168
 169   if ( @ARGV ) {
 170     push @search, "( ".
 171       join(' OR ', map "cust_main.custnum = $_", @ARGV ).
 172     " )";
 173   }
 174
 175   ###
 176   # generate where_pkg/where_event search clause
 177   ###
 178
 179   # select * from cust_main where
 180   my $where_pkg = <<"END";
 181     EXISTS(
 182       SELECT 1 FROM cust_pkg
 183         WHERE cust_main.custnum = cust_pkg.custnum
 184           AND ( cancel IS NULL OR cancel = 0 )
 185           AND (    ( ( setup IS NULL OR setup =  0 )
 186                      AND ( start_date IS NULL OR start_date = 0
 187                            OR ( start_date IS NOT NULL AND start_date <= $^T )
 188                          )
 189                    )
 190                 OR bill  IS NULL OR bill  <= $time
 191                 OR ( expire  IS NOT NULL AND expire  <= $^T )
 192                 OR ( adjourn IS NOT NULL AND adjourn <= $^T )
 193               )
 194     )
 195 END
 196
 197   #some false laziness w/cust_main::Billing due_cust_event
 198   my $where_event = join(' OR ', map {
 199     my $eventtable = $_;
 200
 201     my $join  = FS::part_event_condition->join_conditions_sql(  $eventtable );
 202     my $where = FS::part_event_condition->where_conditions_sql( $eventtable,
 203                                                                 'time'=>$time,
 204                                                               );
 205     $where = $where ? "AND $where" : '';
 206
 207     my $are_part_event =
 208       "EXISTS ( SELECT 1 FROM part_event $join
 209                   WHERE check_freq = '$check_freq'
 210                     AND eventtable = '$eventtable'
 211                     AND ( disabled = '' OR disabled IS NULL )
 212                     $where
 213               )
 214       ";
 215
 216     if ( $eventtable eq 'cust_main' ) {
 217       $are_part_event;
 218     } else {
 219       "EXISTS ( SELECT 1 FROM $eventtable
 220                   WHERE cust_main.custnum = $eventtable.custnum
 221                     AND $are_part_event
 222               )
 223       ";
 224     }
 225
 226   } FS::part_event->eventtables);
 227
 228   push @search, "( $where_pkg OR $where_event )";
 229
 230   warn "searching for customers:\n". join("\n", @search). "\n"
 231     if $opt{'v'} || $opt{'l'};
 232
 233   join(' AND ', @search);
 234
 235 }
 236
 237 1;