FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw( $cache $DEBUG );
   5 use subs qw( _cache _provision );
   6 use Data::Dumper;
   7 use Digest::MD5 qw(md5_hex);
   8 use Date::Format;
   9 use Business::CreditCard;
  10 use Time::Duration;
  11 use FS::UI::Web::small_custview qw(small_custview); #less doh
  12 use FS::UI::Web;
  13 use FS::UI::bytecount;
  14 use FS::Conf;
  15 use FS::Record qw(qsearch qsearchs);
  16 use FS::Msgcat qw(gettext);
  17 use FS::Misc qw(card_types);
  18 use FS::ClientAPI_SessionCache;
  19 use FS::svc_acct;
  20 use FS::svc_domain;
  21 use FS::svc_phone;
  22 use FS::svc_external;
  23 use FS::part_svc;
  24 use FS::cust_main;
  25 use FS::cust_bill;
  26 use FS::cust_main_county;
  27 use FS::cust_pkg;
  28 use FS::payby;
  29 use FS::acct_rt_transaction;
  30 use HTML::Entities;
  31
  32 $DEBUG = 0;
  33
  34 #false laziness with FS::cust_main
  35 BEGIN {
  36   eval "use Time::Local;";
  37   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  38     if $] < 5.006 && !defined($Time::Local::VERSION);
  39   eval "use Time::Local qw(timelocal_nocheck);";
  40 }
  41
  42 use vars qw( @cust_main_editable_fields );
  43 @cust_main_editable_fields = qw(
  44   first last company address1 address2 city
  45     county state zip country daytime night fax
  46   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  47     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  48   payby payinfo payname paystart_month paystart_year payissue payip
  49   ss paytype paystate stateid stateid_state
  50 );
  51
  52 sub _cache {
  53   $cache ||= new FS::ClientAPI_SessionCache( {
  54                'namespace' => 'FS::ClientAPI::MyAccount',
  55              } );
  56 }
  57
  58 sub login_info {
  59   my $p = shift;
  60
  61   my $conf = new FS::Conf;
  62
  63   my %info = (
  64     'phone_login'  => $conf->exists('selfservice_server-phone_login'),
  65     'single_domain'=> scalar($conf->config('selfservice_server-single_domain')),
  66   );
  67
  68   return \%info;
  69
  70 }
  71
  72 #false laziness w/FS::ClientAPI::passwd::passwd
  73 sub login {
  74   my $p = shift;
  75
  76   my $conf = new FS::Conf;
  77
  78   my $svc_x = '';
  79   if ( $p->{'domain'} eq 'svc_phone'
  80        && $conf->exists('selfservice_server-phone_login') ) {
  81
  82     my $svc_phone = qsearchs( 'svc_phone', { 'phonenum' => $p->{'username'} } );
  83     return { error => 'Number not found.' } unless $svc_phone;
  84
  85     #XXX?
  86     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  87     #return { error => 'Only primary user may log in.' }
  88     #  if $conf->exists('selfservice_server-primary_only')
  89     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  90
  91     return { error => 'Incorrect PIN.' }
  92       unless $svc_phone->check_pin($p->{'password'});
  93
  94     $svc_x = $svc_phone;
  95
  96   } else {
  97
  98     my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  99       or return { error => 'Domain '. $p->{'domain'}. ' not found' };
 100
 101     my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
 102                                            'domsvc'    => $svc_domain->svcnum, }
 103                            );
 104     return { error => 'User not found.' } unless $svc_acct;
 105
 106     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 107     #return { error => 'Only primary user may log in.' }
 108     #  if $conf->exists('selfservice_server-primary_only')
 109     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 110     my $cust_svc = $svc_acct->cust_svc;
 111     my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 112     return { error => 'Only primary user may log in.' }
 113       if $conf->exists('selfservice_server-primary_only')
 114          && $cust_svc->svcpart != $part_pkg->svcpart('svc_acct');
 115
 116     return { error => 'Incorrect password.' }
 117       unless $svc_acct->check_password($p->{'password'});
 118
 119     $svc_x = $svc_acct;
 120
 121   }
 122
 123   my $session = {
 124     'svcnum' => $svc_x->svcnum,
 125   };
 126
 127   my $cust_pkg = $svc_x->cust_svc->cust_pkg;
 128   if ( $cust_pkg ) {
 129     my $cust_main = $cust_pkg->cust_main;
 130     $session->{'custnum'} = $cust_main->custnum;
 131   }
 132
 133   my $session_id;
 134   do {
 135     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
 136   } until ( ! defined _cache->get($session_id) ); #just in case
 137
 138   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 139   _cache->set( $session_id, $session, $timeout );
 140
 141   return { 'error'      => '',
 142            'session_id' => $session_id,
 143          };
 144 }
 145
 146 sub logout {
 147   my $p = shift;
 148   if ( $p->{'session_id'} ) {
 149     _cache->remove($p->{'session_id'});
 150     return { 'error' => '' };
 151   } else {
 152     return { 'error' => "Can't resume session" }; #better error message
 153   }
 154 }
 155
 156 sub customer_info {
 157   my $p = shift;
 158
 159   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 160   return { 'error' => $session } if $context eq 'error';
 161
 162   my %return;
 163
 164   my $conf = new FS::Conf;
 165   if ($conf->exists('cust_main-require_address2')) {
 166     $return{'require_address2'} = '1';
 167   }else{
 168     $return{'require_address2'} = '';
 169   }
 170
 171   if ( $custnum ) { #customer record
 172
 173     my $search = { 'custnum' => $custnum };
 174     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 175     my $cust_main = qsearchs('cust_main', $search )
 176       or return { 'error' => "unknown custnum $custnum" };
 177
 178     $return{balance} = $cust_main->balance;
 179
 180     $return{tickets} = [ ($cust_main->tickets) ];
 181
 182     my @open = map {
 183                      {
 184                        invnum => $_->invnum,
 185                        date   => time2str("%b %o, %Y", $_->_date),
 186                        owed   => $_->owed,
 187                      };
 188                    } $cust_main->open_cust_bill;
 189     $return{open_invoices} = \@open;
 190
 191     $return{small_custview} =
 192       small_custview( $cust_main, $conf->config('countrydefault') );
 193
 194     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 195
 196     for (@cust_main_editable_fields) {
 197       $return{$_} = $cust_main->get($_);
 198     }
 199
 200     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 201       $return{payinfo} = $cust_main->paymask;
 202       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 203     }
 204
 205     $return{'invoicing_list'} =
 206       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 207     $return{'postal_invoicing'} =
 208       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 209
 210     if (scalar($conf->config('support_packages'))) {
 211       my @support_services = ();
 212       foreach ($cust_main->support_services) {
 213         my $seconds = $_->svc_x->seconds;
 214         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 215                              int(abs($seconds)/3600)."h".
 216                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 217         my $cust_pkg = $_->cust_pkg;
 218         my $pkgnum = '';
 219         my $pkg = '';
 220         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 221         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 222         push @support_services, { svcnum => $_->svcnum,
 223                                   time => $time_remaining,
 224                                   pkgnum => $pkgnum,
 225                                   pkg => $pkg,
 226                                 };
 227       }
 228       $return{support_services} = \@support_services;
 229     }
 230
 231   } elsif ( $session->{'svcnum'} ) { #no customer record
 232
 233     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 234       or die "unknown svcnum";
 235     $return{name} = $svc_acct->email;
 236
 237   } else {
 238
 239     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 240
 241   }
 242
 243   return { 'error'          => '',
 244            'custnum'        => $custnum,
 245            %return,
 246          };
 247
 248 }
 249
 250 sub edit_info {
 251   my $p = shift;
 252   my $session = _cache->get($p->{'session_id'})
 253     or return { 'error' => "Can't resume session" }; #better error message
 254
 255   my $custnum = $session->{'custnum'}
 256     or return { 'error' => "no customer record" };
 257
 258   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 259     or return { 'error' => "unknown custnum $custnum" };
 260
 261   my $new = new FS::cust_main { $cust_main->hash };
 262   $new->set( $_ => $p->{$_} )
 263     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 264
 265   my $payby = '';
 266   if (exists($p->{'payby'})) {
 267     $p->{'payby'} =~ /^([A-Z]{4})$/
 268       or return { 'error' => "illegal_payby " . $p->{'payby'} };
 269     $payby = $1;
 270   }
 271
 272   if ( $payby =~ /^(CARD|DCRD)$/ ) {
 273
 274     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 275
 276     if ( $new->payinfo eq $cust_main->paymask ) {
 277       $new->payinfo($cust_main->payinfo);
 278     } else {
 279       $new->payinfo($p->{'payinfo'});
 280     }
 281
 282     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 283
 284   }elsif ( $payby =~ /^(CHEK|DCHK)$/ ) {
 285     my $payinfo;
 286     $p->{'payinfo1'} =~ /^([\dx]+)$/
 287       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 288     my $payinfo1 = $1;
 289      $p->{'payinfo2'} =~ /^([\dx]+)$/
 290       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 291     my $payinfo2 = $1;
 292     $payinfo = $payinfo1. '@'. $payinfo2;
 293
 294     if ( $payinfo eq $cust_main->paymask ) {
 295       $new->payinfo($cust_main->payinfo);
 296     } else {
 297       $new->payinfo($payinfo);
 298     }
 299
 300     $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 301
 302   }elsif ( $payby =~ /^(BILL)$/ ) {
 303   } elsif ( $payby ) {  #notyet ready
 304     return { 'error' => "unknown payby $payby" };
 305   }
 306
 307   my @invoicing_list;
 308   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 309     #false laziness with httemplate/edit/process/cust_main.cgi
 310     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 311     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 312   } else {
 313     @invoicing_list = $cust_main->invoicing_list;
 314   }
 315
 316   my $error = $new->replace($cust_main, \@invoicing_list);
 317   return { 'error' => $error } if $error;
 318   #$cust_main = $new;
 319
 320   return { 'error' => '' };
 321 }
 322
 323 sub payment_info {
 324   my $p = shift;
 325   my $session = _cache->get($p->{'session_id'})
 326     or return { 'error' => "Can't resume session" }; #better error message
 327
 328   ##
 329   #generic
 330   ##
 331
 332   use vars qw($payment_info); #cache for performance
 333   unless ( $payment_info ) {
 334
 335     my $conf = new FS::Conf;
 336     my %states = map { $_->state => 1 }
 337                    qsearch('cust_main_county', {
 338                      'country' => $conf->config('countrydefault') || 'US'
 339                    } );
 340
 341     $payment_info = {
 342
 343       #list all counties/states/countries
 344       'cust_main_county' =>
 345         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 346
 347       #shortcut for one-country folks
 348       'states' =>
 349         [ sort { $a cmp $b } keys %states ],
 350
 351       'card_types' => card_types(),
 352
 353       'paytypes' => [ @FS::cust_main::paytypes ],
 354
 355       'paybys' => [ $conf->config('signup_server-payby') ],
 356
 357       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 358       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 359
 360       'show_ss'  => $conf->exists('show_ss'),
 361       'show_stateid' => $conf->exists('show_stateid'),
 362       'show_paystate' => $conf->exists('show_bankstate'),
 363     };
 364
 365   }
 366
 367   ##
 368   #customer-specific
 369   ##
 370
 371   my %return = %$payment_info;
 372
 373   my $custnum = $session->{'custnum'};
 374
 375   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 376     or return { 'error' => "unknown custnum $custnum" };
 377
 378   $return{balance} = $cust_main->balance;
 379
 380   $return{payname} = $cust_main->payname
 381                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 382
 383   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 384
 385   $return{payby} = $cust_main->payby;
 386   $return{stateid_state} = $cust_main->stateid_state;
 387
 388   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 389     $return{card_type} = cardtype($cust_main->payinfo);
 390     $return{payinfo} = $cust_main->paymask;
 391
 392     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 393
 394   }
 395
 396   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 397     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 398     $return{payinfo1} = $payinfo1;
 399     $return{payinfo2} = $payinfo2;
 400     $return{paytype}  = $cust_main->paytype;
 401     $return{paystate} = $cust_main->paystate;
 402
 403   }
 404
 405   #doubleclick protection
 406   my $_date = time;
 407   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 408
 409   return { 'error' => '',
 410            %return,
 411          };
 412
 413 };
 414
 415 #some false laziness with httemplate/process/payment.cgi - look there for
 416 #ACH and CVV support stuff
 417 sub process_payment {
 418
 419   my $p = shift;
 420
 421   my $session = _cache->get($p->{'session_id'})
 422     or return { 'error' => "Can't resume session" }; #better error message
 423
 424   my %return;
 425
 426   my $custnum = $session->{'custnum'};
 427
 428   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 429     or return { 'error' => "unknown custnum $custnum" };
 430
 431   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 432     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 433   my $payname = $1;
 434
 435   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 436     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 437   my $paybatch = $1;
 438
 439   $p->{'payby'} =~ /^([A-Z]{4})$/
 440     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 441   my $payby = $1;
 442
 443   #false laziness w/process/payment.cgi
 444   my $payinfo;
 445   my $paycvv = '';
 446   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 447
 448     $p->{'payinfo1'} =~ /^([\dx]+)$/
 449       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 450     my $payinfo1 = $1;
 451      $p->{'payinfo2'} =~ /^([\dx]+)$/
 452       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 453     my $payinfo2 = $1;
 454     $payinfo = $payinfo1. '@'. $payinfo2;
 455
 456     $payinfo = $cust_main->payinfo
 457       if $cust_main->paymask eq $payinfo;
 458
 459   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 460
 461     $payinfo = $p->{'payinfo'};
 462
 463     $payinfo = $cust_main->payinfo
 464       if $cust_main->paymask eq $payinfo;
 465
 466     $payinfo =~ s/\D//g;
 467     $payinfo =~ /^(\d{13,16})$/
 468       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 469     $payinfo = $1;
 470
 471     validate($payinfo)
 472       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 473     return { 'error' => gettext('unknown_card_type') }
 474       if cardtype($payinfo) eq "Unknown";
 475
 476     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 477       if ( cardtype($payinfo) eq 'American Express card' ) {
 478         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 479           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 480         $paycvv = $1;
 481       } else {
 482         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 483           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 484         $paycvv = $1;
 485       }
 486     }
 487
 488   } else {
 489     die "unknown payby $payby";
 490   }
 491
 492   my %payby2fields = (
 493     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 494     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 495   );
 496
 497   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 498     'quiet'    => 1,
 499     'payinfo'  => $payinfo,
 500     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 501     'payname'  => $payname,
 502     'paybatch' => $paybatch,
 503     'paycvv'   => $paycvv,
 504     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 505   );
 506   return { 'error' => $error } if $error;
 507
 508   $cust_main->apply_payments;
 509
 510   if ( $p->{'save'} ) {
 511     my $new = new FS::cust_main { $cust_main->hash };
 512     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 513       $new->set( $_ => $p->{$_} )
 514         foreach qw( payname paystart_month paystart_year payissue payip
 515                     address1 address2 city state zip payinfo );
 516       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 517     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 518       $new->set( $_ => $p->{$_} )
 519         foreach qw( payname payip paytype paystate
 520                     stateid stateid_state );
 521       $new->set( 'payinfo' => $payinfo );
 522       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 523     }
 524     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 525     my $error = $new->replace($cust_main);
 526     return { 'error' => $error } if $error;
 527     $cust_main = $new;
 528   }
 529
 530   return { 'error' => '' };
 531
 532 }
 533
 534 sub process_payment_order_pkg {
 535   my $p = shift;
 536
 537   my $hr = process_payment($p);
 538   return $hr if $hr->{'error'};
 539
 540   order_pkg($p);
 541 }
 542
 543 sub process_prepay {
 544
 545   my $p = shift;
 546
 547   my $session = _cache->get($p->{'session_id'})
 548     or return { 'error' => "Can't resume session" }; #better error message
 549
 550   my %return;
 551
 552   my $custnum = $session->{'custnum'};
 553
 554   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 555     or return { 'error' => "unknown custnum $custnum" };
 556
 557   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 558   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 559                                            \$amount,
 560                                            \$seconds,
 561                                            \$upbytes,
 562                                            \$downbytes,
 563                                            \$totalbytes,
 564                                          );
 565
 566   return { 'error' => $error } if $error;
 567
 568   return { 'error'     => '',
 569            'amount'    => $amount,
 570            'seconds'   => $seconds,
 571            'duration'  => duration_exact($seconds),
 572            'upbytes'   => $upbytes,
 573            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 574            'downbytes' => $downbytes,
 575            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 576            'totalbytes'=> $totalbytes,
 577            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 578          };
 579
 580 }
 581
 582 sub invoice {
 583   my $p = shift;
 584   my $session = _cache->get($p->{'session_id'})
 585     or return { 'error' => "Can't resume session" }; #better error message
 586
 587   my $custnum = $session->{'custnum'};
 588
 589   my $invnum = $p->{'invnum'};
 590
 591   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 592                                           'custnum' => $custnum } )
 593     or return { 'error' => "Can't find invnum" };
 594
 595   #my %return;
 596
 597   return { 'error'        => '',
 598            'invnum'       => $invnum,
 599            'invoice_text' => join('', $cust_bill->print_text ),
 600            'invoice_html' => $cust_bill->print_html( { unsquelch_cdr => 1 } ),
 601          };
 602
 603 }
 604
 605 sub invoice_logo {
 606   my $p = shift;
 607
 608   #sessioning for this?  how do we get the session id to the backend invoice
 609   # template so it can add it to the link, blah
 610
 611   my $templatename = $p->{'templatename'};
 612
 613   #false laziness-ish w/view/cust_bill-logo.cgi
 614
 615   my $conf = new FS::Conf;
 616   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 617     $templatename = "_$1";
 618   } else {
 619     $templatename = '';
 620   }
 621
 622   my $filename = "logo$templatename.png";
 623
 624   return { 'error'        => '',
 625            'logo'         => $conf->config_binary($filename),
 626            'content_type' => 'image/png', #should allow gif, jpg too
 627          };
 628 }
 629
 630
 631 sub list_invoices {
 632   my $p = shift;
 633   my $session = _cache->get($p->{'session_id'})
 634     or return { 'error' => "Can't resume session" }; #better error message
 635
 636   my $custnum = $session->{'custnum'};
 637
 638   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 639     or return { 'error' => "unknown custnum $custnum" };
 640
 641   my @cust_bill = $cust_main->cust_bill;
 642
 643   return  { 'error'       => '',
 644             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 645                                         '_date'  => $_->_date,
 646                                       }
 647                                     } @cust_bill
 648                               ]
 649           };
 650 }
 651
 652 sub cancel {
 653   my $p = shift;
 654   my $session = _cache->get($p->{'session_id'})
 655     or return { 'error' => "Can't resume session" }; #better error message
 656
 657   my $custnum = $session->{'custnum'};
 658
 659   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 660     or return { 'error' => "unknown custnum $custnum" };
 661
 662   my @errors = $cust_main->cancel( 'quiet'=>1 );
 663
 664   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 665
 666   return { 'error' => $error };
 667
 668 }
 669
 670 sub list_pkgs {
 671   my $p = shift;
 672
 673   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 674   return { 'error' => $session } if $context eq 'error';
 675
 676   my $search = { 'custnum' => $custnum };
 677   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 678   my $cust_main = qsearchs('cust_main', $search )
 679     or return { 'error' => "unknown custnum $custnum" };
 680
 681   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 682
 683   my $conf = new FS::Conf;
 684
 685   { 'svcnum'   => $session->{'svcnum'},
 686     'custnum'  => $custnum,
 687     'cust_pkg' => [ map {
 688                           { $_->hash,
 689                             $_->part_pkg->hash,
 690                             part_svc =>
 691                               [ map $_->hashref, $_->available_part_svc ],
 692                             cust_svc =>
 693                               [ map { my $ref = { $_->hash,
 694                                                   label => [ $_->label ],
 695                                                 };
 696                                       $ref->{_password} = $_->svc_x->_password
 697                                         if $context eq 'agent'
 698                                         && $conf->exists('agent-showpasswords')
 699                                         && $_->part_svc->svcdb eq 'svc_acct';
 700                                       $ref;
 701                                     } $_->cust_svc
 702                               ],
 703                           };
 704                         } $cust_main->ncancelled_pkgs
 705                   ],
 706     'small_custview' =>
 707       small_custview( $cust_main, $conf->config('countrydefault') ),
 708   };
 709
 710 }
 711
 712 sub list_svcs {
 713   my $p = shift;
 714
 715   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 716   return { 'error' => $session } if $context eq 'error';
 717
 718   my $search = { 'custnum' => $custnum };
 719   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 720   my $cust_main = qsearchs('cust_main', $search )
 721     or return { 'error' => "unknown custnum $custnum" };
 722
 723   my @cust_svc = ();
 724   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 725   foreach my $cust_pkg ( $p->{'ncancelled'}
 726                          ? $cust_main->ncancelled_pkgs
 727                          : $cust_main->unsuspended_pkgs ) {
 728     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 729   }
 730   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 731     if $p->{'svcdb'};
 732
 733   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 734   #              @svc_x;
 735
 736   {
 737     #no#'svcnum'   => $session->{'svcnum'},
 738     'custnum'  => $custnum,
 739     'svcs'     => [ map {
 740                           my $svc_x = $_->svc_x;
 741                           my($label, $value) = $_->label;
 742                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 743
 744                           { 'svcnum'    => $_->svcnum,
 745                             'label'     => $label,
 746                             'value'     => $value,
 747                             'username'  => $svc_x->username,
 748                             'email'     => $svc_x->email,
 749                             'seconds'   => $svc_x->seconds,
 750                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 751                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 752                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 753                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 754                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 755                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 756                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 757                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 758                             # more...
 759                           };
 760                         }
 761                         @cust_svc
 762                   ],
 763   };
 764
 765 }
 766
 767 sub _list_svc_usage {
 768   my($svc_acct, $begin, $end) = @_;
 769   my @usage = ();
 770   foreach my $part_export (
 771     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 772     qw (sqlradius sqlradius_withdomain')
 773   ) {
 774
 775     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
 776   }
 777   (@usage);
 778 }
 779
 780 sub list_svc_usage {
 781   _usage_details(\&_list_svc_usage, @_);
 782 }
 783
 784 sub _list_support_usage {
 785   my($svc_acct, $begin, $end) = @_;
 786   my @usage = ();
 787   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
 788             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
 789           ) {
 790     push @usage, { 'seconds'  => $_->seconds,
 791                    'support'  => $_->support,
 792                    '_date'    => $_->_date,
 793                    'id'       => $_->transaction_id,
 794                    'creator'  => $_->creator,
 795                    'subject'  => $_->subject,
 796                    'status'   => $_->status,
 797                    'ticketid' => $_->ticketid,
 798                  };
 799   }
 800   (@usage);
 801 }
 802
 803 sub list_support_usage {
 804   _usage_details(\&_list_support_usage, @_);
 805 }
 806
 807 sub _usage_details {
 808   my ($callback, $p) = (shift,shift);
 809
 810   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 811   return { 'error' => $session } if $context eq 'error';
 812
 813   my $search = { 'svcnum' => $p->{'svcnum'} };
 814   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 815   my $svc_acct = qsearchs ( 'svc_acct', $search );
 816   return { 'error' => 'No service selected in list_svc_usage' }
 817     unless $svc_acct;
 818
 819   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 820   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 821   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 822   my $end    = time;
 823
 824   unless($p->{beginning}){
 825     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 826     $p->{ending} = $end;
 827   }
 828
 829   my (@usage) = &$callback($svc_acct,$p->{beginning},$p->{ending});
 830
 831   #kinda false laziness with FS::cust_main::bill, but perhaps
 832   #we should really change this bit to DateTime and DateTime::Duration
 833   #
 834   #change this bit to use Date::Manip? CAREFUL with timezones (see
 835   # mailing list archive)
 836   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 837     (localtime($p->{ending}) )[0,1,2,3,4,5];
 838   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 839     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 840
 841   if ( $freq =~ /^\d+$/ ) {
 842     $nmon += $freq;
 843     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 844     $pmon -= $freq;
 845     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 846   } elsif ( $freq =~ /^(\d+)w$/ ) {
 847     my $weeks = $1;
 848     $nmday += $weeks * 7;
 849     $pmday -= $weeks * 7;
 850   } elsif ( $freq =~ /^(\d+)d$/ ) {
 851     my $days = $1;
 852     $nmday += $days;
 853     $pmday -= $days;
 854   } elsif ( $freq =~ /^(\d+)h$/ ) {
 855     my $hours = $1;
 856     $nhour += $hours;
 857     $phour -= $hours;
 858   } else {
 859     return { 'error' => "unparsable frequency: ". $freq };
 860   }
 861
 862   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 863   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 864
 865   {
 866     'error'     => '',
 867     'svcnum'    => $p->{svcnum},
 868     'beginning' => $p->{beginning},
 869     'ending'    => $p->{ending},
 870     'previous'  => ($previous > $start) ? $previous : $start,
 871     'next'      => ($next < $end) ? $next : $end,
 872     'usage'     => \@usage,
 873   };
 874 }
 875
 876 sub order_pkg {
 877   my $p = shift;
 878
 879   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 880   return { 'error' => $session } if $context eq 'error';
 881
 882   my $search = { 'custnum' => $custnum };
 883   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 884   my $cust_main = qsearchs('cust_main', $search )
 885     or return { 'error' => "unknown custnum $custnum" };
 886
 887   my $status = $cust_main->status;
 888   #false laziness w/ClientAPI/Signup.pm
 889
 890   my $cust_pkg = new FS::cust_pkg ( {
 891     'custnum' => $custnum,
 892     'pkgpart' => $p->{'pkgpart'},
 893   } );
 894   my $error = $cust_pkg->check;
 895   return { 'error' => $error } if $error;
 896
 897   my @svc = ();
 898   unless ( $p->{'svcpart'} eq 'none' ) {
 899
 900     my $svcdb;
 901     my $svcpart = '';
 902     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 903       $svcpart = $1;
 904       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 905       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 906       $svcdb = $part_svc->svcdb;
 907     } else {
 908       $svcdb = 'svc_acct';
 909     }
 910     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 911
 912     my %fields = (
 913       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 914       'svc_domain'   => [ qw( domain ) ],
 915       'svc_external' => [ qw( id title ) ],
 916     );
 917
 918     my $svc_x = "FS::$svcdb"->new( {
 919       'svcpart'   => $svcpart,
 920       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 921     } );
 922
 923     if ( $svcdb eq 'svc_acct' ) {
 924       my @acct_snarf;
 925       my $snarfnum = 1;
 926       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 927         my $acct_snarf = new FS::acct_snarf ( {
 928           'machine'   => $p->{"snarf_machine$snarfnum"},
 929           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 930           'username'  => $p->{"snarf_username$snarfnum"},
 931           '_password' => $p->{"snarf_password$snarfnum"},
 932         } );
 933         $snarfnum++;
 934         push @acct_snarf, $acct_snarf;
 935       }
 936       $svc_x->child_objects( \@acct_snarf );
 937     }
 938
 939     my $y = $svc_x->setdefault; # arguably should be in new method
 940     return { 'error' => $y } if $y && !ref($y);
 941
 942     $error = $svc_x->check;
 943     return { 'error' => $error } if $error;
 944
 945     push @svc, $svc_x;
 946
 947   }
 948
 949   use Tie::RefHash;
 950   tie my %hash, 'Tie::RefHash';
 951   %hash = ( $cust_pkg => \@svc );
 952   #msgcat
 953   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 954   return { 'error' => $error } if $error;
 955
 956   my $conf = new FS::Conf;
 957   if ( $conf->exists('signup_server-realtime') ) {
 958
 959     my $bill_error = _do_bop_realtime( $cust_main, $status );
 960
 961     if ($bill_error) {
 962       $cust_pkg->cancel('quiet'=>1);
 963       return $bill_error;
 964     } else {
 965       $cust_pkg->reexport;
 966     }
 967
 968   } else {
 969     $cust_pkg->reexport;
 970   }
 971
 972   return { error => '', pkgnum => $cust_pkg->pkgnum };
 973
 974 }
 975
 976 sub change_pkg {
 977   my $p = shift;
 978
 979   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 980   return { 'error' => $session } if $context eq 'error';
 981
 982   my $search = { 'custnum' => $custnum };
 983   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 984   my $cust_main = qsearchs('cust_main', $search )
 985     or return { 'error' => "unknown custnum $custnum" };
 986
 987   my $status = $cust_main->status;
 988   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 989     or return { 'error' => "unknown package $p->{pkgnum}" };
 990
 991   my @newpkg;
 992   my $error = FS::cust_pkg::order( $custnum,
 993                                    [$p->{pkgpart}],
 994                                    [$p->{pkgnum}],
 995                                    \@newpkg,
 996                                  );
 997
 998   my $conf = new FS::Conf;
 999   if ( $conf->exists('signup_server-realtime') ) {
1000
1001     my $bill_error = _do_bop_realtime( $cust_main, $status );
1002
1003     if ($bill_error) {
1004       $newpkg[0]->suspend;
1005       return $bill_error;
1006     } else {
1007       $newpkg[0]->reexport;
1008     }
1009
1010   } else {
1011     $newpkg[0]->reexport;
1012   }
1013
1014   return { error => '', pkgnum => $cust_pkg->pkgnum };
1015
1016 }
1017
1018 sub order_recharge {
1019   my $p = shift;
1020
1021   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1022   return { 'error' => $session } if $context eq 'error';
1023
1024   my $search = { 'custnum' => $custnum };
1025   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1026   my $cust_main = qsearchs('cust_main', $search )
1027     or return { 'error' => "unknown custnum $custnum" };
1028
1029   my $status = $cust_main->status;
1030   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
1031     or return { 'error' => "unknown service " . $p->{'svcnum'} };
1032
1033   my $svc_x = $cust_svc->svc_x;
1034   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
1035
1036   my %vhash =
1037     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
1038     qw ( recharge_seconds recharge_upbytes recharge_downbytes
1039          recharge_totalbytes );
1040   my $amount = $part_pkg->option('recharge_amount', 1);
1041
1042   my ($l, $v, $d) = $cust_svc->label;  # blah
1043   my $pkg = "Recharge $v";
1044
1045   my $bill_error = $cust_main->charge($amount, $pkg,
1046      "time: $vhash{seconds}, up: $vhash{upbytes}," .
1047      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
1048      $part_pkg->taxclass); #meh
1049
1050   my $conf = new FS::Conf;
1051   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
1052
1053     $bill_error = _do_bop_realtime( $cust_main, $status );
1054
1055     if ($bill_error) {
1056       return $bill_error;
1057     } else {
1058       my $error = $svc_x->recharge (\%vhash);
1059       return { 'error' => $error } if $error;
1060     }
1061
1062   } else {
1063     my $error = $bill_error;
1064     $error ||= $svc_x->recharge (\%vhash);
1065     return { 'error' => $error } if $error;
1066   }
1067
1068   return { error => '', svc => $cust_svc->part_svc->svc };
1069
1070 }
1071
1072 sub _do_bop_realtime {
1073   my ($cust_main, $status) = (shift, shift);
1074
1075     my $old_balance = $cust_main->balance;
1076
1077     my $bill_error =    $cust_main->bill
1078                      || $cust_main->apply_payments_and_credits
1079                      || $cust_main->collect('realtime' => 1);
1080
1081     if (    $cust_main->balance > $old_balance
1082          && $cust_main->balance > 0
1083          && ( $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ?
1084               1 : $status eq 'suspended' ) ) {
1085       #this makes sense.  credit is "un-doing" the invoice
1086       my $conf = new FS::Conf;
1087       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
1088                           'self-service decline',
1089                           'reason_type' => $conf->config('signup_credit_type'),
1090                         );
1091       $cust_main->apply_credits( 'order' => 'newest' );
1092
1093       return { 'error' => '_decline', 'bill_error' => $bill_error };
1094     }
1095
1096     '';
1097 }
1098
1099 sub cancel_pkg {
1100   my $p = shift;
1101   my $session = _cache->get($p->{'session_id'})
1102     or return { 'error' => "Can't resume session" }; #better error message
1103
1104   my $custnum = $session->{'custnum'};
1105
1106   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1107     or return { 'error' => "unknown custnum $custnum" };
1108
1109   my $pkgnum = $p->{'pkgnum'};
1110
1111   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1112                                         'pkgnum'  => $pkgnum,   } )
1113     or return { 'error' => "unknown pkgnum $pkgnum" };
1114
1115   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1116   return { 'error' => $error };
1117
1118 }
1119
1120 sub provision_acct {
1121   my $p = shift;
1122   warn "provision_acct called\n"
1123     if $DEBUG;
1124
1125   return { 'error' => gettext('passwords_dont_match') }
1126     if $p->{'_password'} ne $p->{'_password2'};
1127   return { 'error' => gettext('empty_password') }
1128     unless length($p->{'_password'});
1129
1130   if ($p->{'domsvc'}) {
1131     my %domains = domain_select_hash FS::svc_acct(map { $_ => $p->{$_} }
1132                                                   qw ( svcpart pkgnum ) );
1133     return { 'error' => gettext('invalid_domain') }
1134       unless ($domains{$p->{'domsvc'}});
1135   }
1136
1137   warn "provision_acct calling _provision\n"
1138     if $DEBUG;
1139   _provision( 'FS::svc_acct',
1140               [qw(username _password domsvc)],
1141               [qw(username _password domsvc)],
1142               $p,
1143               @_
1144             );
1145 }
1146
1147 sub provision_external {
1148   my $p = shift;
1149   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1150   _provision( 'FS::svc_external',
1151               [],
1152               [qw(id title)],
1153               $p,
1154               @_
1155             );
1156 }
1157
1158 sub _provision {
1159   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1160   warn "_provision called for $class\n"
1161     if $DEBUG;
1162
1163   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1164   return { 'error' => $session } if $context eq 'error';
1165
1166   my $search = { 'custnum' => $custnum };
1167   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1168   my $cust_main = qsearchs('cust_main', $search )
1169     or return { 'error' => "unknown custnum $custnum" };
1170
1171   my $pkgnum = $p->{'pkgnum'};
1172
1173   warn "searching for custnum $custnum pkgnum $pkgnum\n"
1174     if $DEBUG;
1175   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1176                                         'pkgnum'  => $pkgnum,
1177                                                                } )
1178     or return { 'error' => "unknown pkgnum $pkgnum" };
1179
1180   warn "searching for svcpart ". $p->{'svcpart'}. "\n"
1181     if $DEBUG;
1182   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1183     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1184
1185   warn "creating $class record\n"
1186     if $DEBUG;
1187   my $svc_x = $class->new( {
1188     'pkgnum'  => $p->{'pkgnum'},
1189     'svcpart' => $p->{'svcpart'},
1190     map { $_ => $p->{$_} } @$fields
1191   } );
1192   warn "inserting $class record\n"
1193     if $DEBUG;
1194   my $error = $svc_x->insert;
1195
1196   unless ( $error ) {
1197     warn "finding inserted record for svcnum ". $svc_x->svcnum. "\n"
1198       if $DEBUG;
1199     $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1200   }
1201
1202   my $return = { 'svc'   => $part_svc->svc,
1203                  'error' => $error,
1204                  map { $_ => $svc_x->get($_) } @$return_fields
1205                };
1206   warn "_provision returning ". Dumper($return). "\n"
1207     if $DEBUG;
1208   return $return;
1209
1210 }
1211
1212 sub part_svc_info {
1213   my $p = shift;
1214
1215   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1216   return { 'error' => $session } if $context eq 'error';
1217
1218   my $search = { 'custnum' => $custnum };
1219   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1220   my $cust_main = qsearchs('cust_main', $search )
1221     or return { 'error' => "unknown custnum $custnum" };
1222
1223   my $pkgnum = $p->{'pkgnum'};
1224
1225   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1226                                         'pkgnum'  => $pkgnum,
1227                                                                } )
1228     or return { 'error' => "unknown pkgnum $pkgnum" };
1229
1230   my $svcpart = $p->{'svcpart'};
1231
1232   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1233                                       'svcpart' => $svcpart,           } )
1234     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1235   my $part_svc = $pkg_svc->part_svc;
1236
1237   my $conf = new FS::Conf;
1238
1239   return {
1240     'svc'     => $part_svc->svc,
1241     'svcdb'   => $part_svc->svcdb,
1242     'pkgnum'  => $pkgnum,
1243     'svcpart' => $svcpart,
1244     'custnum' => $custnum,
1245
1246     'security_phrase' => 0, #XXX !
1247     'svc_acct_pop'    => [], #XXX !
1248     'popnum'          => '',
1249     'init_popstate'   => '',
1250     'popac'           => '',
1251     'acstate'         => '',
1252
1253     'small_custview' =>
1254       small_custview( $cust_main, $conf->config('countrydefault') ),
1255
1256   };
1257
1258 }
1259
1260 sub unprovision_svc {
1261   my $p = shift;
1262
1263   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1264   return { 'error' => $session } if $context eq 'error';
1265
1266   my $search = { 'custnum' => $custnum };
1267   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1268   my $cust_main = qsearchs('cust_main', $search )
1269     or return { 'error' => "unknown custnum $custnum" };
1270
1271   my $svcnum = $p->{'svcnum'};
1272
1273   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1274     or return { 'error' => "unknown svcnum $svcnum" };
1275
1276   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1277     unless $cust_svc->cust_pkg->custnum == $custnum;
1278
1279   my $conf = new FS::Conf;
1280
1281   return { 'svc'   => $cust_svc->part_svc->svc,
1282            'error' => $cust_svc->cancel,
1283            'small_custview' =>
1284              small_custview( $cust_main, $conf->config('countrydefault') ),
1285          };
1286
1287 }
1288
1289 sub myaccount_passwd {
1290   my $p = shift;
1291   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1292   return { 'error' => $session } if $context eq 'error';
1293
1294   return { 'error' => "New passwords don't match." }
1295     if $p->{'new_password'} ne $p->{'new_password2'};
1296
1297   return { 'error' => 'Enter new password' }
1298     unless length($p->{'new_password'});
1299
1300   #my $search = { 'custnum' => $custnum };
1301   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1302   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1303   my $search = " AND custnum = $1";
1304   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1305
1306   my $svc_acct = qsearchs( {
1307     'table'     => 'svc_acct',
1308     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1309                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1310                    'LEFT JOIN cust_main USING ( custnum ) ',
1311     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1312     'extra_sql' => $search, #important
1313   } )
1314     or return { 'error' => "Service not found" };
1315
1316   $svc_acct->_password($p->{'new_password'});
1317   my $error = $svc_acct->replace();
1318
1319   my($label, $value) = $svc_acct->cust_svc->label;
1320
1321   return { 'error' => $error,
1322            'label' => $label,
1323            'value' => $value,
1324          };
1325
1326 }
1327
1328 #--
1329
1330 sub _custoragent_session_custnum {
1331   my $p = shift;
1332
1333   my($context, $session, $custnum);
1334   if ( $p->{'session_id'} ) {
1335
1336     $context = 'customer';
1337     $session = _cache->get($p->{'session_id'})
1338       or return ( 'error' => "Can't resume session" ); #better error message
1339     $custnum = $session->{'custnum'};
1340
1341   } elsif ( $p->{'agent_session_id'} ) {
1342
1343     $context = 'agent';
1344     my $agent_cache = new FS::ClientAPI_SessionCache( {
1345       'namespace' => 'FS::ClientAPI::Agent',
1346     } );
1347     $session = $agent_cache->get($p->{'agent_session_id'})
1348       or return ( 'error' => "Can't resume session" ); #better error message
1349     $custnum = $p->{'custnum'};
1350
1351   } else {
1352     return ( 'error' => "Can't resume session" ); #better error message
1353   }
1354
1355   ($context, $session, $custnum);
1356
1357 }
1358
1359 1;
1360