FS/FS/ClientAPI/Signup.pm

   1 package FS::ClientAPI::Signup;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use Data::Dumper;
   6 use Tie::RefHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearch qsearchs dbdef);
   9 use FS::CGI qw(popurl);
  10 use FS::Msgcat qw(gettext);
  11 use FS::Misc qw(card_types);
  12 use FS::ClientAPI_SessionCache;
  13 use FS::agent;
  14 use FS::cust_main_county;
  15 use FS::part_pkg;
  16 use FS::svc_acct_pop;
  17 use FS::cust_main;
  18 use FS::cust_pkg;
  19 use FS::svc_acct;
  20 use FS::svc_phone;
  21 use FS::acct_snarf;
  22 use FS::queue;
  23 use FS::reg_code;
  24 use FS::payby;
  25
  26 $DEBUG = 0;
  27 $me = '[FS::ClientAPI::Signup]';
  28
  29 sub clear_cache {
  30   warn "$me clear_cache called\n" if $DEBUG;
  31   my $cache = new FS::ClientAPI_SessionCache( {
  32       'namespace' => 'FS::ClientAPI::Signup',
  33   } );
  34   $cache->clear();
  35   return {};
  36 }
  37
  38 sub signup_info {
  39   my $packet = shift;
  40
  41   warn "$me signup_info called on $packet\n" if $DEBUG;
  42
  43   my $conf = new FS::Conf;
  44   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
  45
  46   my $cache = new FS::ClientAPI_SessionCache( {
  47     'namespace' => 'FS::ClientAPI::Signup',
  48   } );
  49   my $signup_info_cache = $cache->get('signup_info_cache');
  50
  51   if ( $signup_info_cache ) {
  52
  53     warn "$me loading cached signup info\n" if $DEBUG > 1;
  54
  55   } else {
  56
  57     warn "$me populating signup info cache\n" if $DEBUG > 1;
  58
  59     my $agentnum2part_pkg =
  60       {
  61         map {
  62           my $agent = $_;
  63           my $href = $agent->pkgpart_hashref;
  64           $agent->agentnum =>
  65             [
  66               map { { 'payby'       => [ $_->payby ],
  67                       'freq_pretty' => $_->freq_pretty,
  68                       'options'     => { $_->options },
  69                       %{$_->hashref}
  70                   } }
  71                 grep { $_->svcpart($svc_x)
  72                        && ( $href->{ $_->pkgpart }
  73                             || ( $_->agentnum
  74                                  && $_->agentnum == $agent->agentnum
  75                                )
  76                           )
  77                      }
  78                   qsearch( 'part_pkg', { 'disabled' => '' } )
  79             ];
  80         } qsearch('agent', { 'disabled' => '' })
  81       };
  82
  83     my $msgcat = { map { $_=>gettext($_) }
  84                        qw( passwords_dont_match invalid_card unknown_card_type
  85                            not_a empty_password illegal_or_empty_text )
  86                  };
  87     warn "msgcat: ". Dumper($msgcat). "\n" if $DEBUG > 2;
  88
  89     my $label = { map { $_ => FS::Msgcat::_gettext($_) }
  90                       qw( stateid stateid_state )
  91                 };
  92     warn "label: ". Dumper($label). "\n" if $DEBUG > 2;
  93
  94     my @agent_fields = qw( agentnum agent );
  95
  96     my @bools = qw( emailinvoiceonly security_phrase );
  97
  98     my @signup_bools = qw( no_company recommend_daytime recommend_email );
  99
 100     my @signup_server_scalars = qw( default_pkgpart default_svcpart );
 101
 102     my @selfservice_textareas = qw( head body_header body_footer );
 103
 104     my @selfservice_scalars = qw(
 105       body_bgcolor box_bgcolor
 106       text_color link_color vlink_color hlink_color alink_color
 107       font title_color title_align title_size menu_bgcolor menu_fontsize
 108     );
 109
 110     #XXX my @selfservice_bools = qw(
 111     #  menu_skipblanks menu_skipheadings menu_nounderline
 112     #);
 113
 114     #my $selfservice_binaries = qw(
 115     #  title_left_image title_right_image
 116     #  menu_top_image menu_body_image menu_bottom_image
 117     #);
 118
 119     $signup_info_cache = {
 120
 121       'cust_main_county' => [ map $_->hashref,
 122                                   qsearch('cust_main_county', {} )
 123                             ],
 124
 125       'agent' => [ map { my $agent = $_;
 126                          +{ map { $_ => $agent->get($_) } @agent_fields }
 127                        }
 128                        qsearch('agent', { 'disabled' => '' } )
 129                  ],
 130
 131       'part_referral' => [ map $_->hashref,
 132                                qsearch('part_referral', { 'disabled' => '' } )
 133                          ],
 134
 135       'agentnum2part_pkg' => $agentnum2part_pkg,
 136
 137       'svc_acct_pop' => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 138
 139       'emailinvoiceonly' => $conf->exists('emailinvoiceonly'),
 140
 141       'security_phrase' => $conf->exists('security_phrase'),
 142
 143       'nomadix' => $conf->exists('signup_server-nomadix'),
 144
 145       'payby' => [ $conf->config('signup_server-payby') ],
 146
 147       'payby_longname' => [ map { FS::payby->longname($_) }
 148                             $conf->config('signup_server-payby') ],
 149
 150       'card_types' => card_types(),
 151
 152       ( map { $_ => $conf->exists("signup-$_") } @signup_bools ),
 153
 154       ( map { $_ => scalar($conf->config("signup_server-$_")) }
 155             @signup_server_scalars
 156       ),
 157
 158       ( map { $_ => join("\n", $conf->config("selfservice-$_")) }
 159             @selfservice_textareas
 160       ),
 161       ( map { $_ => scalar($conf->config("selfservice-$_")) }
 162             @selfservice_scalars
 163       ),
 164
 165       #( map { $_ => scalar($conf->config_binary("selfservice-$_")) }
 166       #      @selfservice_binaries
 167       #),
 168
 169       'agentnum2part_pkg'  => $agentnum2part_pkg,
 170       'svc_acct_pop'       => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 171       'nomadix'            => $conf->exists('signup_server-nomadix'),
 172       'payby'              => [ $conf->config('signup_server-payby') ],
 173       'card_types'         => card_types(),
 174       'paytypes'           => [ @FS::cust_main::paytypes ],
 175       'cvv_enabled'        => 1,
 176       'stateid_enabled'    => $conf->exists('show_stateid'),
 177       'paystate_enabled'   => $conf->exists('show_bankstate'),
 178       'ship_enabled'       => 1,
 179       'msgcat'             => $msgcat,
 180       'label'              => $label,
 181       'statedefault'       => scalar($conf->config('statedefault')) || 'CA',
 182       'countrydefault'     => scalar($conf->config('countrydefault')) || 'US',
 183       'refnum'             => scalar($conf->config('signup_server-default_refnum')),
 184       'signup_service'     => $svc_x,
 185       'company_name'       => scalar($conf->config('company_name')),
 186       #per-agent?
 187       'agent_ship_address' => scalar($conf->exists('agent-ship_address')),
 188       'require_phone'      => scalar($conf->exists('cust_main-require_phone')),
 189       'logo'               => scalar($conf->config_binary('logo.png')),
 190
 191     };
 192
 193     $cache->set('signup_info_cache', $signup_info_cache);
 194
 195   }
 196
 197   my $signup_info = { %$signup_info_cache };
 198   warn "$me signup info loaded\n" if $DEBUG > 1;
 199   warn Dumper($signup_info). "\n" if $DEBUG > 2;
 200
 201   my @addl = qw( signup_server-classnum2 signup_server-classnum3 );
 202
 203   if ( grep { $conf->exists($_) } @addl ) {
 204
 205     $signup_info->{optional_packages} = [];
 206
 207     foreach my $addl ( @addl ) {
 208
 209       warn "$me adding optional package info\n" if $DEBUG > 1;
 210
 211       my $classnum = $conf->config($addl) or next;
 212
 213       my @pkgs = map { {
 214                          'freq_pretty' => $_->freq_pretty,
 215                          'options'     => { $_->options },
 216                          %{ $_->hashref }
 217                        };
 218                      }
 219                      qsearch( 'part_pkg', { classnum => $classnum } );
 220
 221       push @{$signup_info->{optional_packages}}, \@pkgs;
 222
 223       warn "$me done adding opt. package info for $classnum\n" if $DEBUG > 1;
 224
 225     }
 226
 227   }
 228
 229   my $agentnum = $packet->{'agentnum'}
 230                  || $conf->config('signup_server-default_agentnum');
 231   $agentnum =~ /^(\d*)$/ or die "illegal agentnum";
 232   $agentnum = $1;
 233
 234   my $session = '';
 235   if ( exists $packet->{'session_id'} ) {
 236
 237     warn "$me loading agent session\n" if $DEBUG > 1;
 238     my $cache = new FS::ClientAPI_SessionCache( {
 239       'namespace' => 'FS::ClientAPI::Agent',
 240     } );
 241     $session = $cache->get($packet->{'session_id'});
 242     if ( $session ) {
 243       $agentnum = $session->{'agentnum'};
 244     } else {
 245       return { 'error' => "Can't resume session" }; #better error message
 246     }
 247     warn "$me done loading agent session\n" if $DEBUG > 1;
 248
 249   } elsif ( exists $packet->{'customer_session_id'} ) {
 250
 251     warn "$me loading customer session\n" if $DEBUG > 1;
 252     my $cache = new FS::ClientAPI_SessionCache( {
 253       'namespace' => 'FS::ClientAPI::MyAccount',
 254     } );
 255     $session = $cache->get($packet->{'customer_session_id'});
 256     if ( $session ) {
 257       my $custnum = $session->{'custnum'};
 258       my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum });
 259       return { 'error' => "Can't find your customer record" } unless $cust_main;
 260       $agentnum = $cust_main->agentnum;
 261     } else {
 262       return { 'error' => "Can't resume session" }; #better error message
 263     }
 264     warn "$me done loading customer session\n" if $DEBUG > 1;
 265
 266   }
 267
 268   $signup_info->{'part_pkg'} = [];
 269
 270   if ( $packet->{'reg_code'} ) {
 271
 272     warn "$me setting package list via reg_code\n" if $DEBUG > 1;
 273
 274     $signup_info->{'part_pkg'} =
 275       [ map { { 'payby'       => [ $_->payby ],
 276                 'freq_pretty' => $_->freq_pretty,
 277                 'options'     => { $_->options },
 278                 %{$_->hashref}
 279               };
 280             }
 281           grep { $_->svcpart($svc_x) }
 282           map { $_->part_pkg }
 283             qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 284                                     'agentnum' => $agentnum,              } )
 285
 286       ];
 287
 288     $signup_info->{'error'} = 'Unknown registration code'
 289       unless @{ $signup_info->{'part_pkg'} };
 290
 291     warn "$me done setting package list via reg_code\n" if $DEBUG > 1;
 292
 293   } elsif ( $packet->{'promo_code'} ) {
 294
 295     warn "$me setting package list via promo_code\n" if $DEBUG > 1;
 296
 297     $signup_info->{'part_pkg'} =
 298       [ map { { 'payby'   => [ $_->payby ],
 299                 'freq_pretty' => $_->freq_pretty,
 300                 'options'     => { $_->options },
 301                 %{$_->hashref}
 302             } }
 303           grep { $_->svcpart($svc_x) }
 304             qsearch( 'part_pkg', { 'promo_code' => {
 305                                      op=>'ILIKE',
 306                                      value=>$packet->{'promo_code'}
 307                                    },
 308                                    'disabled'   => '',                  } )
 309       ];
 310
 311     $signup_info->{'error'} = 'Unknown promotional code'
 312       unless @{ $signup_info->{'part_pkg'} };
 313
 314     warn "$me done setting package list via promo_code\n" if $DEBUG > 1;
 315   }
 316
 317   if ( $agentnum ) {
 318
 319     warn "$me setting agent-specific payment flag\n" if $DEBUG > 1;
 320     my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 321     warn "$me has agent $agent\n" if $DEBUG > 1;
 322     if ( $agent ) { #else complain loudly?
 323       $signup_info->{'hide_payment_fields'} = [];
 324       my $gatewaynum = $conf->config('selfservice-payment_gateway');
 325       if ( $gatewaynum ) {
 326         my $pg = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 327         die "configured gatewaynum $gatewaynum not found!" if !$pg;
 328         my $hide = $pg->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 329         $signup_info->{'hide_payment_fields'} = [
 330           map { $hide } @{$signup_info->{'payby'}}
 331         ];
 332       }
 333       else {
 334         foreach my $payby (@{$signup_info->{payby}}) {
 335           warn "$me checking $payby payment fields\n" if $DEBUG > 1;
 336           my $hide = 0;
 337           if ( FS::payby->realtime($payby) ) {
 338             my $payment_gateway =
 339               $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 340                                        'nofatal' => 1,
 341                                      );
 342             if ( $payment_gateway
 343                    && $payment_gateway->gateway_namespace
 344                         eq 'Business::OnlineThirdPartyPayment'
 345                ) {
 346               warn "$me hiding $payby payment fields\n" if $DEBUG > 1;
 347               $hide = 1;
 348             }
 349           }
 350           push @{$signup_info->{'hide_payment_fields'}}, $hide;
 351         } # foreach $payby
 352       }
 353     }
 354     warn "$me done setting agent-specific payment flag\n" if $DEBUG > 1;
 355
 356     warn "$me setting agent-specific package list\n" if $DEBUG > 1;
 357     $signup_info->{'part_pkg'} = $signup_info->{'agentnum2part_pkg'}{$agentnum}
 358       unless @{ $signup_info->{'part_pkg'} };
 359     warn "$me done setting agent-specific package list\n" if $DEBUG > 1;
 360
 361     warn "$me setting agent-specific adv. source list\n" if $DEBUG > 1;
 362     $signup_info->{'part_referral'} =
 363       [
 364         map { $_->hashref }
 365           qsearch( {
 366                      'table'     => 'part_referral',
 367                      'hashref'   => { 'disabled' => '' },
 368                      'extra_sql' => "AND (    agentnum = $agentnum  ".
 369                                     "      OR agentnum IS NULL    ) ",
 370                    },
 371                  )
 372       ];
 373     warn "$me done setting agent-specific adv. source list\n" if $DEBUG > 1;
 374
 375     $signup_info->{'agent_name'} = $agent->agent;
 376
 377     $signup_info->{'company_name'} = $conf->config('company_name', $agentnum);
 378
 379     if ( $signup_info->{'agent_ship_address'} && $agent->agent_custnum ) {
 380       my $cust_main = $agent->agent_cust_main;
 381       my $prefix = length($cust_main->ship_last) ? 'ship_' : '';
 382       $signup_info->{"ship_$_"} = $cust_main->get("$prefix$_")
 383         foreach qw( address1 city county state zip country );
 384     }
 385
 386     #some of the above could probably be cached, too
 387
 388     my $signup_info_cache_agent = $cache->get("signup_info_cache_agent$agentnum");
 389
 390     if ( $signup_info_cache_agent ) {
 391
 392       warn "$me loading cached signup info for agentnum $agentnum\n"
 393         if $DEBUG > 1;
 394
 395     } else {
 396
 397       warn "$me populating signup info cache for agentnum $agentnum\n"
 398         if $DEBUG > 1;
 399
 400       $signup_info_cache_agent = {
 401         #( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 402         #  qw( company_name ) ),
 403         ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 404           qw( body_bgcolor box_bgcolor menu_bgcolor ) ),
 405         ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 406           qw( head body_header body_footer ) ),
 407       };
 408
 409       $cache->set("signup_info_cache_agent$agentnum", $signup_info_cache_agent);
 410
 411     }
 412
 413     $signup_info->{$_} = $signup_info_cache_agent->{$_}
 414       foreach keys %$signup_info_cache_agent;
 415
 416   }
 417   # else {
 418   # delete $signup_info->{'part_pkg'};
 419   #}
 420
 421   warn "$me sorting package list\n" if $DEBUG > 1;
 422   $signup_info->{'part_pkg'} = [ sort { $a->{pkg} cmp $b->{pkg} }  # case?
 423                                       @{ $signup_info->{'part_pkg'} }
 424                                ];
 425   warn "$me done sorting package list\n" if $DEBUG > 1;
 426
 427   if ( exists $packet->{'session_id'} ) {
 428     my $agent_signup_info = { %$signup_info };
 429     delete $agent_signup_info->{agentnum2part_pkg};
 430     $agent_signup_info->{'agent'} = $session->{'agent'};
 431     return $agent_signup_info;
 432   }
 433   elsif ( exists $packet->{'keys'} ) {
 434     my @keys = @{ $packet->{'keys'} };
 435     return { map { $_ => $signup_info->{$_} } @keys };
 436   }
 437   else {
 438     return $signup_info;
 439   }
 440
 441 }
 442
 443 sub domain_select_hash {
 444   my $packet = shift;
 445
 446   my $response = {};
 447
 448   if ($packet->{pkgpart}) {
 449     my $part_pkg = qsearchs('part_pkg' => { 'pkgpart' => $packet->{pkgpart} } );
 450     #$packet->{svcpart} = $part_pkg->svcpart('svc_acct')
 451     $packet->{svcpart} = $part_pkg->svcpart
 452       if $part_pkg;
 453   }
 454
 455   if ($packet->{svcpart}) {
 456     my $part_svc = qsearchs('part_svc' => { 'svcpart' => $packet->{svcpart} } );
 457     $response->{'domsvc'} = $part_svc->part_svc_column('domsvc')->columnvalue
 458       if ($part_svc && $part_svc->part_svc_column('domsvc')->columnflag  eq 'D');
 459   }
 460
 461   $response->{'domains'}
 462     = { domain_select_hash FS::svc_acct( map { $_ => $packet->{$_} }
 463                                                  qw(svcpart pkgnum)
 464                                        ) };
 465
 466   $response;
 467 }
 468
 469 sub new_customer {
 470   my $packet = shift;
 471
 472   my $conf = new FS::Conf;
 473   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 474
 475   if ( $svc_x eq 'svc_acct' ) {
 476
 477     #things that aren't necessary in base class, but are for signup server
 478       #return "Passwords don't match"
 479       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 480     return { 'error' => gettext('empty_password') }
 481       unless length($packet->{'_password'});
 482     # a bit inefficient for large numbers of pops
 483     return { 'error' => gettext('no_access_number_selected') }
 484       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 485
 486   }
 487   elsif ( $svc_x eq 'svc_pbx' ) {
 488     #possibly some validation will be needed
 489   }
 490
 491   my $agentnum;
 492   if ( exists $packet->{'session_id'} ) {
 493     my $cache = new FS::ClientAPI_SessionCache( {
 494       'namespace' => 'FS::ClientAPI::Agent',
 495     } );
 496     my $session = $cache->get($packet->{'session_id'});
 497     if ( $session ) {
 498       $agentnum = $session->{'agentnum'};
 499     } else {
 500       return { 'error' => "Can't resume session" }; #better error message
 501     }
 502   } else {
 503     $agentnum = $packet->{agentnum}
 504                 || $conf->config('signup_server-default_agentnum');
 505   }
 506
 507   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 508   # common that are still here and library them.
 509   my $cust_main = new FS::cust_main ( {
 510     #'custnum'          => '',
 511     'agentnum'      => $agentnum,
 512     'refnum'        => $packet->{refnum}
 513                        || $conf->config('signup_server-default_refnum'),
 514
 515     map { $_ => $packet->{$_} } qw(
 516
 517       last first ss company address1 address2
 518       city county state zip country
 519       daytime night fax stateid stateid_state
 520
 521       ship_last ship_first ship_ss ship_company ship_address1 ship_address2
 522       ship_city ship_county ship_state ship_zip ship_country
 523       ship_daytime ship_night ship_fax
 524
 525       payby
 526       payinfo paycvv paydate payname paystate paytype
 527       paystart_month paystart_year payissue
 528       payip
 529
 530       referral_custnum comments
 531     )
 532
 533   } );
 534
 535   my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 536   if ( $conf->exists('agent_ship_address') && $agent->agent_custnum ) {
 537     my $agent_cust_main = $agent->agent_cust_main;
 538     my $prefix = length($agent_cust_main->ship_last) ? 'ship_' : '';
 539     $cust_main->set("ship_$_", $agent_cust_main->get("$prefix$_") )
 540       foreach qw( address1 city county state zip country );
 541
 542     $cust_main->set("ship_$_", $cust_main->get($_))
 543       foreach qw( last first );
 544
 545   }
 546
 547
 548   return { 'error' => "Illegal payment type" }
 549     unless grep { $_ eq $packet->{'payby'} }
 550                 $conf->config('signup_server-payby');
 551
 552   if (FS::payby->realtime($packet->{payby})) {
 553     my $payby = $packet->{payby};
 554
 555     my $agent = qsearchs('agent', { 'agentnum' => $agentnum });
 556     return { 'error' => "Unknown reseller" }
 557       unless $agent;
 558
 559     my $gw;
 560     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 561     if ( $gatewaynum ) {
 562       $gw = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 563       die "configured gatewaynum $gatewaynum not found!" if !$gw;
 564     }
 565     else {
 566       $gw = $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 567                                      'nofatal' => 1,
 568                                     );
 569     }
 570
 571     $cust_main->payby('BILL')   # MCRD better?
 572       if $gw && $gw->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 573   }
 574
 575   $cust_main->payinfo($cust_main->daytime)
 576     if $cust_main->payby eq 'LECB' && ! $cust_main->payinfo;
 577
 578   my @invoicing_list = $packet->{'invoicing_list'}
 579                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 580                          : ();
 581
 582   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 583   my $pkgpart = $1;
 584   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 585
 586   my $part_pkg =
 587     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 588       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 589   my $svcpart = $part_pkg->svcpart($svc_x);
 590
 591   my $reg_code = '';
 592   if ( $packet->{'reg_code'} ) {
 593     $reg_code = qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 594                                         'agentnum' => $agentnum,             } )
 595       or return { 'error' => 'Unknown registration code' };
 596   }
 597
 598   my $cust_pkg = new FS::cust_pkg ( {
 599     #later#'custnum' => $custnum,
 600     'pkgpart'    => $packet->{'pkgpart'},
 601     'promo_code' => $packet->{'promo_code'},
 602     'reg_code'   => $packet->{'reg_code'},
 603   } );
 604   #my $error = $cust_pkg->check;
 605   #return { 'error' => $error } if $error;
 606
 607   #should be all auto-magic and shit
 608   my @svc = ();
 609   if ( $svc_x eq 'svc_acct' ) {
 610
 611     my $svc = new FS::svc_acct {
 612       'svcpart'   => $svcpart,
 613       map { $_ => $packet->{$_} }
 614         qw( username _password sec_phrase popnum ),
 615     };
 616
 617     my @acct_snarf;
 618     my $snarfnum = 1;
 619     while (    exists($packet->{"snarf_machine$snarfnum"})
 620             && length($packet->{"snarf_machine$snarfnum"}) ) {
 621       my $acct_snarf = new FS::acct_snarf ( {
 622         'machine'   => $packet->{"snarf_machine$snarfnum"},
 623         'protocol'  => $packet->{"snarf_protocol$snarfnum"},
 624         'username'  => $packet->{"snarf_username$snarfnum"},
 625         '_password' => $packet->{"snarf_password$snarfnum"},
 626       } );
 627       $snarfnum++;
 628       push @acct_snarf, $acct_snarf;
 629     }
 630     $svc->child_objects( \@acct_snarf );
 631     push @svc, $svc;
 632
 633   } elsif ( $svc_x eq 'svc_phone' ) {
 634
 635     push @svc, new FS::svc_phone ( {
 636       'svcpart' => $svcpart,
 637        map { $_ => $packet->{$_} }
 638          qw( countrycode phonenum sip_password pin ),
 639     } );
 640
 641   } elsif ( $svc_x eq 'svc_pbx' ) {
 642
 643     push @svc, new FS::svc_pbx ( {
 644         'svcpart' => $svcpart,
 645         map { $_ => $packet->{$_} }
 646           qw( id title ),
 647         } );
 648
 649   } else {
 650     die "unknown signup service $svc_x";
 651   }
 652
 653   if ($packet->{'mac_addr'} && $conf->exists('signup_server-mac_addr_svcparts'))
 654   {
 655
 656     my %mac_addr_svcparts = map { $_ => 1 }
 657                             $conf->config('signup_server-mac_addr_svcparts');
 658     my @pkg_svc = grep { $_->quantity && $mac_addr_svcparts{$_->svcpart} }
 659                   $cust_pkg->part_pkg->pkg_svc;
 660
 661     return { 'error' => 'No service defined to assign mac address' }
 662       unless @pkg_svc;
 663
 664     my $svc = new FS::svc_acct {
 665       'svcpart'   => $pkg_svc[0]->svcpart, #multiple matches? alas..
 666       'username'  => $packet->{'mac_addr'},
 667       '_password' => '', #blank as requested (set passwordmin to 0)
 668     };
 669
 670     push @svc, $svc;
 671
 672   }
 673
 674   foreach my $svc ( @svc ) {
 675     my $y = $svc->setdefault; # arguably should be in new method
 676     return { 'error' => $y } if $y && !ref($y);
 677     #$error = $svc->check;
 678     #return { 'error' => $error } if $error;
 679   }
 680
 681   #setup a job dependancy to delay provisioning
 682   my $placeholder = new FS::queue ( {
 683     'job'    => 'FS::ClientAPI::Signup::__placeholder',
 684     'status' => 'locked',
 685   } );
 686   my $error = $placeholder->insert;
 687   return { 'error' => $error } if $error;
 688
 689   use Tie::RefHash;
 690   tie my %hash, 'Tie::RefHash';
 691   %hash = ( $cust_pkg => \@svc );
 692   #msgcat
 693   $error = $cust_main->insert(
 694     \%hash,
 695     \@invoicing_list,
 696     'depend_jobnum' => $placeholder->jobnum,
 697   );
 698   if ( $error ) {
 699     my $perror = $placeholder->delete;
 700     $error .= " (Additionally, error removing placeholder: $perror)" if $perror;
 701     return { 'error' => $error };
 702   }
 703
 704   if ( $conf->exists('signup_server-realtime') ) {
 705
 706     #warn "$me Billing customer...\n" if $Debug;
 707
 708     my $bill_error = $cust_main->bill;
 709     #warn "$me error billing new customer: $bill_error"
 710     #  if $bill_error;
 711
 712     $bill_error = $cust_main->apply_payments_and_credits;
 713     #warn "$me error applying payments and credits for".
 714     #     " new customer: $bill_error"
 715     #  if $bill_error;
 716
 717     $bill_error = $cust_main->realtime_collect(
 718        method        => FS::payby->payby2bop( $packet->{payby} ),
 719        depend_jobnum => $placeholder->jobnum,
 720        selfservice   => 1,
 721     );
 722     #warn "$me error collecting from new customer: $bill_error"
 723     #  if $bill_error;
 724
 725     if ($bill_error && ref($bill_error) eq 'HASH') {
 726       return { 'error' => '_collect',
 727                ( map { $_ => $bill_error->{$_} }
 728                  qw(popup_url reference collectitems)
 729                ),
 730                amount => $cust_main->balance,
 731              };
 732     }
 733
 734     $bill_error = $cust_main->apply_payments_and_credits;
 735     #warn "$me error applying payments and credits for".
 736     #     " new customer: $bill_error"
 737     #  if $bill_error;
 738
 739     if ( $cust_main->balance > 0 ) {
 740
 741       #this makes sense.  credit is "un-doing" the invoice
 742       $cust_main->credit( $cust_main->balance, 'signup server decline',
 743                           'reason_type' => $conf->config('signup_credit_type'),
 744                         );
 745       $cust_main->apply_credits;
 746
 747       #should check list for errors...
 748       #$cust_main->suspend;
 749       local $FS::svc_Common::noexport_hack = 1;
 750       $cust_main->cancel('quiet'=>1);
 751
 752       my $perror = $placeholder->depended_delete;
 753       warn "error removing provisioning jobs after decline: $perror" if $perror;
 754       unless ( $perror ) {
 755         $perror = $placeholder->delete;
 756         warn "error removing placeholder after decline: $perror" if $perror;
 757       }
 758
 759       return { 'error' => '_decline' };
 760     }
 761
 762   }
 763
 764   if ( $reg_code ) {
 765     $error = $reg_code->delete;
 766     return { 'error' => $error } if $error;
 767   }
 768
 769   $error = $placeholder->delete;
 770   return { 'error' => $error } if $error;
 771
 772   my %return = ( 'error'          => '',
 773                  'signup_service' => $svc_x,
 774                  'custnum'        => $cust_main->custnum,
 775                );
 776
 777   if ( $svc[0] ) {
 778
 779     $return{'svcnum'} = $svc[0]->svcnum;
 780
 781     if ( $svc_x eq 'svc_acct' ) {
 782       $return{$_} = $svc[0]->$_() for qw( username _password );
 783     } elsif ( $svc_x eq 'svc_phone' ) {
 784       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
 785     } elsif ( $svc_x eq 'svc_pbx' ) {
 786       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
 787      } else {
 788       return {'error' => "configuration error: unknown signup service $svc_x"};
 789       #die "unknown signup service $svc_x";
 790       # return an error that's visible to someone somewhere
 791     }
 792
 793   }
 794
 795   return \%return;
 796
 797 }
 798
 799 sub capture_payment {
 800   my $packet = shift;
 801
 802   warn "$me capture_payment called on $packet\n" if $DEBUG;
 803
 804   ###
 805   # identify processor/gateway from called back URL
 806   ###
 807
 808   my $conf = new FS::Conf;
 809
 810   my $payment_gateway;
 811   if ( my $gwnum = $conf->config('selfservice-payment_gateway') ) {
 812     $payment_gateway = qsearchs('payment_gateway', { 'gatewaynum' => $gwnum })
 813       or die "configured gatewaynum $gwnum not found!";
 814   }
 815   else {
 816     my $url = $packet->{url};
 817
 818     $payment_gateway = qsearchs('payment_gateway',
 819         { 'gateway_callback_url' => popurl(0, $url) }
 820       );
 821     if (!$payment_gateway) {
 822
 823       my ( $processor, $login, $password, $action, @bop_options ) =
 824         $conf->config('business-onlinepayment');
 825       $action ||= 'normal authorization';
 826       pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
 827       die "No real-time processor is enabled - ".
 828           "did you set the business-onlinepayment configuration value?\n"
 829         unless $processor;
 830
 831       $payment_gateway = new FS::payment_gateway( {
 832         gateway_namespace => $conf->config('business-onlinepayment-namespace'),
 833         gateway_module    => $processor,
 834         gateway_username  => $login,
 835         gateway_password  => $password,
 836         gateway_action    => $action,
 837         options   => [ ( @bop_options ) ],
 838       });
 839     }
 840   }
 841
 842   die "No real-time third party processor is enabled - ".
 843       "did you set the business-onlinepayment configuration value?\n*"
 844     unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 845
 846   ###
 847   # locate pending transaction
 848   ###
 849
 850   eval "use Business::OnlineThirdPartyPayment";
 851   die $@ if $@;
 852
 853   my $transaction =
 854     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
 855                                            @{ [ $payment_gateway->options ] },
 856                                          );
 857
 858   my $paypendingnum = $transaction->reference($packet->{data});
 859
 860   my $cust_pay_pending =
 861     qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
 862
 863   unless ($cust_pay_pending) {
 864     my $bill_error = "No payment is being processed with id $paypendingnum".
 865                      "; Transaction aborted.";
 866     return { error => '_decline', bill_error => $bill_error };
 867   }
 868
 869   if ($cust_pay_pending->status ne 'pending') {
 870     my $bill_error = "Payment with id $paypendingnum is not pending, but ".
 871                      $cust_pay_pending->status.  "; Transaction aborted.";
 872     return { error => '_decline', bill_error => $bill_error };
 873   }
 874
 875   my $cust_main = $cust_pay_pending->cust_main;
 876   my $bill_error =
 877     $cust_main->realtime_botpp_capture( $cust_pay_pending,
 878       %{$packet->{data}},
 879       apply => 1,
 880   );
 881
 882   return { 'error'      => ( $bill_error->{bill_error} ? '_decline' : '' ),
 883            %$bill_error,
 884          };
 885
 886 }
 887
 888 1;