FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::UI::Web;
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14 use FS::Record qw(qsearch qsearchs);
  15 use FS::Msgcat qw(gettext);
  16 use FS::Misc qw(card_types);
  17 use FS::ClientAPI_SessionCache;
  18 use FS::svc_acct;
  19 use FS::svc_domain;
  20 use FS::svc_external;
  21 use FS::part_svc;
  22 use FS::cust_main;
  23 use FS::cust_bill;
  24 use FS::cust_main_county;
  25 use FS::cust_pkg;
  26 use FS::payby;
  27 use FS::acct_rt_transaction;
  28 use HTML::Entities;
  29
  30 #false laziness with FS::cust_main
  31 BEGIN {
  32   eval "use Time::Local;";
  33   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  34     if $] < 5.006 && !defined($Time::Local::VERSION);
  35   eval "use Time::Local qw(timelocal_nocheck);";
  36 }
  37
  38 use vars qw( @cust_main_editable_fields );
  39 @cust_main_editable_fields = qw(
  40   first last company address1 address2 city
  41     county state zip country daytime night fax
  42   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  43     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  44   payby payinfo payname paystart_month paystart_year payissue payip
  45 );
  46
  47 use subs qw(_provision);
  48
  49 sub _cache {
  50   $cache ||= new FS::ClientAPI_SessionCache( {
  51                'namespace' => 'FS::ClientAPI::MyAccount',
  52              } );
  53 }
  54
  55 #false laziness w/FS::ClientAPI::passwd::passwd
  56 sub login {
  57   my $p = shift;
  58
  59   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  60     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  61
  62   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  63                                          'domsvc'    => $svc_domain->svcnum, }
  64                          );
  65   return { error => 'User not found.' } unless $svc_acct;
  66
  67   my $conf = new FS::Conf;
  68   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  69   return { error => 'Only primary user may log in.' }
  70     if $conf->exists('selfservice_server-primary_only')
  71        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  72
  73   return { error => 'Incorrect password.' }
  74     unless $svc_acct->check_password($p->{'password'});
  75
  76   my $session = {
  77     'svcnum' => $svc_acct->svcnum,
  78   };
  79
  80   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  81   if ( $cust_pkg ) {
  82     my $cust_main = $cust_pkg->cust_main;
  83     $session->{'custnum'} = $cust_main->custnum;
  84   }
  85
  86   my $session_id;
  87   do {
  88     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  89   } until ( ! defined _cache->get($session_id) ); #just in case
  90
  91   _cache->set( $session_id, $session, '1 hour' );
  92
  93   return { 'error'      => '',
  94            'session_id' => $session_id,
  95          };
  96 }
  97
  98 sub logout {
  99   my $p = shift;
 100   if ( $p->{'session_id'} ) {
 101     _cache->remove($p->{'session_id'});
 102     return { 'error' => '' };
 103   } else {
 104     return { 'error' => "Can't resume session" }; #better error message
 105   }
 106 }
 107
 108 sub customer_info {
 109   my $p = shift;
 110
 111   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 112   return { 'error' => $session } if $context eq 'error';
 113
 114   my %return;
 115   if ( $custnum ) { #customer record
 116
 117     my $search = { 'custnum' => $custnum };
 118     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 119     my $cust_main = qsearchs('cust_main', $search )
 120       or return { 'error' => "unknown custnum $custnum" };
 121
 122     $return{balance} = $cust_main->balance;
 123
 124     $return{tickets} = [ ($cust_main->tickets) ];
 125
 126     my @open = map {
 127                      {
 128                        invnum => $_->invnum,
 129                        date   => time2str("%b %o, %Y", $_->_date),
 130                        owed   => $_->owed,
 131                      };
 132                    } $cust_main->open_cust_bill;
 133     $return{open_invoices} = \@open;
 134
 135     my $conf = new FS::Conf;
 136     $return{small_custview} =
 137       small_custview( $cust_main, $conf->config('countrydefault') );
 138
 139     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 140
 141     for (@cust_main_editable_fields) {
 142       $return{$_} = $cust_main->get($_);
 143     }
 144
 145     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 146       $return{payinfo} = $cust_main->paymask;
 147       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 148     }
 149
 150     $return{'invoicing_list'} =
 151       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 152     $return{'postal_invoicing'} =
 153       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 154
 155     if (scalar($conf->config('support_packages'))) {
 156       my @support_services = ();
 157       foreach ($cust_main->support_services) {
 158         my $seconds = $_->svc_x->seconds;
 159         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 160                              int(abs($seconds)/3600)."h".
 161                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 162         my $cust_pkg = $_->cust_pkg;
 163         my $pkgnum = '';
 164         my $pkg = '';
 165         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 166         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 167         push @support_services, { svcnum => $_->svcnum,
 168                                   time => $time_remaining,
 169                                   pkgnum => $pkgnum,
 170                                   pkg => $pkg,
 171                                 };
 172       }
 173       $return{support_services} = \@support_services;
 174     }
 175
 176   } elsif ( $session->{'svcnum'} ) { #no customer record
 177
 178     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 179       or die "unknown svcnum";
 180     $return{name} = $svc_acct->email;
 181
 182   } else {
 183
 184     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 185
 186   }
 187
 188   return { 'error'          => '',
 189            'custnum'        => $custnum,
 190            %return,
 191          };
 192
 193 }
 194
 195 sub edit_info {
 196   my $p = shift;
 197   my $session = _cache->get($p->{'session_id'})
 198     or return { 'error' => "Can't resume session" }; #better error message
 199
 200   my $custnum = $session->{'custnum'}
 201     or return { 'error' => "no customer record" };
 202
 203   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 204     or return { 'error' => "unknown custnum $custnum" };
 205
 206   my $new = new FS::cust_main { $cust_main->hash };
 207   $new->set( $_ => $p->{$_} )
 208     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 209
 210   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 211     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 212     if ( $new->payinfo eq $cust_main->paymask ) {
 213       $new->payinfo($cust_main->payinfo);
 214     } else {
 215       $new->paycvv($p->{'paycvv'});
 216     }
 217   }
 218
 219   my @invoicing_list;
 220   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 221     #false laziness with httemplate/edit/process/cust_main.cgi
 222     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 223     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 224   } else {
 225     @invoicing_list = $cust_main->invoicing_list;
 226   }
 227
 228   my $error = $new->replace($cust_main, \@invoicing_list);
 229   return { 'error' => $error } if $error;
 230   #$cust_main = $new;
 231
 232   return { 'error' => '' };
 233 }
 234
 235 sub payment_info {
 236   my $p = shift;
 237   my $session = _cache->get($p->{'session_id'})
 238     or return { 'error' => "Can't resume session" }; #better error message
 239
 240   ##
 241   #generic
 242   ##
 243
 244   use vars qw($payment_info); #cache for performance
 245   unless ( $payment_info ) {
 246
 247     my $conf = new FS::Conf;
 248     my %states = map { $_->state => 1 }
 249                    qsearch('cust_main_county', {
 250                      'country' => $conf->config('countrydefault') || 'US'
 251                    } );
 252
 253     $payment_info = {
 254
 255       #list all counties/states/countries
 256       'cust_main_county' =>
 257         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 258
 259       #shortcut for one-country folks
 260       'states' =>
 261         [ sort { $a cmp $b } keys %states ],
 262
 263       'card_types' => card_types(),
 264
 265       'paytypes' => [ @FS::cust_main::paytypes ],
 266
 267       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 268       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 269
 270       'show_ss'  => $conf->exists('show_ss'),
 271       'show_stateid' => $conf->exists('show_stateid'),
 272       'show_paystate' => $conf->exists('show_bankstate'),
 273     };
 274
 275   }
 276
 277   ##
 278   #customer-specific
 279   ##
 280
 281   my %return = %$payment_info;
 282
 283   my $custnum = $session->{'custnum'};
 284
 285   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 286     or return { 'error' => "unknown custnum $custnum" };
 287
 288   $return{balance} = $cust_main->balance;
 289
 290   $return{payname} = $cust_main->payname
 291                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 292
 293   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 294
 295   $return{payby} = $cust_main->payby;
 296   $return{stateid_state} = $cust_main->stateid_state;
 297
 298   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 299     $return{card_type} = cardtype($cust_main->payinfo);
 300     $return{payinfo} = $cust_main->payinfo;
 301
 302     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 303
 304   }
 305
 306   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 307     my ($payinfo1, $payinfo2) = split '@', $cust_main->payinfo;
 308     $return{payinfo1} = $payinfo1;
 309     $return{payinfo2} = $payinfo2;
 310     $return{paytype}  = $cust_main->paytype;
 311     $return{paystate} = $cust_main->paystate;
 312
 313   }
 314
 315   #doubleclick protection
 316   my $_date = time;
 317   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 318
 319   return { 'error' => '',
 320            %return,
 321          };
 322
 323 };
 324
 325 #some false laziness with httemplate/process/payment.cgi - look there for
 326 #ACH and CVV support stuff
 327 sub process_payment {
 328
 329   my $p = shift;
 330
 331   my $session = _cache->get($p->{'session_id'})
 332     or return { 'error' => "Can't resume session" }; #better error message
 333
 334   my %return;
 335
 336   my $custnum = $session->{'custnum'};
 337
 338   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 339     or return { 'error' => "unknown custnum $custnum" };
 340
 341   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 342     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 343   my $payname = $1;
 344
 345   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 346     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 347   my $paybatch = $1;
 348
 349   $p->{'payby'} =~ /^([A-Z]{4})$/
 350     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 351   my $payby = $1;
 352
 353   my $payinfo;
 354   my $paycvv = '';
 355   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 356
 357     $p->{'payinfo1'} =~ /^(\d+)$/
 358       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 359     my $payinfo1 = $1;
 360      $p->{'payinfo2'} =~ /^(\d+)$/
 361       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 362     my $payinfo2 = $1;
 363     $payinfo = $payinfo1. '@'. $payinfo2;
 364
 365   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 366
 367     $payinfo = $p->{'payinfo'};
 368     $payinfo =~ s/\D//g;
 369     $payinfo =~ /^(\d{13,16})$/
 370       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 371     $payinfo = $1;
 372     validate($payinfo)
 373       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 374     return { 'error' => gettext('unknown_card_type') }
 375       if cardtype($payinfo) eq "Unknown";
 376
 377     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 378       if ( cardtype($payinfo) eq 'American Express card' ) {
 379         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 380           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 381         $paycvv = $1;
 382       } else {
 383         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 384           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 385         $paycvv = $1;
 386       }
 387     }
 388
 389   } else {
 390     die "unknown payby $payby";
 391   }
 392
 393   my %payby2fields = (
 394     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 395     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 396   );
 397
 398   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 399     'quiet'    => 1,
 400     'payinfo'  => $payinfo,
 401     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 402     'payname'  => $payname,
 403     'paybatch' => $paybatch,
 404     'paycvv'   => $paycvv,
 405     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 406   );
 407   return { 'error' => $error } if $error;
 408
 409   $cust_main->apply_payments;
 410
 411   if ( $p->{'save'} ) {
 412     my $new = new FS::cust_main { $cust_main->hash };
 413     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 414       $new->set( $_ => $p->{$_} )
 415         foreach qw( payname paystart_month paystart_year payissue payip
 416                     address1 address2 city state zip payinfo );
 417       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 418     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 419       $new->set( $_ => $p->{$_} )
 420         foreach qw( payname payip paytype paystate
 421                     stateid stateid_state );
 422       $new->set( 'payinfo' => $payinfo );
 423       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 424     }
 425     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 426     my $error = $new->replace($cust_main);
 427     return { 'error' => $error } if $error;
 428     $cust_main = $new;
 429   }
 430
 431   return { 'error' => '' };
 432
 433 }
 434
 435 sub process_prepay {
 436
 437   my $p = shift;
 438
 439   my $session = _cache->get($p->{'session_id'})
 440     or return { 'error' => "Can't resume session" }; #better error message
 441
 442   my %return;
 443
 444   my $custnum = $session->{'custnum'};
 445
 446   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 447     or return { 'error' => "unknown custnum $custnum" };
 448
 449   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 450   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 451                                            \$amount,
 452                                            \$seconds,
 453                                            \$upbytes,
 454                                            \$downbytes,
 455                                            \$totalbytes,
 456                                          );
 457
 458   return { 'error' => $error } if $error;
 459
 460   return { 'error'     => '',
 461            'amount'    => $amount,
 462            'seconds'   => $seconds,
 463            'duration'  => duration_exact($seconds),
 464            'upbytes'   => $upbytes,
 465            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 466            'downbytes' => $downbytes,
 467            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 468            'totalbytes'=> $totalbytes,
 469            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 470          };
 471
 472 }
 473
 474 sub invoice {
 475   my $p = shift;
 476   my $session = _cache->get($p->{'session_id'})
 477     or return { 'error' => "Can't resume session" }; #better error message
 478
 479   my $custnum = $session->{'custnum'};
 480
 481   my $invnum = $p->{'invnum'};
 482
 483   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 484                                           'custnum' => $custnum } )
 485     or return { 'error' => "Can't find invnum" };
 486
 487   #my %return;
 488
 489   return { 'error'        => '',
 490            'invnum'       => $invnum,
 491            'invoice_text' => join('', $cust_bill->print_text ),
 492            'invoice_html' => $cust_bill->print_html,
 493          };
 494
 495 }
 496
 497 sub invoice_logo {
 498   my $p = shift;
 499
 500   #sessioning for this?  how do we get the session id to the backend invoice
 501   # template so it can add it to the link, blah
 502
 503   my $templatename = $p->{'templatename'};
 504
 505   #false laziness-ish w/view/cust_bill-logo.cgi
 506
 507   my $conf = new FS::Conf;
 508   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 509     $templatename = "_$1";
 510   } else {
 511     $templatename = '';
 512   }
 513
 514   my $filename = "logo$templatename.png";
 515
 516   return { 'error'        => '',
 517            'logo'         => $conf->config_binary($filename),
 518            'content_type' => 'image/png', #should allow gif, jpg too
 519          };
 520 }
 521
 522
 523 sub list_invoices {
 524   my $p = shift;
 525   my $session = _cache->get($p->{'session_id'})
 526     or return { 'error' => "Can't resume session" }; #better error message
 527
 528   my $custnum = $session->{'custnum'};
 529
 530   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 531     or return { 'error' => "unknown custnum $custnum" };
 532
 533   my @cust_bill = $cust_main->cust_bill;
 534
 535   return  { 'error'       => '',
 536             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 537                                         '_date'  => $_->_date,
 538                                       }
 539                                     } @cust_bill
 540                               ]
 541           };
 542 }
 543
 544 sub cancel {
 545   my $p = shift;
 546   my $session = _cache->get($p->{'session_id'})
 547     or return { 'error' => "Can't resume session" }; #better error message
 548
 549   my $custnum = $session->{'custnum'};
 550
 551   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 552     or return { 'error' => "unknown custnum $custnum" };
 553
 554   my @errors = $cust_main->cancel( 'quiet'=>1 );
 555
 556   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 557
 558   return { 'error' => $error };
 559
 560 }
 561
 562 sub list_pkgs {
 563   my $p = shift;
 564
 565   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 566   return { 'error' => $session } if $context eq 'error';
 567
 568   my $search = { 'custnum' => $custnum };
 569   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 570   my $cust_main = qsearchs('cust_main', $search )
 571     or return { 'error' => "unknown custnum $custnum" };
 572
 573   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 574
 575   my $conf = new FS::Conf;
 576
 577   { 'svcnum'   => $session->{'svcnum'},
 578     'custnum'  => $custnum,
 579     'cust_pkg' => [ map {
 580                           { $_->hash,
 581                             $_->part_pkg->hash,
 582                             part_svc =>
 583                               [ map $_->hashref, $_->available_part_svc ],
 584                             cust_svc =>
 585                               [ map { my $ref = { $_->hash,
 586                                                   label => [ $_->label ],
 587                                                 };
 588                                       $ref->{_password} = $_->svc_x->_password
 589                                         if $context eq 'agent'
 590                                         && $conf->exists('agent-showpasswords')
 591                                         && $_->part_svc->svcdb eq 'svc_acct';
 592                                       $ref;
 593                                     } $_->cust_svc
 594                               ],
 595                           };
 596                         } $cust_main->ncancelled_pkgs
 597                   ],
 598     'small_custview' =>
 599       small_custview( $cust_main, $conf->config('countrydefault') ),
 600   };
 601
 602 }
 603
 604 sub list_svcs {
 605   my $p = shift;
 606
 607   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 608   return { 'error' => $session } if $context eq 'error';
 609
 610   my $search = { 'custnum' => $custnum };
 611   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 612   my $cust_main = qsearchs('cust_main', $search )
 613     or return { 'error' => "unknown custnum $custnum" };
 614
 615   my @cust_svc = ();
 616   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 617   foreach my $cust_pkg ( $p->{'ncancelled'}
 618                          ? $cust_main->ncancelled_pkgs
 619                          : $cust_main->unsuspended_pkgs ) {
 620     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 621   }
 622   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 623     if $p->{'svcdb'};
 624
 625   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 626   #              @svc_x;
 627
 628   {
 629     #no#'svcnum'   => $session->{'svcnum'},
 630     'custnum'  => $custnum,
 631     'svcs'     => [ map {
 632                           my $svc_x = $_->svc_x;
 633                           my($label, $value) = $_->label;
 634                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 635
 636                           { 'svcnum'    => $_->svcnum,
 637                             'label'     => $label,
 638                             'value'     => $value,
 639                             'username'  => $svc_x->username,
 640                             'email'     => $svc_x->email,
 641                             'seconds'   => $svc_x->seconds,
 642                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 643                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 644                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 645                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 646                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 647                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 648                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 649                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 650                             # more...
 651                           };
 652                         }
 653                         @cust_svc
 654                   ],
 655   };
 656
 657 }
 658
 659 sub _list_svc_usage {
 660   my($svc_acct, $begin, $end) = @_;
 661   my @usage = ();
 662   foreach my $part_export (
 663     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 664     qw (sqlradius sqlradius_withdomain')
 665   ) {
 666
 667     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
 668   }
 669   (@usage);
 670 }
 671
 672 sub list_svc_usage {
 673   _usage_details(\&_list_svc_usage, @_);
 674 }
 675
 676 sub _list_support_usage {
 677   my($svc_acct, $begin, $end) = @_;
 678   my @usage = ();
 679   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
 680             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
 681           ) {
 682     push @usage, { 'seconds'  => $_->seconds,
 683                    'support'  => $_->support,
 684                    '_date'    => $_->_date,
 685                    'id'       => $_->transaction_id,
 686                    'creator'  => $_->creator,
 687                    'subject'  => $_->subject,
 688                    'status'   => $_->status,
 689                    'ticketid' => $_->ticketid,
 690                  };
 691   }
 692   (@usage);
 693 }
 694
 695 sub list_support_usage {
 696   _usage_details(\&_list_support_usage, @_);
 697 }
 698
 699 sub _usage_details {
 700   my ($callback, $p) = (shift,shift);
 701
 702   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 703   return { 'error' => $session } if $context eq 'error';
 704
 705   my $search = { 'svcnum' => $p->{'svcnum'} };
 706   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 707   my $svc_acct = qsearchs ( 'svc_acct', $search );
 708   return { 'error' => 'No service selected in list_svc_usage' }
 709     unless $svc_acct;
 710
 711   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 712   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 713   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 714   my $end    = time;
 715
 716   unless($p->{beginning}){
 717     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 718     $p->{ending} = $end;
 719   }
 720
 721   my (@usage) = &$callback($svc_acct,$p->{beginning},$p->{ending});
 722
 723   #kinda false laziness with FS::cust_main::bill, but perhaps
 724   #we should really change this bit to DateTime and DateTime::Duration
 725   #
 726   #change this bit to use Date::Manip? CAREFUL with timezones (see
 727   # mailing list archive)
 728   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 729     (localtime($p->{ending}) )[0,1,2,3,4,5];
 730   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 731     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 732
 733   if ( $freq =~ /^\d+$/ ) {
 734     $nmon += $freq;
 735     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 736     $pmon -= $freq;
 737     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 738   } elsif ( $freq =~ /^(\d+)w$/ ) {
 739     my $weeks = $1;
 740     $nmday += $weeks * 7;
 741     $pmday -= $weeks * 7;
 742   } elsif ( $freq =~ /^(\d+)d$/ ) {
 743     my $days = $1;
 744     $nmday += $days;
 745     $pmday -= $days;
 746   } elsif ( $freq =~ /^(\d+)h$/ ) {
 747     my $hours = $1;
 748     $nhour += $hours;
 749     $phour -= $hours;
 750   } else {
 751     return { 'error' => "unparsable frequency: ". $freq };
 752   }
 753
 754   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 755   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 756
 757   {
 758     'error'     => '',
 759     'svcnum'    => $p->{svcnum},
 760     'beginning' => $p->{beginning},
 761     'ending'    => $p->{ending},
 762     'previous'  => ($previous > $start) ? $previous : $start,
 763     'next'      => ($next < $end) ? $next : $end,
 764     'usage'     => \@usage,
 765   };
 766 }
 767
 768 sub order_pkg {
 769   my $p = shift;
 770
 771   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 772   return { 'error' => $session } if $context eq 'error';
 773
 774   my $search = { 'custnum' => $custnum };
 775   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 776   my $cust_main = qsearchs('cust_main', $search )
 777     or return { 'error' => "unknown custnum $custnum" };
 778
 779   #false laziness w/ClientAPI/Signup.pm
 780
 781   my $cust_pkg = new FS::cust_pkg ( {
 782     'custnum' => $custnum,
 783     'pkgpart' => $p->{'pkgpart'},
 784   } );
 785   my $error = $cust_pkg->check;
 786   return { 'error' => $error } if $error;
 787
 788   my @svc = ();
 789   unless ( $p->{'svcpart'} eq 'none' ) {
 790
 791     my $svcdb;
 792     my $svcpart = '';
 793     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 794       $svcpart = $1;
 795       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 796       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 797       $svcdb = $part_svc->svcdb;
 798     } else {
 799       $svcdb = 'svc_acct';
 800     }
 801     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 802
 803     my %fields = (
 804       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 805       'svc_domain'   => [ qw( domain ) ],
 806       'svc_external' => [ qw( id title ) ],
 807     );
 808
 809     my $svc_x = "FS::$svcdb"->new( {
 810       'svcpart'   => $svcpart,
 811       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 812     } );
 813
 814     if ( $svcdb eq 'svc_acct' ) {
 815       my @acct_snarf;
 816       my $snarfnum = 1;
 817       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 818         my $acct_snarf = new FS::acct_snarf ( {
 819           'machine'   => $p->{"snarf_machine$snarfnum"},
 820           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 821           'username'  => $p->{"snarf_username$snarfnum"},
 822           '_password' => $p->{"snarf_password$snarfnum"},
 823         } );
 824         $snarfnum++;
 825         push @acct_snarf, $acct_snarf;
 826       }
 827       $svc_x->child_objects( \@acct_snarf );
 828     }
 829
 830     my $y = $svc_x->setdefault; # arguably should be in new method
 831     return { 'error' => $y } if $y && !ref($y);
 832
 833     $error = $svc_x->check;
 834     return { 'error' => $error } if $error;
 835
 836     push @svc, $svc_x;
 837
 838   }
 839
 840   use Tie::RefHash;
 841   tie my %hash, 'Tie::RefHash';
 842   %hash = ( $cust_pkg => \@svc );
 843   #msgcat
 844   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 845   return { 'error' => $error } if $error;
 846
 847   my $conf = new FS::Conf;
 848   if ( $conf->exists('signup_server-realtime') ) {
 849
 850     my $bill_error = _do_bop_realtime( $cust_main );
 851
 852     if ($bill_error) {
 853       $cust_pkg->cancel('quiet'=>1);
 854       return $bill_error;
 855     } else {
 856       $cust_pkg->reexport;
 857     }
 858
 859   } else {
 860     $cust_pkg->reexport;
 861   }
 862
 863   return { error => '', pkgnum => $cust_pkg->pkgnum };
 864
 865 }
 866
 867 sub change_pkg {
 868   my $p = shift;
 869
 870   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 871   return { 'error' => $session } if $context eq 'error';
 872
 873   my $search = { 'custnum' => $custnum };
 874   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 875   my $cust_main = qsearchs('cust_main', $search )
 876     or return { 'error' => "unknown custnum $custnum" };
 877
 878   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 879     or return { 'error' => "unknown package $p->{pkgnum}" };
 880
 881   my @newpkg;
 882   my $error = FS::cust_pkg::order( $custnum,
 883                                    [$p->{pkgpart}],
 884                                    [$p->{pkgnum}],
 885                                    \@newpkg,
 886                                  );
 887
 888   my $conf = new FS::Conf;
 889   if ( $conf->exists('signup_server-realtime') ) {
 890
 891     my $bill_error = _do_bop_realtime( $cust_main );
 892
 893     if ($bill_error) {
 894       $newpkg[0]->suspend;
 895       return $bill_error;
 896     } else {
 897       $newpkg[0]->reexport;
 898     }
 899
 900   } else {
 901     $newpkg[0]->reexport;
 902   }
 903
 904   return { error => '', pkgnum => $cust_pkg->pkgnum };
 905
 906 }
 907
 908 sub order_recharge {
 909   my $p = shift;
 910
 911   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 912   return { 'error' => $session } if $context eq 'error';
 913
 914   my $search = { 'custnum' => $custnum };
 915   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 916   my $cust_main = qsearchs('cust_main', $search )
 917     or return { 'error' => "unknown custnum $custnum" };
 918
 919   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 920     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 921
 922   my $svc_x = $cust_svc->svc_x;
 923   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 924
 925   my %vhash =
 926     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 927     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 928          recharge_totalbytes );
 929   my $amount = $part_pkg->option('recharge_amount', 1);
 930
 931   my ($l, $v, $d) = $cust_svc->label;  # blah
 932   my $pkg = "Recharge $v";
 933
 934   my $bill_error = $cust_main->charge($amount, $pkg,
 935      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 936      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 937      $part_pkg->taxclass); #meh
 938
 939   my $conf = new FS::Conf;
 940   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 941
 942     $bill_error = _do_bop_realtime( $cust_main );
 943
 944     if ($bill_error) {
 945       return $bill_error;
 946     } else {
 947       my $error = $svc_x->recharge (\%vhash);
 948       return { 'error' => $error } if $error;
 949     }
 950
 951   } else {
 952     my $error = $bill_error;
 953     $error ||= $svc_x->recharge (\%vhash);
 954     return { 'error' => $error } if $error;
 955   }
 956
 957   return { error => '', svc => $cust_svc->part_svc->svc };
 958
 959 }
 960
 961 sub _do_bop_realtime {
 962   my ($cust_main) = @_;
 963
 964     my $old_balance = $cust_main->balance;
 965
 966     my $bill_error =    $cust_main->bill
 967                      || $cust_main->apply_payments_and_credits
 968                      || $cust_main->collect('realtime' => 1);
 969
 970     if (    $cust_main->balance > $old_balance
 971          && $cust_main->balance > 0
 972          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 973       #this makes sense.  credit is "un-doing" the invoice
 974       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 975                           'self-service decline' );
 976       $cust_main->apply_credits( 'order' => 'newest' );
 977
 978       return { 'error' => '_decline', 'bill_error' => $bill_error };
 979     }
 980
 981     '';
 982 }
 983
 984 sub cancel_pkg {
 985   my $p = shift;
 986   my $session = _cache->get($p->{'session_id'})
 987     or return { 'error' => "Can't resume session" }; #better error message
 988
 989   my $custnum = $session->{'custnum'};
 990
 991   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 992     or return { 'error' => "unknown custnum $custnum" };
 993
 994   my $pkgnum = $p->{'pkgnum'};
 995
 996   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 997                                         'pkgnum'  => $pkgnum,   } )
 998     or return { 'error' => "unknown pkgnum $pkgnum" };
 999
