FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw( $cache $DEBUG );
   5 use subs qw( _cache _provision );
   6 use Data::Dumper;
   7 use Digest::MD5 qw(md5_hex);
   8 use Date::Format;
   9 use Business::CreditCard;
  10 use Time::Duration;
  11 use FS::UI::Web::small_custview qw(small_custview); #less doh
  12 use FS::UI::Web;
  13 use FS::UI::bytecount;
  14 use FS::Conf;
  15 use FS::Record qw(qsearch qsearchs);
  16 use FS::Msgcat qw(gettext);
  17 use FS::Misc qw(card_types);
  18 use FS::ClientAPI_SessionCache;
  19 use FS::svc_acct;
  20 use FS::svc_domain;
  21 use FS::svc_phone;
  22 use FS::svc_external;
  23 use FS::part_svc;
  24 use FS::cust_main;
  25 use FS::cust_bill;
  26 use FS::cust_main_county;
  27 use FS::cust_pkg;
  28 use FS::payby;
  29 use FS::acct_rt_transaction;
  30 use HTML::Entities;
  31
  32 $DEBUG = 0;
  33
  34 #false laziness with FS::cust_main
  35 BEGIN {
  36   eval "use Time::Local;";
  37   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  38     if $] < 5.006 && !defined($Time::Local::VERSION);
  39   eval "use Time::Local qw(timelocal_nocheck);";
  40 }
  41
  42 use vars qw( @cust_main_editable_fields );
  43 @cust_main_editable_fields = qw(
  44   first last company address1 address2 city
  45     county state zip country daytime night fax
  46   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  47     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  48   payby payinfo payname paystart_month paystart_year payissue payip
  49   ss paytype paystate stateid stateid_state
  50 );
  51
  52 sub _cache {
  53   $cache ||= new FS::ClientAPI_SessionCache( {
  54                'namespace' => 'FS::ClientAPI::MyAccount',
  55              } );
  56 }
  57
  58 sub login_info {
  59   my $p = shift;
  60
  61   my $conf = new FS::Conf;
  62
  63   my %info = (
  64     'phone_login'  => $conf->exists('selfservice_server-phone_login'),
  65     'single_domain'=> scalar($conf->config('selfservice_server-single_domain')),
  66   );
  67
  68   return \%info;
  69
  70 }
  71
  72 #false laziness w/FS::ClientAPI::passwd::passwd
  73 sub login {
  74   my $p = shift;
  75
  76   my $conf = new FS::Conf;
  77
  78   my $svc_x = '';
  79   if ( $p->{'domain'} eq 'svc_phone'
  80        && $conf->exists('selfservice_server-phone_login') ) {
  81
  82     my $svc_phone = qsearchs( 'svc_phone', { 'phonenum' => $p->{'username'} } );
  83     return { error => 'Number not found.' } unless $svc_phone;
  84
  85     #XXX?
  86     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  87     #return { error => 'Only primary user may log in.' }
  88     #  if $conf->exists('selfservice_server-primary_only')
  89     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  90
  91     return { error => 'Incorrect PIN.' }
  92       unless $svc_phone->check_pin($p->{'password'});
  93
  94     $svc_x = $svc_phone;
  95
  96   } else {
  97
  98     my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  99       or return { error => 'Domain '. $p->{'domain'}. ' not found' };
 100
 101     my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
 102                                            'domsvc'    => $svc_domain->svcnum, }
 103                            );
 104     return { error => 'User not found.' } unless $svc_acct;
 105
 106     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 107     #return { error => 'Only primary user may log in.' }
 108     #  if $conf->exists('selfservice_server-primary_only')
 109     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 110     my $cust_svc = $svc_acct->cust_svc;
 111     my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 112     return { error => 'Only primary user may log in.' }
 113       if $conf->exists('selfservice_server-primary_only')
 114          && $cust_svc->svcpart != $part_pkg->svcpart('svc_acct');
 115
 116     return { error => 'Incorrect password.' }
 117       unless $svc_acct->check_password($p->{'password'});
 118
 119     $svc_x = $svc_acct;
 120
 121   }
 122
 123   my $session = {
 124     'svcnum' => $svc_x->svcnum,
 125   };
 126
 127   my $cust_pkg = $svc_x->cust_svc->cust_pkg;
 128   if ( $cust_pkg ) {
 129     my $cust_main = $cust_pkg->cust_main;
 130     $session->{'custnum'} = $cust_main->custnum;
 131   }
 132
 133   my $session_id;
 134   do {
 135     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
 136   } until ( ! defined _cache->get($session_id) ); #just in case
 137
 138   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 139   _cache->set( $session_id, $session, $timeout );
 140
 141   return { 'error'      => '',
 142            'session_id' => $session_id,
 143          };
 144 }
 145
 146 sub logout {
 147   my $p = shift;
 148   if ( $p->{'session_id'} ) {
 149     _cache->remove($p->{'session_id'});
 150     return { 'error' => '' };
 151   } else {
 152     return { 'error' => "Can't resume session" }; #better error message
 153   }
 154 }
 155
 156 sub customer_info {
 157   my $p = shift;
 158
 159   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 160   return { 'error' => $session } if $context eq 'error';
 161
 162   my %return;
 163
 164   my $conf = new FS::Conf;
 165   if ($conf->exists('cust_main-require_address2')) {
 166     $return{'require_address2'} = '1';
 167   }else{
 168     $return{'require_address2'} = '';
 169   }
 170
 171   if ( $custnum ) { #customer record
 172
 173     my $search = { 'custnum' => $custnum };
 174     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 175     my $cust_main = qsearchs('cust_main', $search )
 176       or return { 'error' => "unknown custnum $custnum" };
 177
 178     $return{balance} = $cust_main->balance;
 179
 180     $return{tickets} = [ ($cust_main->tickets) ];
 181
 182     my @open = map {
 183                      {
 184                        invnum => $_->invnum,
 185                        date   => time2str("%b %o, %Y", $_->_date),
 186                        owed   => $_->owed,
 187                      };
 188                    } $cust_main->open_cust_bill;
 189     $return{open_invoices} = \@open;
 190
 191     $return{small_custview} =
 192       small_custview( $cust_main, $conf->config('countrydefault') );
 193
 194     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 195
 196     for (@cust_main_editable_fields) {
 197       $return{$_} = $cust_main->get($_);
 198     }
 199
 200     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 201       $return{payinfo} = $cust_main->paymask;
 202       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 203     }
 204
 205     $return{'invoicing_list'} =
 206       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 207     $return{'postal_invoicing'} =
 208       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 209
 210     if (scalar($conf->config('support_packages'))) {
 211       my @support_services = ();
 212       foreach ($cust_main->support_services) {
 213         my $seconds = $_->svc_x->seconds;
 214         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 215                              int(abs($seconds)/3600)."h".
 216                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 217         my $cust_pkg = $_->cust_pkg;
 218         my $pkgnum = '';
 219         my $pkg = '';
 220         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 221         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 222         push @support_services, { svcnum => $_->svcnum,
 223                                   time => $time_remaining,
 224                                   pkgnum => $pkgnum,
 225                                   pkg => $pkg,
 226                                 };
 227       }
 228       $return{support_services} = \@support_services;
 229     }
 230
 231   } elsif ( $session->{'svcnum'} ) { #no customer record
 232
 233     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 234       or die "unknown svcnum";
 235     $return{name} = $svc_acct->email;
 236
 237   } else {
 238
 239     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 240
 241   }
 242
 243   return { 'error'          => '',
 244            'custnum'        => $custnum,
 245            %return,
 246          };
 247
 248 }
 249
 250 sub edit_info {
 251   my $p = shift;
 252   my $session = _cache->get($p->{'session_id'})
 253     or return { 'error' => "Can't resume session" }; #better error message
 254
 255   my $custnum = $session->{'custnum'}
 256     or return { 'error' => "no customer record" };
 257
 258   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 259     or return { 'error' => "unknown custnum $custnum" };
 260
 261   my $new = new FS::cust_main { $cust_main->hash };
 262   $new->set( $_ => $p->{$_} )
 263     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 264
 265   my $payby = '';
 266   if (exists($p->{'payby'})) {
 267     $p->{'payby'} =~ /^([A-Z]{4})$/
 268       or return { 'error' => "illegal_payby " . $p->{'payby'} };
 269     $payby = $1;
 270   }
 271
 272   if ( $payby =~ /^(CARD|DCRD)$/ ) {
 273
 274     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 275
 276     if ( $new->payinfo eq $cust_main->paymask ) {
 277       $new->payinfo($cust_main->payinfo);
 278     } else {
 279       $new->payinfo($p->{'payinfo'});
 280     }
 281
 282     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 283
 284   }elsif ( $payby =~ /^(CHEK|DCHK)$/ ) {
 285     my $payinfo;
 286     $p->{'payinfo1'} =~ /^([\dx]+)$/
 287       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 288     my $payinfo1 = $1;
 289      $p->{'payinfo2'} =~ /^([\dx]+)$/
 290       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 291     my $payinfo2 = $1;
 292     $payinfo = $payinfo1. '@'. $payinfo2;
 293
 294     if ( $payinfo eq $cust_main->paymask ) {
 295       $new->payinfo($cust_main->payinfo);
 296     } else {
 297       $new->payinfo($payinfo);
 298     }
 299
 300     $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 301
 302   }elsif ( $payby =~ /^(BILL)$/ ) {
 303   } elsif ( $payby ) {  #notyet ready
 304     return { 'error' => "unknown payby $payby" };
 305   }
 306
 307   my @invoicing_list;
 308   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 309     #false laziness with httemplate/edit/process/cust_main.cgi
 310     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 311     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 312   } else {
 313     @invoicing_list = $cust_main->invoicing_list;
 314   }
 315
 316   my $error = $new->replace($cust_main, \@invoicing_list);
 317   return { 'error' => $error } if $error;
 318   #$cust_main = $new;
 319
 320   return { 'error' => '' };
 321 }
 322
 323 sub payment_info {
 324   my $p = shift;
 325   my $session = _cache->get($p->{'session_id'})
 326     or return { 'error' => "Can't resume session" }; #better error message
 327
 328   ##
 329   #generic
 330   ##
 331
 332   use vars qw($payment_info); #cache for performance
 333   unless ( $payment_info ) {
 334
 335     my $conf = new FS::Conf;
 336     my %states = map { $_->state => 1 }
 337                    qsearch('cust_main_county', {
 338                      'country' => $conf->config('countrydefault') || 'US'
 339                    } );
 340
 341     $payment_info = {
 342
 343       #list all counties/states/countries
 344       'cust_main_county' =>
 345         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 346
 347       #shortcut for one-country folks
 348       'states' =>
 349         [ sort { $a cmp $b } keys %states ],
 350
 351       'card_types' => card_types(),
 352
 353       'paytypes' => [ @FS::cust_main::paytypes ],
 354
 355       'paybys' => [ $conf->config('signup_server-payby') ],
 356       'cust_paybys' => [ map { FS::payby->payby2payment($_) }
 357                                  $conf->config('signup_server-payby')
 358                        ],
 359
 360       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 361       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 362
 363       'show_ss'  => $conf->exists('show_ss'),
 364       'show_stateid' => $conf->exists('show_stateid'),
 365       'show_paystate' => $conf->exists('show_bankstate'),
 366     };
 367
 368   }
 369
 370   ##
 371   #customer-specific
 372   ##
 373
 374   my %return = %$payment_info;
 375
 376   my $custnum = $session->{'custnum'};
 377
 378   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 379     or return { 'error' => "unknown custnum $custnum" };
 380
 381   $return{hide_payment_fields} =
 382   [
 383     map { FS::payby->realtime($_) &&
 384           $cust_main
 385             ->agent
 386             ->payment_gateway( 'method' => FS::payby->payby2bop($_) )
 387             ->gateway_namespace
 388             eq 'Business::OnlineThirdPartyPayment'
 389         }
 390     @{ $return{cust_paybys} }
 391   ];
 392
 393   $return{balance} = $cust_main->balance;
 394
 395   $return{payname} = $cust_main->payname
 396                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 397
 398   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 399
 400   $return{payby} = $cust_main->payby;
 401   $return{stateid_state} = $cust_main->stateid_state;
 402
 403   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 404     $return{card_type} = cardtype($cust_main->payinfo);
 405     $return{payinfo} = $cust_main->paymask;
 406
 407     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 408
 409   }
 410
 411   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 412     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 413     $return{payinfo1} = $payinfo1;
 414     $return{payinfo2} = $payinfo2;
 415     $return{paytype}  = $cust_main->paytype;
 416     $return{paystate} = $cust_main->paystate;
 417
 418   }
 419
 420   #doubleclick protection
 421   my $_date = time;
 422   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 423
 424   return { 'error' => '',
 425            %return,
 426          };
 427
 428 };
 429
 430 #some false laziness with httemplate/process/payment.cgi - look there for
 431 #ACH and CVV support stuff
 432 sub process_payment {
 433
 434   my $p = shift;
 435
 436   my $session = _cache->get($p->{'session_id'})
 437     or return { 'error' => "Can't resume session" }; #better error message
 438
 439   my %return;
 440
 441   my $custnum = $session->{'custnum'};
 442
 443   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 444     or return { 'error' => "unknown custnum $custnum" };
 445
 446   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 447     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 448   my $payname = $1;
 449
 450   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 451     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 452   my $paybatch = $1;
 453
 454   $p->{'payby'} ||= 'CARD';
 455   $p->{'payby'} =~ /^([A-Z]{4})$/
 456     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 457   my $payby = $1;
 458
 459   #false laziness w/process/payment.cgi
 460   my $payinfo;
 461   my $paycvv = '';
 462   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 463
 464     $p->{'payinfo1'} =~ /^([\dx]+)$/
 465       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 466     my $payinfo1 = $1;
 467      $p->{'payinfo2'} =~ /^([\dx]+)$/
 468       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 469     my $payinfo2 = $1;
 470     $payinfo = $payinfo1. '@'. $payinfo2;
 471
 472     $payinfo = $cust_main->payinfo
 473       if $cust_main->paymask eq $payinfo;
 474
 475   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 476
 477     $payinfo = $p->{'payinfo'};
 478
 479     $payinfo = $cust_main->payinfo
 480       if $cust_main->paymask eq $payinfo;
 481
 482     $payinfo =~ s/\D//g;
 483     $payinfo =~ /^(\d{13,16})$/
 484       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 485     $payinfo = $1;
 486
 487     validate($payinfo)
 488       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 489     return { 'error' => gettext('unknown_card_type') }
 490       if cardtype($payinfo) eq "Unknown";
 491
 492     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 493       if ( cardtype($payinfo) eq 'American Express card' ) {
 494         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 495           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 496         $paycvv = $1;
 497       } else {
 498         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 499           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 500         $paycvv = $1;
 501       }
 502     }
 503
 504   } else {
 505     die "unknown payby $payby";
 506   }
 507
 508   my %payby2fields = (
 509     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 510     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 511   );
 512
 513   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 514     'quiet'    => 1,
 515     'payinfo'  => $payinfo,
 516     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 517     'payname'  => $payname,
 518     'paybatch' => $paybatch, #this doesn't actually do anything
 519     'paycvv'   => $paycvv,
 520     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 521   );
 522   return { 'error' => $error } if $error;
 523
 524   $cust_main->apply_payments;
 525
 526   if ( $p->{'save'} ) {
 527     my $new = new FS::cust_main { $cust_main->hash };
 528     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 529       $new->set( $_ => $p->{$_} )
 530         foreach qw( payname paystart_month paystart_year payissue payip
 531                     address1 address2 city state zip payinfo );
 532       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 533     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 534       $new->set( $_ => $p->{$_} )
 535         foreach qw( payname payip paytype paystate
 536                     stateid stateid_state );
 537       $new->set( 'payinfo' => $payinfo );
 538       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 539     }
 540     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 541     my $error = $new->replace($cust_main);
 542     return { 'error' => $error } if $error;
 543     $cust_main = $new;
 544   }
 545
 546   return { 'error' => '' };
 547
 548 }
 549
 550 sub realtime_collect {
 551
 552   my $p = shift;
 553
 554   my $session = _cache->get($p->{'session_id'})
 555     or return { 'error' => "Can't resume session" }; #better error message
 556
 557   my $custnum = $session->{'custnum'};
 558
 559   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 560     or return { 'error' => "unknown custnum $custnum" };
 561
 562   my $error = $cust_main->realtime_collect( 'method'     => $p->{'method'},
 563                                             'session_id' => $p->{'session_id'},
 564                                           );
 565   return { 'error' => $error } unless ref( $error );
 566
 567   return { 'error' => '', amount => $cust_main->balance, %$error };
 568 }
 569
 570 sub process_payment_order_pkg {
 571   my $p = shift;
 572
 573   my $hr = process_payment($p);
 574   return $hr if $hr->{'error'};
 575
 576   order_pkg($p);
 577 }
 578
 579 sub process_payment_order_renew {
 580   my $p = shift;
 581
 582   my $hr = process_payment($p);
 583   return $hr if $hr->{'error'};
 584
 585   order_renew($p);
 586 }
 587
 588 sub process_prepay {
 589
 590   my $p = shift;
 591
 592   my $session = _cache->get($p->{'session_id'})
 593     or return { 'error' => "Can't resume session" }; #better error message
 594
 595   my %return;
 596
 597   my $custnum = $session->{'custnum'};
 598
 599   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 600     or return { 'error' => "unknown custnum $custnum" };
 601
 602   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 603   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 604                                            \$amount,
 605                                            \$seconds,
 606                                            \$upbytes,
 607                                            \$downbytes,
 608                                            \$totalbytes,
 609                                          );
 610
 611   return { 'error' => $error } if $error;
 612
 613   return { 'error'     => '',
 614            'amount'    => $amount,
 615            'seconds'   => $seconds,
 616            'duration'  => duration_exact($seconds),
 617            'upbytes'   => $upbytes,
 618            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 619            'downbytes' => $downbytes,
 620            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 621            'totalbytes'=> $totalbytes,
 622            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 623          };
 624
 625 }
 626
 627 sub invoice {
 628   my $p = shift;
 629   my $session = _cache->get($p->{'session_id'})
 630     or return { 'error' => "Can't resume session" }; #better error message
 631
 632   my $custnum = $session->{'custnum'};
 633
 634   my $invnum = $p->{'invnum'};
 635
 636   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 637                                           'custnum' => $custnum } )
 638     or return { 'error' => "Can't find invnum" };
 639
 640   #my %return;
 641
 642   return { 'error'        => '',
 643            'invnum'       => $invnum,
 644            'invoice_text' => join('', $cust_bill->print_text ),
 645            'invoice_html' => $cust_bill->print_html( { unsquelch_cdr => 1 } ),
 646          };
 647
 648 }
 649
 650 sub invoice_logo {
 651   my $p = shift;
 652
 653   #sessioning for this?  how do we get the session id to the backend invoice
 654   # template so it can add it to the link, blah
 655
 656   my $templatename = $p->{'templatename'};
 657
 658   #false laziness-ish w/view/cust_bill-logo.cgi
 659
 660   my $conf = new FS::Conf;
 661   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 662     $templatename = "_$1";
 663   } else {
 664     $templatename = '';
 665   }
 666
 667   my $filename = "logo$templatename.png";
 668
 669   return { 'error'        => '',
 670            'logo'         => $conf->config_binary($filename),
 671            'content_type' => 'image/png', #should allow gif, jpg too
 672          };
 673 }
 674
 675
 676 sub list_invoices {
 677   my $p = shift;
 678   my $session = _cache->get($p->{'session_id'})
 679     or return { 'error' => "Can't resume session" }; #better error message
 680
 681   my $custnum = $session->{'custnum'};
 682
 683   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 684     or return { 'error' => "unknown custnum $custnum" };
 685
 686   my @cust_bill = $cust_main->cust_bill;
 687
 688   return  { 'error'       => '',
 689             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 690                                         '_date'  => $_->_date,
 691                                       }
 692                                     } @cust_bill
 693                               ]
 694           };
 695 }
 696
 697 sub cancel {
 698   my $p = shift;
 699   my $session = _cache->get($p->{'session_id'})
 700     or return { 'error' => "Can't resume session" }; #better error message
 701
 702   my $custnum = $session->{'custnum'};
 703
 704   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 705     or return { 'error' => "unknown custnum $custnum" };
 706
 707   my @errors = $cust_main->cancel( 'quiet'=>1 );
 708
 709   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 710
 711   return { 'error' => $error };
 712
 713 }
 714
 715 sub list_pkgs {
 716   my $p = shift;
 717
 718   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 719   return { 'error' => $session } if $context eq 'error';
 720
 721   my $search = { 'custnum' => $custnum };
 722   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 723   my $cust_main = qsearchs('cust_main', $search )
 724     or return { 'error' => "unknown custnum $custnum" };
 725
 726   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 727
 728   my $conf = new FS::Conf;
 729
 730   { 'svcnum'   => $session->{'svcnum'},
 731     'custnum'  => $custnum,
 732     'cust_pkg' => [ map {
 733                           { $_->hash,
 734                             $_->part_pkg->hash,
 735                             part_svc =>
 736                               [ map $_->hashref, $_->available_part_svc ],
 737                             cust_svc =>
 738                               [ map { my $ref = { $_->hash,
 739                                                   label => [ $_->label ],
 740                                                 };
 741                                       $ref->{_password} = $_->svc_x->_password
 742                                         if $context eq 'agent'
 743                                         && $conf->exists('agent-showpasswords')
 744                                         && $_->part_svc->svcdb eq 'svc_acct';
 745                                       $ref;
 746                                     } $_->cust_svc
 747                               ],
 748                           };
 749                         } $cust_main->ncancelled_pkgs
 750                   ],
 751     'small_custview' =>
 752       small_custview( $cust_main, $conf->config('countrydefault') ),
 753   };
 754
 755 }
 756
 757 sub list_svcs {
 758   my $p = shift;
 759
 760   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 761   return { 'error' => $session } if $context eq 'error';
 762
 763   my $search = { 'custnum' => $custnum };
 764   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 765   my $cust_main = qsearchs('cust_main', $search )
 766     or return { 'error' => "unknown custnum $custnum" };
 767
 768   my @cust_svc = ();
 769   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 770   foreach my $cust_pkg ( $p->{'ncancelled'}
 771                          ? $cust_main->ncancelled_pkgs
 772                          : $cust_main->unsuspended_pkgs ) {
 773     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 774   }
 775   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 776     if $p->{'svcdb'};
 777
 778   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 779   #              @svc_x;
 780
 781   {
 782     #no#'svcnum'   => $session->{'svcnum'},
 783     'custnum'  => $custnum,
 784     'svcs'     => [ map {
 785                           my $svc_x = $_->svc_x;
 786                           my($label, $value) = $_->label;
 787                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 788
 789                           { 'svcnum'    => $_->svcnum,
 790                             'label'     => $label,
 791                             'value'     => $value,
 792                             'username'  => $svc_x->username,
 793                             'email'     => $svc_x->email,
 794                             'seconds'   => $svc_x->seconds,
 795                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 796                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 797                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 798                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 799                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 800                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 801                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 802                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 803                             # more...
 804                           };
 805                         }
 806                         @cust_svc
 807                   ],
 808   };
 809
 810 }
 811
 812 sub _list_svc_usage {
 813   my($svc_acct, $begin, $end) = @_;
 814   my @usage = ();
 815   foreach my $part_export (
 816     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 817     qw (sqlradius sqlradius_withdomain')
 818   ) {
 819
 820     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
 821   }
 822   (@usage);
 823 }
 824
 825 sub list_svc_usage {
 826   _usage_details(\&_list_svc_usage, @_);
 827 }
 828
 829 sub _list_support_usage {
 830   my($svc_acct, $begin, $end) = @_;
 831   my @usage = ();
 832   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
 833             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
 834           ) {
 835     push @usage, { 'seconds'  => $_->seconds,
 836                    'support'  => $_->support,
 837                    '_date'    => $_->_date,
 838                    'id'       => $_->transaction_id,
 839                    'creator'  => $_->creator,
 840                    'subject'  => $_->subject,
 841                    'status'   => $_->status,
 842                    'ticketid' => $_->ticketid,
 843                  };
 844   }
 845   (@usage);
 846 }
 847
 848 sub list_support_usage {
 849   _usage_details(\&_list_support_usage, @_);
 850 }
 851
 852 sub _usage_details {
 853   my ($callback, $p) = (shift,shift);
 854
 855   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 856   return { 'error' => $session } if $context eq 'error';
 857
 858   my $search = { 'svcnum' => $p->{'svcnum'} };
 859   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 860   my $svc_acct = qsearchs ( 'svc_acct', $search );
 861   return { 'error' => 'No service selected in list_svc_usage' }
 862     unless $svc_acct;
 863
 864   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 865   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 866   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 867   my $end    = time;
 868
 869   unless($p->{beginning}){
 870     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 871     $p->{ending} = $end;
 872   }
 873
 874   my (@usage) = &$callback($svc_acct,$p->{beginning},$p->{ending});
 875
 876   #kinda false laziness with FS::cust_main::bill, but perhaps
 877   #we should really change this bit to DateTime and DateTime::Duration
 878   #
 879   #change this bit to use Date::Manip? CAREFUL with timezones (see
 880   # mailing list archive)
 881   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 882     (localtime($p->{ending}) )[0,1,2,3,4,5];
 883   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 884     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 885
 886   if ( $freq =~ /^\d+$/ ) {
 887     $nmon += $freq;
 888     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 889     $pmon -= $freq;
 890     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 891   } elsif ( $freq =~ /^(\d+)w$/ ) {
 892     my $weeks = $1;
 893     $nmday += $weeks * 7;
 894     $pmday -= $weeks * 7;
 895   } elsif ( $freq =~ /^(\d+)d$/ ) {
 896     my $days = $1;
 897     $nmday += $days;
 898     $pmday -= $days;
 899   } elsif ( $freq =~ /^(\d+)h$/ ) {
 900     my $hours = $1;
 901     $nhour += $hours;
 902     $phour -= $hours;
 903   } else {
 904     return { 'error' => "unparsable frequency: ". $freq };
 905   }
 906
 907   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 908   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 909
 910   {
 911     'error'     => '',
 912     'svcnum'    => $p->{svcnum},
 913     'beginning' => $p->{beginning},
 914     'ending'    => $p->{ending},
 915     'previous'  => ($previous > $start) ? $previous : $start,
 916     'next'      => ($next < $end) ? $next : $end,
 917     'usage'     => \@usage,
 918   };
 919 }
 920
 921 sub order_pkg {
 922   my $p = shift;
 923
 924   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 925   return { 'error' => $session } if $context eq 'error';
 926
 927   my $search = { 'custnum' => $custnum };
 928   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 929   my $cust_main = qsearchs('cust_main', $search )
 930     or return { 'error' => "unknown custnum $custnum" };
 931
 932   my $status = $cust_main->status;
 933   #false laziness w/ClientAPI/Signup.pm
 934
 935   my $cust_pkg = new FS::cust_pkg ( {
 936     'custnum' => $custnum,
 937     'pkgpart' => $p->{'pkgpart'},
 938   } );
 939   my $error = $cust_pkg->check;
 940   return { 'error' => $error } if $error;
 941
 942   my @svc = ();
 943   unless ( $p->{'svcpart'} eq 'none' ) {
 944
 945     my $svcdb;
 946     my $svcpart = '';
 947     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 948       $svcpart = $1;
 949       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 950       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 951       $svcdb = $part_svc->svcdb;
 952     } else {
 953       $svcdb = 'svc_acct';
 954     }
 955     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 956
 957     my %fields = (
 958       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 959       'svc_domain'   => [ qw( domain ) ],
 960       'svc_phone'    => [ qw( phonenum pin sip_password ) ],
 961       'svc_external' => [ qw( id title ) ],
 962     );
 963
 964     my $svc_x = "FS::$svcdb"->new( {
 965       'svcpart'   => $svcpart,
 966       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 967     } );
 968
 969     if ( $svcdb eq 'svc_acct' ) {
 970       my @acct_snarf;
 971       my $snarfnum = 1;
 972       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 973         my $acct_snarf = new FS::acct_snarf ( {
 974           'machine'   => $p->{"snarf_machine$snarfnum"},
 975           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 976           'username'  => $p->{"snarf_username$snarfnum"},
 977           '_password' => $p->{"snarf_password$snarfnum"},
 978         } );
 979         $snarfnum++;
 980         push @acct_snarf, $acct_snarf;
 981       }
 982       $svc_x->child_objects( \@acct_snarf );
 983     }
 984
 985     my $y = $svc_x->setdefault; # arguably should be in new method
 986     return { 'error' => $y } if $y && !ref($y);
 987
 988     $error = $svc_x->check;
 989     return { 'error' => $error } if $error;
 990
 991     push @svc, $svc_x;
 992
 993   }
 994
 995   use Tie::RefHash;
 996   tie my %hash, 'Tie::RefHash';
 997   %hash = ( $cust_pkg => \@svc );
 998   #msgcat
 999   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
