FS/FS/ClientAPI/Signup.pm

   1 package FS::ClientAPI::Signup;
   2
   3 use strict;
   4 use vars qw($DEBUG $me);
   5 use Data::Dumper;
   6 use Tie::RefHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearch qsearchs dbdef);
   9 use FS::CGI qw(popurl);
  10 use FS::Msgcat qw(gettext);
  11 use FS::Misc qw(card_types);
  12 use FS::ClientAPI_SessionCache;
  13 use FS::agent;
  14 use FS::cust_main_county;
  15 use FS::part_pkg;
  16 use FS::svc_acct_pop;
  17 use FS::cust_main;
  18 use FS::cust_pkg;
  19 use FS::svc_acct;
  20 use FS::svc_phone;
  21 use FS::acct_snarf;
  22 use FS::queue;
  23 use FS::reg_code;
  24 use FS::payby;
  25
  26 $DEBUG = 0;
  27 $me = '[FS::ClientAPI::Signup]';
  28
  29 sub signup_info {
  30   my $packet = shift;
  31
  32   warn "$me signup_info called on $packet\n" if $DEBUG;
  33
  34   my $conf = new FS::Conf;
  35   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
  36
  37   my $cache = new FS::ClientAPI_SessionCache( {
  38     'namespace' => 'FS::ClientAPI::Signup',
  39   } );
  40   my $signup_info_cache = $cache->get('signup_info_cache');
  41
  42   if ( $signup_info_cache ) {
  43
  44     warn "$me loading cached signup info\n" if $DEBUG > 1;
  45
  46   } else {
  47
  48     warn "$me populating signup info cache\n" if $DEBUG > 1;
  49
  50     my $agentnum2part_pkg =
  51       {
  52         map {
  53           my $agent = $_;
  54           my $href = $agent->pkgpart_hashref;
  55           $agent->agentnum =>
  56             [
  57               map { { 'payby'       => [ $_->payby ],
  58                       'freq_pretty' => $_->freq_pretty,
  59                       'options'     => { $_->options },
  60                       %{$_->hashref}
  61                   } }
  62                 grep { $_->svcpart($svc_x)
  63                        && ( $href->{ $_->pkgpart }
  64                             || ( $_->agentnum
  65                                  && $_->agentnum == $agent->agentnum
  66                                )
  67                           )
  68                      }
  69                   qsearch( 'part_pkg', { 'disabled' => '' } )
  70             ];
  71         } qsearch('agent', { 'disabled' => '' })
  72       };
  73
  74     my $msgcat = { map { $_=>gettext($_) }
  75                        qw( passwords_dont_match invalid_card unknown_card_type
  76                            not_a empty_password illegal_or_empty_text )
  77                  };
  78     warn "msgcat: ". Dumper($msgcat). "\n" if $DEBUG > 2;
  79
  80     my $label = { map { $_ => FS::Msgcat::_gettext($_) }
  81                       qw( stateid stateid_state )
  82                 };
  83     warn "label: ". Dumper($label). "\n" if $DEBUG > 2;
  84
  85     my @agent_fields = qw( agentnum agent );
  86
  87     $signup_info_cache = {
  88       'cust_main_county' => [ map $_->hashref,
  89                                   qsearch('cust_main_county', {} )
  90                             ],
  91
  92       'agent' => [ map { my $agent = $_;
  93                          map { $_ => $agent->get($_) } @agent_fields;
  94                        }
  95                        qsearch('agent', { 'disabled' => '' } )
  96                  ],
  97
  98       'part_referral' => [ map $_->hashref,
  99                                qsearch('part_referral', { 'disabled' => '' } )
 100                          ],
 101
 102       'agentnum2part_pkg' => $agentnum2part_pkg,
 103
 104       'svc_acct_pop' => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 105
 106       'emailinvoiceonly' => $conf->exists('emailinvoiceonly'),
 107
 108       'security_phrase' => $conf->exists('security_phrase'),
 109
 110       'nomadix' => $conf->exists('signup_server-nomadix'),
 111
 112       'payby' => [ $conf->config('signup_server-payby') ],
 113
 114       'card_types' => card_types(),
 115
 116       'paytypes' => [ @FS::cust_main::paytypes ],
 117
 118       'cvv_enabled' => 1,
 119
 120       'stateid_enabled' => $conf->exists('show_stateid'),
 121
 122       'paystate_enabled' => $conf->exists('show_bankstate'),
 123
 124       'ship_enabled' => 1,
 125
 126       'msgcat' => $msgcat,
 127
 128       'label' => $label,
 129
 130       'statedefault' => scalar($conf->config('statedefault')) || 'CA',
 131
 132       'countrydefault' => scalar($conf->config('countrydefault')) || 'US',
 133
 134       'refnum' => scalar($conf->config('signup_server-default_refnum')),
 135
 136       'default_pkgpart' => scalar($conf->config('signup_server-default_pkgpart')),
 137
 138       'signup_service' => $svc_x,
 139       'default_svcpart' => scalar($conf->config('signup_server-default_svcpart')),
 140
 141       'head'         => join("\n", $conf->config('selfservice-head') ),
 142       'body_header'  => join("\n", $conf->config('selfservice-body_header') ),
 143       'body_footer'  => join("\n", $conf->config('selfservice-body_footer') ),
 144       'body_bgcolor' => scalar( $conf->config('selfservice-body_bgcolor') ),
 145       'box_bgcolor'  => scalar( $conf->config('selfservice-box_bgcolor')  ),
 146
 147       'company_name'   => scalar($conf->config('company_name')),
 148
 149       #per-agent?
 150       'agent_ship_address' => scalar($conf->exists('agent-ship_address')),
 151
 152       'no_company'        => scalar($conf->exists('signup-no_company')),
 153       'require_phone'     => scalar($conf->exists('cust_main-require_phone')),
 154       'recommend_daytime' => scalar($conf->exists('signup-recommend_daytime')),
 155       'recommend_email'   => scalar($conf->exists('signup-recommend_email')),
 156
 157     };
 158
 159     $cache->set('signup_info_cache', $signup_info_cache);
 160
 161   }
 162
 163   my $signup_info = { %$signup_info_cache };
 164   warn "$me signup info loaded\n" if $DEBUG > 1;
 165   warn Dumper($signup_info). "\n" if $DEBUG > 2;
 166
 167   my @addl = qw( signup_server-classnum2 signup_server-classnum3 );
 168
 169   if ( grep { $conf->exists($_) } @addl ) {
 170
 171     $signup_info->{optional_packages} = [];
 172
 173     foreach my $addl ( @addl ) {
 174
 175       warn "$me adding optional package info\n" if $DEBUG > 1;
 176
 177       my $classnum = $conf->config($addl) or next;
 178
 179       my @pkgs = map { {
 180                          'freq_pretty' => $_->freq_pretty,
 181                          'options'     => { $_->options },
 182                          %{ $_->hashref }
 183                        };
 184                      }
 185                      qsearch( 'part_pkg', { classnum => $classnum } );
 186
 187       push @{$signup_info->{optional_packages}}, \@pkgs;
 188
 189       warn "$me done adding opt. package info for $classnum\n" if $DEBUG > 1;
 190
 191     }
 192
 193   }
 194
 195   my $agentnum = $packet->{'agentnum'}
 196                  || $conf->config('signup_server-default_agentnum');
 197   $agentnum =~ /^(\d*)$/ or die "illegal agentnum";
 198   $agentnum = $1;
 199
 200   my $session = '';
 201   if ( exists $packet->{'session_id'} ) {
 202
 203     warn "$me loading agent session\n" if $DEBUG > 1;
 204     my $cache = new FS::ClientAPI_SessionCache( {
 205       'namespace' => 'FS::ClientAPI::Agent',
 206     } );
 207     $session = $cache->get($packet->{'session_id'});
 208     if ( $session ) {
 209       $agentnum = $session->{'agentnum'};
 210     } else {
 211       return { 'error' => "Can't resume session" }; #better error message
 212     }
 213     warn "$me done loading agent session\n" if $DEBUG > 1;
 214
 215   } elsif ( exists $packet->{'customer_session_id'} ) {
 216
 217     warn "$me loading customer session\n" if $DEBUG > 1;
 218     my $cache = new FS::ClientAPI_SessionCache( {
 219       'namespace' => 'FS::ClientAPI::MyAccount',
 220     } );
 221     $session = $cache->get($packet->{'customer_session_id'});
 222     if ( $session ) {
 223       my $custnum = $session->{'custnum'};
 224       my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum });
 225       return { 'error' => "Can't find your customer record" } unless $cust_main;
 226       $agentnum = $cust_main->agentnum;
 227     } else {
 228       return { 'error' => "Can't resume session" }; #better error message
 229     }
 230     warn "$me done loading customer session\n" if $DEBUG > 1;
 231
 232   }
 233
 234   $signup_info->{'part_pkg'} = [];
 235
 236   if ( $packet->{'reg_code'} ) {
 237
 238     warn "$me setting package list via reg_code\n" if $DEBUG > 1;
 239
 240     $signup_info->{'part_pkg'} =
 241       [ map { { 'payby'       => [ $_->payby ],
 242                 'freq_pretty' => $_->freq_pretty,
 243                 'options'     => { $_->options },
 244                 %{$_->hashref}
 245               };
 246             }
 247           grep { $_->svcpart($svc_x) }
 248           map { $_->part_pkg }
 249             qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 250                                     'agentnum' => $agentnum,              } )
 251
 252       ];
 253
 254     $signup_info->{'error'} = 'Unknown registration code'
 255       unless @{ $signup_info->{'part_pkg'} };
 256
 257     warn "$me done setting package list via reg_code\n" if $DEBUG > 1;
 258
 259   } elsif ( $packet->{'promo_code'} ) {
 260
 261     warn "$me setting package list via promo_code\n" if $DEBUG > 1;
 262
 263     $signup_info->{'part_pkg'} =
 264       [ map { { 'payby'   => [ $_->payby ],
 265                 'freq_pretty' => $_->freq_pretty,
 266                 'options'     => { $_->options },
 267                 %{$_->hashref}
 268             } }
 269           grep { $_->svcpart($svc_x) }
 270             qsearch( 'part_pkg', { 'promo_code' => {
 271                                      op=>'ILIKE',
 272                                      value=>$packet->{'promo_code'}
 273                                    },
 274                                    'disabled'   => '',                  } )
 275       ];
 276
 277     $signup_info->{'error'} = 'Unknown promotional code'
 278       unless @{ $signup_info->{'part_pkg'} };
 279
 280     warn "$me done setting package list via promo_code\n" if $DEBUG > 1;
 281   }
 282
 283   if ( $agentnum ) {
 284
 285     warn "$me setting agent-specific payment flag\n" if $DEBUG > 1;
 286     my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 287     warn "$me has agent $agent\n" if $DEBUG > 1;
 288     if ( $agent ) { #else complain loudly?
 289       $signup_info->{'hide_payment_fields'} = [];
 290       foreach my $payby (@{$signup_info->{payby}}) {
 291         warn "$me checking $payby payment fields\n" if $DEBUG > 1;
 292         my $hide = 0;
 293         if ( FS::payby->realtime($payby) ) {
 294           my $payment_gateway =
 295             $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 296                                      'nofatal' => 1,
 297                                    );
 298           if ( $payment_gateway
 299                  && $payment_gateway->gateway_namespace
 300                       eq 'Business::OnlineThirdPartyPayment'
 301              ) {
 302             warn "$me hiding $payby payment fields\n" if $DEBUG > 1;
 303             $hide = 1;
 304           }
 305         }
 306         push @{$signup_info->{'hide_payment_fields'}}, $hide;
 307       }
 308     }
 309     warn "$me done setting agent-specific payment flag\n" if $DEBUG > 1;
 310
 311     warn "$me setting agent-specific package list\n" if $DEBUG > 1;
 312     $signup_info->{'part_pkg'} = $signup_info->{'agentnum2part_pkg'}{$agentnum}
 313       unless @{ $signup_info->{'part_pkg'} };
 314     warn "$me done setting agent-specific package list\n" if $DEBUG > 1;
 315
 316     warn "$me setting agent-specific adv. source list\n" if $DEBUG > 1;
 317     $signup_info->{'part_referral'} =
 318       [
 319         map { $_->hashref }
 320           qsearch( {
 321                      'table'     => 'part_referral',
 322                      'hashref'   => { 'disabled' => '' },
 323                      'extra_sql' => "AND (    agentnum = $agentnum  ".
 324                                     "      OR agentnum IS NULL    ) ",
 325                    },
 326                  )
 327       ];
 328     warn "$me done setting agent-specific adv. source list\n" if $DEBUG > 1;
 329
 330     $signup_info->{'agent_name'} = $agent->agent;
 331
 332     $signup_info->{'company_name'} = $conf->config('company_name', $agentnum);
 333
 334     if ( $signup_info->{'agent_ship_address'} && $agent->agent_custnum ) {
 335       my $cust_main = $agent->agent_cust_main;
 336       my $prefix = length($cust_main->ship_last) ? 'ship_' : '';
 337       $signup_info->{"ship_$_"} = $cust_main->get("$prefix$_")
 338         foreach qw( address1 city county state zip country );
 339     }
 340
 341   }
 342   # else {
 343   # delete $signup_info->{'part_pkg'};
 344   #}
 345
 346   warn "$me sorting package list\n" if $DEBUG > 1;
 347   $signup_info->{'part_pkg'} = [ sort { $a->{pkg} cmp $b->{pkg} }  # case?
 348                                       @{ $signup_info->{'part_pkg'} }
 349                                ];
 350   warn "$me done sorting package list\n" if $DEBUG > 1;
 351
 352   if ( exists $packet->{'session_id'} ) {
 353     my $agent_signup_info = { %$signup_info };
 354     delete $agent_signup_info->{agentnum2part_pkg};
 355     $agent_signup_info->{'agent'} = $session->{'agent'};
 356     $agent_signup_info;
 357   } else {
 358     $signup_info;
 359   }
 360
 361 }
 362
 363 sub domain_select_hash {
 364   my $packet = shift;
 365
 366   my $response = {};
 367
 368   if ($packet->{pkgpart}) {
 369     my $part_pkg = qsearchs('part_pkg' => { 'pkgpart' => $packet->{pkgpart} } );
 370     #$packet->{svcpart} = $part_pkg->svcpart('svc_acct')
 371     $packet->{svcpart} = $part_pkg->svcpart
 372       if $part_pkg;
 373   }
 374
 375   if ($packet->{svcpart}) {
 376     my $part_svc = qsearchs('part_svc' => { 'svcpart' => $packet->{svcpart} } );
 377     $response->{'domsvc'} = $part_svc->part_svc_column('domsvc')->columnvalue
 378       if ($part_svc && $part_svc->part_svc_column('domsvc')->columnflag  eq 'D');
 379   }
 380
 381   $response->{'domains'}
 382     = { domain_select_hash FS::svc_acct( map { $_ => $packet->{$_} }
 383                                                  qw(svcpart pkgnum)
 384                                        ) };
 385
 386   $response;
 387 }
 388
 389 sub new_customer {
 390   my $packet = shift;
 391
 392   my $conf = new FS::Conf;
 393   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 394
 395   if ( $svc_x eq 'svc_acct' ) {
 396
 397     #things that aren't necessary in base class, but are for signup server
 398       #return "Passwords don't match"
 399       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 400     return { 'error' => gettext('empty_password') }
 401       unless length($packet->{'_password'});
 402     # a bit inefficient for large numbers of pops
 403     return { 'error' => gettext('no_access_number_selected') }
 404       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 405
 406   }
 407
 408   my $agentnum;
 409   if ( exists $packet->{'session_id'} ) {
 410     my $cache = new FS::ClientAPI_SessionCache( {
 411       'namespace' => 'FS::ClientAPI::Agent',
 412     } );
 413     my $session = $cache->get($packet->{'session_id'});
 414     if ( $session ) {
 415       $agentnum = $session->{'agentnum'};
 416     } else {
 417       return { 'error' => "Can't resume session" }; #better error message
 418     }
 419   } else {
 420     $agentnum = $packet->{agentnum}
 421                 || $conf->config('signup_server-default_agentnum');
 422   }
 423
 424   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 425   # common that are still here and library them.
 426   my $cust_main = new FS::cust_main ( {
 427     #'custnum'          => '',
 428     'agentnum'      => $agentnum,
 429     'refnum'        => $packet->{refnum}
 430                        || $conf->config('signup_server-default_refnum'),
 431
 432     map { $_ => $packet->{$_} } qw(
 433
 434       last first ss company address1 address2
 435       city county state zip country
 436       daytime night fax stateid stateid_state
 437
 438       ship_last ship_first ship_ss ship_company ship_address1 ship_address2
 439       ship_city ship_county ship_state ship_zip ship_country
 440       ship_daytime ship_night ship_fax
 441
 442       payby
 443       payinfo paycvv paydate payname paystate paytype
 444       paystart_month paystart_year payissue
 445       payip
 446
 447       referral_custnum comments
 448     )
 449
 450   } );
 451
 452   my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 453   if ( $conf->exists('agent_ship_address') && $agent->agent_custnum ) {
 454     my $agent_cust_main = $agent->agent_cust_main;
 455     my $prefix = length($agent_cust_main->ship_last) ? 'ship_' : '';
 456     $cust_main->set("ship_$_", $agent_cust_main->get("$prefix$_") )
 457       foreach qw( address1 city county state zip country );
 458
 459     $cust_main->set("ship_$_", $cust_main->get($_))
 460       foreach qw( last first );
 461
 462   }
 463
 464
 465   return { 'error' => "Illegal payment type" }
 466     unless grep { $_ eq $packet->{'payby'} }
 467                 $conf->config('signup_server-payby');
 468
 469   if (FS::payby->realtime($packet->{payby})) {
 470     my $payby = $packet->{payby};
 471
 472     my $agent = qsearchs('agent', { 'agentnum' => $agentnum });
 473     return { 'error' => "Unknown reseller" }
 474       unless $agent;
 475
 476     my $gw = $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 477                                       'nofatal' => 1,
 478                                     );
 479
 480     $cust_main->payby('BILL')   # MCRD better?
 481       if $gw && $gw->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 482   }
 483
 484   $cust_main->payinfo($cust_main->daytime)
 485     if $cust_main->payby eq 'LECB' && ! $cust_main->payinfo;
 486
 487   my @invoicing_list = $packet->{'invoicing_list'}
 488                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 489                          : ();
 490
 491   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 492   my $pkgpart = $1;
 493   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 494
 495   my $part_pkg =
 496     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 497       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 498   my $svcpart = $part_pkg->svcpart($svc_x);
 499
 500   my $reg_code = '';
 501   if ( $packet->{'reg_code'} ) {
 502     $reg_code = qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 503                                         'agentnum' => $agentnum,             } )
 504       or return { 'error' => 'Unknown registration code' };
 505   }
 506
 507   my $cust_pkg = new FS::cust_pkg ( {
 508     #later#'custnum' => $custnum,
 509     'pkgpart'    => $packet->{'pkgpart'},
 510     'promo_code' => $packet->{'promo_code'},
 511     'reg_code'   => $packet->{'reg_code'},
 512   } );
 513   #my $error = $cust_pkg->check;
 514   #return { 'error' => $error } if $error;
 515
 516   #should be all auto-magic and shit
 517   my @svc = ();
 518   if ( $svc_x eq 'svc_acct' ) {
 519
 520     my $svc = new FS::svc_acct {
 521       'svcpart'   => $svcpart,
 522       map { $_ => $packet->{$_} }
 523         qw( username _password sec_phrase popnum ),
 524     };
 525
 526     my @acct_snarf;
 527     my $snarfnum = 1;
 528     while (    exists($packet->{"snarf_machine$snarfnum"})
 529             && length($packet->{"snarf_machine$snarfnum"}) ) {
 530       my $acct_snarf = new FS::acct_snarf ( {
 531         'machine'   => $packet->{"snarf_machine$snarfnum"},
 532         'protocol'  => $packet->{"snarf_protocol$snarfnum"},
 533         'username'  => $packet->{"snarf_username$snarfnum"},
 534         '_password' => $packet->{"snarf_password$snarfnum"},
 535       } );
 536       $snarfnum++;
 537       push @acct_snarf, $acct_snarf;
 538     }
 539     $svc->child_objects( \@acct_snarf );
 540
 541     push @svc, $svc;
 542
 543   } elsif ( $svc_x eq 'svc_phone' ) {
 544
 545     my $svc = new FS::svc_phone ( {
 546       'svcpart' => $svcpart,
 547        map { $_ => $packet->{$_} }
 548          qw( countrycode phonenum sip_password pin ),
 549     } );
 550
 551     push @svc, $svc;
 552
 553   } else {
 554     die "unknown signup service $svc_x";
 555   }
 556   my $y = $svc[0]->setdefault; # arguably should be in new method
 557   return { 'error' => $y } if $y && !ref($y);
 558
 559   if ($packet->{'mac_addr'} && $conf->exists('signup_server-mac_addr_svcparts'))
 560   {
 561
 562     my %mac_addr_svcparts = map { $_ => 1 }
 563                             $conf->config('signup_server-mac_addr_svcparts');
 564     my @pkg_svc = grep { $_->quantity && $mac_addr_svcparts{$_->svcpart} }
 565                   $cust_pkg->part_pkg->pkg_svc;
 566
 567     return { 'error' => 'No service defined to assign mac address' }
 568       unless @pkg_svc;
 569
 570     my $svc = new FS::svc_acct {
 571       'svcpart'   => $pkg_svc[0]->svcpart, #multiple matches? alas..
 572       'username'  => $packet->{'mac_addr'},
 573       '_password' => '', #blank as requested (set passwordmin to 0)
 574     };
 575
 576     my $y = $svc->setdefault; # arguably should be in new method
 577     return { 'error' => $y } if $y && !ref($y);
 578
 579     push @svc, $svc;
 580
 581   }
 582
 583   #$error = $svc->check;
 584   #return { 'error' => $error } if $error;
 585
 586   #setup a job dependancy to delay provisioning
 587   my $placeholder = new FS::queue ( {
 588     'job'    => 'FS::ClientAPI::Signup::__placeholder',
 589     'status' => 'locked',
 590   } );
 591   my $error = $placeholder->insert;
 592   return { 'error' => $error } if $error;
 593
 594   use Tie::RefHash;
 595   tie my %hash, 'Tie::RefHash';
 596   %hash = ( $cust_pkg => \@svc );
 597   #msgcat
 598   $error = $cust_main->insert(
 599     \%hash,
 600     \@invoicing_list,
 601     'depend_jobnum' => $placeholder->jobnum,
 602   );
 603   if ( $error ) {
 604     my $perror = $placeholder->delete;
 605     $error .= " (Additionally, error removing placeholder: $perror)" if $perror;
 606     return { 'error' => $error };
 607   }
 608
 609   if ( $conf->exists('signup_server-realtime') ) {
 610
 611     #warn "[fs_signup_server] Billing customer...\n" if $Debug;
 612
 613     my $bill_error = $cust_main->bill;
 614     #warn "[fs_signup_server] error billing new customer: $bill_error"
 615     #  if $bill_error;
 616
 617     $bill_error = $cust_main->apply_payments_and_credits;
 618     #warn "[fs_signup_server] error applying payments and credits for".
 619     #     " new customer: $bill_error"
 620     #  if $bill_error;
 621
 622     if ($cust_main->_new_bop_required()) {
 623       $bill_error = $cust_main->realtime_collect(
 624          method        => FS::payby->payby2bop( $packet->{payby} ),
 625          depend_jobnum => $placeholder->jobnum,
 626       );
 627     } else {
 628       $bill_error = $cust_main->collect('realtime' => 1);
 629     }
 630     #warn "[fs_signup_server] error collecting from new customer: $bill_error"
 631     #  if $bill_error;
 632
 633     if ($bill_error && ref($bill_error) eq 'HASH') {
 634       return { 'error' => '_collect',
 635                ( map { $_ => $bill_error->{$_} }
 636                  qw(popup_url reference collectitems)
 637                ),
 638                amount => $cust_main->balance,
 639              };
 640     }
 641
 642     if ( $cust_main->balance > 0 ) {
 643
 644       #this makes sense.  credit is "un-doing" the invoice
 645       $cust_main->credit( $cust_main->balance, 'signup server decline',
 646                           'reason_type' => $conf->config('signup_credit_type'),
 647                         );
 648       $cust_main->apply_credits;
 649
 650       #should check list for errors...
 651       #$cust_main->suspend;
 652       local $FS::svc_Common::noexport_hack = 1;
 653       $cust_main->cancel('quiet'=>1);
 654
 655       my $perror = $placeholder->depended_delete;
 656       warn "error removing provisioning jobs after decline: $perror" if $perror;
 657       unless ( $perror ) {
 658         $perror = $placeholder->delete;
 659         warn "error removing placeholder after decline: $perror" if $perror;
 660       }
 661
 662       return { 'error' => '_decline' };
 663     }
 664
 665   }
 666
 667   if ( $reg_code ) {
 668     $error = $reg_code->delete;
 669     return { 'error' => $error } if $error;
 670   }
 671
 672   $error = $placeholder->delete;
 673   return { 'error' => $error } if $error;
 674
 675   my %return = ( 'error'          => '',
 676                  'signup_service' => $svc_x,
 677                );
 678
 679   if ( $svc_x eq 'svc_acct' ) {
 680     $return{$_} = $svc[0]->$_() for qw( username _password );
 681   } elsif ( $svc_x eq 'svc_phone' ) {
 682     $return{$_} = $svc[0]->$_() for qw( countrycode phonenum sip_password pin );
 683   } else {
 684     die "unknown signup service $svc_x";
 685   }
 686
 687   return \%return;
 688
 689 }
 690
 691 sub capture_payment {
 692   my $packet = shift;
 693
 694   warn "$me capture_payment called on $packet\n" if $DEBUG;
 695
 696   ###
 697   # identify processor/gateway from called back URL
 698   ###
 699
 700   my $conf = new FS::Conf;
 701
 702   my $url = $packet->{url};
 703   my $payment_gateway =
 704     qsearchs('payment_gateway', { 'gateway_callback_url' => popurl(0, $url) } );
 705
 706   unless ($payment_gateway) {
 707
 708     my ( $processor, $login, $password, $action, @bop_options ) =
 709       $conf->config('business-onlinepayment');
 710     $action ||= 'normal authorization';
 711     pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
 712     die "No real-time processor is enabled - ".
 713         "did you set the business-onlinepayment configuration value?\n"
 714       unless $processor;
 715
 716     $payment_gateway = new FS::payment_gateway( {
 717       gateway_namespace => $conf->config('business-onlinepayment-namespace'),
 718       gateway_module    => $processor,
 719       gateway_username  => $login,
 720       gateway_password  => $password,
 721       gateway_action    => $action,
 722       options   => [ ( @bop_options ) ],
 723     });
 724
 725   }
 726
 727   die "No real-time third party processor is enabled - ".
 728       "did you set the business-onlinepayment configuration value?\n*"
 729     unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 730
 731   ###
 732   # locate pending transaction
 733   ###
 734
 735   eval "use Business::OnlineThirdPartyPayment";
 736   die $@ if $@;
 737
 738   my $transaction =
 739     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
 740                                            @{ [ $payment_gateway->options ] },
 741                                          );
 742
 743   my $paypendingnum = $transaction->reference($packet->{data});
 744
 745   my $cust_pay_pending =
 746     qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
 747
 748   unless ($cust_pay_pending) {
 749     my $bill_error = "No payment is being processed with id $paypendingnum".
 750                      "; Transaction aborted.";
 751     return { error => '_decline', bill_error => $bill_error };
 752   }
 753
 754   if ($cust_pay_pending->status ne 'pending') {
 755     my $bill_error = "Payment with id $paypendingnum is not pending, but ".
 756                      $cust_pay_pending->status.  "; Transaction aborted.";
 757     return { error => '_decline', bill_error => $bill_error };
 758   }
 759
 760   my $cust_main = $cust_pay_pending->cust_main;
 761   my $bill_error =
 762     $cust_main->realtime_botpp_capture( $cust_pay_pending, %{$packet->{data}} );
 763
 764   return { 'error'      => ( $bill_error->{bill_error} ? '_decline' : '' ),
 765            %$bill_error,
 766          };
 767
 768 }
 769
 770 1;