1000   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1001   return { 'error' => $error };
1002
1003 }
1004
1005 sub provision_acct {
1006   my $p = shift;
1007
1008   return { 'error' => gettext('passwords_dont_match') }
1009     if $p->{'_password'} ne $p->{'_password2'};
1010   return { 'error' => gettext('empty_password') }
1011     unless length($p->{'_password'});
1012
1013   _provision( 'FS::svc_acct',
1014               [qw(username _password)],
1015               [qw(username _password)],
1016               $p,
1017               @_
1018             );
1019 }
1020
1021 sub provision_external {
1022   my $p = shift;
1023   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1024   _provision( 'FS::svc_external',
1025               [],
1026               [qw(id title)],
1027               $p,
1028               @_
1029             );
1030 }
1031
1032 sub _provision {
1033   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1034
1035   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1036   return { 'error' => $session } if $context eq 'error';
1037
1038   my $search = { 'custnum' => $custnum };
1039   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1040   my $cust_main = qsearchs('cust_main', $search )
1041     or return { 'error' => "unknown custnum $custnum" };
1042
1043   my $pkgnum = $p->{'pkgnum'};
1044
1045   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1046                                         'pkgnum'  => $pkgnum,
1047                                                                } )
1048     or return { 'error' => "unknown pkgnum $pkgnum" };
1049
1050   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1051     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1052
1053   my $svc_x = $class->new( {
1054     'pkgnum'  => $p->{'pkgnum'},
1055     'svcpart' => $p->{'svcpart'},
1056     map { $_ => $p->{$_} } @$fields
1057   } );
1058   my $error = $svc_x->insert;
1059   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1060     unless $error;
1061
1062   return { 'svc'   => $part_svc->svc,
1063            'error' => $error,
1064            map { $_ => $svc_x->get($_) } @$return_fields
1065          };
1066
1067 }
1068
1069 sub part_svc_info {
1070   my $p = shift;
1071
1072   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1073   return { 'error' => $session } if $context eq 'error';
1074
1075   my $search = { 'custnum' => $custnum };
1076   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1077   my $cust_main = qsearchs('cust_main', $search )
1078     or return { 'error' => "unknown custnum $custnum" };
1079
1080   my $pkgnum = $p->{'pkgnum'};
1081
1082   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1083                                         'pkgnum'  => $pkgnum,
1084                                                                } )
1085     or return { 'error' => "unknown pkgnum $pkgnum" };
1086
1087   my $svcpart = $p->{'svcpart'};
1088
1089   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1090                                       'svcpart' => $svcpart,           } )
1091     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1092   my $part_svc = $pkg_svc->part_svc;
1093
1094   my $conf = new FS::Conf;
1095
1096   return {
1097     'svc'     => $part_svc->svc,
1098     'svcdb'   => $part_svc->svcdb,
1099     'pkgnum'  => $pkgnum,
1100     'svcpart' => $svcpart,
1101     'custnum' => $custnum,
1102
1103     'security_phrase' => 0, #XXX !
1104     'svc_acct_pop'    => [], #XXX !
1105     'popnum'          => '',
1106     'init_popstate'   => '',
1107     'popac'           => '',
1108     'acstate'         => '',
1109
1110     'small_custview' =>
1111       small_custview( $cust_main, $conf->config('countrydefault') ),
1112
1113   };
1114
1115 }
1116
1117 sub unprovision_svc {
1118   my $p = shift;
1119
1120   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1121   return { 'error' => $session } if $context eq 'error';
1122
1123   my $search = { 'custnum' => $custnum };
1124   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1125   my $cust_main = qsearchs('cust_main', $search )
1126     or return { 'error' => "unknown custnum $custnum" };
1127
1128   my $svcnum = $p->{'svcnum'};
1129
1130   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1131     or return { 'error' => "unknown svcnum $svcnum" };
1132
1133   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1134     unless $cust_svc->cust_pkg->custnum == $custnum;
1135
1136   my $conf = new FS::Conf;
1137
1138   return { 'svc'   => $cust_svc->part_svc->svc,
1139            'error' => $cust_svc->cancel,
1140            'small_custview' =>
1141              small_custview( $cust_main, $conf->config('countrydefault') ),
1142          };
1143
1144 }
1145
1146 sub myaccount_passwd {
1147   my $p = shift;
1148   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1149   return { 'error' => $session } if $context eq 'error';
1150
1151   return { 'error' => "New passwords don't match." }
1152     if $p->{'new_password'} ne $p->{'new_password2'};
1153
1154   return { 'error' => 'Enter new password' }
1155     unless length($p->{'new_password'});
1156
1157   #my $search = { 'custnum' => $custnum };
1158   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1159   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1160   my $search = " AND custnum = $1";
1161   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1162
1163   my $svc_acct = qsearchs( {
1164     'table'     => 'svc_acct',
1165     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1166                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1167                    'LEFT JOIN cust_main USING ( custnum ) ',
1168     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1169     'extra_sql' => $search, #important
1170   } )
1171     or return { 'error' => "Service not found" };
1172
1173   $svc_acct->_password($p->{'new_password'});
1174   my $error = $svc_acct->replace();
1175
1176   my($label, $value) = $svc_acct->cust_svc->label;
1177
1178   return { 'error' => $error,
1179            'label' => $label,
1180            'value' => $value,
1181          };
1182
1183 }
1184
1185 #--
1186
1187 sub _custoragent_session_custnum {
1188   my $p = shift;
1189
1190   my($context, $session, $custnum);
1191   if ( $p->{'session_id'} ) {
1192
1193     $context = 'customer';
1194     $session = _cache->get($p->{'session_id'})
1195       or return ( 'error' => "Can't resume session" ); #better error message
1196     $custnum = $session->{'custnum'};
1197
1198   } elsif ( $p->{'agent_session_id'} ) {
1199
1200     $context = 'agent';
1201     my $agent_cache = new FS::ClientAPI_SessionCache( {
1202       'namespace' => 'FS::ClientAPI::Agent',
1203     } );
1204     $session = $agent_cache->get($p->{'agent_session_id'})
1205       or return ( 'error' => "Can't resume session" ); #better error message
1206     $custnum = $p->{'custnum'};
1207
1208   } else {
1209     return ( 'error' => "Can't resume session" ); #better error message
1210   }
1211
1212   ($context, $session, $custnum);
1213
1214 }
1215
1216 1;
1217