1000   return { 'error' => $error } if $error;
1001
1002   my $conf = new FS::Conf;
1003   if ( $conf->exists('signup_server-realtime') ) {
1004
1005     my $bill_error = _do_bop_realtime( $cust_main, $status );
1006
1007     if ($bill_error) {
1008       $cust_pkg->cancel('quiet'=>1);
1009       return $bill_error;
1010     } else {
1011       $cust_pkg->reexport;
1012     }
1013
1014   } else {
1015     $cust_pkg->reexport;
1016   }
1017
1018   return { error => '', pkgnum => $cust_pkg->pkgnum };
1019
1020 }
1021
1022 sub change_pkg {
1023   my $p = shift;
1024
1025   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1026   return { 'error' => $session } if $context eq 'error';
1027
1028   my $search = { 'custnum' => $custnum };
1029   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1030   my $cust_main = qsearchs('cust_main', $search )
1031     or return { 'error' => "unknown custnum $custnum" };
1032
1033   my $status = $cust_main->status;
1034   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
1035     or return { 'error' => "unknown package $p->{pkgnum}" };
1036
1037   my @newpkg;
1038   my $error = FS::cust_pkg::order( $custnum,
1039                                    [$p->{pkgpart}],
1040                                    [$p->{pkgnum}],
1041                                    \@newpkg,
1042                                  );
1043
1044   my $conf = new FS::Conf;
1045   if ( $conf->exists('signup_server-realtime') ) {
1046
1047     my $bill_error = _do_bop_realtime( $cust_main, $status );
1048
1049     if ($bill_error) {
1050       $newpkg[0]->suspend;
1051       return $bill_error;
1052     } else {
1053       $newpkg[0]->reexport;
1054     }
1055
1056   } else {
1057     $newpkg[0]->reexport;
1058   }
1059
1060   return { error => '', pkgnum => $cust_pkg->pkgnum };
1061
1062 }
1063
1064 sub order_recharge {
1065   my $p = shift;
1066
1067   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1068   return { 'error' => $session } if $context eq 'error';
1069
1070   my $search = { 'custnum' => $custnum };
1071   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1072   my $cust_main = qsearchs('cust_main', $search )
1073     or return { 'error' => "unknown custnum $custnum" };
1074
1075   my $status = $cust_main->status;
1076   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
1077     or return { 'error' => "unknown service " . $p->{'svcnum'} };
1078
1079   my $svc_x = $cust_svc->svc_x;
1080   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
1081
1082   my %vhash =
1083     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
1084     qw ( recharge_seconds recharge_upbytes recharge_downbytes
1085          recharge_totalbytes );
1086   my $amount = $part_pkg->option('recharge_amount', 1);
1087
1088   my ($l, $v, $d) = $cust_svc->label;  # blah
1089   my $pkg = "Recharge $v";
1090
1091   my $bill_error = $cust_main->charge($amount, $pkg,
1092      "time: $vhash{seconds}, up: $vhash{upbytes}," .
1093      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
1094      $part_pkg->taxclass); #meh
1095
1096   my $conf = new FS::Conf;
1097   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
1098
1099     $bill_error = _do_bop_realtime( $cust_main, $status );
1100
1101     if ($bill_error) {
1102       return $bill_error;
1103     } else {
1104       my $error = $svc_x->recharge (\%vhash);
1105       return { 'error' => $error } if $error;
1106     }
1107
1108   } else {
1109     my $error = $bill_error;
1110     $error ||= $svc_x->recharge (\%vhash);
1111     return { 'error' => $error } if $error;
1112   }
1113
1114   return { error => '', svc => $cust_svc->part_svc->svc };
1115
1116 }
1117
1118 sub _do_bop_realtime {
1119   my ($cust_main, $status) = (shift, shift);
1120
1121     my $old_balance = $cust_main->balance;
1122
1123     my $bill_error =    $cust_main->bill
1124                      || $cust_main->apply_payments_and_credits
1125                      || $cust_main->collect('realtime' => 1);
1126
1127     if (    $cust_main->balance > $old_balance
1128          && $cust_main->balance > 0
1129          && ( $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ?
1130               1 : $status eq 'suspended' ) ) {
1131       #this makes sense.  credit is "un-doing" the invoice
1132       my $conf = new FS::Conf;
1133       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
1134                           'self-service decline',
1135                           'reason_type' => $conf->config('signup_credit_type'),
1136                         );
1137       $cust_main->apply_credits( 'order' => 'newest' );
1138
1139       return { 'error' => '_decline', 'bill_error' => $bill_error };
1140     }
1141
1142     '';
1143 }
1144
1145 sub renew_info {
1146   my $p = shift;
1147
1148   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1149   return { 'error' => $session } if $context eq 'error';
1150
1151   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1152     or return { 'error' => "unknown custnum $custnum" };
1153
1154   my @cust_pkg = sort { $a->bill <=> $b->bill }
1155                  grep { $_->part_pkg->freq ne '0' }
1156                  $cust_main->ncancelled_pkgs;
1157
1158   #return { 'error' => 'No active packages to renew.' } unless @cust_pkg;
1159
1160   my $total = $cust_main->balance;
1161
1162   my @array = map {
1163                     $total += $_->part_pkg->base_recur;
1164                     my $renew_date = $_->part_pkg->add_freq($_->bill);
1165                     {
1166                       'pkgnum'             => $_->pkgnum,
1167                       'amount'             => sprintf('%.2f', $total),
1168                       'bill_date'          => $_->bill,
1169                       'bill_date_pretty'   => time2str('%x', $_->bill),
1170                       'renew_date'         => $renew_date,
1171                       'renew_date_pretty'  => time2str('%x', $renew_date),
1172                       'expire_date'        => $_->expire,
1173                       'expire_date_pretty' => time2str('%x', $_->expire),
1174                     };
1175                   }
1176                   @cust_pkg;
1177
1178   return { 'dates' => \@array };
1179
1180 }
1181
1182 sub payment_info_renew_info {
1183   my $p = shift;
1184   my $renew_info   = renew_info($p);
1185   my $payment_info = payment_info($p);
1186   return { %$renew_info,
1187            %$payment_info,
1188          };
1189 }
1190
1191 sub order_renew {
1192   my $p = shift;
1193
1194   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1195   return { 'error' => $session } if $context eq 'error';
1196
1197   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1198     or return { 'error' => "unknown custnum $custnum" };
1199
1200   my $date = $p->{'date'};
1201
1202   my $now = time;
1203
1204   #freeside-daily -n -d $date fs_daily $custnum
1205   $cust_main->bill_and_collect( 'time'         => $date,
1206                                 'invoice_time' => $now,
1207                                 'actual_time'  => $now,
1208                                 'check_freq'   => '1d',
1209                               );
1210
1211   return { 'error' => '' };
1212
1213 }
1214
1215 sub cancel_pkg {
1216   my $p = shift;
1217   my $session = _cache->get($p->{'session_id'})
1218     or return { 'error' => "Can't resume session" }; #better error message
1219
1220   my $custnum = $session->{'custnum'};
1221
1222   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1223     or return { 'error' => "unknown custnum $custnum" };
1224
1225   my $pkgnum = $p->{'pkgnum'};
1226
1227   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1228                                         'pkgnum'  => $pkgnum,   } )
1229     or return { 'error' => "unknown pkgnum $pkgnum" };
1230
1231   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1232   return { 'error' => $error };
1233
1234 }
1235
1236 sub provision_acct {
1237   my $p = shift;
1238   warn "provision_acct called\n"
1239     if $DEBUG;
1240
1241   return { 'error' => gettext('passwords_dont_match') }
1242     if $p->{'_password'} ne $p->{'_password2'};
1243   return { 'error' => gettext('empty_password') }
1244     unless length($p->{'_password'});
1245
1246   if ($p->{'domsvc'}) {
1247     my %domains = domain_select_hash FS::svc_acct(map { $_ => $p->{$_} }
1248                                                   qw ( svcpart pkgnum ) );
1249     return { 'error' => gettext('invalid_domain') }
1250       unless ($domains{$p->{'domsvc'}});
1251   }
1252
1253   warn "provision_acct calling _provision\n"
1254     if $DEBUG;
1255   _provision( 'FS::svc_acct',
1256               [qw(username _password domsvc)],
1257               [qw(username _password domsvc)],
1258               $p,
1259               @_
1260             );
1261 }
1262
1263 sub provision_external {
1264   my $p = shift;
1265   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1266   _provision( 'FS::svc_external',
1267               [],
1268               [qw(id title)],
1269               $p,
1270               @_
1271             );
1272 }
1273
1274 sub _provision {
1275   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1276   warn "_provision called for $class\n"
1277     if $DEBUG;
1278
1279   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1280   return { 'error' => $session } if $context eq 'error';
1281
1282   my $search = { 'custnum' => $custnum };
1283   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1284   my $cust_main = qsearchs('cust_main', $search )
1285     or return { 'error' => "unknown custnum $custnum" };
1286
1287   my $pkgnum = $p->{'pkgnum'};
1288
1289   warn "searching for custnum $custnum pkgnum $pkgnum\n"
1290     if $DEBUG;
1291   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1292                                         'pkgnum'  => $pkgnum,
1293                                                                } )
1294     or return { 'error' => "unknown pkgnum $pkgnum" };
1295
1296   warn "searching for svcpart ". $p->{'svcpart'}. "\n"
1297     if $DEBUG;
1298   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1299     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1300
1301   warn "creating $class record\n"
1302     if $DEBUG;
1303   my $svc_x = $class->new( {
1304     'pkgnum'  => $p->{'pkgnum'},
1305     'svcpart' => $p->{'svcpart'},
1306     map { $_ => $p->{$_} } @$fields
1307   } );
1308   warn "inserting $class record\n"
1309     if $DEBUG;
1310   my $error = $svc_x->insert;
1311
1312   unless ( $error ) {
1313     warn "finding inserted record for svcnum ". $svc_x->svcnum. "\n"
1314       if $DEBUG;
1315     $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1316   }
1317
1318   my $return = { 'svc'   => $part_svc->svc,
1319                  'error' => $error,
1320                  map { $_ => $svc_x->get($_) } @$return_fields
1321                };
1322   warn "_provision returning ". Dumper($return). "\n"
1323     if $DEBUG;
1324   return $return;
1325
1326 }
1327
1328 sub part_svc_info {
1329   my $p = shift;
1330
1331   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1332   return { 'error' => $session } if $context eq 'error';
1333
1334   my $search = { 'custnum' => $custnum };
1335   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1336   my $cust_main = qsearchs('cust_main', $search )
1337     or return { 'error' => "unknown custnum $custnum" };
1338
1339   my $pkgnum = $p->{'pkgnum'};
1340
1341   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1342                                         'pkgnum'  => $pkgnum,
1343                                                                } )
1344     or return { 'error' => "unknown pkgnum $pkgnum" };
1345
1346   my $svcpart = $p->{'svcpart'};
1347
1348   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1349                                       'svcpart' => $svcpart,           } )
1350     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1351   my $part_svc = $pkg_svc->part_svc;
1352
1353   my $conf = new FS::Conf;
1354
1355   return {
1356     'svc'     => $part_svc->svc,
1357     'svcdb'   => $part_svc->svcdb,
1358     'pkgnum'  => $pkgnum,
1359     'svcpart' => $svcpart,
1360     'custnum' => $custnum,
1361
1362     'security_phrase' => 0, #XXX !
1363     'svc_acct_pop'    => [], #XXX !
1364     'popnum'          => '',
1365     'init_popstate'   => '',
1366     'popac'           => '',
1367     'acstate'         => '',
1368
1369     'small_custview' =>
1370       small_custview( $cust_main, $conf->config('countrydefault') ),
1371
1372   };
1373
1374 }
1375
1376 sub unprovision_svc {
1377   my $p = shift;
1378
1379   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1380   return { 'error' => $session } if $context eq 'error';
1381
1382   my $search = { 'custnum' => $custnum };
1383   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1384   my $cust_main = qsearchs('cust_main', $search )
1385     or return { 'error' => "unknown custnum $custnum" };
1386
1387   my $svcnum = $p->{'svcnum'};
1388
1389   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1390     or return { 'error' => "unknown svcnum $svcnum" };
1391
1392   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1393     unless $cust_svc->cust_pkg->custnum == $custnum;
1394
1395   my $conf = new FS::Conf;
1396
1397   return { 'svc'   => $cust_svc->part_svc->svc,
1398            'error' => $cust_svc->cancel,
1399            'small_custview' =>
1400              small_custview( $cust_main, $conf->config('countrydefault') ),
1401          };
1402
1403 }
1404
1405 sub myaccount_passwd {
1406   my $p = shift;
1407   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1408   return { 'error' => $session } if $context eq 'error';
1409
1410   return { 'error' => "New passwords don't match." }
1411     if $p->{'new_password'} ne $p->{'new_password2'};
1412
1413   return { 'error' => 'Enter new password' }
1414     unless length($p->{'new_password'});
1415
1416   #my $search = { 'custnum' => $custnum };
1417   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1418   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1419   my $search = " AND custnum = $1";
1420   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1421
1422   my $svc_acct = qsearchs( {
1423     'table'     => 'svc_acct',
1424     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1425                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1426                    'LEFT JOIN cust_main USING ( custnum ) ',
1427     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1428     'extra_sql' => $search, #important
1429   } )
1430     or return { 'error' => "Service not found" };
1431
1432   $svc_acct->_password($p->{'new_password'});
1433   my $error = $svc_acct->replace();
1434
1435   my($label, $value) = $svc_acct->cust_svc->label;
1436
1437   return { 'error' => $error,
1438            'label' => $label,
1439            'value' => $value,
1440          };
1441
1442 }
1443
1444 #--
1445
1446 sub _custoragent_session_custnum {
1447   my $p = shift;
1448
1449   my($context, $session, $custnum);
1450   if ( $p->{'session_id'} ) {
1451
1452     $context = 'customer';
1453     $session = _cache->get($p->{'session_id'})
1454       or return ( 'error' => "Can't resume session" ); #better error message
1455     $custnum = $session->{'custnum'};
1456
1457   } elsif ( $p->{'agent_session_id'} ) {
1458
1459     $context = 'agent';
1460     my $agent_cache = new FS::ClientAPI_SessionCache( {
1461       'namespace' => 'FS::ClientAPI::Agent',
1462     } );
1463     $session = $agent_cache->get($p->{'agent_session_id'})
1464       or return ( 'error' => "Can't resume session" ); #better error message
1465     $custnum = $p->{'custnum'};
1466
1467   } else {
1468     return ( 'error' => "Can't resume session" ); #better error message
1469   }
1470
1471   ($context, $session, $custnum);
1472
1473 }
1474
1475 1;
1476