FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use 5.008; #require 5.8+ for Time::Local 1.05+
   4 use strict;
   5 use vars qw( $cache $DEBUG $me );
   6 use subs qw( _cache _provision );
   7 use IO::Scalar;
   8 use Data::Dumper;
   9 use Digest::MD5 qw(md5_hex);
  10 use Digest::SHA qw(sha512_hex);
  11 use Date::Format;
  12 use Time::Duration;
  13 use Time::Local qw(timelocal_nocheck);
  14 use Business::CreditCard 0.35;
  15 use HTML::Entities;
  16 use Text::CSV_XS;
  17 use Spreadsheet::WriteExcel;
  18 use OLE::Storage_Lite;
  19 use FS::UI::Web::small_custview qw(small_custview); #less doh
  20 use FS::UI::Web;
  21 use FS::UI::bytecount qw( display_bytecount );
  22 use FS::Conf;
  23 #use FS::UID qw(dbh);
  24 use FS::Record qw(qsearch qsearchs dbh);
  25 use FS::Msgcat qw(gettext);
  26 use FS::Misc qw(card_types money_pretty);
  27 use FS::Misc::DateTime qw(parse_datetime);
  28 use FS::TicketSystem;
  29 use FS::ClientAPI_SessionCache;
  30 use FS::cust_svc;
  31 use FS::svc_acct;
  32 use FS::svc_forward;
  33 use FS::svc_domain;
  34 use FS::svc_phone;
  35 use FS::svc_external;
  36 use FS::svc_dsl;
  37 use FS::dsl_device;
  38 use FS::part_svc;
  39 use FS::cust_main;
  40 use FS::cust_bill;
  41 use FS::legacy_cust_bill;
  42 use FS::cust_main_county;
  43 use FS::part_pkg;
  44 use FS::cust_pkg;
  45 use FS::payby;
  46 use FS::acct_rt_transaction;
  47 use FS::msg_template;
  48 use FS::contact;
  49 use FS::cust_contact;
  50 use FS::cust_location;
  51 use FS::cust_payby;
  52
  53 # for code organization
  54 use FS::ClientAPI::MyAccount::contact;
  55 use FS::ClientAPI::MyAccount::quotation;
  56
  57 $DEBUG = 0;
  58 $me = '[FS::ClientAPI::MyAccount]';
  59
  60 use vars qw( @cust_main_editable_fields @location_editable_fields );
  61 @cust_main_editable_fields = qw(
  62   first last company daytime night fax mobile
  63   locale
  64   ss stateid stateid_state
  65 );
  66 @location_editable_fields = qw(
  67   address1 address2 city county state zip country
  68 );
  69
  70
  71 BEGIN { #preload to reduce time customer_info takes
  72   if ( $FS::TicketSystem::system ) {
  73     warn "$me: initializing ticket system\n" if $DEBUG;
  74     FS::TicketSystem->init();
  75   }
  76 }
  77
  78 sub _cache {
  79   $cache ||= new FS::ClientAPI_SessionCache( {
  80                'namespace' => 'FS::ClientAPI::MyAccount',
  81              } );
  82 }
  83
  84 sub skin_info {
  85   my $p = shift;
  86
  87   my($context, $session, $custnum) = _custoragent_session_custnum($p);
  88   #return { 'error' => $session } if $context eq 'error';
  89
  90   my $agentnum = '';
  91   if ( $context eq 'customer' && $custnum ) {
  92
  93     my $sth = dbh->prepare('SELECT agentnum FROM cust_main WHERE custnum = ?')
  94       or die dbh->errstr;
  95
  96     $sth->execute($custnum) or die $sth->errstr;
  97
  98     $agentnum = $sth->fetchrow_arrayref->[0]
  99       or die "no agentnum for custnum $custnum";
 100
 101   #} elsif ( $context eq 'agent' ) {
 102   } elsif ( defined($p->{'agentnum'}) and $p->{'agentnum'} =~ /^(\d+)$/ ) {
 103     $agentnum = $1;
 104   }
 105   $p->{'agentnum'} = $agentnum;
 106
 107   my $conf = new FS::Conf;
 108
 109   #false laziness w/Signup.pm
 110
 111   my $skin_info_cache_agent = _cache->get("skin_info_cache_agent$agentnum");
 112
 113   if ( $skin_info_cache_agent ) {
 114
 115     warn "$me loading cached skin info for agentnum $agentnum\n"
 116       if $DEBUG > 1;
 117
 118   } else {
 119
 120     warn "$me populating skin info cache for agentnum $agentnum\n"
 121       if $DEBUG > 1;
 122
 123     $skin_info_cache_agent = {
 124       'agentnum' => $agentnum,
 125       ( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 126         qw( company_name date_format ) ),
 127       ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 128         qw( body_bgcolor box_bgcolor stripe1_bgcolor stripe2_bgcolor
 129             text_color link_color vlink_color hlink_color alink_color
 130             font title_color title_align title_size menu_bgcolor menu_fontsize
 131           )
 132       ),
 133       'menu_disable' => [ $conf->config('selfservice-menu_disable',$agentnum) ],
 134       ( map { $_ => $conf->exists("selfservice-$_", $agentnum ) }
 135         qw( menu_skipblanks menu_skipheadings menu_nounderline no_logo enable_payment_without_balance )
 136       ),
 137       ( map { $_ => scalar($conf->config_binary("selfservice-$_", $agentnum)) }
 138         qw( title_left_image title_right_image
 139             menu_top_image menu_body_image menu_bottom_image
 140           )
 141       ),
 142       'logo' => scalar($conf->config_binary('logo.png', $agentnum )),
 143       ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 144         qw( head body_header body_footer company_address ) ),
 145       'money_char' => $conf->config("money_char") || '$',
 146       'menu' => join("\n", $conf->config("ng_selfservice-menu", $agentnum ) ) ||
 147                 'main.php Home
 148
 149                  services.php Services
 150                  services.php My Services
 151                  services_new.php Order a new service
 152
 153                  personal.php Profile
 154                  personal.php Personal Information
 155                  password.php Change Password
 156
 157                  payment.php Payments
 158                  payment_cc.php Credit Card Payment
 159                  payment_ach.php Electronic Check Payment
 160                  payment_paypal.php PayPal Payment
 161                  payment_webpay.php Webpay Payments
 162
 163                  usage.php Usage
 164                  usage_data.php Data usage
 165                  usage_cdr.php Call usage
 166
 167                  tickets.php Help Desk
 168                  tickets.php Open Tickets
 169                  tickets_resolved.php Resolved Tickets
 170                  ticket_create.php Create a new ticket
 171
 172                  docs.php FAQs
 173
 174                  logout.php Logout
 175                 ',
 176     };
 177
 178     _cache->set("skin_info_cache_agent$agentnum", $skin_info_cache_agent);
 179
 180   }
 181
 182   #{ %$skin_info_cache_agent };
 183   $skin_info_cache_agent;
 184
 185 }
 186
 187 sub login_info {
 188   my $p = shift;
 189
 190   my $conf = new FS::Conf;
 191
 192   my %info = (
 193     %{ skin_info($p) },
 194     'phone_login'  => $conf->exists('selfservice_server-phone_login'),
 195     'single_domain'=> scalar($conf->config('selfservice_server-single_domain')),
 196     'banner_url'       => scalar($conf->config('selfservice-login_banner_url')),
 197     'banner_image_md5' =>
 198       md5_hex($conf->config_binary('selfservice-login_banner_image')),
 199   );
 200
 201   return \%info;
 202
 203 }
 204
 205 sub login_banner_image {
 206   my $p = shift;
 207   my $conf = new FS::Conf;
 208   my $image = $conf->config_binary('selfservice-login_banner_image');
 209   return {
 210     'md5'   => md5_hex($image),
 211     'image' => $image,
 212   };
 213 }
 214
 215 #false laziness w/FS::ClientAPI::passwd::passwd
 216 sub login {
 217   my $p = shift;
 218
 219   my $conf = new FS::Conf;
 220
 221   my $svc_x = '';
 222   my $session = {};
 223   if ( $p->{'domain'} eq 'svc_phone'
 224        && $conf->exists('selfservice_server-phone_login') ) {
 225
 226     my $svc_phone = qsearchs( 'svc_phone', { 'phonenum' => $p->{'username'} } );
 227     return { error => 'Number not found.' } unless $svc_phone;
 228
 229     #XXX?
 230     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 231     #return { error => 'Only primary user may log in.' }
 232     #  if $conf->exists('selfservice_server-primary_only')
 233     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 234
 235     return { error => 'Incorrect PIN.' }
 236       unless $svc_phone->check_pin($p->{'password'});
 237
 238     $svc_x = $svc_phone;
 239
 240   } elsif ( $p->{email}
 241               && (my $contact = FS::contact->by_selfservice_email($p->{email}))
 242           )
 243   {
 244     return { error => 'Incorrect contact password.' }
 245       unless $contact->authenticate_password($p->{'password'});
 246
 247     $session->{'contactnum'} = $contact->contactnum;
 248
 249     my @cust_contact = grep $_->selfservice_access, $contact->cust_contact;
 250     if ( scalar(@cust_contact) == 1 ) {
 251       $session->{'custnum'} = $cust_contact[0]->custnum;
 252     } elsif ( scalar(@cust_contact) ) {
 253       $session->{'customers'} = { map { $_->custnum => $_->cust_main->name }
 254                                     @cust_contact
 255                                 };
 256     } else {
 257       return { error => 'No customer self-service access for contact' }; #??
 258     }
 259
 260   } else {
 261
 262     ( $p->{username}, $p->{domain} ) = split('@', $p->{email}) if $p->{email};
 263
 264     my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
 265       or return { error => 'Domain '. $p->{'domain'}. ' not found' };
 266
 267     my @svc_acct = qsearch( 'svc_acct', { 'username'  => $p->{'username'},
 268                                           'domsvc'    => $svc_domain->svcnum, }
 269                           );
 270
 271     if ( $conf->exists('selfservice_server-login_svcpart') ) {
 272       my @svcpart = $conf->config('selfservice_server-login_svcpart');
 273       @svc_acct = grep { my $svcpart = $_->cust_svc->svcpart;
 274                          scalar( grep( $_ eq $svcpart, @svcpart ) );
 275                        }
 276                     @svc_acct;
 277     }
 278
 279     if ( $conf->exists('selfservice_server-primary_only') ) {
 280         @svc_acct =
 281           grep {
 282             my $cust_svc = $_->cust_svc;
 283             $cust_svc->cust_pkg->part_pkg->svcpart([qw( svc_acct svc_phone )])
 284               == $cust_svc->svcpart
 285           }
 286           @svc_acct;
 287     }
 288
 289     return { error => 'User not found.' } unless @svc_acct;
 290
 291     return { error => 'Multiple users.' } if scalar(@svc_acct) > 1;
 292
 293     my $svc_acct = $svc_acct[0];
 294
 295     if ( $conf->exists('selfservice_server-login_svcpart') ) {
 296       my @svcpart = $conf->config('selfservice_server-login_svcpart');
 297       my $svcpart = $svc_acct->cust_svc->svcpart;
 298       return { error => 'Invalid user.' }
 299         unless grep($_ eq $svcpart, @svcpart);
 300     }
 301
 302     return { error => 'Incorrect password.' }
 303       unless $svc_acct->check_password($p->{'password'});
 304
 305     $svc_x = $svc_acct;
 306
 307   }
 308
 309   if ( $svc_x ) {
 310
 311     $session->{'svcnum'} = $svc_x->svcnum;
 312
 313     my $cust_svc = $svc_x->cust_svc;
 314     my $cust_pkg = $cust_svc->cust_pkg;
 315     if ( $cust_pkg ) {
 316       my $cust_main = $cust_pkg->cust_main;
 317       $session->{'custnum'} = $cust_main->custnum;
 318       if ( $conf->exists('pkg-balances') ) {
 319         my @cust_pkg = grep { $_->part_pkg->freq !~ /^(0|$)/ }
 320                             $cust_main->ncancelled_pkgs;
 321         $session->{'pkgnum'} = $cust_pkg->pkgnum
 322           if scalar(@cust_pkg) > 1;
 323       }
 324     }
 325
 326     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 327     #return { error => 'Only primary user may log in.' }
 328     #  if $conf->exists('selfservice_server-primary_only')
 329     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 330     my $part_pkg = $cust_pkg->part_pkg;
 331     return { error => 'Only primary user may log in.' }
 332       if $conf->exists('selfservice_server-primary_only')
 333          && $cust_svc->svcpart != $part_pkg->svcpart([qw( svc_acct svc_phone )]);
 334
 335   }
 336
 337   my $session_id;
 338   do {
 339     $session_id = sha512_hex(time(). {}. rand(). $$)
 340   } until ( ! defined _cache->get($session_id) ); #just in case
 341
 342   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 343   _cache->set( $session_id, $session, $timeout );
 344
 345   return { 'error'      => '',
 346            'session_id' => $session_id,
 347            %$session,
 348          };
 349 }
 350
 351 sub logout {
 352   my $p = shift;
 353   my $skin_info = skin_info($p);
 354   if ( $p->{'session_id'} ) {
 355     _cache->remove($p->{'session_id'});
 356     return { %$skin_info, 'error' => '' };
 357   } else {
 358     return { %$skin_info, 'error' => "Can't resume session" }; #better error message
 359   }
 360 }
 361
 362 sub switch_acct {
 363   my $p = shift;
 364
 365   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 366   return { 'error' => $session } if $context eq 'error';
 367
 368   my $svc_acct = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_acct' )
 369     or return { 'error' => "Service not found" };
 370
 371   $session->{'svcnum'} = $svc_acct->svcnum;
 372
 373   my $conf = new FS::Conf;
 374   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 375   _cache->set( $p->{'session_id'}, $session, $timeout );
 376
 377   return { 'error' => '' };
 378
 379 }
 380
 381 sub switch_cust {
 382   my $p = shift;
 383   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 384   return { 'error' => $session } if $context eq 'error';
 385
 386   $session->{'custnum'} = $p->{'custnum'}
 387     if exists $session->{'customers'}{ $p->{'custnum'} };
 388
 389   my $conf = new FS::Conf;
 390   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 391   _cache->set( $p->{'session_id'}, $session, $timeout );
 392
 393   return { 'error'      => '',
 394            %{ customer_info( { session_id=>$p->{'session_id'} } ) },
 395          };
 396 }
 397
 398 sub payment_gateway {
 399   # internal use only
 400   # takes a cust_main and a cust_payby entry, returns the payment_gateway
 401   my $conf = new FS::Conf;
 402   my $cust_main = shift;
 403   my $cust_payby = shift;
 404   return '' if ! FS::payby->realtime($cust_payby);
 405   my $pg = $cust_main->agent->payment_gateway(
 406     'method'  => FS::payby->payby2bop($cust_payby),
 407     'nofatal' => 1
 408   );
 409   return $pg;
 410 }
 411
 412 sub access_info {
 413   my $p = shift;
 414
 415   my $conf = new FS::Conf;
 416
 417   my $info = skin_info($p);
 418
 419   use vars qw( $cust_paybys ); #cache for performance
 420   unless ( $cust_paybys ) {
 421
 422     my %cust_paybys = map { $_ => 1 }
 423                       map { FS::payby->payby2payment($_) }
 424                           $conf->config('signup_server-payby');
 425
 426     $cust_paybys = [ keys %cust_paybys ];
 427
 428   }
 429   $info->{'cust_paybys'} = $cust_paybys;
 430
 431   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 432   return { 'error' => $session } if $context eq 'error';
 433
 434   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } );
 435
 436   $info->{'hide_payment_fields'} = [
 437     map {
 438       my $pg = $cust_main && payment_gateway($cust_main, $_);
 439       $pg && $pg->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 440     } @{ $info->{cust_paybys} }
 441   ];
 442
 443   $info->{'self_suspend_reason'} =
 444       $conf->config('selfservice-self_suspend_reason',
 445                       $cust_main ? $cust_main->agentnum : ''
 446                    );
 447
 448   $info->{'edit_ticket_subject'} =
 449       $conf->exists('ticket_system-selfservice_edit_subject') &&
 450       $cust_main && $cust_main->edit_subject;
 451
 452   $info->{'timeout'} = $conf->config('selfservice-timeout') || 3600;
 453
 454   $info->{'hide_usage'} = $conf->exists('selfservice_hide-usage');
 455
 456   return { %$info,
 457            'custnum'       => $custnum,
 458            'access_pkgnum' => $session->{'pkgnum'},
 459            'access_svcnum' => $session->{'svcnum'},
 460          };
 461 }
 462
 463 sub customer_info {
 464   my $p = shift;
 465
 466   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 467   return { 'error' => $session } if $context eq 'error';
 468
 469   my %return;
 470
 471   my $conf = new FS::Conf;
 472   $return{'require_address2'} = $conf->exists('cust_main-require_address2');
 473
 474 #  if ( $FS::TicketSystem::system ) {
 475 #    warn "$me customer_info: initializing ticket system\n" if $DEBUG;
 476 #    FS::TicketSystem->init();
 477 #  }
 478
 479   if ( $custnum ) { #customer record
 480
 481     %return = ( %return, %{ customer_info_short($p) } );
 482
 483     #redundant with customer_info_short, but we need it for several things below
 484     my $search = { 'custnum' => $custnum };
 485     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 486     my $cust_main = qsearchs('cust_main', $search )
 487       or return { 'error' => "customer_info: unknown custnum $custnum" };
 488
 489     my $list_tickets = list_tickets($p);
 490     $return{'tickets'} = $list_tickets->{'tickets'};
 491
 492     if ( $session->{'pkgnum'} ) {
 493       #XXX open invoices in the pkg-balances case
 494     } else {
 495       $return{'money_char'} = $conf->config("money_char") || '$';
 496       my @open = map {
 497                        {
 498                          invnum     => $_->invnum,
 499                          date       => time2str("%b %o, %Y", $_->_date),
 500                          owed       => $_->owed,
 501                          charged    => $_->charged,
 502                        };
 503                      } $cust_main->open_cust_bill;
 504       $return{open_invoices} = \@open;
 505
 506       my $sql = 'SELECT MAX(_date) FROM cust_bill WHERE custnum = ?';
 507       my $sth = dbh->prepare($sql) or die  dbh->errstr;
 508       $sth->execute($custnum)      or die $sth->errstr;
 509       $return{'last_invoice_date'} = $sth->fetchrow_arrayref->[0];
 510       $return{'last_invoice_date_pretty'} =
 511         time2str('%m/%d/%Y', $return{'last_invoice_date'} );
 512     }
 513
 514     #customer_info_short always has nobalance on..
 515     $return{small_custview} =
 516       small_custview( $cust_main,
 517                       $return{countrydefault},
 518                       ( $session->{'pkgnum'} ? 1 : 0 ), #nobalance
 519                     );
 520
 521     $return{has_ship_address} = $cust_main->has_ship_address;
 522     $return{status} = $cust_main->status_label; #$cust_main->status; #better to break anyone obscurely testing for strings in self-service than to have to upgrade every front-end to get the new status to display
 523     $return{statuscolor} = $cust_main->statuscolor;
 524     $return{status_label} = $cust_main->status_label;
 525
 526     # compatibility: some places in selfservice use this to determine
 527     # if there's a ship address
 528     if ( $return{has_ship_address} ) {
 529       $return{ship_last}  = $cust_main->last;
 530       $return{ship_first} = $cust_main->first;
 531     }
 532
 533     if (scalar($conf->config('support_packages'))) {
 534       my @support_services = ();
 535       foreach ($cust_main->support_services) {
 536         my $seconds = $_->svc_x->seconds || 0;
 537         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 538                              int(abs($seconds)/3600)."h".
 539                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 540         my $cust_pkg = $_->cust_pkg;
 541         my $pkgnum = '';
 542         my $pkg = '';
 543         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 544         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 545         push @support_services, { svcnum => $_->svcnum,
 546                                   time => $time_remaining,
 547                                   pkgnum => $pkgnum,
 548                                   pkg => $pkg,
 549                                 };
 550       }
 551       $return{support_services} = \@support_services;
 552     }
 553
 554     if ( $conf->config('prepayment_discounts-credit_type') ) {
 555       #need to eval?
 556       $return{discount_terms_hash} = { $cust_main->discount_terms_hash };
 557     }
 558
 559   } elsif ( $session->{'svcnum'} ) { #no customer record
 560
 561     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 562       or die "unknown svcnum";
 563     $return{name} = $svc_acct->email;
 564
 565   } else {
 566
 567     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 568
 569   }
 570
 571   return { 'error'   => '',
 572            'custnum' => $custnum,
 573            %return,
 574          };
 575
 576 }
 577
 578 sub customer_info_short {
 579   my $p = shift;
 580
 581   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 582   return { 'error' => $session } if $context eq 'error';
 583
 584   my %return;
 585
 586   my $conf = new FS::Conf;
 587
 588   if ( $custnum ) { #customer record
 589
 590     my $search = { 'custnum' => $custnum };
 591     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 592     my $cust_main = qsearchs('cust_main', $search )
 593       or return { 'error' => "customer_info_short: unknown custnum $custnum" };
 594
 595     $return{display_custnum} = $cust_main->display_custnum;
 596     $return{max_invnum}      = $cust_main->max_invnum;
 597
 598     if ( $session->{'pkgnum'} ) {
 599       $return{balance} = $cust_main->balance_pkgnum( $session->{'pkgnum'} );
 600       #next_bill_date from cust_pkg?
 601     } else {
 602       $return{balance} = $cust_main->balance;
 603       $return{next_bill_date} = $cust_main->next_bill_date;
 604       $return{next_bill_date_pretty} =
 605         $return{next_bill_date} ? time2str('%m/%d/%Y', $return{next_bill_date} )
 606                                 : '(none)';
 607     }
 608     $return{balance_pretty} = money_pretty($return{balance});
 609
 610     $return{countrydefault} = scalar($conf->config('countrydefault'));
 611
 612     $return{small_custview} =
 613       small_custview( $cust_main,
 614                       $return{countrydefault},
 615                       1, ##nobalance
 616                     );
 617
 618     $return{first}  = $cust_main->first;
 619     $return{'last'} = $cust_main->get('last');
 620     $return{name}   = $cust_main->first. ' '. $cust_main->get('last');
 621
 622     #none of these are terribly expensive if we want 'em...
 623     for (@cust_main_editable_fields) {
 624       $return{$_} = $cust_main->get($_);
 625     }
 626     #maybe a little more expensive, but it should be cached by now
 627     for (@location_editable_fields) {
 628       $return{$_} = $cust_main->bill_location->get($_)
 629         if $cust_main->bill_locationnum;
 630       $return{'ship_'.$_} = $cust_main->ship_location->get($_)
 631         if $cust_main->ship_locationnum;
 632     }
 633
 634     my @invoicing_list = $cust_main->invoicing_list;
 635     $return{'invoicing_list'} =
 636       join(', ', grep { $_ !~ /^(POST|FAX)$/ } @invoicing_list );
 637     $return{'postal_invoicing'} =
 638       0 < ( grep { $_ eq 'POST' } @invoicing_list );
 639
 640     if ( $session->{'svcnum'} ) {
 641       my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $session->{'svcnum'} });
 642       $return{'svc_label'} = ($cust_svc->label)[1] if $cust_svc;
 643       $return{'svcnum'} = $session->{'svcnum'};
 644     }
 645
 646   } elsif ( $session->{'svcnum'} ) { #no customer record
 647
 648     #uuh, not supproted yet... die?
 649     return { 'error' => 'customer_info_short not yet supported as agent' };
 650
 651   } else {
 652
 653     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 654
 655   }
 656
 657   # this is here because this routine is called by both fs_ and ng_ main pages, where it appears
 658   # it is not customer-specific, though it is only shown to authenticated customers
 659   # it is not currently agent-specific, though at some point it might be
 660   $return{'announcement'} = join(' ',$conf->config('selfservice-announcement')) || '';
 661
 662   return { 'error'          => '',
 663            'custnum'        => $custnum,
 664            %return,
 665          };
 666 }
 667
 668 sub customer_recurring {
 669   my $p = shift;
 670
 671   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 672   return { 'error' => $session } if $context eq 'error';
 673
 674   my %return;
 675
 676   my $conf = new FS::Conf;
 677
 678   my $search = { 'custnum' => $custnum };
 679   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 680   my $cust_main = qsearchs('cust_main', $search )
 681     or return { 'error' => "customer_info_short: unknown custnum $custnum" };
 682
 683   $return{'display_recurring'} = [ $cust_main->display_recurring ];
 684
 685   return { 'error'          => '',
 686            'custnum'        => $custnum,
 687            %return,
 688          };
 689 }
 690
 691 sub billing_history {
 692   my $p = shift;
 693
 694   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 695   return { 'error' => $session } if $context eq 'error';
 696
 697   return { 'error' => 'No customer' } unless $custnum;
 698
 699   my $search = { 'custnum' => $custnum };
 700   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 701   my $cust_main = qsearchs('cust_main', $search )
 702     or return { 'error' => "unknown custnum $custnum" };
 703
 704   my %return = ();
 705
 706   if ( $session->{'pkgnum'} ) {
 707     #$return{balance} = $cust_main->balance_pkgnum( $session->{'pkgnum'} );
 708     #next_bill_date from cust_pkg?
 709     return { 'error' => 'No history for package' };
 710   }
 711
 712   $return{balance} = $cust_main->balance;
 713   $return{balance_pretty} = money_pretty($return{balance});
 714   $return{next_bill_date} = $cust_main->next_bill_date;
 715   $return{next_bill_date_pretty} =
 716     $return{next_bill_date} ? time2str('%m/%d/%Y', $return{next_bill_date} )
 717                             : '(none)';
 718
 719   my $conf = new FS::Conf;
 720
 721   $return{'history'} = [
 722     $cust_main->payment_history(
 723       'line_items' => $conf->exists('selfservice-billing_history-line_items'),
 724       'reverse_sort' => 1,
 725     )
 726   ];
 727
 728   $return{'money_char'} = $conf->config("money_char") || '$',
 729
 730   return \%return;
 731
 732 }
 733
 734 sub edit_info {
 735   my $p = shift;
 736   my $session = _cache->get($p->{'session_id'})
 737     or return { 'error' => "Can't resume session" }; #better error message
 738
 739   my $custnum = $session->{'custnum'}
 740     or return { 'error' => "no customer record" };
 741
 742   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 743     or return { 'error' => "unknown custnum $custnum" };
 744
 745   my $new = new FS::cust_main { $cust_main->hash };
 746
 747   $new->set( $_ => $p->{$_} )
 748     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 749
 750   if ( exists($p->{address1}) ) {
 751     my $bill_location = FS::cust_location->new({
 752         map { $_ => $p->{$_} } @location_editable_fields
 753     });
 754     # if this is unchanged from before, cust_main::replace will ignore it
 755     $new->set('bill_location' => $bill_location);
 756   }
 757
 758   if ( exists($p->{ship_address1}) ) {
 759     my $ship_location = FS::cust_location->new({
 760         map { $_ => $p->{"ship_$_"} } @location_editable_fields
 761     });
 762     if ( !grep { length($p->{"ship_$_"}) } @location_editable_fields ) {
 763       # Selfservice unfortunately tries to indicate "same as billing
 764       # address" by sending all fields empty.  Did this ever work?
 765       $ship_location = $cust_main->bill_location;
 766     }
 767     $new->set('ship_location' => $ship_location);
 768   }
 769   # but if it hasn't been passed in at all, leave ship_location alone--
 770   # DON'T change it to match bill_location.
 771
 772   my $conf = new FS::Conf;
 773
 774   my @invoicing_list;
 775   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 776     #false laziness with httemplate/edit/process/cust_main.cgi
 777     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 778     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 779   } else {
 780     @invoicing_list = $cust_main->invoicing_list;
 781   }
 782
 783   my $error = $new->replace($cust_main, \@invoicing_list);
 784   return { 'error' => $error } if $error;
 785   #$cust_main = $new;
 786
 787   return { 'error' => '' };
 788 }
 789
 790 sub payment_info {
 791   my $p = shift;
 792   my $session = _cache->get($p->{'session_id'})
 793     or return { 'error' => "Can't resume session" }; #better error message
 794
 795   ##
 796   #generic
 797   ##
 798
 799   my $conf = new FS::Conf;
 800   use vars qw($payment_info); #cache for performance
 801   unless ( $payment_info ) {
 802
 803     my %states = map { $_->state => 1 }
 804                    qsearch('cust_main_county', {
 805                      'country' => $conf->config('countrydefault') || 'US'
 806                    } );
 807
 808     my %cust_paybys = map { $_ => 1 }
 809                       map { FS::payby->payby2payment($_) }
 810                           $conf->config('signup_server-payby');
 811
 812     my @cust_paybys = keys %cust_paybys;
 813
 814     $payment_info = {
 815
 816       #list all counties/states/countries
 817       'cust_main_county' =>
 818         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 819
 820       #shortcut for one-country folks
 821       'states' =>
 822         [ sort { $a cmp $b } keys %states ],
 823
 824       'card_types' => card_types(),
 825
 826       'withcvv'            => $conf->exists('selfservice-require_cvv'), #or enable optional cvv?
 827       'require_cvv'        => $conf->exists('selfservice-require_cvv'),
 828       'onfile_require_cvv' => $conf->exists('selfservice-onfile_require_cvv'),
 829
 830       'paytypes' => [ FS::cust_payby::paytypes ],
 831
 832       'paybys' => [ $conf->config('signup_server-payby') ],
 833       'cust_paybys' => \@cust_paybys,
 834
 835       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 836       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 837
 838       'show_ss'  => $conf->exists('show_ss'),
 839       'show_stateid' => $conf->exists('show_stateid'),
 840       'show_paystate' => $conf->exists('show_bankstate'),
 841
 842       'save_unchecked' => $conf->exists('selfservice-save_unchecked'),
 843
 844     };
 845
 846   }
 847
 848   ##
 849   #customer-specific
 850   ##
 851
 852   my %return = %$payment_info;
 853
 854   delete $return{'cust_main_county'} if $p->{'omit_cust_main_county'};
 855
 856   my $custnum = $session->{'custnum'};
 857
 858   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 859     or return { 'error' => "unknown custnum $custnum" };
 860
 861   $return{'hide_payment_fields'} = [
 862     map {
 863       my $pg = payment_gateway($cust_main, $_);
 864       $pg && $pg->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 865     } @{ $return{cust_paybys} }
 866   ];
 867
 868   $return{balance} = $cust_main->balance; #XXX pkg-balances?
 869
 870   $return{$_} = $cust_main->bill_location->get($_)
 871     for qw(address1 address2 city state zip);
 872
 873   # look for stored cust_payby info
 874   #   only if we've been given a clear payment_payby (to avoid payname conflicts)
 875   if ($p->{'payment_payby'} =~ /^(CARD|CHEK)$/) {
 876     my @search_payby = ($p->{'payment_payby'} eq 'CARD') ? ('CARD','DCRD') : ('CHEK','DCHK');
 877     my ($cust_payby) = $cust_main->cust_payby(@search_payby);
 878     if ($cust_payby) {
 879       $return{payname} = $cust_payby->payname
 880                          || ( $cust_main->first. ' '. $cust_main->get('last') );
 881
 882       if ( $cust_payby->payby =~ /^(CARD|DCRD)$/ ) {
 883         $return{card_type} = cardtype($cust_payby->payinfo);
 884         $return{payinfo} = $cust_payby->paymask;
 885
 886         @return{'month', 'year'} = $cust_payby->paydate_monthyear;
 887
 888       }
 889
 890       if ( $cust_payby->payby =~ /^(CHEK|DCHK)$/ ) {
 891         my ($payinfo1, $payinfo2) = split '@', $cust_payby->paymask;
 892         $return{payinfo1} = $payinfo1;
 893         $return{payinfo2} = $payinfo2;
 894         $return{paytype}  = $cust_payby->paytype;
 895         $return{paystate} = $cust_payby->paystate;
 896         $return{payname}  = $cust_payby->payname;       # override 'first/last name' default from above, if any.  Is instution-name here.  (#15819)
 897       }
 898     }
 899   }
 900
 901   if ( $conf->config('prepayment_discounts-credit_type') ) {
 902     #need to eval?
 903     $return{discount_terms_hash} = { $cust_main->discount_terms_hash };
 904   }
 905
 906   #doubleclick protection
 907   my $_date = time;
 908   $return{payunique} = "webui-MyAccount-$_date-$$-". rand() * 2**32; #new
 909   $return{paybatch} = $return{payunique};  #back compat
 910
 911   $return{credit_card_surcharge_percentage} = $conf->config('credit-card-surcharge-percentage', $cust_main->agentnum);
 912
 913   return { 'error' => '',
 914            %return,
 915          };
 916
 917 }
 918
 919 #some false laziness with httemplate/process/payment.cgi - look there for
 920 #ACH and CVV support stuff
 921
 922 sub validate_payment {
 923   my $p = shift;
 924
 925   my $session = _cache->get($p->{'session_id'})
 926     or return { 'error' => "Can't resume session" }; #better error message
 927
 928   my $custnum = $session->{'custnum'};
 929
 930   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 931     or return { 'error' => "unknown custnum $custnum" };
 932
 933   $p->{'amount'} =~ /^\s*(\d+(\.\d{2})?)\s*$/
 934     or return { 'error' => gettext('illegal_amount') };
 935   my $amount = $1;
 936   return { error => 'Amount must be greater than 0' } unless $amount > 0;
 937
 938   #false laziness w/tr-amount_fee.html, but we don't want selfservice users
 939   #changing the hidden form values
 940   my $conf = new FS::Conf;
 941   my $fee_display = $conf->config('selfservice_process-display') || 'add';
 942   my $fee_pkgpart = $conf->config('selfservice_process-pkgpart', $cust_main->agentnum);
 943   my $fee_skip_first = $conf->exists('selfservice_process-skip_first');
 944   if ( $fee_display eq 'add'
 945          and $fee_pkgpart
 946          and ! $fee_skip_first || scalar($cust_main->cust_pay)
 947      )
 948   {
 949     my $fee_pkg = qsearchs('part_pkg', { pkgpart=>$fee_pkgpart } );
 950     $amount = sprintf('%.2f', $amount + $fee_pkg->option('setup_fee') );
 951   }
 952
 953   $p->{'discount_term'} =~ /^\s*(\d*)\s*$/
 954     or return { 'error' => gettext('illegal_discount_term'). ': '. $p->{'discount_term'} };
 955   my $discount_term = $1;
 956
 957   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 958     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 959   my $payname = $1;
 960
 961   $p->{'payunique'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 962     or return { 'error' => gettext('illegal_text'). " payunique: ". $p->{'payunique'} };
 963   my $payunique = $1;
 964
 965   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 966     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 967   my $paybatch = $1;
 968
 969   $payunique = $paybatch if ! length($payunique) && length($paybatch);
 970
 971   $p->{'payby'} ||= 'CARD';
 972   $p->{'payby'} =~ /^([A-Z]{4})$/
 973     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 974   my $payby = $1;
 975
 976   #false laziness w/process/payment.cgi
 977   my $payinfo;
 978   my $paycvv = '';
 979   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 980
 981     $p->{'payinfo1'} =~ /^([\dx]+)$/
 982       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 983     my $payinfo1 = $1;
 984      $p->{'payinfo2'} =~ /^([\dx]+)$/
 985       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 986     my $payinfo2 = $1;
 987     $payinfo = $payinfo1. '@'. $payinfo2;
 988
 989     foreach my $cust_payby ($cust_main->cust_payby('CHEK','DCHK')) {
 990       if ( $cust_payby->paymask eq $payinfo ) {
 991         $payinfo = $cust_payby->payinfo;
 992         last;
 993       }
 994     }
 995
 996   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 997
 998     $payinfo = $p->{'payinfo'};
 999
1000     my $onfile = 0;
1001
1002     #more intelligent matching will be needed here if you change
1003     #card_masking_method and don't remove existing paymasks
1004     foreach my $cust_payby ($cust_main->cust_payby('CARD','DCRD')) {
1005       if ( $cust_payby->paymask eq $payinfo ) {
1006         $payinfo = $cust_payby->payinfo;
1007         $onfile = 1;
1008         last;
1009       }
1010     }
1011
1012     $payinfo =~ s/\D//g;
1013     $payinfo =~ /^(\d{13,19}|\d{8,9})$/
1014       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
1015     $payinfo = $1;
1016
1017     validate($payinfo)
1018       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
1019     return { 'error' => gettext('unknown_card_type') }
1020       if !$cust_main->tokenized($payinfo) && cardtype($payinfo) eq "Unknown";
1021
1022     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
1023       if ( cardtype($payinfo) eq 'American Express card' ) {
1024         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
1025           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
1026         $paycvv = $1;
1027       } else {
1028         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
1029           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
1030         $paycvv = $1;
1031       }
1032     } elsif ( $conf->exists('selfservice-onfile_require_cvv') ) {
1033       return { 'error' => 'CVV2 is required' };
1034     } elsif ( !$onfile && $conf->exists('selfservice-require_cvv') ) {
1035       return { 'error' => 'CVV2 is required' };
1036     }
1037
1038   } else {
1039     die "unknown payby $payby";
1040   }
1041
1042   my %payby2fields = (
1043     'CARD' => [ qw( paystart_month paystart_year payissue payip
1044                     address1 address2 city state zip country    ) ],
1045     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
1046   );
1047
1048   my $card_type = '';
1049   $card_type = cardtype($payinfo) if $payby eq 'CARD';
1050
1051   {
1052     'cust_main'      => $cust_main, #XXX or just custnum??
1053     'amount'         => sprintf('%.2f', $amount),
1054     'payby'          => $payby,
1055     'payinfo'        => $payinfo,
1056     'paymask'        => $cust_main->mask_payinfo( $payby, $payinfo ),
1057     'card_type'      => $card_type,
1058     'paydate'        => $p->{'year'}. '-'. $p->{'month'}. '-01',
1059     'paydate_pretty' => $p->{'month'}. ' / '. $p->{'year'},
1060     'month'          => $p->{'month'},
1061     'year'           => $p->{'year'},
1062     'payname'        => $payname,
1063     'payunique'      => $payunique,
1064     'paybatch'       => $paybatch,
1065     'paycvv'         => $paycvv,
1066     'payname'        => $payname,
1067     'discount_term'  => $discount_term,
1068     'pkgnum'         => $session->{'pkgnum'},
1069     map { $_ => $p->{$_} } ( @{ $payby2fields{$payby} },
1070                              qw( save auto ),
1071                            )
1072   };
1073
1074 }
1075
1076 sub store_payment {
1077   my $p = shift;
1078
1079   my $validate = validate_payment($p);
1080   return $validate if $validate->{'error'};
1081
1082   my $conf = new FS::Conf;
1083   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour'; #?
1084   _cache->set( 'payment_'.$p->{'session_id'}, $validate, $timeout );
1085
1086   +{ map { $_=>$validate->{$_} }
1087       qw( card_type paymask payname paydate_pretty month year amount
1088           address1 address2 city state zip country
1089         )
1090   };
1091
1092 }
1093
1094 sub process_stored_payment {
1095   my $p = shift;
1096
1097   my $session_id = $p->{'session_id'};
1098
1099   my $payment_info = _cache->get( "payment_$session_id" )
1100     or return { 'error' => "Can't resume session" }; #better error message
1101
1102   do_process_payment($payment_info);
1103
1104 }
1105
1106 sub process_payment {
1107   my $p = shift;
1108
1109   my $payment_info = validate_payment($p);
1110   return $payment_info if $payment_info->{'error'};
1111
1112   do_process_payment($payment_info);
1113
1114 }
1115
1116 sub do_process_payment {
1117   my $validate = shift;
1118
1119   my $cust_main = $validate->{'cust_main'};
1120
1121   my $amount = delete $validate->{'amount'};
1122   my $paynum = '';
1123
1124   my $payby = delete $validate->{'payby'};
1125
1126   if ( $validate->{'save'} ) {
1127
1128     my %saveopt;
1129     foreach my $field ( qw( auto payinfo paymask payname payip ) ) {
1130       $saveopt{$field} = $validate->{$field};
1131     }
1132
1133     if ( $payby eq 'CARD' ) {
1134       my $bill_location = FS::cust_location->new({
1135           map { $_ => $validate->{$_} }
1136           qw(address1 address2 city state country zip)
1137       });
1138       $saveopt{'bill_location'} = $bill_location;
1139       foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
1140         $saveopt{$field} = $validate->{$field};
1141       }
1142     } else {
1143       # stateid/stateid_state won't be saved, might be broken as of 4.x
1144       foreach my $field ( qw( paytype paystate ) ) {
1145         $saveopt{$field} = $validate->{$field};
1146       }
1147     }
1148
1149     my $error = $cust_main->save_cust_payby(
1150       'payment_payby' => $payby,
1151       %saveopt
1152     );
1153
1154     if ( $error ) {
1155       #no, this causes customers to process their payments again
1156       #return { 'error' => $error };
1157       #XXX just warn verosely for now so i can figure out how these happen in
1158       # the first place, eventually should redirect them to the "change
1159       #address" page but indicate if the payment processed?
1160       delete($validate->{'payinfo'}); #don't want to log this!
1161       warn "WARNING: error changing customer info when processing payment (not returning to customer as a processing error): $error\n".
1162            "PAYBY: $payby\n".
1163            "SAVEOPT: ".Dumper(\%saveopt)."\n".
1164            "CUST_MAIN: ". Dumper($cust_main)."\n".
1165            "PACKET: ". Dumper($validate)."\n";
1166     }
1167   }
1168
1169   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $amount,
1170     'quiet'       => 1,
1171     'manual'      => 1,
1172     'selfservice' => 1,
1173     'paynum_ref'  => \$paynum,
1174     %$validate,
1175   );
1176   return { 'error' => $error } if $error;
1177
1178   #no error, so order the fee package if applicable...
1179   my $conf = new FS::Conf;
1180   my $fee_pkgpart = $conf->config('selfservice_process-pkgpart', $cust_main->agentnum);
1181   my $fee_skip_first = $conf->exists('selfservice_process-skip_first');
1182
1183   if ( $fee_pkgpart and ! $fee_skip_first || scalar($cust_main->cust_pay) ) {
1184
1185     my $cust_pkg = new FS::cust_pkg { 'pkgpart' => $fee_pkgpart };
1186
1187     $error = $cust_main->order_pkg( 'cust_pkg' => $cust_pkg );
1188     return { 'error' => "payment processed successfully, but error ordering fee: $error" }
1189       if $error;
1190
1191     #and generate an invoice for it now too
1192     $error = $cust_main->bill( 'pkg_list' => [ $cust_pkg ] );
1193     return { 'error' => "payment processed and fee ordered successfully, but error billing fee: $error" }
1194       if $error;
1195
1196   }
1197
1198   $cust_main->apply_payments;
1199
1200   my $cust_pay = '';
1201   my $receipt_html = '';
1202   if ($paynum) {
1203       # currently supported for realtime CC only; send receipt data to SS
1204       $cust_pay = qsearchs('cust_pay', { 'paynum' => $paynum } );
1205       if($cust_pay) {
1206         $receipt_html = qq!
1207 <TABLE BGCOLOR="#cccccc" BORDER=0 CELLSPACING=2>
1208
1209 <TR>
1210   <TD ALIGN="right">Payment#</TD>
1211   <TD BGCOLOR="#FFFFFF"><B>! . $cust_pay->paynum . qq!</B></TD>
1212 </TR>
1213
1214 <TR>
1215   <TD ALIGN="right">Date</TD>
1216
1217   <TD BGCOLOR="#FFFFFF"><B>! .
1218         time2str("%a&nbsp;%b&nbsp;%o,&nbsp;%Y&nbsp;%r", $cust_pay->_date)
1219                                                             . qq!</B></TD>
1220 </TR>
1221
1222
1223 <TR>
1224   <TD ALIGN="right">Amount</TD>
1225   <TD BGCOLOR="#FFFFFF"><B>! . sprintf('%.2f', $cust_pay->paid) . qq!</B></TD>
1226
1227 </TR>
1228
1229 <TR>
1230   <TD ALIGN="right">Payment method</TD>
1231   <TD BGCOLOR="#FFFFFF"><B>! . $cust_pay->payby_name .' #'. $cust_pay->paymask
1232                                                                 . qq!</B></TD>
1233 </TR>
1234
1235 </TABLE>
1236 !;
1237       }
1238   }
1239
1240   if ( $cust_pay ) {
1241
1242     return {
1243       'error'        => '',
1244       'amount'       => sprintf('%.2f', $cust_pay->paid),
1245       'date'         => $cust_pay->_date,
1246       'date_pretty'  => time2str('%Y-%m-%d', $cust_pay->_date),
1247       'time_pretty'  => time2str('%T', $cust_pay->_date),
1248       'auth_num'     => $cust_pay->auth,
1249       'order_num'    => $cust_pay->order_number,
1250       'receipt_html' => $receipt_html,
1251     };
1252
1253   } else {
1254
1255     return {
1256       'error'        => '',
1257       'receipt_html' => '',
1258     };
1259
1260   }
1261
1262 }
1263
1264 sub realtime_collect {
1265   my $p = shift;
1266
1267   my $session = _cache->get($p->{'session_id'})
1268     or return { 'error' => "Can't resume session" }; #better error message
1269
1270   my $custnum = $session->{'custnum'};
1271
1272   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1273     or return { 'error' => "unknown custnum $custnum" };
1274
1275   my $amount;
1276   if ( $p->{'amount'} ) {
1277     $amount = $p->{'amount'};
1278   }
1279   elsif ( $session->{'pkgnum'} ) {
1280     $amount = $cust_main->balance_pkgnum( $session->{'pkgnum'} );
1281   }
1282   else {
1283     $amount = $cust_main->balance;
1284   }
1285
1286   my $error = $cust_main->realtime_collect(
1287     'method'     => $p->{'method'},
1288     'amount'     => $amount,
1289     'pkgnum'     => $session->{'pkgnum'},
1290     'session_id' => $p->{'session_id'},
1291     'apply'      => 1,
1292     'selfservice'=> 1,
1293   );
1294   return { 'error' => $error } unless ref( $error );
1295
1296   return { 'error' => '', amount => $amount, %$error };
1297 }
1298
1299 sub start_thirdparty {
1300   my $p = shift;
1301   my $session = _cache->get($p->{'session_id'})
1302     or return { 'error' => "Can't resume session" }; #better error message
1303   my $custnum = $session->{'custnum'};
1304   my $cust_main = FS::cust_main->by_key($custnum);
1305
1306   my $amount = $p->{'amount'}
1307     or return { error => 'no amount' };
1308
1309   my $result = $cust_main->create_payment(
1310     'method'      => $p->{'method'},
1311     'amount'      => $p->{'amount'},
1312     'pkgnum'      => $session->{'pkgnum'},
1313     'session_id'  => $p->{'session_id'},
1314   );
1315
1316   if ( ref($result) ) { # hashref or error
1317     return $result;
1318   } else {
1319     return { error => $result };
1320   }
1321 }
1322
1323 sub finish_thirdparty {
1324   my $p = shift;
1325   my $session_id = delete $p->{'session_id'};
1326   my $session = _cache->get($session_id)
1327     or return { 'error' => "Can't resume session" };
1328   my $custnum = $session->{'custnum'};
1329   my $cust_main = FS::cust_main->by_key($custnum);
1330
1331   if ( $p->{_cancel} ) {
1332     # customer backed out of making a payment
1333     return $cust_main->cancel_payment( $session_id );
1334   }
1335   my $result = $cust_main->execute_payment( $session_id, %$p );
1336   if ( ref($result) ) {
1337     return $result;
1338   } else {
1339     return { error => $result };
1340   }
1341 }
1342
1343 sub process_payment_order_pkg {
1344   my $p = shift;
1345
1346   my $hr = process_payment($p);
1347   return $hr if $hr->{'error'};
1348
1349   order_pkg($p);
1350 }
1351
1352 sub process_payment_order_renew {
1353   my $p = shift;
1354
1355   my $hr = process_payment($p);
1356   return $hr if $hr->{'error'};
1357
1358   order_renew($p);
1359 }
1360
1361 sub process_prepay {
1362
1363   my $p = shift;
1364
1365   my $session = _cache->get($p->{'session_id'})
1366     or return { 'error' => "Can't resume session" }; #better error message
1367
1368   my %return;
1369
1370   my $custnum = $session->{'custnum'};
1371
1372   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1373     or return { 'error' => "unknown custnum $custnum" };
1374
1375   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
1376   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
1377                                            \$amount,
1378                                            \$seconds,
1379                                            \$upbytes,
1380                                            \$downbytes,
1381                                            \$totalbytes,
1382                                          );
1383
1384   return { 'error' => $error } if $error;
1385
1386   return { 'error'     => '',
1387            'amount'    => $amount,
1388            'seconds'   => $seconds,
1389            'duration'  => duration_exact($seconds),
1390            'upbytes'   => $upbytes,
1391            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
1392            'downbytes' => $downbytes,
1393            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
1394            'totalbytes'=> $totalbytes,
1395            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
1396          };
1397
1398 }
1399
1400 sub invoice {
1401   my $p = shift;
1402   my $session = _cache->get($p->{'session_id'})
1403     or return { 'error' => "Can't resume session" }; #better error message
1404
1405   my $custnum = $session->{'custnum'};
1406
1407   my $invnum = $p->{'invnum'};
1408
1409   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
1410                                           'custnum' => $custnum } )
1411     or return { 'error' => "Can't find invnum" };
1412
1413   #my %return;
1414
1415   return { 'error'        => '',
1416            'invnum'       => $invnum,
1417            'invoice_text' => join('', $cust_bill->print_text ),
1418            'invoice_html' => $cust_bill->print_html( { unsquelch_cdr => 1 } ),
1419          };
1420
1421 }
1422
1423 sub invoice_pdf {
1424   my $p = shift;
1425   my $session = _cache->get($p->{'session_id'})
1426     or return { 'error' => "Can't resume session" }; #better error message
1427
1428   my $custnum = $session->{'custnum'};
1429
1430   my $invnum = $p->{'invnum'};
1431
1432   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
1433                                           'custnum' => $custnum } )
1434     or return { 'error' => "Can't find invnum" };
1435
1436   #my %return;
1437
1438   return { 'error'       => '',
1439            'invnum'      => $invnum,
1440            'invoice_pdf' => $cust_bill->print_pdf({
1441                               'unsquelch_cdr' => 1,
1442                               'locale'        => $p->{'locale'},
1443                             }),
1444          };
1445
1446 }
1447
1448 sub legacy_invoice {
1449   my $p = shift;
1450   my $session = _cache->get($p->{'session_id'})
1451     or return { 'error' => "Can't resume session" }; #better error message
1452
1453   my $custnum = $session->{'custnum'};
1454
1455   my $legacyinvnum = $p->{'legacyinvnum'};
1456
1457   my %hash = (
1458     'legacyinvnum' => $legacyinvnum,
1459     'custnum'      => $custnum,
1460   );
1461
1462   my $legacy_cust_bill =
1463          qsearchs('legacy_cust_bill', { %hash, 'locale' => $p->{'locale'} } )
1464       || qsearchs('legacy_cust_bill', \%hash )
1465     or return { 'error' => "Can't find legacyinvnum" };
1466
1467   #my %return;
1468
1469   return { 'error'        => '',
1470            'legacyinvnum' => $legacyinvnum,
1471            'legacyid'     => $legacy_cust_bill->legacyid,
1472            'invoice_html' => $legacy_cust_bill->content_html,
1473          };
1474
1475 }
1476
1477 sub legacy_invoice_pdf {
1478   my $p = shift;
1479   my $session = _cache->get($p->{'session_id'})
1480     or return { 'error' => "Can't resume session" }; #better error message
1481
1482   my $custnum = $session->{'custnum'};
1483
1484   my $legacyinvnum = $p->{'legacyinvnum'};
1485
1486   my $legacy_cust_bill = qsearchs('legacy_cust_bill', {
1487     'legacyinvnum' => $legacyinvnum,
1488     'custnum'      => $custnum,
1489   }) or return { 'error' => "Can't find legacyinvnum" };
1490
1491   #my %return;
1492
1493   return { 'error'        => '',
1494            'legacyinvnum' => $legacyinvnum,
1495            'legacyid'     => $legacy_cust_bill->legacyid,
1496            'invoice_pdf'  => $legacy_cust_bill->content_pdf,
1497          };
1498
1499 }
1500
1501 sub invoice_logo {
1502   my $p = shift;
1503
1504   #sessioning for this?  how do we get the session id to the backend invoice
1505   # template so it can add it to the link, blah
1506
1507   my $agentnum = '';
1508   if ( $p->{'invnum'} ) {
1509     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $p->{'invnum'} } )
1510       or return { 'error' => 'unknown invnum' };
1511     $agentnum = $cust_bill->cust_main->agentnum;
1512   }
1513
1514   my $templatename = $p->{'template'} || $p->{'templatename'};
1515
1516   #false laziness-ish w/view/cust_bill-logo.cgi
1517
1518   my $conf = new FS::Conf;
1519   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
1520     $templatename = "_$1";
1521   } else {
1522     $templatename = '';
1523   }
1524
1525   my $filename = "logo$templatename.png";
1526
1527   return { 'error'        => '',
1528            'logo'         => $conf->config_binary($filename, $agentnum),
1529            'content_type' => 'image/png', #should allow gif, jpg too
1530          };
1531 }
1532
1533 sub list_invoices {
1534   my $p = shift;
1535   my $session = _cache->get($p->{'session_id'})
1536     or return { 'error' => "Can't resume session" }; #better error message
1537
1538   my $custnum = $session->{'custnum'};
1539
1540   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1541     or return { 'error' => "unknown custnum $custnum" };
1542
1543   my $conf = new FS::Conf;
1544
1545   my @legacy_cust_bill = $cust_main->legacy_cust_bill;
1546
1547   my @cust_bill = grep ! $_->hide, $cust_main->cust_bill;
1548
1549   my $balance = 0;
1550   my $invoices = [
1551     map {
1552       #not super efficient, we also run cust_bill_pay/cust_credited inside owed
1553       my @payments_and_credits = sort {$b->_date <=> $a->_date} ($_->cust_bill_pay,$_->cust_credited);
1554       my $owed = $_->owed;
1555       $balance += $owed;
1556       +{ 'invnum'       => $_->invnum,
1557          '_date'        => $_->_date,
1558          'date'         => time2str("%b %o, %Y", $_->_date),
1559          'date_short'   => time2str("%m-%d-%Y",  $_->_date),
1560          'previous'     => sprintf('%.2f', ($_->previous)[0]),
1561          'charged'      => sprintf('%.2f', $_->charged),
1562          'owed'         => sprintf('%.2f', $owed),
1563          'balance'      => sprintf('%.2f', $balance),
1564          'lastpay'      => @payments_and_credits
1565                            ? time2str("%b %o, %Y", $payments_and_credits[0]->_date)
1566                            : '',
1567       }
1568     } @cust_bill
1569   ];
1570
1571   return  { 'error'       => '',
1572             'balance'     => $cust_main->balance,
1573             'money_char'  => $conf->config("money_char") || '$',
1574             'invoices'    => $invoices,
1575             'legacy_invoices' => [
1576               map {
1577                     +{ 'legacyinvnum' => $_->legacyinvnum,
1578                        'legacyid'     => $_->legacyid,
1579                        '_date'        => $_->_date,
1580                        'date'         => time2str("%b %o, %Y", $_->_date),
1581                        'date_short'   => time2str("%m-%d-%Y",  $_->_date),
1582                        'charged'      => sprintf('%.2f', $_->charged),
1583                        'has_content'  => (    length($_->content_pdf)
1584                                            || length($_->content_html) ),
1585                      }
1586                   }
1587                   @legacy_cust_bill
1588             ],
1589           };
1590 }
1591
1592 sub list_payments {
1593   my $p = shift;
1594   my $session = _cache->get($p->{'session_id'})
1595     or return { 'error' => "Can't resume session" }; #better error message
1596
1597   my $custnum = $session->{'custnum'};
1598
1599   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1600     or return { 'error' => "unknown custnum $custnum" };
1601
1602   return  { 'error'       => '',
1603             'balance'     => $cust_main->balance,
1604             'money_char'  => FS::Conf->new->config("money_char") || '$',
1605             'payments'    => [ map $_->SSAPI_getinfo, $cust_main->cust_pay ],
1606           };
1607 }
1608
1609 sub payment_receipt {
1610   my $p = shift;
1611   my $session = _cache->get($p->{'session_id'})
1612     or return { 'error' => "Can't resume session" }; #better error message
1613
1614   my $custnum = $session->{'custnum'};
1615
1616   my $cust_pay = qsearchs('cust_pay', { 'custnum' => $custnum,
1617                                         'paynum'  => $p->{'paynum'},
1618                                       }
1619                          )
1620     or return { 'error' => "unknown payment ". $p->{'paynum'} };
1621
1622   return {
1623            'error' => '',
1624            %{ $cust_pay->SSAPI_getinfo },
1625          };
1626 }
1627
1628 sub list_payby {
1629   my $p = shift;
1630
1631   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1632   return { 'error' => $session } if $context eq 'error';
1633
1634   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1635     or return { 'error' => "unknown custnum $custnum" };
1636
1637   return {
1638     'payby' => [ map {
1639                        my $cust_payby = $_;
1640                        +{
1641                           map { $_ => $cust_payby->$_ }
1642                             qw( custpaybynum weight payby paymask paydate
1643                                 payname paystate paytype
1644                               )
1645                         };
1646                      }
1647                    $cust_main->cust_payby
1648                ],
1649   };
1650 }
1651
1652 sub insert_payby {
1653   my $p = shift;
1654
1655   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1656   return { 'error' => $session } if $context eq 'error';
1657
1658   #XXX payinfo1 + payinfo2 for CHEK?
1659   #or take the opportunity to use separate, more well- named fields?
1660   # my $payinfo;
1661   # $p->{'payinfo1'} =~ /^([\dx]+)$/
1662   #   or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
1663   # my $payinfo1 = $1;
1664   #  $p->{'payinfo2'} =~ /^([\dx\.]+)$/ # . turned on by echeck-country CA ?
1665   #   or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
1666   # my $payinfo2 = $1;
1667   # $payinfo = $payinfo1. '@'. $payinfo2;
1668
1669   my $cust_payby = new FS::cust_payby {
1670     'custnum' => $custnum,
1671     map { $_ => $p->{$_} } qw( weight payby payinfo paycvv paydate payname
1672                                paystate paytype payip
1673                              ),
1674   };
1675
1676   my $error = $cust_payby->insert;
1677   if ( $error ) {
1678     return { 'error' => $error };
1679   } else {
1680     return { 'custpaybynum' => $cust_payby->custpaybynum };
1681   }
1682
1683 }
1684
1685 sub update_payby {
1686   my $p = shift;
1687
1688   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1689   return { 'error' => $session } if $context eq 'error';
1690
1691   my $cust_payby = qsearchs('cust_payby', {
1692                               'custnum'      => $custnum,
1693                               'custpaybynum' => $p->{'custpaybynum'},
1694                            })
1695     or return { 'error' => 'unknown custpaybynum '. $p->{'custpaybynum'} };
1696
1697   foreach my $field (
1698     qw( weight payby payinfo paycvv paydate payname paystate paytype payip )
1699   ) {
1700     next unless exists($p->{$field});
1701     $cust_payby->set($field,$p->{$field});
1702   }
1703
1704   my $error = $cust_payby->replace;
1705   if ( $error ) {
1706     return { 'error' => $error };
1707   } else {
1708     return { 'custpaybynum' => $cust_payby->custpaybynum };
1709   }
1710
1711 }
1712
1713 sub verify_payby {
1714   my $p = shift;
1715
1716   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1717   return { 'error' => $session } if $context eq 'error';
1718
1719   my $cust_payby = qsearchs('cust_payby', {
1720                               'custnum'      => $custnum,
1721                               'custpaybynum' => $p->{'custpaybynum'},
1722                            })
1723     or return { 'error' => 'unknown custpaybynum '. $p->{'custpaybynum'} };
1724
1725   return { 'error' => $cust_payby->verify };
1726
1727 }
1728
1729 sub delete_payby {
1730   my $p = shift;
1731
1732   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1733   return { 'error' => $session } if $context eq 'error';
1734
1735   my $cust_payby = qsearchs('cust_payby', {
1736                               'custnum'      => $custnum,
1737                               'custpaybynum' => $p->{'custpaybynum'},
1738                            })
1739     or return { 'error' => 'unknown custpaybynum '. $p->{'custpaybynum'} };
1740
1741   return { 'error' => $cust_payby->delete };
1742
1743 }
1744
1745 sub cancel {
1746   my $p = shift;
1747   my $session = _cache->get($p->{'session_id'})
1748     or return { 'error' => "Can't resume session" }; #better error message
1749
1750   my $custnum = $session->{'custnum'};
1751
1752   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1753     or return { 'error' => "unknown custnum $custnum" };
1754
1755   my @errors = $cust_main->cancel( 'quiet'=>1 );
1756
1757   my $error = scalar(@errors) ? join(' / ', @errors) : '';
1758
1759   return { 'error' => $error };
1760
1761 }
1762
1763 sub list_pkgs {
1764   my $p = shift;
1765
1766   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1767   return { 'error' => $session } if $context eq 'error';
1768
1769   my $search = { 'custnum' => $custnum };
1770   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1771   my $cust_main = qsearchs('cust_main', $search )
1772     or return { 'error' => "unknown custnum $custnum" };
1773
1774   my $conf = new FS::Conf;
1775   my $immutable = $conf->exists('selfservice_immutable-package');
1776
1777 # the duplication below is necessary:
1778 # 1. to maintain the current buggy behaviour wrt the cust_pkg and part_pkg
1779 # hashes overwriting each other (setup and no_auto fields). Fixing that is a
1780 # non-backwards-compatible change breaking the software of anyone using the API
1781 # instead of the stock selfservice
1782 # 2. to return cancelled packages as well - for wholesale and non-wholesale
1783   if( $conf->exists('selfservice_server-view-wholesale') ) {
1784     return { 'svcnum'   => $session->{'svcnum'},
1785             'custnum'  => $custnum,
1786             'cust_pkg' => [ map {
1787                           { $_->hash,
1788                             immutable => $immutable,
1789                             part_pkg => [ map $_->hashref, $_->part_pkg ],
1790                             part_svc =>
1791                               [ map $_->hashref, $_->available_part_svc ],
1792                             cust_svc =>
1793                               [ map { my $ref = { $_->hash,
1794                                                   label => [ $_->label ],
1795                                                 };
1796                                       $ref->{_password} = $_->svc_x->_password
1797                                         if $context eq 'agent'
1798                                         && $conf->exists('agent-showpasswords')
1799                                         && $_->part_svc->svcdb eq 'svc_acct';
1800                                       $ref;
1801                                     } $_->cust_svc
1802                               ],
1803                           };
1804                         } $cust_main->cust_pkg
1805                   ],
1806     'small_custview' =>
1807       small_custview( $cust_main, $conf->config('countrydefault') ),
1808     'wholesale_view' => 1,
1809     'login_svcpart' => [ $conf->config('selfservice_server-login_svcpart') ],
1810     'date_format' => $conf->config('date_format') || '%m/%d/%Y',
1811     'lnp' => $conf->exists('svc_phone-lnp'),
1812       };
1813   }
1814
1815   { 'svcnum'   => $session->{'svcnum'},
1816     'custnum'  => $custnum,
1817     'cust_pkg' => [ map {
1818                           my $primary_cust_svc = $_->primary_cust_svc;
1819                           +{ $_->hash,
1820                             $_->part_pkg->hash,
1821                             immutable   => $immutable,
1822                             pkg_label   => $_->pkg_locale,
1823                             status      => $_->status,
1824                             statuscolor => $_->statuscolor,
1825                             part_svc =>
1826                               [ map { $_->hashref }
1827                                   grep { $_->selfservice_access ne 'hidden' }
1828                                     $_->available_part_svc
1829                               ],
1830                             cust_svc =>
1831                               [ map { my $ref = { $_->hash,
1832                                                   label => [ $_->label ],
1833                                                 };
1834                                       $ref->{_password} = $_->svc_x->_password
1835                                         if $context eq 'agent'
1836                                         && $conf->exists('agent-showpasswords')
1837                                         && $_->part_svc->svcdb eq 'svc_acct';
1838                                       $ref->{svchash} = { $_->svc_x->hash } if
1839                                         $_->part_svc->svcdb eq 'svc_phone';
1840                                       $ref->{svchash}->{svcpart} =  $_->part_svc->svcpart
1841                                         if $_->part_svc->svcdb eq 'svc_phone'; # hack
1842                                       $ref;
1843                                     }
1844                                   grep { $_->part_svc->selfservice_access ne 'hidden' }
1845                                     $_->cust_svc
1846                               ],
1847                             primary_cust_svc =>
1848                               $primary_cust_svc
1849                                 ? { $primary_cust_svc->hash,
1850                                     label => [ $primary_cust_svc->label ],
1851                                     finger => $primary_cust_svc->svc_x->finger, #uuh
1852                                     $primary_cust_svc->part_svc->hash,
1853                                   }
1854                                 : {}, #'' ?
1855                           };
1856                         } $cust_main->ncancelled_pkgs
1857                   ],
1858     'small_custview' =>
1859       small_custview( $cust_main, $conf->config('countrydefault') ),
1860     'date_format' => $conf->config('date_format') || '%m/%d/%Y',
1861   };
1862
1863 }
1864
1865 sub list_svcs {
1866   my $p = shift;
1867
1868   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1869   return { 'error' => $session } if $context eq 'error';
1870
1871   my $conf = new FS::Conf;
1872
1873   my $hide_usage = $conf->exists('selfservice_hide-usage') ? 1 : 0;
1874   my $search = { 'custnum' => $custnum };
1875   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1876   my $cust_main = qsearchs('cust_main', $search )
1877     or return { 'error' => "unknown custnum $custnum" };
1878
1879   my $pkgnum = $session->{'pkgnum'} || $p->{'pkgnum'} || '';
1880   if ( ! $pkgnum && $p->{'svcnum'} ) {
1881     my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $p->{'svcnum'} } );
1882     $pkgnum = $cust_svc->pkgnum if $cust_svc;
1883   }
1884
1885   my @cust_svc = ();
1886   my @cust_pkg_usage = ();
1887   foreach my $cust_pkg ( $p->{'ncancelled'}
1888                          ? $cust_main->ncancelled_pkgs
1889                          : $cust_main->unsuspended_pkgs ) {
1890     next if $pkgnum && $cust_pkg->pkgnum != $pkgnum;
1891     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
1892     push @cust_pkg_usage, $cust_pkg->cust_pkg_usage;
1893   }
1894
1895   @cust_svc = grep { $_->part_svc->selfservice_access ne 'hidden' } @cust_svc;
1896   my %usage_pools;
1897   if (!$hide_usage) {
1898     foreach (@cust_pkg_usage) {
1899       my $part = $_->part_pkg_usage;
1900       my $tag = $part->description . ($part->shared ? 1 : 0);
1901       my $row = $usage_pools{$tag}
1902             ||= [ $part->description, 0, 0, $part->shared ? 1 : 0 ];
1903       $row->[1] += sprintf('%.1f', $_->minutes); # minutes remaining
1904       $row->[2] += $part->minutes; # minutes total
1905     }
1906   } # otherwise just leave them empty
1907
1908   if ( $p->{'svcdb'} ) {
1909     my $svcdb = ref($p->{'svcdb'}) eq 'HASH'
1910                   ? $p->{'svcdb'}
1911                   : ref($p->{'svcdb'}) eq 'ARRAY'
1912                     ? { map { $_=>1 } @{ $p->{'svcdb'} } }
1913                     : { $p->{'svcdb'} => 1 };
1914     @cust_svc = grep $svcdb->{ $_->part_svc->svcdb }, @cust_svc
1915   }
1916
1917   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
1918   #              @svc_x;
1919
1920   my @svcs; # stuff to return to the client
1921   my %bytes_used_total; # for _used columns only
1922   foreach my $cust_svc (@cust_svc) {
1923     my $svc_x = $cust_svc->svc_x;
1924     my($label, $value) = $cust_svc->label;
1925     my $part_svc = $cust_svc->part_svc;
1926     my $svcdb = $part_svc->svcdb;
1927     my $cust_pkg = $cust_svc->cust_pkg;
1928     my $part_pkg = $cust_pkg->part_pkg;
1929
1930     my %hash = (
1931       'svcnum'         => $cust_svc->svcnum,
1932       'display_svcnum' => $cust_svc->display_svcnum,
1933       'svcdb'          => $svcdb,
1934       'label'          => $label,
1935       'value'          => $value,
1936       'pkg_label'      => $cust_pkg->pkg_locale,
1937       'pkg_status'     => $cust_pkg->status,
1938       'readonly'       => ($part_svc->selfservice_access eq 'readonly'),
1939     );
1940
1941     # would it make sense to put this in a svc_* method?
1942
1943     if (!$hide_usage and grep(/^$svcdb$/, qw(svc_acct svc_broadband)) and $part_svc->part_export_usage) {
1944       my $last_bill = $cust_pkg->last_bill || 0;
1945       my $now = time;
1946       my $up_used = $cust_svc->attribute_since_sqlradacct($last_bill,$now,'AcctInputOctets');
1947       my $down_used = $cust_svc->attribute_since_sqlradacct($last_bill,$now,'AcctOutputOctets');
1948       %hash = (
1949         %hash,
1950         'seconds_used'    => $cust_svc->seconds_since_sqlradacct($last_bill,$now),
1951         'upbytes_used'    => display_bytecount($up_used),
1952         'downbytes_used'  => display_bytecount($down_used),
1953         'totalbytes_used' => display_bytecount($up_used + $down_used)
1954       );
1955       $bytes_used_total{'seconds_used'} += $hash{'seconds_used'};
1956       $bytes_used_total{'upbytes_used'} += $up_used;
1957       $bytes_used_total{'downbytes_used'} += $down_used;
1958       $bytes_used_total{'totalbytes_used'} += $up_used + $down_used;
1959     }
1960
1961     if ( $svcdb eq 'svc_acct' ) {
1962       foreach (qw(username email finger seconds)) {
1963         $hash{$_} = $svc_x->$_;
1964       }
1965
1966       if (!$hide_usage) {
1967         %hash = (
1968           %hash,
1969           'upbytes'    => display_bytecount($svc_x->upbytes),
1970           'downbytes'  => display_bytecount($svc_x->downbytes),
1971           'totalbytes' => display_bytecount($svc_x->totalbytes),
1972
1973           'recharge_amount'  => $part_pkg->option('recharge_amount',1),
1974           'recharge_seconds' => $part_pkg->option('recharge_seconds',1),
1975           'recharge_upbytes'    =>
1976             display_bytecount($part_pkg->option('recharge_upbytes',1)),
1977           'recharge_downbytes'  =>
1978             display_bytecount($part_pkg->option('recharge_downbytes',1)),
1979           'recharge_totalbytes' =>
1980             display_bytecount($part_pkg->option('recharge_totalbytes',1)),
1981           # more...
1982         );
1983       }
1984
1985     } elsif ( $svcdb eq 'svc_dsl' ) {
1986
1987       $hash{'phonenum'} = $svc_x->phonenum;
1988       if ( $svc_x->first || $svc_x->get('last') || $svc_x->company ) {
1989         $hash{'name'} = $svc_x->first. ' '. $svc_x->get('last');
1990         $hash{'name'} = $svc_x->company. ' ('. $hash{'name'}. ')'
1991           if $svc_x->company;
1992       } else {
1993         $hash{'name'} = $cust_main->name;
1994       }
1995       # no usage to hide here
1996
1997     } elsif ( $svcdb eq 'svc_phone' or $svcdb eq 'svc_pbx' ) {
1998       if (!$hide_usage) {
1999         # could potentially show lots of things...
2000         $hash{'outbound'} = 1;
2001         $hash{'inbound'}  = 0;
2002         if ( $svcdb eq 'svc_phone' ) {
2003           if ( $part_pkg->plan eq 'voip_inbound' ) {
2004             $hash{'outbound'} = 0;
2005             $hash{'inbound'}  = 1;
2006           } elsif ( $part_pkg->option('selfservice_inbound_format')
2007                 or  $conf->config('selfservice-default_inbound_cdr_format')
2008           ) {
2009             $hash{'inbound'}  = 1;
2010           }
2011         }
2012         foreach (qw(inbound outbound)) {
2013           # hmm...we can't filter by status here, because there might
2014           # not be cdr_terminations at all.  have to go by date.
2015           # find all since the last bill date.
2016           # XXX cdr types?  we are going to need them.
2017           if ( $hash{$_} ) {
2018             my $sum_cdr = $svc_x->sum_cdrs(
2019               'inbound' => ( $_ eq 'inbound' ? 1 : 0 ),
2020               'begin'   => ($cust_pkg->last_bill || 0),
2021               'nonzero' => 1,
2022               'disable_charged_party' => 1,
2023             );
2024             $hash{$_} = $sum_cdr->hashref;
2025           }
2026         }
2027       } # not hiding usage
2028     } # svcdb
2029
2030     push @svcs, \%hash;
2031   } # foreach $cust_svc
2032
2033   foreach my $field (keys %bytes_used_total) {
2034     if ($field =~ /bytes/) {
2035       $bytes_used_total{$field} = display_bytecount($bytes_used_total{$field});
2036     }
2037   }
2038
2039   return {
2040     'svcnum'   => $session->{'svcnum'},
2041     'custnum'  => $custnum,
2042     'date_format' => $conf->config('date_format') || '%m/%d/%Y',
2043     'view_usage_nodomain' => $conf->exists('selfservice-view_usage_nodomain'),
2044     'svcs'     => \@svcs,
2045     'bytes_used_total' => \%bytes_used_total,
2046     'usage_pools' => [
2047       map { $usage_pools{$_} }
2048       sort { $a cmp $b }
2049       keys %usage_pools
2050     ],
2051     'hide_usage' => $hide_usage,
2052   };
2053
2054 }
2055
2056 sub _customer_svc_x {
2057   my($custnum, $svcnum, $table) = (shift, shift, shift);
2058   my $hashref = ref($svcnum) ? $svcnum : { 'svcnum' => $svcnum };
2059
2060   $custnum =~ /^(\d+)$/ or die "illegal custnum";
2061   my $search = " AND custnum = $1";
2062   #$search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
2063
2064   qsearchs( {
2065     'table'     => ($table || 'svc_acct'),
2066     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
2067                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) ',#.
2068                    #'LEFT JOIN cust_main USING ( custnum ) ',
2069     'hashref'   => $hashref,
2070     'extra_sql' => $search, #important
2071   } );
2072
2073 }
2074
2075 sub svc_status_html {
2076   my $p = shift;
2077
2078   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2079   return { 'error' => $session } if $context eq 'error';
2080
2081   #XXX only svc_dsl for now
2082   my $svc_x = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_dsl')
2083     or return { 'error' => "Service not found" };
2084
2085   my $html = $svc_x->getstatus_html;
2086
2087   return { 'html' => $html };
2088
2089 }
2090
2091 sub svc_status_hash {
2092   my $p = shift;
2093
2094   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2095   return { 'error' => $session } if $context eq 'error';
2096
2097   #XXX only svc_acct for now
2098   my $svc_x = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_acct')
2099     or return { 'error' => "Service not found" };
2100
2101   my ( $html, $hashref ) = $svc_x->export_getstatus;
2102   return $hashref;
2103
2104 }
2105
2106 sub set_svc_status_hash    { _svc_method_X(shift, 'export_setstatus') }
2107 sub set_svc_status_listadd { _svc_method_X(shift, 'export_setstatus_listadd') }
2108 sub set_svc_status_listdel { _svc_method_X(shift, 'export_setstatus_listdel') }
2109 sub set_svc_status_vacationadd { _svc_method_X(shift, 'export_setstatus_vacationadd') }
2110 sub set_svc_status_vacationdel { _svc_method_X(shift, 'export_setstatus_vacationdel') }
2111
2112 sub _svc_method_X {
2113   my( $p, $method ) = @_;
2114
2115   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2116   return { 'error' => $session } if $context eq 'error';
2117
2118   #XXX only svc_acct for now
2119   my $svc_x = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_acct')
2120     or return { 'error' => "Service not found" };
2121
2122   warn "$method ". join(' / ', map "$_=>".$p->{$_}, keys %$p )
2123     if $DEBUG;
2124   my $error = $svc_x->$method($p); #$p? returns error?
2125   return { 'error' => $error } if $error;
2126
2127   return {}; #? { 'error' => '' }
2128
2129 }
2130
2131 sub acct_forward_info {
2132   my $p = shift;
2133
2134   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2135   return { 'error' => $session } if $context eq 'error';
2136
2137   my $svc_forward = _customer_svc_x( $custnum,
2138                                      { 'srcsvc' => $p->{'svcnum'} },
2139                                      'svc_forward',
2140                                    )
2141     or return { 'error' => '',
2142                 'dst'   => '',
2143               };
2144
2145   return { 'error' => '',
2146            'dst'   => $svc_forward->dst || $svc_forward->dstsvc_acct->email,
2147          };
2148
2149 }
2150
2151 sub process_acct_forward {
2152   my $p = shift;
2153   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2154   return { 'error' => $session } if $context eq 'error';
2155
2156   my $old = _customer_svc_x( $custnum,
2157                              { 'srcsvc' => $p->{'svcnum'} },
2158                              'svc_forward',
2159                            );
2160
2161   if ( $p->{'dst'} eq '' ) {
2162     if ( $old ) {
2163       my $error = $old->delete;
2164       return { 'error' => $error };
2165     }
2166     return { 'error' => '' };
2167   }
2168
2169   my $new = new FS::svc_forward { 'srcsvc' => $p->{'svcnum'},
2170                                   'dst'    => $p->{'dst'},
2171                                 };
2172
2173   my $error;
2174   if ( $old ) {
2175     $new->svcnum($old->svcnum);
2176     my $cust_svc = $old->cust_svc;
2177     $new->svcpart($old->svcpart);
2178     $new->pkgnuym($old->pkgnum);
2179     $error = $new->replace($old);
2180   } else {
2181     my $conf = new FS::Conf;
2182     $new->svcpart($conf->config('selfservice-svc_forward_svcpart'));
2183
2184     my $svc_acct = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_acct' )
2185       or return { 'error' => 'No service' }; #how would we even get here?
2186
2187     $new->pkgnum( $svc_acct->cust_svc->pkgnum );
2188
2189     $error = $new->insert;
2190   }
2191
2192   return { 'error' => $error };
2193
2194 }
2195
2196 sub list_dsl_devices {
2197   my $p = shift;
2198
2199   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2200   return { 'error' => $session } if $context eq 'error';
2201
2202   my $svc_dsl = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_dsl' )
2203     or return { 'error' => "Service not found" };
2204
2205   return {
2206     'devices' => [ map {
2207                          +{ 'mac_addr' => $_->mac_addr };
2208                        } $svc_dsl->dsl_device
2209                  ],
2210   };
2211
2212 }
2213
2214 sub add_dsl_device {
2215   my $p = shift;
2216
2217   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2218   return { 'error' => $session } if $context eq 'error';
2219
2220   my $svc_dsl = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_dsl' )
2221     or return { 'error' => "Service not found" };
2222
2223   return { 'error' => 'No MAC address supplied' }
2224     unless length($p->{'mac_addr'});
2225
2226   my $dsl_device = new FS::dsl_device { 'svcnum'   => $svc_dsl->svcnum,
2227                                         'mac_addr' => scalar($p->{'mac_addr'}),
2228                                       };
2229   my $error = $dsl_device->insert;
2230   return { 'error' => $error };
2231
2232 }
2233
2234 sub delete_dsl_device {
2235   my $p = shift;
2236
2237   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2238   return { 'error' => $session } if $context eq 'error';
2239
2240   my $svc_dsl = _customer_svc_x( $custnum, $p->{'svcnum'}, 'svc_dsl' )
2241     or return { 'error' => "Service not found" };
2242
2243   my $dsl_device = qsearchs('dsl_device', { 'svcnum'   => $svc_dsl->svcnum,
2244                                             'mac_addr' => scalar($p->{'mac_addr'}),
2245                                           }
2246                            )
2247     or return { 'error' => 'Unknown MAC address: '. $p->{'mac_addr'} };
2248
2249   my $error = $dsl_device->delete;
2250   return { 'error' => $error };
2251
2252 }
2253
2254 sub port_graph {
2255   my $p = shift;
2256   _usage_details( \&_port_graph, $p,
2257                   'svcdb' => 'svc_port',
2258                 );
2259 }
2260
2261 sub _port_graph {
2262   my($svc_port, $begin, $end) = @_;
2263   my @usage = ();
2264   my $pngOrError = $svc_port->graph_png( start=>$begin, end=> $end );
2265   push @usage, { 'png' => $pngOrError };
2266   (@usage);
2267 }
2268
2269 sub _list_svc_usage {
2270   my($svc_acct, $begin, $end) = @_;
2271   my @usage = ();
2272   foreach my $part_export (
2273     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
2274     qw( sqlradius sqlradius_withdomain )
2275   ) {
2276     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
2277   }
2278   (@usage);
2279 }
2280
2281 sub list_svc_usage {
2282   _usage_details(\&_list_svc_usage, @_);
2283 }
2284
2285 sub _list_support_usage {
2286   my($svc_acct, $begin, $end) = @_;
2287   my @usage = ();
2288   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
2289             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
2290           ) {
2291     push @usage, { 'seconds'  => $_->seconds,
2292                    'support'  => $_->support,
2293                    '_date'    => $_->_date,
2294                    'id'       => $_->transaction_id,
2295                    'creator'  => $_->creator,
2296                    'subject'  => $_->subject,
2297                    'status'   => $_->status,
2298                    'ticketid' => $_->ticketid,
2299                  };
2300   }
2301   (@usage);
2302 }
2303
2304 sub list_support_usage {
2305   _usage_details(\&_list_support_usage, @_);
2306 }
2307
2308 sub _list_cdr_usage {
2309   # XXX CDR type support...
2310   # XXX any way to do a paged search on this?
2311   # we have to return the results all at once...
2312   my($svc_x, $begin, $end, %opt) = @_;
2313   map [ $_->downstream_csv(%opt, 'keeparray' => 1) ],
2314     $svc_x->get_cdrs(
2315       'begin' => $begin,
2316       'end'   => $end,
2317       'disable_charged_party' => 1,
2318       %opt
2319     );
2320 }
2321
2322 sub list_cdr_usage {
2323   my $p = shift;
2324   _usage_details( \&_list_cdr_usage, $p );
2325 }
2326
2327 sub _usage_details {
2328   my($callback, $p, %opt) = @_;
2329   my $conf = FS::Conf->new;
2330
2331   if ( $conf->exists('selfservice_hide-usage') ) {
2332     return { 'error' => 'Viewing usage is not allowed.' };
2333   }
2334
2335   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2336   return { 'error' => $session } if $context eq 'error';
2337
2338   my $search = { 'svcnum' => $p->{'svcnum'} };
2339   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
2340
2341   my $cust_svc = qsearchs( 'cust_svc', $search );
2342   return { 'error' => 'No service selected in list_svc_usage' }
2343     unless $cust_svc;
2344
2345   my $svc_x = $cust_svc->svc_x;
2346   my $svcdb = $svc_x->table;
2347   my $cust_pkg = $cust_svc->cust_pkg;
2348   my $freq     = $cust_pkg->part_pkg->freq;
2349   my %callback_opt;
2350   my $header = [];
2351   if ( $svcdb eq 'svc_phone' or $svcdb eq 'svc_pbx' ) {
2352     my $format = '';
2353     if ( $p->{inbound} ) {
2354       $format = $cust_pkg->part_pkg->option('selfservice_inbound_format')
2355                 || $conf->config('selfservice-default_inbound_cdr_format')
2356                 || 'source_default';
2357       $callback_opt{inbound} = 1;
2358     } else {
2359       $format = $cust_pkg->part_pkg->option('selfservice_format')
2360                 || $conf->config('selfservice-default_cdr_format')
2361                 || 'default';
2362     }
2363
2364     $callback_opt{format} = $format;
2365     $callback_opt{use_clid} = 1;
2366     $header = [ split(',', FS::cdr::invoice_header($format) ) ];
2367   }
2368
2369   my $start    = $cust_pkg->setup;
2370   #my $end      = $cust_pkg->bill; # or time?
2371   my $end      = time;
2372
2373   unless ( $p->{beginning} ) {
2374     $p->{beginning} = $cust_pkg->last_bill;
2375     $p->{ending}    = $end;
2376   }
2377
2378   die "illegal beginning" if $p->{beginning} !~ /^\d*$/;
2379   die "illegal ending"    if $p->{ending}    !~ /^\d*$/;
2380
2381   my (@usage) = &$callback($svc_x, $p->{beginning}, $p->{ending},
2382     %callback_opt
2383   );
2384
2385   if ( $conf->exists('selfservice-hide_cdr_price') ) {
2386     # ugly kludge, I know
2387     my ($delete_col) = grep { $header->[$_] eq 'Price' } (0..scalar(@$header));
2388     if (defined $delete_col) {
2389       delete($_->[$delete_col]) foreach ($header, @usage);
2390     }
2391   }
2392
2393   #kinda false laziness with FS::cust_main::bill, but perhaps
2394   #we should really change this bit to DateTime and DateTime::Duration
2395   #
2396   #change this bit to use Date::Manip? CAREFUL with timezones (see
2397   # mailing list archive)
2398   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
2399     (localtime($p->{ending}) )[0,1,2,3,4,5];
2400   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
2401     (localtime($p->{beginning}) )[0,1,2,3,4,5];
2402
2403   if ( $freq =~ /^\d+$/ ) {
2404     $nmon += $freq;
2405     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
2406     $pmon -= $freq;
2407     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
2408   } elsif ( $freq =~ /^(\d+)w$/ ) {
2409     my $weeks = $1;
2410     $nmday += $weeks * 7;
2411     $pmday -= $weeks * 7;
2412   } elsif ( $freq =~ /^(\d+)d$/ ) {
2413     my $days = $1;
2414     $nmday += $days;
2415     $pmday -= $days;
2416   } elsif ( $freq =~ /^(\d+)h$/ ) {
2417     my $hours = $1;
2418     $nhour += $hours;
2419     $phour -= $hours;
2420   } else {
2421     return { 'error' => "unparsable frequency: ". $freq };
2422   }
2423
2424   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
2425   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
2426
2427   {
2428     'error'     => '',
2429     'svcnum'    => $p->{svcnum},
2430     'beginning' => $p->{beginning},
2431     'ending'    => $p->{ending},
2432     'inbound'   => $p->{inbound},
2433     'previous'  => ($previous > $start) ? $previous : $start,
2434     'next'      => ($next < $end) ? $next : $end,
2435     'header'    => $header,
2436     'usage'     => \@usage,
2437   };
2438 }
2439
2440 sub order_pkg {
2441   my $p = shift;
2442
2443   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2444   return { 'error' => $session } if $context eq 'error';
2445
2446   my $search = { 'custnum' => $custnum };
2447   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
2448   my $cust_main = qsearchs('cust_main', $search )
2449     or return { 'error' => "unknown custnum $custnum" };
2450
2451   my $status = $cust_main->status;
2452
2453   my %order_pkg_options = ();
2454   if ( $p->{locationnum} > 0 ) {
2455     $order_pkg_options{locationnum} = delete($p->{locationnum});
2456   } elsif ( $p->{address1} ) {
2457     $order_pkg_options{'cust_location'} = new FS::cust_location {
2458       map { $_ => $p->{$_} }
2459         qw( address1 address2 city county state zip country )
2460     };
2461   }
2462
2463   #false laziness w/ClientAPI/Signup.pm
2464
2465   my $cust_pkg = new FS::cust_pkg ( {
2466     'custnum'  => $custnum,
2467     'pkgpart'  => $p->{'pkgpart'},
2468     'quantity' => $p->{'quantity'} || 1,
2469   } );
2470   my $error = $cust_pkg->check;
2471   return { 'error' => $error } if $error;
2472
2473   my @svc = ();
2474   unless ( $p->{'svcpart'} eq 'none' ) {
2475
2476     my $svcdb;
2477     my $svcpart = '';
2478     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
2479       $svcpart = $1;
2480       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
2481       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
2482       $svcdb = $part_svc->svcdb;
2483     } else {
2484       $svcdb = 'svc_acct';
2485     }
2486     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
2487
2488     my %fields = (
2489       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
2490       'svc_domain'   => [ qw( domain ) ],
2491       'svc_phone'    => [ qw( phonenum pin sip_password phone_name ) ],
2492       'svc_external' => [ qw( id title ) ],
2493       'svc_pbx'      => [ qw( id title ) ],
2494     );
2495
2496     my $svc_x = "FS::$svcdb"->new( {
2497       'svcpart'   => $svcpart,
2498       map { $_ => $p->{$_} } @{$fields{$svcdb}}
2499     } );
2500
2501     if ( $svcdb eq 'svc_acct' && exists($p->{"snarf_machine1"}) ) {
2502       my @acct_snarf;
2503       my $snarfnum = 1;
2504       while ( length($p->{"snarf_machine$snarfnum"}) ) {
2505         my $acct_snarf = new FS::acct_snarf ( {
2506           'machine'   => $p->{"snarf_machine$snarfnum"},
2507           'protocol'  => $p->{"snarf_protocol$snarfnum"},
2508           'username'  => $p->{"snarf_username$snarfnum"},
2509           '_password' => $p->{"snarf_password$snarfnum"},
2510         } );
2511         $snarfnum++;
2512         push @acct_snarf, $acct_snarf;
2513       }
2514       $svc_x->child_objects( \@acct_snarf );
2515     }
2516
2517     my $y = $svc_x->setdefault; # arguably should be in new method
2518     return { 'error' => $y } if $y && !ref($y);
2519
2520     $error = $svc_x->check;
2521     return { 'error' => $error } if $error;
2522
2523     push @svc, $svc_x;
2524
2525   }
2526
2527   $error = $cust_main->order_pkg(
2528     'cust_pkg' => $cust_pkg,
2529     'svcs'     => \@svc,
2530     'noexport' => 1,
2531     %order_pkg_options,
2532   );
2533   return { 'error' => $error } if $error;
2534
2535   my $conf = new FS::Conf;
2536   if ( $conf->exists('signup_server-realtime') ) {
2537
2538     my $bill_error = _do_bop_realtime( $cust_main, $status, 'collect'=>$p->{run_bill_events} );
2539
2540     if ($bill_error) {
2541       $cust_pkg->cancel('quiet'=>1);
2542       return $bill_error;
2543     } else {
2544       $cust_pkg->reexport;
2545     }
2546
2547   } else {
2548     $cust_pkg->reexport;
2549   }
2550
2551   my $svcnum = $svc[0] ? $svc[0]->svcnum : '';
2552
2553   return { error=>'', pkgnum=>$cust_pkg->pkgnum, svcnum=>$svcnum };
2554
2555 }
2556
2557 sub change_pkg {
2558   my $p = shift;
2559
2560   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2561   return { 'error' => $session } if $context eq 'error';
2562
2563   my $conf = new FS::Conf;
2564   my $immutable = $conf->exists('selfservice_immutable-package');
2565   return { 'error' => "Package modification disabled" } if $immutable;
2566
2567   my $search = { 'custnum' => $custnum };
2568   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
2569   my $cust_main = qsearchs('cust_main', $search )
2570     or return { 'error' => "unknown custnum $custnum" };
2571
2572   my $status = $cust_main->status;
2573   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
2574     or return { 'error' => "unknown package $p->{pkgnum}" };
2575
2576   #if someone does need self-service package change of suspended packages,
2577   # figure out how to be more discriminating
2578   return { error=>"Can't change a suspended package", pkgnum=>$cust_pkg->pkgnum}
2579     if $cust_pkg->status eq 'suspended';
2580
2581   my $err_or_cust_pkg = $cust_pkg->change( 'pkgpart'  => $p->{'pkgpart'},
2582                                            'quantity' => $p->{'quantity'} || 1,
2583                                          );
2584
2585   my $new_pkg = qsearchs('part_pkg', { 'pkgpart' => $p->{pkgpart} } )
2586     or return { 'error' => "unknown package $p->{pkgpart}" };
2587
2588   return { error=>$err_or_cust_pkg, pkgnum=>$cust_pkg->pkgnum }
2589     unless ref($err_or_cust_pkg);
2590
2591
2592   if ( $conf->exists('signup_server-realtime') ) {
2593
2594     my $bill_error = _do_bop_realtime( $cust_main, $status, 'no_invoice_void'=>1 );
2595
2596     if ($bill_error) {
2597       $err_or_cust_pkg->suspend;
2598       return $bill_error;
2599     } else {
2600       $err_or_cust_pkg->reexport;
2601     }
2602
2603   } else {
2604     $err_or_cust_pkg->reexport;
2605   }
2606
2607   return { error => '', pkg => $new_pkg->pkg, pkgnum => $err_or_cust_pkg->pkgnum };
2608
2609 }
2610
2611 sub order_recharge {
2612   my $p = shift;
2613
2614   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2615   return { 'error' => $session } if $context eq 'error';
2616
2617   my $search = { 'custnum' => $custnum };
2618   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
2619   my $cust_main = qsearchs('cust_main', $search )
2620     or return { 'error' => "unknown custnum $custnum" };
2621
2622   my $status = $cust_main->status;
2623   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
2624     or return { 'error' => "unknown service " . $p->{'svcnum'} };
2625
2626   my $svc_x = $cust_svc->svc_x;
2627   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
2628
2629   my %vhash =
2630     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
2631     qw ( recharge_seconds recharge_upbytes recharge_downbytes
2632          recharge_totalbytes );
2633   my $amount = $part_pkg->option('recharge_amount', 1);
2634
2635   my ($l, $v, $d) = $cust_svc->label;  # blah
2636   my $pkg = "Recharge $v";
2637
2638   my $bill_error = $cust_main->charge($amount, $pkg,
2639      "time: $vhash{seconds}, up: $vhash{upbytes}," .
2640      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
2641      $part_pkg->taxclass); #meh
2642
2643   my $conf = new FS::Conf;
2644   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
2645
2646     $bill_error = _do_bop_realtime( $cust_main, $status );
2647
2648     if ($bill_error) {
2649       return $bill_error;
2650     } else {
2651       my $error = $svc_x->recharge (\%vhash);
2652       return { 'error' => $error } if $error;
2653     }
2654
2655   } else {
2656     my $error = $bill_error;
2657     $error ||= $svc_x->recharge (\%vhash);
2658     return { 'error' => $error } if $error;
2659   }
2660
2661   return { error => '', svc => $cust_svc->part_svc->svc };
2662
2663 }
2664
2665 sub _do_bop_realtime {
2666   my ($cust_main, $status, %opt) = @_;
2667
2668   my $old_balance = $cust_main->balance;
2669
2670   my @cust_bill;
2671   my $bill_error = $cust_main->bill(
2672     'return_bill'   => \@cust_bill,
2673   );
2674
2675   $bill_error ||= $cust_main->apply_payments_and_credits;
2676
2677   $bill_error ||= $cust_main->realtime_collect('selfservice' => 1);
2678
2679   if (    $cust_main->balance > $old_balance
2680        && $cust_main->balance > 0
2681        && ( $cust_main->has_cust_payby_auto || $status eq 'suspended' )
2682      )
2683   {
2684     unless ( $opt{'no_invoice_void'} ) {
2685
2686       #this used to apply a credit, but now we can void invoices...
2687       foreach my $cust_bill (@cust_bill) {
2688         my $voiderror = $cust_bill->void('automatic payment failed');
2689         warn "Error voiding cust bill after decline: $voiderror" if $voiderror;
2690       }
2691
2692     }
2693
2694     return { 'error' => '_decline', 'bill_error' => $bill_error };
2695   }
2696
2697   if ( $opt{'collect'} ) {
2698     my $collect_error = $cust_main->collect();
2699     return { 'error' => '_decline', 'bill_error' => $collect_error }
2700      if $collect_error; #?
2701   }
2702
2703   '';
2704 }
2705
2706 sub renew_info {
2707   my $p = shift;
2708
2709   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2710   return { 'error' => $session } if $context eq 'error';
2711
2712   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
2713     or return { 'error' => "unknown custnum $custnum" };
2714
2715   my @cust_pkg = sort { $a->bill <=> $b->bill }
2716                  grep { $_->part_pkg->freq ne '0' }
2717                  $cust_main->ncancelled_pkgs;
2718
2719   #return { 'error' => 'No active packages to renew.' } unless @cust_pkg;
2720
2721   my $total = $cust_main->balance;
2722
2723   my @array = map {
2724                     my $bill = $_->bill;
2725                     $total += $_->part_pkg->base_recur($_, \$bill);
2726                     my $renew_date = $_->part_pkg->add_freq($_->bill);
2727                     {
2728                       'pkgnum'             => $_->pkgnum,
2729                       'amount'             => sprintf('%.2f', $total),
2730                       'bill_date'          => $_->bill,
2731                       'bill_date_pretty'   => time2str('%x', $_->bill),
2732                       'renew_date'         => $renew_date,
2733                       'renew_date_pretty'  => time2str('%x', $renew_date),
2734                       'expire_date'        => $_->expire,
2735                       'expire_date_pretty' => time2str('%x', $_->expire),
2736                     };
2737                   }
2738                   @cust_pkg;
2739
2740   return { 'dates' => \@array };
2741
2742 }
2743
2744 sub payment_info_renew_info {
2745   my $p = shift;
2746   my $renew_info   = renew_info($p);
2747   my $payment_info = payment_info($p);
2748   return { %$renew_info,
2749            %$payment_info,
2750          };
2751 }
2752
2753 sub order_renew {
2754   my $p = shift;
2755
2756   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2757   return { 'error' => $session } if $context eq 'error';
2758
2759   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
2760     or return { 'error' => "unknown custnum $custnum" };
2761
2762   my $date = $p->{'date'};
2763
2764   my $now = time;
2765
2766   #freeside-daily -n -d $date fs_daily $custnum
2767   $cust_main->bill_and_collect( 'time'         => $date,
2768                                 'invoice_time' => $now,
2769                                 'actual_time'  => $now,
2770                                 'check_freq'   => '1d',
2771                               );
2772
2773   return { 'error' => '' };
2774
2775 }
2776
2777 sub suspend_pkg {
2778   my $p = shift;
2779   my $session = _cache->get($p->{'session_id'})
2780     or return { 'error' => "Can't resume session" }; #better error message
2781
2782   my $custnum = $session->{'custnum'};
2783
2784   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
2785     or return { 'error' => "unknown custnum $custnum" };
2786
2787   my $conf = new FS::Conf;
2788   my $reasonnum =
2789     $conf->config('selfservice-self_suspend_reason', $cust_main->agentnum)
2790       or return { 'error' => 'Permission denied' };
2791
2792   my $pkgnum = $p->{'pkgnum'};
2793
2794   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
2795                                         'pkgnum'  => $pkgnum,   } )
2796     or return { 'error' => "unknown pkgnum $pkgnum" };
2797
2798   my $error = $cust_pkg->suspend(reason => $reasonnum);
2799   return { 'error' => $error };
2800
2801 }
2802
2803 sub cancel_pkg {
2804   my $p = shift;
2805   my $session = _cache->get($p->{'session_id'})
2806     or return { 'error' => "Can't resume session" }; #better error message
2807
2808   my $custnum = $session->{'custnum'};
2809   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
2810     or return { 'error' => "unknown custnum $custnum" };
2811
2812   my $pkgnum = $p->{'pkgnum'};
2813   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
2814                                         'pkgnum'  => $pkgnum,   } )
2815     or return { 'error' => "unknown pkgnum $pkgnum" };
2816
2817   my $error = $cust_pkg->cancel( 'quiet' => 1,
2818                                  'date'  => $p->{'date'},
2819                                );
2820   return { 'error' => $error };
2821 }
2822
2823 sub provision_phone {
2824   my $p = shift;
2825   my @bulkdid;
2826   @bulkdid = @{$p->{'bulkdid'}} if $p->{'bulkdid'};
2827
2828   #editing an existing phone number
2829   if ( $p->{'svcnum'} && $p->{'svcnum'} =~ /^\d+$/ ) {
2830       my($context, $session, $custnum) = _custoragent_session_custnum($p);
2831       return { 'error' => $session } if $context eq 'error';
2832
2833       my $svc_phone = qsearchs('svc_phone', { svcnum => $p->{'svcnum'} });
2834       return { 'error' => 'service not found' } unless $svc_phone;
2835       return { 'error' => 'invalid svcnum' }
2836         if $svc_phone && $svc_phone->cust_svc->cust_pkg->custnum != $custnum;
2837
2838       $svc_phone->email($p->{'email'})
2839         if $svc_phone->email ne $p->{'email'} && $p->{'email'} =~ /^([\w\.\d@]+|)$/;
2840       $svc_phone->forwarddst($p->{'forwarddst'})
2841         if $svc_phone->forwarddst ne $p->{'forwarddst'}
2842             && $p->{'forwarddst'} =~ /^(\d+|)$/;
2843       return { 'error' => $svc_phone->replace };
2844  }
2845
2846   # single DID LNP
2847   unless ( $p->{'lnp'} ) {
2848     $p->{'lnp_desired_due_date'} = parse_datetime($p->{'lnp_desired_due_date'});
2849     $p->{'lnp_status'} = "portingin";
2850     return _provision( 'FS::svc_phone',
2851                   [qw(lnp_desired_due_date lnp_other_provider
2852                     lnp_other_provider_account phonenum countrycode lnp_status)],
2853                   [qw(phonenum countrycode)],
2854                   $p,
2855                   @_
2856                 );
2857   }
2858
2859   # single DID order (the usual case)
2860   unless (scalar(@bulkdid)) {
2861     return _provision( 'FS::svc_phone',
2862                   [qw(phonenum countrycode)],
2863                   [qw(phonenum countrycode)],
2864                   $p,
2865                   @_
2866                 );
2867   }
2868
2869   # bulk DID order case
2870   my $error;
2871   foreach my $did ( @bulkdid ) {
2872     $did =~ s/[^0-9]//g;
2873     $error = _provision( 'FS::svc_phone',
2874               [qw(phonenum countrycode)],
2875               [qw(phonenum countrycode)],
2876               {
2877                 'pkgnum' => $p->{'pkgnum'},
2878                 'svcpart' => $p->{'svcpart'},
2879                 'phonenum' => $did,
2880                 'countrycode' => $p->{'countrycode'},
2881                 'session_id' => $p->{'session_id'},
2882               }
2883             );
2884     return $error if ($error->{'error'} && length($error->{'error'}) > 1);
2885   }
2886   { 'bulkdid' => [ @bulkdid ], 'svc' => $error->{'svc'} }
2887 }
2888
2889 sub provision_pbx {
2890   my $p = shift;
2891   warn "provision_pbx called\n"
2892     if $DEBUG;
2893
2894   warn "provision_pbx calling _provision\n"
2895     if $DEBUG;
2896   _provision( 'FS::svc_pbx',
2897               [qw(id title max_extensions max_simultaneous ip_addr)],
2898               [qw(id title max_extensions max_simultaneous ip_addr)],
2899               $p,
2900               @_
2901             );
2902 }
2903
2904 sub provision_acct {
2905   my $p = shift;
2906   warn "provision_acct called\n"
2907     if $DEBUG;
2908
2909   return { 'error' => gettext('passwords_dont_match') }
2910     if $p->{'_password'} ne $p->{'_password2'};
2911   return { 'error' => gettext('empty_password') }
2912     unless length($p->{'_password'});
2913
2914   if ($p->{'domsvc'}) {
2915     my %domains = domain_select_hash FS::svc_acct(map { $_ => $p->{$_} }
2916                                                   qw ( svcpart pkgnum ) );
2917     return { 'error' => gettext('invalid_domain') }
2918       unless ($domains{$p->{'domsvc'}});
2919   }
2920
2921   warn "provision_acct calling _provision\n"
2922     if $DEBUG;
2923   _provision( 'FS::svc_acct',
2924               [qw(username _password domsvc)],
2925               [qw(username _password domsvc)],
2926               $p,
2927               @_
2928             );
2929 }
2930
2931 sub provision_external {
2932   my $p = shift;
2933   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
2934   _provision( 'FS::svc_external',
2935               [],
2936               [qw(id title)],
2937               $p,
2938               @_
2939             );
2940 }
2941
2942 sub provision_forward {
2943   my $p = shift;
2944   _provision( 'FS::svc_forward',
2945               ['srcsvc','src','dstsvc','dst'],
2946               [],
2947               $p,
2948             );
2949 }
2950
2951 sub _provision {
2952   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
2953   warn "_provision called for $class\n"
2954     if $DEBUG;
2955
2956   my($context, $session, $custnum) = _custoragent_session_custnum($p);
2957   return { 'error' => $session } if $context eq 'error';
2958
2959   my $search = { 'custnum' => $custnum };
2960   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
2961   my $cust_main = qsearchs('cust_main', $search )
2962     or return { 'error' => "unknown custnum $custnum" };
2963
2964   my $pkgnum = $p->{'pkgnum'};
2965
2966   warn "searching for custnum $custnum pkgnum $pkgnum\n"
2967     if $DEBUG;
2968   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
2969                                         'pkgnum'  => $pkgnum,
2970                                                                } )
2971     or return { 'error' => "unknown pkgnum $pkgnum" };
2972
2973   warn "searching for svcpart ". $p->{'svcpart'}. "\n"
2974     if $DEBUG;
2975   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
2976     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
2977
2978   return { error=> 'svcpart '. $p->{'svcpart'}. " is not a $class definition" }
2979     if $class ne 'FS::'. $part_svc->svcdb;
2980
2981   warn "creating $class record\n"
2982     if $DEBUG;
2983   my $svc_x = $class->new( {
2984     'pkgnum'  => $p->{'pkgnum'},
2985     'svcpart' => $p->{'svcpart'},
2986     map { $_ => $p->{$_} } @$fields
2987   } );
2988
2989   my %insert_args = ();
2990   #i shouldn't be a special case here (pass an option or something)
2991   if ( $class eq 'FS::svc_phone'
2992          && grep length($p->{$_}), @location_editable_fields
2993      )
2994   {
2995     $insert_args{'cust_location'} = new FS::cust_location {
2996       map { $_ => $p->{$_} } @location_editable_fields
2997     };
2998   }
2999
3000   warn "inserting $class record\n"
3001     if $DEBUG;
3002   my $error = $svc_x->insert(%insert_args);
3003
3004   unless ( $error ) {
3005     warn "finding inserted record for svcnum ". $svc_x->svcnum. "\n"
3006       if $DEBUG;
3007     $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
3008   }
3009
3010   my $return = { 'svc'   => $part_svc->svc,
3011                  'error' => $error,
3012                  map { $_ => $svc_x->get($_) } @$return_fields
3013                };
3014   warn "_provision returning ". Dumper($return). "\n"
3015     if $DEBUG;
3016   return $return;
3017
3018 }
3019
3020 sub part_svc_info {
3021   my $p = shift;
3022
3023   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3024   return { 'error' => $session } if $context eq 'error';
3025
3026   my $search = { 'custnum' => $custnum };
3027   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
3028   my $cust_main = qsearchs('cust_main', $search )
3029     or return { 'error' => "unknown custnum $custnum" };
3030
3031   my $pkgnum = $p->{'pkgnum'};
3032
3033   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
3034                                         'pkgnum'  => $pkgnum,
3035                                                                } )
3036     or return { 'error' => "unknown pkgnum $pkgnum" };
3037
3038   my $svcpart = $p->{'svcpart'};
3039
3040   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
3041                                       'svcpart' => $svcpart,           } )
3042     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
3043   my $part_svc = $pkg_svc->part_svc;
3044
3045   my $conf = new FS::Conf;
3046
3047   my $ret = {
3048     'svc'     => $part_svc->svc,
3049     'svcdb'   => $part_svc->svcdb,
3050     'pkgnum'  => $pkgnum,
3051     'svcpart' => $svcpart,
3052     'custnum' => $custnum,
3053
3054     'security_phrase' => 0, #XXX !
3055     'svc_acct_pop'    => [], #XXX !
3056     'popnum'          => '',
3057     'init_popstate'   => '',
3058     'popac'           => '',
3059     'acstate'         => '',
3060
3061     'small_custview' =>
3062       small_custview( $cust_main, $conf->config('countrydefault') ),
3063
3064   };
3065
3066   if ($p->{'svcnum'} && $p->{'svcnum'} =~ /^\d+$/
3067                      && $ret->{'svcdb'} eq 'svc_phone') {
3068         $ret->{'svcnum'} = $p->{'svcnum'};
3069         my $svc_phone = qsearchs('svc_phone', { svcnum => $p->{'svcnum'} });
3070         if ( $svc_phone && $svc_phone->cust_svc->cust_pkg->custnum == $custnum ) {
3071             $ret->{'email'} = $svc_phone->email;
3072             $ret->{'forwarddst'} = $svc_phone->forwarddst;
3073         }
3074   }
3075
3076   if ($ret->{'svcdb'} eq 'svc_forward') {
3077     $ret->{'forward_emails'} = {$cust_pkg->forward_emails()};
3078   }
3079
3080   $ret;
3081 }
3082
3083 sub unprovision_svc {
3084   my $p = shift;
3085
3086   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3087   return { 'error' => $session } if $context eq 'error';
3088
3089   my $search = { 'custnum' => $custnum };
3090   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
3091   my $cust_main = qsearchs('cust_main', $search )
3092     or return { 'error' => "unknown custnum $custnum" };
3093
3094   my $svcnum = $p->{'svcnum'};
3095
3096   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
3097     or return { 'error' => "unknown svcnum $svcnum" };
3098
3099   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
3100     unless $cust_svc->cust_pkg->custnum == $custnum;
3101
3102   my $conf = new FS::Conf;
3103
3104   return { 'svc'   => $cust_svc->part_svc->svc,
3105            'error' => $cust_svc->cancel,
3106            'small_custview' =>
3107              small_custview( $cust_main, $conf->config('countrydefault') ),
3108          };
3109
3110 }
3111
3112 sub myaccount_passwd {
3113   my $p = shift;
3114   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3115   return { 'error' => $session } if $context eq 'error';
3116
3117   return { 'error' => "New passwords don't match." }
3118     if $p->{'new_password'} ne $p->{'new_password2'};
3119
3120   return { 'error' => 'Enter new password' }
3121     unless length($p->{'new_password'});
3122
3123   #my $search = { 'custnum' => $custnum };
3124   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
3125   $custnum =~ /^(\d+)$/ or die "illegal custnum";
3126   my $search = " AND custnum = $1";
3127   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
3128
3129   my $svc_acct = qsearchs( {
3130     'table'     => 'svc_acct',
3131     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
3132                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
3133                    'LEFT JOIN cust_main USING ( custnum ) ',
3134     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
3135     'extra_sql' => $search, #important
3136   } )
3137     or return { 'error' => "Service not found" };
3138
3139   my $error = '';
3140
3141   my $conf = new FS::Conf;
3142
3143   return { 'error' => 'Incorrect current password.' }
3144     if  ( exists($p->{'old_password'})
3145           || $conf->exists('selfservice-password_change_oldpass')
3146         )
3147     && ! $svc_acct->check_password($p->{'old_password'});
3148
3149   $error ||= $svc_acct->is_password_allowed($p->{'new_password'})
3150          ||  $svc_acct->set_password($p->{'new_password'})
3151          ||  $svc_acct->replace();
3152
3153   #regular pw change in self-service should change contact pw too, otherwise its
3154   #way too confusing.  hell its confusing they're separate at all, but alas.
3155   #need to support the "ISP provides email that's used as a contact email" case
3156   #as well as we can.
3157   my $contact = FS::contact->by_selfservice_email($svc_acct->email);
3158   if ( $contact && qsearchs('cust_contact', { contactnum=> $contact->contactnum,
3159                                               custnum   => $custnum,
3160                                               selfservice_access => 'Y',
3161                                             }
3162                            )
3163   ) {
3164     #svc_acct was successful but this one returns an error?  "shouldn't happen"
3165     #don't recheck is_password_allowed here; if the svc_acct password was
3166     #legal, that's good enough
3167     $error ||= $contact->change_password($p->{'new_password'});
3168   }
3169
3170   my($label, $value) = $svc_acct->cust_svc->label;
3171
3172   return { 'error' => $error,
3173            'label' => $label,
3174            'value' => $value,
3175          };
3176
3177 }
3178
3179 sub reset_passwd {
3180   my $p = shift;
3181
3182   my $info = skin_info($p);
3183
3184   my $conf = new FS::Conf;
3185   my $verification = $conf->config('selfservice-password_reset_verification')
3186     or return { %$info, 'error' => 'Password resets disabled' };
3187
3188   my $contact = '';
3189   my $svc_acct = '';
3190   my $cust_main = '';
3191   if ( $p->{'email'} ) { #new-style, changes contact and svc_acct
3192
3193     $contact = FS::contact->by_selfservice_email($p->{'email'});
3194
3195     if ( $contact ) {
3196       my @cust_contact = grep $_->selfservice_access, $contact->cust_contact;
3197       $cust_main = $cust_contact[0]->cust_main if scalar(@cust_contact) == 1;
3198     }
3199
3200     #also look for an svc_acct, otherwise it would be super confusing
3201
3202     my($username, $domain) = split('@', $p->{'email'});
3203     my $svc_domain = qsearchs('svc_domain', { 'domain' => $domain } );
3204     if ( $svc_domain ) {
3205       $svc_acct = qsearchs('svc_acct', { 'username' => $username,
3206                                          'domsvc'   => $svc_domain->svcnum  }
3207                           );
3208       if ( $svc_acct ) {
3209         my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
3210         $cust_main ||= $cust_pkg->cust_main if $cust_pkg;
3211
3212         #precaution: don't change svc_acct password not part of the same
3213         # customer as contact
3214         $svc_acct = '' if ! $cust_pkg
3215                        || $cust_pkg->custnum != $cust_main->custnum;
3216       }
3217
3218     }
3219
3220     return { %$info, 'error' => 'Email address not found' }
3221       unless $contact || $svc_acct;
3222
3223   } elsif ( $p->{'username'} ) { #old style, looks in svc_acct only
3224
3225     my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
3226       or return { %$info, 'error' => 'Account not found' };
3227
3228     $svc_acct = qsearchs('svc_acct', { 'username' => $p->{'username'},
3229                                        'domsvc'   => $svc_domain->svcnum  }
3230                         )
3231       or return { %$info, 'error' => 'Account not found' };
3232
3233     my $cust_pkg = $svc_acct->cust_svc->cust_pkg
3234       or return { %$info, 'error' => 'Account not found' };
3235
3236     $cust_main = $cust_pkg->cust_main;
3237
3238   }
3239
3240   return { %$info, 'error' => 'Multi-customer contacts incompatible with customer-based verification' }
3241     if ! $cust_main && $verification ne 'email';
3242
3243   my %verify = (
3244     'email'   => sub { 1; },
3245     'paymask' => sub {
3246       my( $p, $cust_main ) = @_;
3247       $cust_main->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/
3248         && $p->{'paymask'} eq substr($cust_main->paymask, -4)
3249     },
3250     'amount'  => sub {
3251       my( $p, $cust_main ) = @_;
3252       my $cust_pay = qsearchs({
3253         'table' => 'cust_pay',
3254         'hashref' => { 'custnum' => $cust_main->custnum },
3255         'order_by' => 'ORDER BY _date DESC LIMIT 1',
3256       })
3257         or return 0;
3258
3259       $p->{'amount'} == $cust_pay->paid;
3260     },
3261     'zip'     => sub {
3262       my( $p, $cust_main ) = @_;
3263       $p->{'zip'} eq $cust_main->zip
3264         || ( $cust_main->ship_zip && $p->{'zip'} eq $cust_main->ship_zip );
3265     },
3266   );
3267
3268   foreach my $verify ( split(',', $verification) ) {
3269
3270     &{ $verify{$verify} }( $p, $cust_main )
3271       or return { %$info, 'error' => 'Account not found' };
3272
3273   }
3274
3275   #okay, we're verified
3276
3277   if ( $contact ) {
3278
3279     my $error = $contact->send_reset_email(
3280                             'svcnum' => ($svc_acct ? $svc_acct->svcnum : ''),
3281                           );
3282
3283     if ( $error ) {
3284       return { %$info, 'error' => $error }; #????
3285     }
3286
3287   } elsif ( $svc_acct ) {
3288
3289     #create a unique session
3290
3291     my $reset_session = {
3292       'svcnum'   => $svc_acct->svcnum,
3293       'agentnum' => $svc_acct->cust_main->agentnum,
3294     };
3295
3296     my $timeout = '1 hour'; #?
3297
3298     my $reset_session_id;
3299     do {
3300       $reset_session_id = sha512_hex(time(). {}. rand(). $$)
3301     } until ( ! defined _cache->get("reset_passwd_$reset_session_id") );
3302       #just in case
3303
3304     _cache->set( "reset_passwd_$reset_session_id", $reset_session, $timeout );
3305
3306     #email it
3307
3308     my $msgnum = $conf->config('selfservice-password_reset_msgnum',
3309                                $cust_main->agentnum);
3310     #die "selfservice-password_reset_msgnum unset" unless $msgnum;
3311     return { %$info, 'error' => "selfservice-password_reset_msgnum unset" }
3312       unless $msgnum;
3313     my $msg_template = qsearchs('msg_template', { msgnum => $msgnum } );
3314     my $error = $msg_template->send( 'cust_main'     => $cust_main,
3315                                      'object'        => $svc_acct,
3316                                      'substitutions' => {
3317                                        'session_id' => $reset_session_id,
3318                                      }
3319                                    );
3320     if ( $error ) {
3321       return { %$info, 'error' => $error }; #????
3322     }
3323
3324   }
3325
3326   return { %$info, 'error' => '' };
3327 }
3328
3329 sub check_reset_passwd {
3330   my $p = shift;
3331
3332   my $conf = new FS::Conf;
3333   my $verification = $conf->config('selfservice-password_reset_verification')
3334     or return { 'error' => 'Password resets disabled' };
3335
3336   my $reset_session = _cache->get('reset_passwd_'. $p->{'session_id'})
3337     or return { 'error' => "Can't resume session" }; #better error message
3338
3339   if ( $reset_session->{'svcnum'} ) {
3340
3341     my $svcnum = $reset_session->{'svcnum'};
3342
3343     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $svcnum } )
3344       or return { 'error' => "Service not found" };
3345
3346     $p->{'agentnum'} = $svc_acct->cust_svc->cust_pkg->cust_main->agentnum;
3347     my $info = skin_info($p);
3348
3349     return { %$info,
3350              'error'      => '',
3351              'session_id' => $p->{'session_id'},
3352              'username'   => $svc_acct->username,
3353            };
3354
3355   } elsif ( $reset_session->{'contactnum'} ) {
3356
3357     my $contactnum = $reset_session->{'contactnum'};
3358
3359     my $contact = qsearchs('contact', { 'contactnum' => $contactnum } )
3360       or return { 'error' => "Contact not found" };
3361
3362     my @contact_email = $contact->contact_email;
3363     return { 'error' => 'No contact email' } unless @contact_email;
3364
3365     my @cust_contact = grep $_->selfservice_access, $contact->cust_contact;
3366     $p->{'agentnum'} = $cust_contact[0]->cust_main->agentnum
3367       if scalar(@cust_contact) == 1;
3368     my $info = skin_info($p);
3369
3370     return { %$info,
3371              'error'      => '',
3372              'session_id' => $p->{'session_id'},
3373              'email'      => $contact_email[0]->email, #the first?
3374            };
3375
3376   } else {
3377
3378     return { 'error' => 'No svcnum or contactnum in session' }; #??
3379
3380   }
3381
3382 }
3383
3384 sub process_reset_passwd {
3385   my $p = shift;
3386
3387   my $conf = new FS::Conf;
3388   my $verification = $conf->config('selfservice-password_reset_verification')
3389     or return { 'error' => 'Password resets disabled' };
3390
3391   my $reset_session = _cache->get('reset_passwd_'. $p->{'session_id'})
3392     or return { 'error' => "Can't resume session" }; #better error message
3393
3394   my $info = '';
3395
3396   my $svc_acct = '';
3397   if ( $reset_session->{'svcnum'} ) {
3398
3399     my $svcnum = $reset_session->{'svcnum'};
3400
3401     $svc_acct = qsearchs('svc_acct', { 'svcnum' => $svcnum } )
3402       or return { 'error' => "Service not found" };
3403
3404     $p->{'agentnum'} ||= $svc_acct->cust_svc->cust_pkg->cust_main->agentnum;
3405     $info ||= skin_info($p);
3406
3407   }
3408
3409   my $contact = '';
3410   if ( $reset_session->{'contactnum'} ) {
3411
3412     my $contactnum = $reset_session->{'contactnum'};
3413
3414     $contact = qsearchs('contact', { 'contactnum' => $contactnum } )
3415       or return { 'error' => "Contact not found" };
3416
3417     my @cust_contact = grep $_->selfservice_access, $contact->cust_contact;
3418     $p->{'agentnum'} = $cust_contact[0]->cust_main->agentnum
3419       if scalar(@cust_contact) == 1;
3420     $info ||= skin_info($p);
3421
3422   }
3423
3424   return { %$info, 'error' => "New passwords don't match." }
3425     if $p->{'new_password'} ne $p->{'new_password2'};
3426
3427   return { %$info, 'error' => 'Enter new password' }
3428     unless length($p->{'new_password'});
3429
3430   if ( $svc_acct ) {
3431
3432     my $error ||= $svc_acct->is_password_allowed($p->{'new_password'})
3433               ||  $svc_acct->set_password($p->{'new_password'})
3434               ||  $svc_acct->replace();
3435
3436     return { %$info, 'error' => $error } if $error;
3437
3438     #my($label, $value) = $svc_acct->cust_svc->label;
3439     #return { 'error' => $error,
3440     #         #'label' => $label,
3441     #         #'value' => $value,
3442     #       };
3443
3444   }
3445
3446   if ( $contact ) {
3447
3448     my $error = $contact->is_password_allowed($p->{'new_password'})
3449             ||  $contact->change_password($p->{'new_password'});
3450
3451     return { %$info, 'error' => $error }; # if $error;
3452
3453   }
3454
3455   #password changed ,so remove session, don't want it reused
3456   _cache->remove($p->{'session_id'});
3457
3458   return { %$info, 'error' => '' };
3459
3460 }
3461
3462 sub validate_passwd {
3463   my $p = shift;
3464
3465   my %result;
3466   %result = ( 'fieldid' => $p->{'fieldid'} )
3467     if $p->{'fieldid'} =~ /^\w+$/;
3468
3469   return { %result, 'password_invalid' => 'Enter new password' }
3470     unless length($p->{'check_password'});
3471
3472   my $svc_acct;
3473   if ($p->{'svcnum'}) {
3474     # false laziness with myaccount_passwd
3475     my($context, $session, $custnum) = _custoragent_session_custnum($p);
3476     return { %result, 'error' => $session } if $context eq 'error';
3477
3478     $custnum =~ /^(\d+)$/ or die "illegal custnum";
3479     my $search = " AND custnum = $1";
3480     $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
3481
3482     $svc_acct = qsearchs( {
3483       'table'     => 'svc_acct',
3484       'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
3485                      'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
3486                      'LEFT JOIN cust_main USING ( custnum ) ',
3487       'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
3488       'extra_sql' => $search, #important
3489     } )
3490       or return { %result, 'error' => "Service not found" };
3491     # end false laziness
3492   }
3493
3494   $svc_acct ||= new FS::svc_acct {};
3495
3496   my $error = $svc_acct->is_password_allowed($p->{'check_password'});
3497   return { %result, 'password_invalid' => $error } if $error;
3498   return { %result, 'password_valid' => 1 };
3499 }
3500
3501 sub list_tickets {
3502   my $p = shift;
3503   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3504   return { 'error' => $session } if $context eq 'error';
3505
3506   my @tickets = ();
3507   if ( $session->{'pkgnum'} ) {
3508
3509     #tickets for specific service with pkg-balances on
3510     my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
3511                                           'pkgnum'  => $session->{'pkgnum'} })
3512                      or return { 'error' => 'unknown package' };
3513     foreach my $cust_svc ( $cust_pkg->cust_svc ) {
3514       push @tickets, $cust_svc->tickets( $p->{status} );
3515     }
3516
3517   } else {
3518
3519     my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
3520       or return { 'error' => "unknown custnum $custnum" };
3521
3522     @tickets = $cust_main->tickets( $p->{status} );
3523   }
3524
3525   # unavoidable false laziness w/ httemplate/view/cust_main/tickets.html
3526   if ( $FS::TicketSystem::system && FS::TicketSystem->selfservice_priority ) {
3527     my $conf = new FS::Conf;
3528     my $dir = $conf->exists('ticket_system-priority_reverse') ? -1 : 1;
3529     +{ tickets => [
3530          sort {
3531            (
3532              ($a->{'_selfservice_priority'} eq '') <=>
3533              ($b->{'_selfservice_priority'} eq '')
3534            ) ||
3535            ( $dir *
3536              ($b->{'_selfservice_priority'} <=> $a->{'_selfservice_priority'})
3537            )
3538          } @tickets
3539        ]
3540     };
3541   } else {
3542     +{ tickets => \@tickets };
3543   }
3544
3545 }
3546
3547 sub create_ticket {
3548   my $p = shift;
3549   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3550   return { 'error' => $session } if $context eq 'error';
3551
3552   warn "$me create_ticket: initializing ticket system\n" if $DEBUG;
3553   FS::TicketSystem->init();
3554
3555   my $conf = new FS::Conf;
3556   my $queue = $p->{'queue'}
3557               || $conf->config('ticket_system-selfservice_queueid')
3558               || $conf->config('ticket_system-default_queueid');
3559
3560   warn "$me create_ticket: creating ticket\n" if $DEBUG;
3561   my $err_or_ticket = FS::TicketSystem->create_ticket(
3562     '', #create RT session based on FS CurrentUser (fs_selfservice)
3563     'queue'   => $queue,
3564     'custnum' => $custnum,
3565     'svcnum'  => $session->{'svcnum'},
3566     map { $_ => $p->{$_} } qw( requestor cc subject message mime_type )
3567   );
3568
3569   if ( ref($err_or_ticket) ) {
3570     warn "$me create_ticket: successful: ". $err_or_ticket->id. "\n"
3571       if $DEBUG;
3572     return { 'error'     => '',
3573              'ticket_id' => $err_or_ticket->id,
3574            };
3575   } else {
3576     warn "$me create_ticket: unsuccessful: $err_or_ticket\n"
3577       if $DEBUG;
3578     return { 'error' => $err_or_ticket };
3579   }
3580
3581
3582 }
3583
3584 sub did_report {
3585   my $p = shift;
3586   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3587   return { 'error' => $session } if $context eq 'error';
3588
3589   return { error => 'requested format not implemented' }
3590     unless ($p->{'format'} eq 'csv' || $p->{'format'} eq 'xls');
3591
3592   my $conf = new FS::Conf;
3593   my $age_threshold = 0;
3594   $age_threshold = time() - $conf->config('selfservice-recent-did-age')
3595     if ($p->{'recentonly'} && $conf->exists('selfservice-recent-did-age'));
3596
3597   my $search = { 'custnum' => $custnum };
3598   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
3599   my $cust_main = qsearchs('cust_main', $search )
3600     or return { 'error' => "unknown custnum $custnum" };
3601
3602 # does it make more sense to just run one sql query for this instead of all the
3603 # insanity below? would increase performance greately for large data sets?
3604   my @svc_phone = ();
3605   foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
3606         my @part_svc = $cust_pkg->part_svc;
3607         foreach my $part_svc ( @part_svc ) {
3608             if($part_svc->svcdb eq 'svc_phone'){
3609                 my @cust_pkg_svc = @{$part_svc->cust_pkg_svc};
3610                 foreach my $cust_pkg_svc ( @cust_pkg_svc ) {
3611                     push @svc_phone, $cust_pkg_svc->svc_x
3612                         if $cust_pkg_svc->date_inserted >= $age_threshold;
3613                 }
3614             }
3615         }
3616   }
3617
3618   my $csv;
3619   my $xls;
3620   my($xls_r,$xls_c) = (0,0);
3621   my $xls_workbook;
3622   my $content = '';
3623   my @fields = qw( countrycode phonenum pin sip_password phone_name );
3624   if($p->{'format'} eq 'csv') {
3625     $csv = new Text::CSV_XS { 'always_quote' => 1,
3626                                  'eol'          => "\n",
3627                                 };
3628     return { 'error' => 'Unable to create CSV' } unless $csv->combine(@fields);
3629     $content .= $csv->string;
3630   }
3631   elsif($p->{'format'} eq 'xls') {
3632     my $XLS1 = new IO::Scalar \$content;
3633     $xls_workbook = Spreadsheet::WriteExcel->new($XLS1)
3634         or return { 'error' => "Error opening .xls file: $!" };
3635     $xls = $xls_workbook->add_worksheet('DIDs');
3636     foreach ( @fields ) {
3637         $xls->write(0,$xls_c++,$_);
3638     }
3639     $xls_r++;
3640   }
3641
3642   foreach my $svc_phone ( @svc_phone ) {
3643     my @cols = map { $svc_phone->$_ } @fields;
3644     if($p->{'format'} eq 'csv') {
3645         return { 'error' => 'Unable to create CSV' }
3646             unless $csv->combine(@cols);
3647         $content .= $csv->string;
3648     }
3649     elsif($p->{'format'} eq 'xls') {
3650         $xls_c = 0;
3651         foreach ( @cols ) {
3652             $xls->write($xls_r,$xls_c++,$_);
3653         }
3654         $xls_r++;
3655     }
3656   }
3657
3658   $xls_workbook->close() if $p->{'format'} eq 'xls';
3659
3660   { content => $content, format => $p->{'format'}, };
3661 }
3662
3663 sub get_ticket {
3664   my $p = shift;
3665   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3666   return { 'error' => $session } if $context eq 'error';
3667
3668 #  warn "$me get_ticket: initializing ticket system\n" if $DEBUG;
3669 #  FS::TicketSystem->init();
3670 #  return { 'error' => 'get_ticket configuration error' }
3671 #    if $FS::TicketSystem::system ne 'RT_Internal';
3672
3673   # check existence and ownership as part of this
3674   warn "$me get_ticket: fetching ticket\n" if $DEBUG;
3675   my $rt_session = FS::TicketSystem->session('');
3676   my $Ticket = FS::TicketSystem->get_ticket_object(
3677     $rt_session,
3678     ticket_id => $p->{'ticket_id'},
3679     custnum => $custnum
3680   );
3681   return { 'error' => 'ticket not found' } if !$Ticket;
3682
3683   if ( length( $p->{'subject'} || '' ) ) {
3684     # subject change
3685     if ( $p->{'subject'} ne $Ticket->Subject ) {
3686       my ($val, $msg) = $Ticket->SetSubject($p->{'subject'});
3687       return { 'error' => "unable to set subject: $msg" } if !$val;
3688     }
3689   }
3690
3691   if(length($p->{'reply'})) {
3692     my @err_or_res = FS::TicketSystem->correspond_ticket(
3693       $rt_session,
3694       'ticket_id' => $p->{'ticket_id'},
3695       'content' => $p->{'reply'},
3696     );
3697
3698     return { 'error' => 'unable to reply to ticket' }
3699     unless ( $err_or_res[0] != 0 && defined $err_or_res[2] );
3700   }
3701
3702   warn "$me get_ticket: getting ticket history\n" if $DEBUG;
3703   my $err_or_ticket = FS::TicketSystem->get_ticket(
3704     $rt_session,
3705     'ticket_id' => $p->{'ticket_id'},
3706   );
3707
3708   if ( !ref($err_or_ticket) ) { # there is no way this should ever happen
3709     warn "$me get_ticket: unsuccessful: $err_or_ticket\n"
3710       if $DEBUG;
3711     return { 'error' => $err_or_ticket };
3712   }
3713
3714   my @custs = @{$err_or_ticket->{'custs'}};
3715   my @txns = @{$err_or_ticket->{'txns'}};
3716   my @filtered_txns;
3717
3718   # superseded by check in get_ticket_object
3719   #return { 'error' => 'invalid ticket requested' }
3720   #unless grep($_ eq $custnum, @custs);
3721
3722   foreach my $txn ( @txns ) {
3723     push @filtered_txns, $txn
3724     if ($txn->{'type'} eq 'EmailRecord'
3725       || $txn->{'type'} eq 'Correspond'
3726       || $txn->{'type'} eq 'Create');
3727   }
3728
3729   warn "$me get_ticket: successful: \n"
3730   if $DEBUG;
3731   return { 'error'     => '',
3732     'transactions' => \@filtered_txns,
3733     'ticket_fields' => $err_or_ticket->{'fields'},
3734     'ticket_id' => $p->{'ticket_id'},
3735   };
3736 }
3737
3738 sub adjust_ticket_priority {
3739   my $p = shift;
3740   my($context, $session, $custnum) = _custoragent_session_custnum($p);
3741   return { 'error' => $session } if $context eq 'error';
3742
3743 #  warn "$me adjust_ticket_priority: initializing ticket system\n" if $DEBUG;
3744 #  FS::TicketSystem->init;
3745   my $ss_priority = FS::TicketSystem->selfservice_priority;
3746
3747   return { 'error' => 'adjust_ticket_priority configuration error' }
3748     if $FS::TicketSystem::system ne 'RT_Internal'
3749       or !$ss_priority;
3750
3751   my $values = $p->{'values'}; #hashref, id => priority value
3752   my %ticket_error;
3753
3754   foreach my $id (keys %$values) {
3755     warn "$me adjust_ticket_priority: fetching ticket $id\n" if $DEBUG;
3756     my $Ticket = FS::TicketSystem->get_ticket_object('',
3757       'ticket_id' => $id,
3758       'custnum'   => $custnum,
3759     );
3760     if ( !$Ticket ) {
3761       $ticket_error{$id} = 'ticket not found';
3762       next;
3763     }
3764
3765   # RT API stuff--would we gain anything by wrapping this in FS::TicketSystem?
3766   # We're not going to implement it for RT_External.
3767     my $old_value = $Ticket->FirstCustomFieldValue($ss_priority);
3768     my $new_value = $values->{$id};
3769     next if $old_value eq $new_value;
3770
3771     warn "$me adjust_ticket_priority: updating ticket $id\n" if $DEBUG;
3772
3773     # AddCustomFieldValue works fine (replacing any existing value) if it's
3774     # a single-valued custom field, which it should be.  If it's not, you're
3775     # doing something wrong.
3776     my ($val, $msg);
3777     if ( length($new_value) ) {
3778       ($val, $msg) = $Ticket->AddCustomFieldValue(
3779         Field => $ss_priority,
3780         Value => $new_value,
3781       );
3782     }
3783     else {
3784       ($val, $msg) = $Ticket->DeleteCustomFieldValue(
3785         Field => $ss_priority,
3786         Value => $old_value,
3787       );
3788     }
3789
3790     $ticket_error{$id} = $msg if !$val;
3791     warn "$me adjust_ticket_priority: $id: $msg\n" if $DEBUG and !$val;
3792   }
3793   return { 'error' => '',
3794            'ticket_error' => \%ticket_error,
3795            %{ customer_info($p) } # send updated customer info back
3796          }
3797 }
3798
3799 #--
3800
3801 sub _custoragent_session_custnum {
3802   my $p = shift;
3803
3804   my($context, $session, $custnum);
3805   if ( $p->{'session_id'} ) {
3806
3807     $context = 'customer';
3808     $session = _cache->get($p->{'session_id'})
3809       or return ( 'error' => "Can't resume session" ); #better error message
3810     $custnum = $session->{'custnum'};
3811
3812   } elsif ( $p->{'agent_session_id'} ) {
3813
3814     $context = 'agent';
3815     my $agent_cache = new FS::ClientAPI_SessionCache( {
3816       'namespace' => 'FS::ClientAPI::Agent',
3817     } );
3818     $session = $agent_cache->get($p->{'agent_session_id'})
3819       or return ( 'error' => "Can't resume session" ); #better error message
3820     $custnum = $p->{'custnum'};
3821
3822   } else {
3823     $context = 'error';
3824     return ( 'error' => "Can't resume session" ); #better error message
3825   }
3826
3827   ($context, $session, $custnum);
3828
3829 }
3830
3831 1;
3832