FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw( $cache $DEBUG $me );
   5 use subs qw( _cache _provision );
   6 use Data::Dumper;
   7 use Digest::MD5 qw(md5_hex);
   8 use Date::Format;
   9 use Business::CreditCard;
  10 use Time::Duration;
  11 use FS::UI::Web::small_custview qw(small_custview); #less doh
  12 use FS::UI::Web;
  13 use FS::UI::bytecount qw( display_bytecount );
  14 use FS::Conf;
  15 #use FS::UID qw(dbh);
  16 use FS::Record qw(qsearch qsearchs dbh);
  17 use FS::Msgcat qw(gettext);
  18 use FS::Misc qw(card_types);
  19 use FS::ClientAPI_SessionCache;
  20 use FS::svc_acct;
  21 use FS::svc_domain;
  22 use FS::svc_phone;
  23 use FS::svc_external;
  24 use FS::part_svc;
  25 use FS::cust_main;
  26 use FS::cust_bill;
  27 use FS::cust_main_county;
  28 use FS::cust_pkg;
  29 use FS::payby;
  30 use FS::acct_rt_transaction;
  31 use HTML::Entities;
  32
  33 $DEBUG = 2;
  34 $me = '[FS::ClientAPI::MyAccount]';
  35
  36 #false laziness with FS::cust_main
  37 BEGIN {
  38   eval "use Time::Local;";
  39   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  40     if $] < 5.006 && !defined($Time::Local::VERSION);
  41   eval "use Time::Local qw(timelocal_nocheck);";
  42 }
  43
  44 use vars qw( @cust_main_editable_fields );
  45 @cust_main_editable_fields = qw(
  46   first last company address1 address2 city
  47     county state zip country daytime night fax
  48   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  49     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  50   payby payinfo payname paystart_month paystart_year payissue payip
  51   ss paytype paystate stateid stateid_state
  52 );
  53
  54 sub _cache {
  55   $cache ||= new FS::ClientAPI_SessionCache( {
  56                'namespace' => 'FS::ClientAPI::MyAccount',
  57              } );
  58 }
  59
  60 sub skin_info {
  61   my $p = shift;
  62
  63   my($context, $session, $custnum) = _custoragent_session_custnum($p);
  64   #return { 'error' => $session } if $context eq 'error';
  65
  66   my $agentnum = '';
  67   if ( $context eq 'customer' ) {
  68
  69     my $sth = dbh->prepare('SELECT agentnum FROM cust_main WHERE custnum = ?')
  70       or die dbh->errstr;
  71
  72     $sth->execute($custnum) or die $sth->errstr;
  73
  74     $agentnum = $sth->fetchrow_arrayref->[0]
  75       or die "no agentnum for custnum $custnum";
  76
  77   #} elsif ( $context eq 'agent' ) {
  78   } elsif ( $p->{'agentnum'} =~ /^(\d+)$/ ) {
  79     $agentnum = $1;
  80   }
  81
  82   my $conf = new FS::Conf;
  83
  84   #false laziness w/Signup.pm
  85
  86   my $skin_info_cache_agent = _cache->get("skin_info_cache_agent$agentnum");
  87
  88   if ( $skin_info_cache_agent ) {
  89
  90     warn "$me loading cached skin info for agentnum $agentnum\n"
  91       if $DEBUG > 1;
  92
  93   } else {
  94
  95     warn "$me populating skin info cache for agentnum $agentnum\n"
  96       if $DEBUG > 1;
  97
  98     $skin_info_cache_agent = {
  99       'agentnum' => $agentnum,
 100       ( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 101         qw( company_name ) ),
 102       ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 103         qw( body_bgcolor box_bgcolor
 104             text_color link_color vlink_color hlink_color alink_color
 105             font title_color title_align title_size menu_bgcolor menu_fontsize
 106           )
 107       ),
 108       ( map { $_ => $conf->exists("selfservice-$_", $agentnum ) }
 109         qw( menu_skipblanks menu_skipheadings menu_nounderline )
 110       ),
 111       ( map { $_ => scalar($conf->config_binary("selfservice-$_", $agentnum)) }
 112         qw( title_left_image title_right_image
 113             menu_top_image menu_body_image menu_bottom_image
 114           )
 115       ),
 116       'logo' => scalar($conf->config_binary('logo.png', $agentnum )),
 117       ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 118         qw( head body_header body_footer company_address ) ),
 119     };
 120
 121     _cache->set("skin_info_cache_agent$agentnum", $skin_info_cache_agent);
 122
 123   }
 124
 125   #{ %$skin_info_cache_agent };
 126   $skin_info_cache_agent;
 127
 128 }
 129
 130 sub login_info {
 131   my $p = shift;
 132
 133   my $conf = new FS::Conf;
 134
 135   my %info = (
 136     %{ skin_info($p) },
 137     'phone_login'  => $conf->exists('selfservice_server-phone_login'),
 138     'single_domain'=> scalar($conf->config('selfservice_server-single_domain')),
 139   );
 140
 141   return \%info;
 142
 143 }
 144
 145 #false laziness w/FS::ClientAPI::passwd::passwd
 146 sub login {
 147   my $p = shift;
 148
 149   my $conf = new FS::Conf;
 150
 151   my $svc_x = '';
 152   if ( $p->{'domain'} eq 'svc_phone'
 153        && $conf->exists('selfservice_server-phone_login') ) {
 154
 155     my $svc_phone = qsearchs( 'svc_phone', { 'phonenum' => $p->{'username'} } );
 156     return { error => 'Number not found.' } unless $svc_phone;
 157
 158     #XXX?
 159     #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 160     #return { error => 'Only primary user may log in.' }
 161     #  if $conf->exists('selfservice_server-primary_only')
 162     #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 163
 164     return { error => 'Incorrect PIN.' }
 165       unless $svc_phone->check_pin($p->{'password'});
 166
 167     $svc_x = $svc_phone;
 168
 169   } else {
 170
 171     my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
 172       or return { error => 'Domain '. $p->{'domain'}. ' not found' };
 173
 174     my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
 175                                            'domsvc'    => $svc_domain->svcnum, }
 176                            );
 177     return { error => 'User not found.' } unless $svc_acct;
 178
 179     return { error => 'Incorrect password.' }
 180       unless $svc_acct->check_password($p->{'password'});
 181
 182     $svc_x = $svc_acct;
 183
 184   }
 185
 186   my $session = {
 187     'svcnum' => $svc_x->svcnum,
 188   };
 189
 190   my $cust_svc = $svc_x->cust_svc;
 191   my $cust_pkg = $cust_svc->cust_pkg;
 192   if ( $cust_pkg ) {
 193     my $cust_main = $cust_pkg->cust_main;
 194     $session->{'custnum'} = $cust_main->custnum;
 195     if ( $conf->exists('pkg-balances') ) {
 196       my @cust_pkg = grep { $_->part_pkg->freq !~ /^(0|$)/ }
 197                           $cust_main->ncancelled_pkgs;
 198       $session->{'pkgnum'} = $cust_pkg->pkgnum
 199         if scalar(@cust_pkg) > 1;
 200     }
 201   }
 202
 203   #my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
 204   #return { error => 'Only primary user may log in.' }
 205   #  if $conf->exists('selfservice_server-primary_only')
 206   #    && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
 207   my $part_pkg = $cust_pkg->part_pkg;
 208   return { error => 'Only primary user may log in.' }
 209     if $conf->exists('selfservice_server-primary_only')
 210        && $cust_svc->svcpart != $part_pkg->svcpart([qw( svc_acct svc_phone )]);
 211
 212   my $session_id;
 213   do {
 214     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
 215   } until ( ! defined _cache->get($session_id) ); #just in case
 216
 217   my $timeout = $conf->config('selfservice-session_timeout') || '1 hour';
 218   _cache->set( $session_id, $session, $timeout );
 219
 220   return { 'error'      => '',
 221            'session_id' => $session_id,
 222          };
 223 }
 224
 225 sub logout {
 226   my $p = shift;
 227   if ( $p->{'session_id'} ) {
 228     _cache->remove($p->{'session_id'});
 229     return { %{ skin_info($p) }, 'error' => '' };
 230   } else {
 231     return { %{ skin_info($p) }, 'error' => "Can't resume session" }; #better error message
 232   }
 233 }
 234
 235 sub access_info {
 236   my $p = shift;
 237
 238   my $conf = new FS::Conf;
 239
 240   my $info = skin_info($p);
 241
 242   use vars qw( $cust_paybys ); #cache for performance
 243   unless ( $cust_paybys ) {
 244
 245     my %cust_paybys = map { $_ => 1 }
 246                       map { FS::payby->payby2payment($_) }
 247                           $conf->config('signup_server-payby');
 248
 249     $cust_paybys = [ keys %cust_paybys ];
 250
 251   }
 252   $info->{'cust_paybys'} = $cust_paybys;
 253
 254   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 255   return { 'error' => $session } if $context eq 'error';
 256
 257   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 258     or return { 'error' => "unknown custnum $custnum" };
 259
 260   $info->{hide_payment_fields} =
 261   [
 262     map { my $pg = '';
 263           if ( FS::payby->realtime($_) ) {
 264             $pg = $cust_main->agent->payment_gateway(
 265               'method'  => FS::payby->payby2bop($_),
 266               'nofatal' => 1,
 267             );
 268           }
 269           $pg && $pg->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 270         }
 271     @{ $info->{cust_paybys} }
 272   ];
 273
 274   return { %$info,
 275            'custnum'       => $custnum,
 276            'access_pkgnum' => $session->{'pkgnum'},
 277            'access_svcnum' => $session->{'svcnum'},
 278          };
 279 }
 280
 281 sub customer_info {
 282   my $p = shift;
 283
 284   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 285   return { 'error' => $session } if $context eq 'error';
 286
 287   my %return;
 288
 289   my $conf = new FS::Conf;
 290   if ($conf->exists('cust_main-require_address2')) {
 291     $return{'require_address2'} = '1';
 292   }else{
 293     $return{'require_address2'} = '';
 294   }
 295
 296   if ( $custnum ) { #customer record
 297
 298     my $search = { 'custnum' => $custnum };
 299     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 300     my $cust_main = qsearchs('cust_main', $search )
 301       or return { 'error' => "unknown custnum $custnum" };
 302
 303     if ( $session->{'pkgnum'} ) {
 304       $return{balance} = $cust_main->balance_pkgnum( $session->{'pkgnum'} );
 305     } else {
 306       $return{balance} = $cust_main->balance;
 307     }
 308
 309     $return{tickets} = [ ($cust_main->tickets) ];
 310
 311     unless ( $session->{'pkgnum'} ) {
 312       my @open = map {
 313                        {
 314                          invnum => $_->invnum,
 315                          date   => time2str("%b %o, %Y", $_->_date),
 316                          owed   => $_->owed,
 317                        };
 318                      } $cust_main->open_cust_bill;
 319       $return{open_invoices} = \@open;
 320     }
 321
 322     $return{small_custview} =
 323       small_custview( $cust_main,
 324                       scalar($conf->config('countrydefault')),
 325                       ( $session->{'pkgnum'} ? 1 : 0 ), #nobalance
 326                     );
 327
 328     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 329
 330     for (@cust_main_editable_fields) {
 331       $return{$_} = $cust_main->get($_);
 332     }
 333
 334     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 335       $return{payinfo} = $cust_main->paymask;
 336       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 337     }
 338
 339     $return{'invoicing_list'} =
 340       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 341     $return{'postal_invoicing'} =
 342       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 343
 344     if (scalar($conf->config('support_packages'))) {
 345       my @support_services = ();
 346       foreach ($cust_main->support_services) {
 347         my $seconds = $_->svc_x->seconds;
 348         my $time_remaining = (($seconds < 0) ? '-' : '' ).
 349                              int(abs($seconds)/3600)."h".
 350                              sprintf("%02d",(abs($seconds)%3600)/60)."m";
 351         my $cust_pkg = $_->cust_pkg;
 352         my $pkgnum = '';
 353         my $pkg = '';
 354         $pkgnum = $cust_pkg->pkgnum if $cust_pkg;
 355         $pkg = $cust_pkg->part_pkg->pkg if $cust_pkg;
 356         push @support_services, { svcnum => $_->svcnum,
 357                                   time => $time_remaining,
 358                                   pkgnum => $pkgnum,
 359                                   pkg => $pkg,
 360                                 };
 361       }
 362       $return{support_services} = \@support_services;
 363     }
 364
 365   } elsif ( $session->{'svcnum'} ) { #no customer record
 366
 367     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 368       or die "unknown svcnum";
 369     $return{name} = $svc_acct->email;
 370
 371   } else {
 372
 373     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 374
 375   }
 376
 377   return { 'error'          => '',
 378            'custnum'        => $custnum,
 379            %return,
 380          };
 381
 382 }
 383
 384 sub edit_info {
 385   my $p = shift;
 386   my $session = _cache->get($p->{'session_id'})
 387     or return { 'error' => "Can't resume session" }; #better error message
 388
 389   my $custnum = $session->{'custnum'}
 390     or return { 'error' => "no customer record" };
 391
 392   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 393     or return { 'error' => "unknown custnum $custnum" };
 394
 395   my $new = new FS::cust_main { $cust_main->hash };
 396   $new->set( $_ => $p->{$_} )
 397     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 398
 399   my $payby = '';
 400   if (exists($p->{'payby'})) {
 401     $p->{'payby'} =~ /^([A-Z]{4})$/
 402       or return { 'error' => "illegal_payby " . $p->{'payby'} };
 403     $payby = $1;
 404   }
 405
 406   if ( $payby =~ /^(CARD|DCRD)$/ ) {
 407
 408     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 409
 410     if ( $new->payinfo eq $cust_main->paymask ) {
 411       $new->payinfo($cust_main->payinfo);
 412     } else {
 413       $new->payinfo($p->{'payinfo'});
 414     }
 415
 416     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 417
 418   } elsif ( $payby =~ /^(CHEK|DCHK)$/ ) {
 419
 420     my $payinfo;
 421     $p->{'payinfo1'} =~ /^([\dx]+)$/
 422       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 423     my $payinfo1 = $1;
 424      $p->{'payinfo2'} =~ /^([\dx]+)$/
 425       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 426     my $payinfo2 = $1;
 427     $payinfo = $payinfo1. '@'. $payinfo2;
 428
 429     $new->payinfo( ($payinfo eq $cust_main->paymask)
 430                      ? $cust_main->payinfo
 431                      : $payinfo
 432                  );
 433
 434     $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 435
 436   } elsif ( $payby =~ /^(BILL)$/ ) {
 437     #no-op
 438   } elsif ( $payby ) {  #notyet ready
 439     return { 'error' => "unknown payby $payby" };
 440   }
 441
 442   my @invoicing_list;
 443   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 444     #false laziness with httemplate/edit/process/cust_main.cgi
 445     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 446     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 447   } else {
 448     @invoicing_list = $cust_main->invoicing_list;
 449   }
 450
 451   my $error = $new->replace($cust_main, \@invoicing_list);
 452   return { 'error' => $error } if $error;
 453   #$cust_main = $new;
 454
 455   return { 'error' => '' };
 456 }
 457
 458 sub payment_info {
 459   my $p = shift;
 460   my $session = _cache->get($p->{'session_id'})
 461     or return { 'error' => "Can't resume session" }; #better error message
 462
 463   ##
 464   #generic
 465   ##
 466
 467   use vars qw($payment_info); #cache for performance
 468   unless ( $payment_info ) {
 469
 470     my $conf = new FS::Conf;
 471     my %states = map { $_->state => 1 }
 472                    qsearch('cust_main_county', {
 473                      'country' => $conf->config('countrydefault') || 'US'
 474                    } );
 475
 476     my %cust_paybys = map { $_ => 1 }
 477                       map { FS::payby->payby2payment($_) }
 478                           $conf->config('signup_server-payby');
 479
 480     my @cust_paybys = keys %cust_paybys;
 481
 482     $payment_info = {
 483
 484       #list all counties/states/countries
 485       'cust_main_county' =>
 486         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 487
 488       #shortcut for one-country folks
 489       'states' =>
 490         [ sort { $a cmp $b } keys %states ],
 491
 492       'card_types' => card_types(),
 493
 494       'paytypes' => [ @FS::cust_main::paytypes ],
 495
 496       'paybys' => [ $conf->config('signup_server-payby') ],
 497       'cust_paybys' => \@cust_paybys,
 498
 499       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 500       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 501
 502       'show_ss'  => $conf->exists('show_ss'),
 503       'show_stateid' => $conf->exists('show_stateid'),
 504       'show_paystate' => $conf->exists('show_bankstate'),
 505     };
 506
 507   }
 508
 509   ##
 510   #customer-specific
 511   ##
 512
 513   my %return = %$payment_info;
 514
 515   my $custnum = $session->{'custnum'};
 516
 517   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 518     or return { 'error' => "unknown custnum $custnum" };
 519
 520   $return{hide_payment_fields} =
 521   [
 522     map { my $pg = '';
 523           if ( FS::payby->realtime($_) ) {
 524             $pg = $cust_main->agent->payment_gateway(
 525               'method'  => FS::payby->payby2bop($_),
 526               'nofatal' => 1,
 527             );
 528           }
 529           $pg && $pg->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 530         }
 531     @{ $return{cust_paybys} }
 532   ];
 533
 534   $return{balance} = $cust_main->balance; #XXX pkg-balances?
 535
 536   $return{payname} = $cust_main->payname
 537                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 538
 539   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 540
 541   $return{payby} = $cust_main->payby;
 542   $return{stateid_state} = $cust_main->stateid_state;
 543
 544   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 545     $return{card_type} = cardtype($cust_main->payinfo);
 546     $return{payinfo} = $cust_main->paymask;
 547
 548     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 549
 550   }
 551
 552   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 553     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 554     $return{payinfo1} = $payinfo1;
 555     $return{payinfo2} = $payinfo2;
 556     $return{paytype}  = $cust_main->paytype;
 557     $return{paystate} = $cust_main->paystate;
 558
 559   }
 560
 561   #doubleclick protection
 562   my $_date = time;
 563   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 564
 565   return { 'error' => '',
 566            %return,
 567          };
 568
 569 };
 570
 571 #some false laziness with httemplate/process/payment.cgi - look there for
 572 #ACH and CVV support stuff
 573 sub process_payment {
 574
 575   my $p = shift;
 576
 577   my $session = _cache->get($p->{'session_id'})
 578     or return { 'error' => "Can't resume session" }; #better error message
 579
 580   my %return;
 581
 582   my $custnum = $session->{'custnum'};
 583
 584   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 585     or return { 'error' => "unknown custnum $custnum" };
 586
 587   $p->{'amount'} =~ /^\s*(\d+(\.\d{2})?)\s*$/
 588     or return { 'error' => gettext('illegal_amount') };
 589   my $amount = $1;
 590   return { error => 'Amount must be greater than 0' } unless $amount > 0;
 591
 592   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 593     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 594   my $payname = $1;
 595
 596   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 597     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 598   my $paybatch = $1;
 599
 600   $p->{'payby'} ||= 'CARD';
 601   $p->{'payby'} =~ /^([A-Z]{4})$/
 602     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 603   my $payby = $1;
 604
 605   #false laziness w/process/payment.cgi
 606   my $payinfo;
 607   my $paycvv = '';
 608   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 609
 610     $p->{'payinfo1'} =~ /^([\dx]+)$/
 611       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 612     my $payinfo1 = $1;
 613      $p->{'payinfo2'} =~ /^([\dx]+)$/
 614       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 615     my $payinfo2 = $1;
 616     $payinfo = $payinfo1. '@'. $payinfo2;
 617
 618     $payinfo = $cust_main->payinfo
 619       if $cust_main->paymask eq $payinfo;
 620
 621   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 622
 623     $payinfo = $p->{'payinfo'};
 624
 625     #more intelligent mathing will be needed here if you change
 626     #card_masking_method and don't remove existing paymasks
 627     $payinfo = $cust_main->payinfo
 628       if $cust_main->paymask eq $payinfo;
 629
 630     $payinfo =~ s/\D//g;
 631     $payinfo =~ /^(\d{13,16})$/
 632       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 633     $payinfo = $1;
 634
 635     validate($payinfo)
 636       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 637     return { 'error' => gettext('unknown_card_type') }
 638       if cardtype($payinfo) eq "Unknown";
 639
 640     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 641       if ( cardtype($payinfo) eq 'American Express card' ) {
 642         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 643           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 644         $paycvv = $1;
 645       } else {
 646         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 647           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 648         $paycvv = $1;
 649       }
 650     }
 651
 652   } else {
 653     die "unknown payby $payby";
 654   }
 655
 656   my %payby2fields = (
 657     'CARD' => [ qw( paystart_month paystart_year payissue payip
 658                     address1 address2 city state zip country    ) ],
 659     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 660   );
 661
 662   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $amount,
 663     'quiet'    => 1,
 664     'payinfo'  => $payinfo,
 665     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 666     'payname'  => $payname,
 667     'paybatch' => $paybatch, #this doesn't actually do anything
 668     'paycvv'   => $paycvv,
 669     'pkgnum'   => $session->{'pkgnum'},
 670     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 671   );
 672   return { 'error' => $error } if $error;
 673
 674   $cust_main->apply_payments;
 675
 676   if ( $p->{'save'} ) {
 677     my $new = new FS::cust_main { $cust_main->hash };
 678     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 679       $new->set( $_ => $p->{$_} )
 680         foreach qw( payname paystart_month paystart_year payissue payip
 681                     address1 address2 city state zip country );
 682       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 683     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 684       $new->set( $_ => $p->{$_} )
 685         foreach qw( payname payip paytype paystate
 686                     stateid stateid_state );
 687       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 688     }
 689     $new->set( 'payinfo' => $payinfo );
 690     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 691     my $error = $new->replace($cust_main);
 692     return { 'error' => $error } if $error;
 693     $cust_main = $new;
 694   }
 695
 696   return { 'error' => '' };
 697
 698 }
 699
 700 sub realtime_collect {
 701   my $p = shift;
 702
 703   my $session = _cache->get($p->{'session_id'})
 704     or return { 'error' => "Can't resume session" }; #better error message
 705
 706   my $custnum = $session->{'custnum'};
 707
 708   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 709     or return { 'error' => "unknown custnum $custnum" };
 710
 711   my $error = $cust_main->realtime_collect(
 712     'method'     => $p->{'method'},
 713     'pkgnum'     => $session->{'pkgnum'},
 714     'session_id' => $p->{'session_id'},
 715     'apply'      => 1,
 716   );
 717   return { 'error' => $error } unless ref( $error );
 718
 719   my $amount = $session->{'pkgnum'}
 720                  ? $cust_main->balance_pkgnum( $session->{'pkgnum'} )
 721                  : $cust_main->balance;
 722
 723   return { 'error' => '', amount => $amount, %$error };
 724 }
 725
 726 sub process_payment_order_pkg {
 727   my $p = shift;
 728
 729   my $hr = process_payment($p);
 730   return $hr if $hr->{'error'};
 731
 732   order_pkg($p);
 733 }
 734
 735 sub process_payment_order_renew {
 736   my $p = shift;
 737
 738   my $hr = process_payment($p);
 739   return $hr if $hr->{'error'};
 740
 741   order_renew($p);
 742 }
 743
 744 sub process_prepay {
 745
 746   my $p = shift;
 747
 748   my $session = _cache->get($p->{'session_id'})
 749     or return { 'error' => "Can't resume session" }; #better error message
 750
 751   my %return;
 752
 753   my $custnum = $session->{'custnum'};
 754
 755   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 756     or return { 'error' => "unknown custnum $custnum" };
 757
 758   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 759   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 760                                            \$amount,
 761                                            \$seconds,
 762                                            \$upbytes,
 763                                            \$downbytes,
 764                                            \$totalbytes,
 765                                          );
 766
 767   return { 'error' => $error } if $error;
 768
 769   return { 'error'     => '',
 770            'amount'    => $amount,
 771            'seconds'   => $seconds,
 772            'duration'  => duration_exact($seconds),
 773            'upbytes'   => $upbytes,
 774            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 775            'downbytes' => $downbytes,
 776            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 777            'totalbytes'=> $totalbytes,
 778            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 779          };
 780
 781 }
 782
 783 sub invoice {
 784   my $p = shift;
 785   my $session = _cache->get($p->{'session_id'})
 786     or return { 'error' => "Can't resume session" }; #better error message
 787
 788   my $custnum = $session->{'custnum'};
 789
 790   my $invnum = $p->{'invnum'};
 791
 792   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 793                                           'custnum' => $custnum } )
 794     or return { 'error' => "Can't find invnum" };
 795
 796   #my %return;
 797
 798   return { 'error'        => '',
 799            'invnum'       => $invnum,
 800            'invoice_text' => join('', $cust_bill->print_text ),
 801            'invoice_html' => $cust_bill->print_html( { unsquelch_cdr => 1 } ),
 802          };
 803
 804 }
 805
 806 sub invoice_logo {
 807   my $p = shift;
 808
 809   #sessioning for this?  how do we get the session id to the backend invoice
 810   # template so it can add it to the link, blah
 811
 812   my $agentnum = '';
 813   if ( $p->{'invnum'} ) {
 814     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $p->{'invnum'} } )
 815       or return { 'error' => 'unknown invnum' };
 816     $agentnum = $cust_bill->cust_main->agentnum;
 817   }
 818
 819   my $templatename = $p->{'template'} || $p->{'templatename'};
 820
 821   #false laziness-ish w/view/cust_bill-logo.cgi
 822
 823   my $conf = new FS::Conf;
 824   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 825     $templatename = "_$1";
 826   } else {
 827     $templatename = '';
 828   }
 829
 830   my $filename = "logo$templatename.png";
 831
 832   return { 'error'        => '',
 833            'logo'         => $conf->config_binary($filename, $agentnum),
 834            'content_type' => 'image/png', #should allow gif, jpg too
 835          };
 836 }
 837
 838
 839 sub list_invoices {
 840   my $p = shift;
 841   my $session = _cache->get($p->{'session_id'})
 842     or return { 'error' => "Can't resume session" }; #better error message
 843
 844   my $custnum = $session->{'custnum'};
 845
 846   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 847     or return { 'error' => "unknown custnum $custnum" };
 848
 849   my @cust_bill = $cust_main->cust_bill;
 850
 851   return  { 'error'       => '',
 852             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 853                                         '_date'  => $_->_date,
 854                                       }
 855                                     } @cust_bill
 856                               ]
 857           };
 858 }
 859
 860 sub cancel {
 861   my $p = shift;
 862   my $session = _cache->get($p->{'session_id'})
 863     or return { 'error' => "Can't resume session" }; #better error message
 864
 865   my $custnum = $session->{'custnum'};
 866
 867   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 868     or return { 'error' => "unknown custnum $custnum" };
 869
 870   my @errors = $cust_main->cancel( 'quiet'=>1 );
 871
 872   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 873
 874   return { 'error' => $error };
 875
 876 }
 877
 878 sub list_pkgs {
 879   my $p = shift;
 880
 881   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 882   return { 'error' => $session } if $context eq 'error';
 883
 884   my $search = { 'custnum' => $custnum };
 885   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 886   my $cust_main = qsearchs('cust_main', $search )
 887     or return { 'error' => "unknown custnum $custnum" };
 888
 889   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 890
 891   my $conf = new FS::Conf;
 892
 893   { 'svcnum'   => $session->{'svcnum'},
 894     'custnum'  => $custnum,
 895     'cust_pkg' => [ map {
 896                           { $_->hash,
 897                             $_->part_pkg->hash,
 898                             part_svc =>
 899                               [ map $_->hashref, $_->available_part_svc ],
 900                             cust_svc =>
 901                               [ map { my $ref = { $_->hash,
 902                                                   label => [ $_->label ],
 903                                                 };
 904                                       $ref->{_password} = $_->svc_x->_password
 905                                         if $context eq 'agent'
 906                                         && $conf->exists('agent-showpasswords')
 907                                         && $_->part_svc->svcdb eq 'svc_acct';
 908                                       $ref;
 909                                     } $_->cust_svc
 910                               ],
 911                           };
 912                         } $cust_main->ncancelled_pkgs
 913                   ],
 914     'small_custview' =>
 915       small_custview( $cust_main, $conf->config('countrydefault') ),
 916   };
 917
 918 }
 919
 920 sub list_svcs {
 921   my $p = shift;
 922
 923   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 924   return { 'error' => $session } if $context eq 'error';
 925
 926   my $search = { 'custnum' => $custnum };
 927   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 928   my $cust_main = qsearchs('cust_main', $search )
 929     or return { 'error' => "unknown custnum $custnum" };
 930
 931   my @cust_svc = ();
 932   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 933   foreach my $cust_pkg ( $p->{'ncancelled'}
 934                          ? $cust_main->ncancelled_pkgs
 935                          : $cust_main->unsuspended_pkgs ) {
 936     next if $session->{'pkgnum'} && $cust_pkg->pkgnum != $session->{'pkgnum'};
 937     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 938   }
 939   if ( $p->{'svcdb'} ) {
 940     my $svcdb = ref($p->{'svcdb'}) eq 'HASH'
 941                   ? $p->{'svcdb'}
 942                   : ref($p->{'svcdb'}) eq 'ARRAY'
 943                     ? { map { $_=>1 } @{ $p->{'svcdb'} } }
 944                     : { $p->{'svcdb'} => 1 };
 945     @cust_svc = grep $svcdb->{ $_->part_svc->svcdb }, @cust_svc
 946   }
 947
 948   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 949   #              @svc_x;
 950
 951   {
 952     'svcnum'   => $session->{'svcnum'},
 953     'custnum'  => $custnum,
 954     'svcs'     => [
 955       map {
 956             my $svc_x = $_->svc_x;
 957             my($label, $value) = $_->label;
 958             my $svcdb = $_->part_svc->svcdb;
 959             my $part_pkg = $_->cust_pkg->part_pkg;
 960
 961             my %hash = (
 962               'svcnum' => $_->svcnum,
 963               'svcdb'  => $svcdb,
 964               'label'  => $label,
 965               'value'  => $value,
 966             );
 967
 968             if ( $svcdb eq 'svc_acct' ) {
 969               %hash = (
 970                 %hash,
 971                 'username'   => $svc_x->username,
 972                 'email'      => $svc_x->email,
 973                 'seconds'    => $svc_x->seconds,
 974                 'upbytes'    => display_bytecount($svc_x->upbytes),
 975                 'downbytes'  => display_bytecount($svc_x->downbytes),
 976                 'totalbytes' => display_bytecount($svc_x->totalbytes),
 977
 978                 'recharge_amount'  => $part_pkg->option('recharge_amount',1),
 979                 'recharge_seconds' => $part_pkg->option('recharge_seconds',1),
 980                 'recharge_upbytes'    =>
 981                   display_bytecount($part_pkg->option('recharge_upbytes',1)),
 982                 'recharge_downbytes'  =>
 983                   display_bytecount($part_pkg->option('recharge_downbytes',1)),
 984                 'recharge_totalbytes' =>
 985                   display_bytecount($part_pkg->option('recharge_totalbytes',1)),
 986                 # more...
 987               );
 988
 989             } elsif ( $svcdb eq 'svc_phone' ) {
 990               %hash = (
 991                 %hash,
 992               );
 993             }
 994
 995             \%hash;
 996           }
 997           @cust_svc
 998     ],
 999   };
1000
1001 }
1002
1003 sub _list_svc_usage {
1004   my($svc_acct, $begin, $end) = @_;
1005   my @usage = ();
1006   foreach my $part_export (
1007     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
1008     qw( sqlradius sqlradius_withdomain )
1009   ) {
1010     push @usage, @ { $part_export->usage_sessions($begin, $end, $svc_acct) };
1011   }
1012   (@usage);
1013 }
1014
1015 sub list_svc_usage {
1016   _usage_details(\&_list_svc_usage, @_);
1017 }
1018
1019 sub _list_support_usage {
1020   my($svc_acct, $begin, $end) = @_;
1021   my @usage = ();
1022   foreach ( grep { $begin <= $_->_date && $_->_date <= $end }
1023             qsearch('acct_rt_transaction', { 'svcnum' => $svc_acct->svcnum })
1024           ) {
1025     push @usage, { 'seconds'  => $_->seconds,
1026                    'support'  => $_->support,
1027                    '_date'    => $_->_date,
1028                    'id'       => $_->transaction_id,
1029                    'creator'  => $_->creator,
1030                    'subject'  => $_->subject,
1031                    'status'   => $_->status,
1032                    'ticketid' => $_->ticketid,
1033                  };
1034   }
1035   (@usage);
1036 }
1037
1038 sub list_support_usage {
1039   _usage_details(\&_list_support_usage, @_);
1040 }
1041
1042 sub _list_cdr_usage {
1043   my($svc_phone, $begin, $end) = @_;
1044   map [ $_->downstream_csv('format' => 'default') ], #XXX config for format
1045       $svc_phone->cust_svc->get_cdrs( 'begin'=>$begin, 'end'=>$end, );
1046 }
1047
1048 sub list_cdr_usage {
1049   my $p = shift;
1050   _usage_details( \&_list_cdr_usage, $p,
1051                   'svcdb' => 'svc_phone',
1052                 );
1053 }
1054
1055 sub _usage_details {
1056   my($callback, $p, %opt) = @_;
1057
1058   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1059   return { 'error' => $session } if $context eq 'error';
1060
1061   my $search = { 'svcnum' => $p->{'svcnum'} };
1062   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1063
1064   my $svcdb = $opt{'svcdb'} || 'svc_acct';
1065
1066   my $svc_x = qsearchs( $svcdb, $search );
1067   return { 'error' => 'No service selected in list_svc_usage' }
1068     unless $svc_x;
1069
1070   my $header = $svcdb eq 'svc_phone'
1071                  ? [ split(',', FS::cdr::invoice_header('default') ) ]  #XXX
1072                  : [];
1073
1074   my $cust_pkg = $svc_x->cust_svc->cust_pkg;
1075   my $freq     = $cust_pkg->part_pkg->freq;
1076   my $start    = $cust_pkg->setup;
1077   #my $end      = $cust_pkg->bill; # or time?
1078   my $end      = time;
1079
1080   unless ( $p->{beginning} ) {
1081     $p->{beginning} = $cust_pkg->last_bill;
1082     $p->{ending}    = $end;
1083   }
1084
1085   my (@usage) = &$callback($svc_x, $p->{beginning}, $p->{ending});
1086
1087   #kinda false laziness with FS::cust_main::bill, but perhaps
1088   #we should really change this bit to DateTime and DateTime::Duration
1089   #
1090   #change this bit to use Date::Manip? CAREFUL with timezones (see
1091   # mailing list archive)
1092   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
1093     (localtime($p->{ending}) )[0,1,2,3,4,5];
1094   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
1095     (localtime($p->{beginning}) )[0,1,2,3,4,5];
1096
1097   if ( $freq =~ /^\d+$/ ) {
1098     $nmon += $freq;
1099     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
1100     $pmon -= $freq;
1101     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
1102   } elsif ( $freq =~ /^(\d+)w$/ ) {
1103     my $weeks = $1;
1104     $nmday += $weeks * 7;
1105     $pmday -= $weeks * 7;
1106   } elsif ( $freq =~ /^(\d+)d$/ ) {
1107     my $days = $1;
1108     $nmday += $days;
1109     $pmday -= $days;
1110   } elsif ( $freq =~ /^(\d+)h$/ ) {
1111     my $hours = $1;
1112     $nhour += $hours;
1113     $phour -= $hours;
1114   } else {
1115     return { 'error' => "unparsable frequency: ". $freq };
1116   }
1117
1118   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
1119   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
1120
1121   {
1122     'error'     => '',
1123     'svcnum'    => $p->{svcnum},
1124     'beginning' => $p->{beginning},
1125     'ending'    => $p->{ending},
1126     'previous'  => ($previous > $start) ? $previous : $start,
1127     'next'      => ($next < $end) ? $next : $end,
1128     'header'    => $header,
1129     'usage'     => \@usage,
1130   };
1131 }
1132
1133 sub order_pkg {
1134   my $p = shift;
1135
1136   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1137   return { 'error' => $session } if $context eq 'error';
1138
1139   my $search = { 'custnum' => $custnum };
1140   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1141   my $cust_main = qsearchs('cust_main', $search )
1142     or return { 'error' => "unknown custnum $custnum" };
1143
1144   my $status = $cust_main->status;
1145   #false laziness w/ClientAPI/Signup.pm
1146
1147   my $cust_pkg = new FS::cust_pkg ( {
1148     'custnum' => $custnum,
1149     'pkgpart' => $p->{'pkgpart'},
1150   } );
1151   my $error = $cust_pkg->check;
1152   return { 'error' => $error } if $error;
1153
1154   my @svc = ();
1155   unless ( $p->{'svcpart'} eq 'none' ) {
1156
1157     my $svcdb;
1158     my $svcpart = '';
1159     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
1160       $svcpart = $1;
1161       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
1162       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
1163       $svcdb = $part_svc->svcdb;
1164     } else {
1165       $svcdb = 'svc_acct';
1166     }
1167     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
1168
1169     my %fields = (
1170       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
1171       'svc_domain'   => [ qw( domain ) ],
1172       'svc_phone'    => [ qw( phonenum pin sip_password phone_name ) ],
1173       'svc_external' => [ qw( id title ) ],
1174     );
1175
1176     my $svc_x = "FS::$svcdb"->new( {
1177       'svcpart'   => $svcpart,
1178       map { $_ => $p->{$_} } @{$fields{$svcdb}}
1179     } );
1180
1181     if ( $svcdb eq 'svc_acct' ) {
1182       my @acct_snarf;
1183       my $snarfnum = 1;
1184       while ( length($p->{"snarf_machine$snarfnum"}) ) {
1185         my $acct_snarf = new FS::acct_snarf ( {
1186           'machine'   => $p->{"snarf_machine$snarfnum"},
1187           'protocol'  => $p->{"snarf_protocol$snarfnum"},
1188           'username'  => $p->{"snarf_username$snarfnum"},
1189           '_password' => $p->{"snarf_password$snarfnum"},
1190         } );
1191         $snarfnum++;
1192         push @acct_snarf, $acct_snarf;
1193       }
1194       $svc_x->child_objects( \@acct_snarf );
1195     }
1196
1197     my $y = $svc_x->setdefault; # arguably should be in new method
1198     return { 'error' => $y } if $y && !ref($y);
1199
1200     $error = $svc_x->check;
1201     return { 'error' => $error } if $error;
1202
1203     push @svc, $svc_x;
1204
1205   }
1206
1207   use Tie::RefHash;
1208   tie my %hash, 'Tie::RefHash';
1209   %hash = ( $cust_pkg => \@svc );
1210   #msgcat
1211   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
1212   return { 'error' => $error } if $error;
1213
1214   my $conf = new FS::Conf;
1215   if ( $conf->exists('signup_server-realtime') ) {
1216
1217     my $bill_error = _do_bop_realtime( $cust_main, $status );
1218
1219     if ($bill_error) {
1220       $cust_pkg->cancel('quiet'=>1);
1221       return $bill_error;
1222     } else {
1223       $cust_pkg->reexport;
1224     }
1225
1226   } else {
1227     $cust_pkg->reexport;
1228   }
1229
1230   return { error => '', pkgnum => $cust_pkg->pkgnum };
1231
1232 }
1233
1234 sub change_pkg {
1235   my $p = shift;
1236
1237   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1238   return { 'error' => $session } if $context eq 'error';
1239
1240   my $search = { 'custnum' => $custnum };
1241   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1242   my $cust_main = qsearchs('cust_main', $search )
1243     or return { 'error' => "unknown custnum $custnum" };
1244
1245   my $status = $cust_main->status;
1246   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
1247     or return { 'error' => "unknown package $p->{pkgnum}" };
1248
1249   my @newpkg;
1250   my $error = FS::cust_pkg::order( $custnum,
1251                                    [$p->{pkgpart}],
1252                                    [$p->{pkgnum}],
1253                                    \@newpkg,
1254                                  );
1255
1256   my $conf = new FS::Conf;
1257   if ( $conf->exists('signup_server-realtime') ) {
1258
1259     my $bill_error = _do_bop_realtime( $cust_main, $status );
1260
1261     if ($bill_error) {
1262       $newpkg[0]->suspend;
1263       return $bill_error;
1264     } else {
1265       $newpkg[0]->reexport;
1266     }
1267
1268   } else {
1269     $newpkg[0]->reexport;
1270   }
1271
1272   return { error => '', pkgnum => $cust_pkg->pkgnum };
1273
1274 }
1275
1276 sub order_recharge {
1277   my $p = shift;
1278
1279   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1280   return { 'error' => $session } if $context eq 'error';
1281
1282   my $search = { 'custnum' => $custnum };
1283   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1284   my $cust_main = qsearchs('cust_main', $search )
1285     or return { 'error' => "unknown custnum $custnum" };
1286
1287   my $status = $cust_main->status;
1288   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
1289     or return { 'error' => "unknown service " . $p->{'svcnum'} };
1290
1291   my $svc_x = $cust_svc->svc_x;
1292   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
1293
1294   my %vhash =
1295     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
1296     qw ( recharge_seconds recharge_upbytes recharge_downbytes
1297          recharge_totalbytes );
1298   my $amount = $part_pkg->option('recharge_amount', 1);
1299
1300   my ($l, $v, $d) = $cust_svc->label;  # blah
1301   my $pkg = "Recharge $v";
1302
1303   my $bill_error = $cust_main->charge($amount, $pkg,
1304      "time: $vhash{seconds}, up: $vhash{upbytes}," .
1305      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
1306      $part_pkg->taxclass); #meh
1307
1308   my $conf = new FS::Conf;
1309   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
1310
1311     $bill_error = _do_bop_realtime( $cust_main, $status );
1312
1313     if ($bill_error) {
1314       return $bill_error;
1315     } else {
1316       my $error = $svc_x->recharge (\%vhash);
1317       return { 'error' => $error } if $error;
1318     }
1319
1320   } else {
1321     my $error = $bill_error;
1322     $error ||= $svc_x->recharge (\%vhash);
1323     return { 'error' => $error } if $error;
1324   }
1325
1326   return { error => '', svc => $cust_svc->part_svc->svc };
1327
1328 }
1329
1330 sub _do_bop_realtime {
1331   my ($cust_main, $status) = (shift, shift);
1332
1333     my $old_balance = $cust_main->balance;
1334
1335     my $bill_error =    $cust_main->bill
1336                      || $cust_main->apply_payments_and_credits
1337                      || $cust_main->collect('realtime' => 1);
1338
1339     if (    $cust_main->balance > $old_balance
1340          && $cust_main->balance > 0
1341          && ( $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ?
1342               1 : $status eq 'suspended' ) ) {
1343       #this makes sense.  credit is "un-doing" the invoice
1344       my $conf = new FS::Conf;
1345       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
1346                           'self-service decline',
1347                           'reason_type' => $conf->config('signup_credit_type'),
1348                         );
1349       $cust_main->apply_credits( 'order' => 'newest' );
1350
1351       return { 'error' => '_decline', 'bill_error' => $bill_error };
1352     }
1353
1354     '';
1355 }
1356
1357 sub renew_info {
1358   my $p = shift;
1359
1360   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1361   return { 'error' => $session } if $context eq 'error';
1362
1363   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1364     or return { 'error' => "unknown custnum $custnum" };
1365
1366   my @cust_pkg = sort { $a->bill <=> $b->bill }
1367                  grep { $_->part_pkg->freq ne '0' }
1368                  $cust_main->ncancelled_pkgs;
1369
1370   #return { 'error' => 'No active packages to renew.' } unless @cust_pkg;
1371
1372   my $total = $cust_main->balance;
1373
1374   my @array = map {
1375                     my $bill = $_->bill;
1376                     $total += $_->part_pkg->base_recur($_, \$bill);
1377                     my $renew_date = $_->part_pkg->add_freq($_->bill);
1378                     {
1379                       'pkgnum'             => $_->pkgnum,
1380                       'amount'             => sprintf('%.2f', $total),
1381                       'bill_date'          => $_->bill,
1382                       'bill_date_pretty'   => time2str('%x', $_->bill),
1383                       'renew_date'         => $renew_date,
1384                       'renew_date_pretty'  => time2str('%x', $renew_date),
1385                       'expire_date'        => $_->expire,
1386                       'expire_date_pretty' => time2str('%x', $_->expire),
1387                     };
1388                   }
1389                   @cust_pkg;
1390
1391   return { 'dates' => \@array };
1392
1393 }
1394
1395 sub payment_info_renew_info {
1396   my $p = shift;
1397   my $renew_info   = renew_info($p);
1398   my $payment_info = payment_info($p);
1399   return { %$renew_info,
1400            %$payment_info,
1401          };
1402 }
1403
1404 sub order_renew {
1405   my $p = shift;
1406
1407   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1408   return { 'error' => $session } if $context eq 'error';
1409
1410   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1411     or return { 'error' => "unknown custnum $custnum" };
1412
1413   my $date = $p->{'date'};
1414
1415   my $now = time;
1416
1417   #freeside-daily -n -d $date fs_daily $custnum
1418   $cust_main->bill_and_collect( 'time'         => $date,
1419                                 'invoice_time' => $now,
1420                                 'actual_time'  => $now,
1421                                 'check_freq'   => '1d',
1422                               );
1423
1424   return { 'error' => '' };
1425
1426 }
1427
1428 sub cancel_pkg {
1429   my $p = shift;
1430   my $session = _cache->get($p->{'session_id'})
1431     or return { 'error' => "Can't resume session" }; #better error message
1432
1433   my $custnum = $session->{'custnum'};
1434
1435   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
1436     or return { 'error' => "unknown custnum $custnum" };
1437
1438   my $pkgnum = $p->{'pkgnum'};
1439
1440   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1441                                         'pkgnum'  => $pkgnum,   } )
1442     or return { 'error' => "unknown pkgnum $pkgnum" };
1443
1444   my $error = $cust_pkg->cancel( 'quiet'=>1 );
1445   return { 'error' => $error };
1446
1447 }
1448
1449 sub provision_acct {
1450   my $p = shift;
1451   warn "provision_acct called\n"
1452     if $DEBUG;
1453
1454   return { 'error' => gettext('passwords_dont_match') }
1455     if $p->{'_password'} ne $p->{'_password2'};
1456   return { 'error' => gettext('empty_password') }
1457     unless length($p->{'_password'});
1458
1459   if ($p->{'domsvc'}) {
1460     my %domains = domain_select_hash FS::svc_acct(map { $_ => $p->{$_} }
1461                                                   qw ( svcpart pkgnum ) );
1462     return { 'error' => gettext('invalid_domain') }
1463       unless ($domains{$p->{'domsvc'}});
1464   }
1465
1466   warn "provision_acct calling _provision\n"
1467     if $DEBUG;
1468   _provision( 'FS::svc_acct',
1469               [qw(username _password domsvc)],
1470               [qw(username _password domsvc)],
1471               $p,
1472               @_
1473             );
1474 }
1475
1476 sub provision_external {
1477   my $p = shift;
1478   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
1479   _provision( 'FS::svc_external',
1480               [],
1481               [qw(id title)],
1482               $p,
1483               @_
1484             );
1485 }
1486
1487 sub _provision {
1488   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
1489   warn "_provision called for $class\n"
1490     if $DEBUG;
1491
1492   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1493   return { 'error' => $session } if $context eq 'error';
1494
1495   my $search = { 'custnum' => $custnum };
1496   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1497   my $cust_main = qsearchs('cust_main', $search )
1498     or return { 'error' => "unknown custnum $custnum" };
1499
1500   my $pkgnum = $p->{'pkgnum'};
1501
1502   warn "searching for custnum $custnum pkgnum $pkgnum\n"
1503     if $DEBUG;
1504   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1505                                         'pkgnum'  => $pkgnum,
1506                                                                } )
1507     or return { 'error' => "unknown pkgnum $pkgnum" };
1508
1509   warn "searching for svcpart ". $p->{'svcpart'}. "\n"
1510     if $DEBUG;
1511   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1512     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1513
1514   warn "creating $class record\n"
1515     if $DEBUG;
1516   my $svc_x = $class->new( {
1517     'pkgnum'  => $p->{'pkgnum'},
1518     'svcpart' => $p->{'svcpart'},
1519     map { $_ => $p->{$_} } @$fields
1520   } );
1521   warn "inserting $class record\n"
1522     if $DEBUG;
1523   my $error = $svc_x->insert;
1524
1525   unless ( $error ) {
1526     warn "finding inserted record for svcnum ". $svc_x->svcnum. "\n"
1527       if $DEBUG;
1528     $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1529   }
1530
1531   my $return = { 'svc'   => $part_svc->svc,
1532                  'error' => $error,
1533                  map { $_ => $svc_x->get($_) } @$return_fields
1534                };
1535   warn "_provision returning ". Dumper($return). "\n"
1536     if $DEBUG;
1537   return $return;
1538
1539 }
1540
1541 sub part_svc_info {
1542   my $p = shift;
1543
1544   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1545   return { 'error' => $session } if $context eq 'error';
1546
1547   my $search = { 'custnum' => $custnum };
1548   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1549   my $cust_main = qsearchs('cust_main', $search )
1550     or return { 'error' => "unknown custnum $custnum" };
1551
1552   my $pkgnum = $p->{'pkgnum'};
1553
1554   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1555                                         'pkgnum'  => $pkgnum,
1556                                                                } )
1557     or return { 'error' => "unknown pkgnum $pkgnum" };
1558
1559   my $svcpart = $p->{'svcpart'};
1560
1561   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1562                                       'svcpart' => $svcpart,           } )
1563     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1564   my $part_svc = $pkg_svc->part_svc;
1565
1566   my $conf = new FS::Conf;
1567
1568   return {
1569     'svc'     => $part_svc->svc,
1570     'svcdb'   => $part_svc->svcdb,
1571     'pkgnum'  => $pkgnum,
1572     'svcpart' => $svcpart,
1573     'custnum' => $custnum,
1574
1575     'security_phrase' => 0, #XXX !
1576     'svc_acct_pop'    => [], #XXX !
1577     'popnum'          => '',
1578     'init_popstate'   => '',
1579     'popac'           => '',
1580     'acstate'         => '',
1581
1582     'small_custview' =>
1583       small_custview( $cust_main, $conf->config('countrydefault') ),
1584
1585   };
1586
1587 }
1588
1589 sub unprovision_svc {
1590   my $p = shift;
1591
1592   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1593   return { 'error' => $session } if $context eq 'error';
1594
1595   my $search = { 'custnum' => $custnum };
1596   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1597   my $cust_main = qsearchs('cust_main', $search )
1598     or return { 'error' => "unknown custnum $custnum" };
1599
1600   my $svcnum = $p->{'svcnum'};
1601
1602   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1603     or return { 'error' => "unknown svcnum $svcnum" };
1604
1605   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1606     unless $cust_svc->cust_pkg->custnum == $custnum;
1607
1608   my $conf = new FS::Conf;
1609
1610   return { 'svc'   => $cust_svc->part_svc->svc,
1611            'error' => $cust_svc->cancel,
1612            'small_custview' =>
1613              small_custview( $cust_main, $conf->config('countrydefault') ),
1614          };
1615
1616 }
1617
1618 sub myaccount_passwd {
1619   my $p = shift;
1620   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1621   return { 'error' => $session } if $context eq 'error';
1622
1623   return { 'error' => "New passwords don't match." }
1624     if $p->{'new_password'} ne $p->{'new_password2'};
1625
1626   return { 'error' => 'Enter new password' }
1627     unless length($p->{'new_password'});
1628
1629   #my $search = { 'custnum' => $custnum };
1630   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1631   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1632   my $search = " AND custnum = $1";
1633   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1634
1635   my $svc_acct = qsearchs( {
1636     'table'     => 'svc_acct',
1637     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1638                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1639                    'LEFT JOIN cust_main USING ( custnum ) ',
1640     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1641     'extra_sql' => $search, #important
1642   } )
1643     or return { 'error' => "Service not found" };
1644
1645   $svc_acct->_password($p->{'new_password'});
1646   my $error = $svc_acct->replace();
1647
1648   my($label, $value) = $svc_acct->cust_svc->label;
1649
1650   return { 'error' => $error,
1651            'label' => $label,
1652            'value' => $value,
1653          };
1654
1655 }
1656
1657 #--
1658
1659 sub _custoragent_session_custnum {
1660   my $p = shift;
1661
1662   my($context, $session, $custnum);
1663   if ( $p->{'session_id'} ) {
1664
1665     $context = 'customer';
1666     $session = _cache->get($p->{'session_id'})
1667       or return ( 'error' => "Can't resume session" ); #better error message
1668     $custnum = $session->{'custnum'};
1669
1670   } elsif ( $p->{'agent_session_id'} ) {
1671
1672     $context = 'agent';
1673     my $agent_cache = new FS::ClientAPI_SessionCache( {
1674       'namespace' => 'FS::ClientAPI::Agent',
1675     } );
1676     $session = $agent_cache->get($p->{'agent_session_id'})
1677       or return ( 'error' => "Can't resume session" ); #better error message
1678     $custnum = $p->{'custnum'};
1679
1680   } else {
1681     return ( 'error' => "Can't resume session" ); #better error message
1682   }
1683
1684   ($context, $session, $custnum);
1685
1686 }
1687
1688 1;
1689