FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::Conf;
  12 use FS::Record qw(qsearch qsearchs);
  13 use FS::Msgcat qw(gettext);
  14 use FS::ClientAPI_SessionCache;
  15 use FS::svc_acct;
  16 use FS::svc_domain;
  17 use FS::svc_external;
  18 use FS::part_svc;
  19 use FS::cust_main;
  20 use FS::cust_bill;
  21 use FS::cust_main_county;
  22 use FS::cust_pkg;
  23
  24 use vars qw( @cust_main_editable_fields );
  25 @cust_main_editable_fields = qw(
  26   first last company address1 address2 city
  27     county state zip country daytime night fax
  28   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  29     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  30   payby payinfo payname paystart_month paystart_year payissue payip
  31 );
  32
  33 use subs qw(_provision);
  34
  35 sub _cache {
  36   $cache ||= new FS::ClientAPI_SessionCache( {
  37                'namespace' => 'FS::ClientAPI::MyAccount',
  38              } );
  39 }
  40
  41 #false laziness w/FS::ClientAPI::passwd::passwd
  42 sub login {
  43   my $p = shift;
  44
  45   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  46     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  47
  48   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  49                                          'domsvc'    => $svc_domain->svcnum, }
  50                          );
  51   return { error => 'User not found.' } unless $svc_acct;
  52
  53   my $conf = new FS::Conf;
  54   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  55   return { error => 'Only primary user may log in.' }
  56     if $conf->exists('selfservice_server-primary_only')
  57        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  58
  59   return { error => 'Incorrect password.' }
  60     unless $svc_acct->check_password($p->{'password'});
  61
  62   my $session = {
  63     'svcnum' => $svc_acct->svcnum,
  64   };
  65
  66   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  67   if ( $cust_pkg ) {
  68     my $cust_main = $cust_pkg->cust_main;
  69     $session->{'custnum'} = $cust_main->custnum;
  70   }
  71
  72   my $session_id;
  73   do {
  74     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  75   } until ( ! defined _cache->get($session_id) ); #just in case
  76
  77   _cache->set( $session_id, $session, '1 hour' );
  78
  79   return { 'error'      => '',
  80            'session_id' => $session_id,
  81          };
  82 }
  83
  84 sub logout {
  85   my $p = shift;
  86   if ( $p->{'session_id'} ) {
  87     _cache->remove($p->{'session_id'});
  88     return { 'error' => '' };
  89   } else {
  90     return { 'error' => "Can't resume session" }; #better error message
  91   }
  92 }
  93
  94 sub customer_info {
  95   my $p = shift;
  96
  97   my($context, $session, $custnum) = _custoragent_session_custnum($p);
  98   return { 'error' => $session } if $context eq 'error';
  99
 100   my %return;
 101   if ( $custnum ) { #customer record
 102
 103     my $search = { 'custnum' => $custnum };
 104     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 105     my $cust_main = qsearchs('cust_main', $search )
 106       or return { 'error' => "unknown custnum $custnum" };
 107
 108     $return{balance} = $cust_main->balance;
 109
 110     my @open = map {
 111                      {
 112                        invnum => $_->invnum,
 113                        date   => time2str("%b %o, %Y", $_->_date),
 114                        owed   => $_->owed,
 115                      };
 116                    } $cust_main->open_cust_bill;
 117     $return{open_invoices} = \@open;
 118
 119     my $conf = new FS::Conf;
 120     $return{small_custview} =
 121       small_custview( $cust_main, $conf->config('countrydefault') );
 122
 123     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 124
 125     for (@cust_main_editable_fields) {
 126       $return{$_} = $cust_main->get($_);
 127     }
 128
 129     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 130       $return{payinfo} = $cust_main->payinfo_masked;
 131       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 132     }
 133
 134     $return{'invoicing_list'} =
 135       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 136     $return{'postal_invoicing'} =
 137       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 138
 139   } elsif ( $session->{'svcnum'} ) { #no customer record
 140
 141     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 142       or die "unknown svcnum";
 143     $return{name} = $svc_acct->email;
 144
 145   } else {
 146
 147     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 148
 149   }
 150
 151   return { 'error'          => '',
 152            'custnum'        => $custnum,
 153            %return,
 154          };
 155
 156 }
 157
 158 sub edit_info {
 159   my $p = shift;
 160   my $session = _cache->get($p->{'session_id'})
 161     or return { 'error' => "Can't resume session" }; #better error message
 162
 163   my $custnum = $session->{'custnum'}
 164     or return { 'error' => "no customer record" };
 165
 166   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 167     or return { 'error' => "unknown custnum $custnum" };
 168
 169   my $new = new FS::cust_main { $cust_main->hash };
 170   $new->set( $_ => $p->{$_} )
 171     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 172
 173   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 174     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 175     if ( $new->payinfo eq $cust_main->payinfo_masked ) {
 176       $new->payinfo($cust_main->payinfo);
 177     } else {
 178       $new->paycvv($p->{'paycvv'});
 179     }
 180   }
 181
 182   my @invoicing_list;
 183   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 184     #false laziness with httemplate/edit/process/cust_main.cgi
 185     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 186     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 187   } else {
 188     @invoicing_list = $cust_main->invoicing_list;
 189   }
 190
 191   my $error = $new->replace($cust_main, \@invoicing_list);
 192   return { 'error' => $error } if $error;
 193   #$cust_main = $new;
 194
 195   return { 'error' => '' };
 196 }
 197
 198 sub payment_info {
 199   my $p = shift;
 200   my $session = _cache->get($p->{'session_id'})
 201     or return { 'error' => "Can't resume session" }; #better error message
 202
 203   ##
 204   #generic
 205   ##
 206
 207   my $conf = new FS::Conf;
 208   my %states = map { $_->state => 1 }
 209                  qsearch('cust_main_county', {
 210                    'country' => $conf->config('countrydefault') || 'US'
 211                  } );
 212
 213   use vars qw($payment_info); #cache for performance
 214   $payment_info ||= {
 215
 216     #list all counties/states/countries
 217     'cust_main_county' =>
 218       [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 219
 220     #shortcut for one-country folks
 221     'states' =>
 222       [ sort { $a cmp $b } keys %states ],
 223
 224     'card_types' => {
 225       'VISA' => 'VISA card',
 226       'MasterCard' => 'MasterCard',
 227       'Discover' => 'Discover card',
 228       'American Express' => 'American Express card',
 229       'Switch' => 'Switch',
 230       'Solo' => 'Solo',
 231     },
 232
 233   };
 234
 235   ##
 236   #customer-specific
 237   ##
 238
 239   my %return = %$payment_info;
 240
 241   my $custnum = $session->{'custnum'};
 242
 243   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 244     or return { 'error' => "unknown custnum $custnum" };
 245
 246   $return{balance} = $cust_main->balance;
 247
 248   $return{payname} = $cust_main->payname
 249                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 250
 251   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 252
 253   $return{payby} = $cust_main->payby;
 254
 255   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 256     #warn $return{card_type} = cardtype($cust_main->payinfo);
 257     $return{payinfo} = $cust_main->payinfo;
 258
 259     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 260
 261   }
 262
 263   #doubleclick protection
 264   my $_date = time;
 265   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 266
 267   return { 'error' => '',
 268            %return,
 269          };
 270
 271 };
 272
 273 #some false laziness with httemplate/process/payment.cgi - look there for
 274 #ACH and CVV support stuff
 275 sub process_payment {
 276
 277   my $p = shift;
 278
 279   my $session = _cache->get($p->{'session_id'})
 280     or return { 'error' => "Can't resume session" }; #better error message
 281
 282   my %return;
 283
 284   my $custnum = $session->{'custnum'};
 285
 286   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 287     or return { 'error' => "unknown custnum $custnum" };
 288
 289   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 290     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 291   my $payname = $1;
 292
 293   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 294     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 295   my $paybatch = $1;
 296
 297   my $payinfo;
 298   my $paycvv = '';
 299   #if ( $payby eq 'CHEK' ) {
 300   #
 301   #  $p->{'payinfo1'} =~ /^(\d+)$/
 302   #    or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 303   #  my $payinfo1 = $1;
 304   #   $p->{'payinfo2'} =~ /^(\d+)$/
 305   #    or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 306   #  my $payinfo2 = $1;
 307   #  $payinfo = $payinfo1. '@'. $payinfo2;
 308   #
 309   #} elsif ( $payby eq 'CARD' ) {
 310
 311     $payinfo = $p->{'payinfo'};
 312     $payinfo =~ s/\D//g;
 313     $payinfo =~ /^(\d{13,16})$/
 314       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 315     $payinfo = $1;
 316     validate($payinfo)
 317       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 318     return { 'error' => gettext('unknown_card_type') }
 319       if cardtype($payinfo) eq "Unknown";
 320
 321     if ( defined $cust_main->dbdef_table->column('paycvv') ) {
 322       if ( length($p->{'paycvv'} ) ) {
 323         if ( cardtype($payinfo) eq 'American Express card' ) {
 324           $p->{'paycvv'} =~ /^(\d{4})$/
 325             or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 326           $paycvv = $1;
 327         } else {
 328           $p->{'paycvv'} =~ /^(\d{3})$/
 329             or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 330           $paycvv = $1;
 331         }
 332       }
 333     }
 334
 335   #} else {
 336   #  die "unknown payby $payby";
 337   #}
 338
 339   my $error = $cust_main->realtime_bop( 'CC', $p->{'amount'},
 340     'quiet'    => 1,
 341     'payinfo'  => $payinfo,
 342     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 343     'payname'  => $payname,
 344     'paybatch' => $paybatch,
 345     'paycvv'   => $paycvv,
 346     map { $_ => $p->{$_} } qw( paystart_month paystart_year payissue payip
 347                                address1 address2 city state zip )
 348   );
 349   return { 'error' => $error } if $error;
 350
 351   $cust_main->apply_payments;
 352
 353   if ( $p->{'save'} ) {
 354     my $new = new FS::cust_main { $cust_main->hash };
 355     $new->set( $_ => $p->{$_} )
 356       foreach qw( payname paystart_month paystart_year payissue payip
 357                   address1 address2 city state zip payinfo );
 358     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 359     $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 360     my $error = $new->replace($cust_main);
 361     return { 'error' => $error } if $error;
 362     $cust_main = $new;
 363   }
 364
 365   return { 'error' => '' };
 366
 367 }
 368
 369 sub process_prepay {
 370
 371   my $p = shift;
 372
 373   my $session = _cache->get($p->{'session_id'})
 374     or return { 'error' => "Can't resume session" }; #better error message
 375
 376   my %return;
 377
 378   my $custnum = $session->{'custnum'};
 379
 380   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 381     or return { 'error' => "unknown custnum $custnum" };
 382
 383   my( $amount, $seconds ) = ( 0, 0 );
 384   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 385                                            \$amount,
 386                                            \$seconds
 387                                          );
 388
 389   return { 'error' => $error } if $error;
 390
 391   return { 'error'    => '',
 392            'amount'   => $amount,
 393            'seconds'  => $seconds,
 394            'duration' => duration_exact($seconds),
 395          };
 396
 397 }
 398
 399 sub invoice {
 400   my $p = shift;
 401   my $session = _cache->get($p->{'session_id'})
 402     or return { 'error' => "Can't resume session" }; #better error message
 403
 404   my $custnum = $session->{'custnum'};
 405
 406   my $invnum = $p->{'invnum'};
 407
 408   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 409                                           'custnum' => $custnum } )
 410     or return { 'error' => "Can't find invnum" };
 411
 412   #my %return;
 413
 414   return { 'error'        => '',
 415            'invnum'       => $invnum,
 416            'invoice_text' => join('', $cust_bill->print_text ),
 417          };
 418
 419 }
 420
 421 sub list_invoices {
 422   my $p = shift;
 423   my $session = _cache->get($p->{'session_id'})
 424     or return { 'error' => "Can't resume session" }; #better error message
 425
 426   my $custnum = $session->{'custnum'};
 427
 428   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 429     or return { 'error' => "unknown custnum $custnum" };
 430
 431   my @cust_bill = $cust_main->cust_bill;
 432
 433   return  { 'error'       => '',
 434             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 435                                         '_date'  => $_->_date,
 436                                       }
 437                                     } @cust_bill
 438                               ]
 439           };
 440 }
 441
 442 sub cancel {
 443   my $p = shift;
 444   my $session = _cache->get($p->{'session_id'})
 445     or return { 'error' => "Can't resume session" }; #better error message
 446
 447   my $custnum = $session->{'custnum'};
 448
 449   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 450     or return { 'error' => "unknown custnum $custnum" };
 451
 452   my @errors = $cust_main->cancel( 'quiet'=>1 );
 453
 454   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 455
 456   return { 'error' => $error };
 457
 458 }
 459
 460 sub list_pkgs {
 461   my $p = shift;
 462
 463   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 464   return { 'error' => $session } if $context eq 'error';
 465
 466   my $search = { 'custnum' => $custnum };
 467   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 468   my $cust_main = qsearchs('cust_main', $search )
 469     or return { 'error' => "unknown custnum $custnum" };
 470
 471   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 472
 473   my $conf = new FS::Conf;
 474
 475   { 'svcnum'   => $session->{'svcnum'},
 476     'custnum'  => $custnum,
 477     'cust_pkg' => [ map {
 478                           { $_->hash,
 479                             $_->part_pkg->hash,
 480                             part_svc =>
 481                               [ map $_->hashref, $_->available_part_svc ],
 482                             cust_svc =>
 483                               [ map { my $ref = { $_->hash,
 484                                                   label => [ $_->label ],
 485                                                 };
 486                                       $ref->{_password} = $_->svc_x->_password
 487                                         if $context eq 'agent'
 488                                         && $conf->exists('agent-showpasswords')
 489                                         && $_->part_svc->svcdb eq 'svc_acct';
 490                                       $ref;
 491                                     } $_->cust_svc
 492                               ],
 493                           };
 494                         } $cust_main->ncancelled_pkgs
 495                   ],
 496     'small_custview' =>
 497       small_custview( $cust_main, $conf->config('countrydefault') ),
 498   };
 499
 500 }
 501
 502 sub order_pkg {
 503   my $p = shift;
 504
 505   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 506   return { 'error' => $session } if $context eq 'error';
 507
 508   my $search = { 'custnum' => $custnum };
 509   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 510   my $cust_main = qsearchs('cust_main', $search )
 511     or return { 'error' => "unknown custnum $custnum" };
 512
 513   #false laziness w/ClientAPI/Signup.pm
 514
 515   my $cust_pkg = new FS::cust_pkg ( {
 516     'custnum' => $custnum,
 517     'pkgpart' => $p->{'pkgpart'},
 518   } );
 519   my $error = $cust_pkg->check;
 520   return { 'error' => $error } if $error;
 521
 522   my @svc = ();
 523   unless ( $p->{'svcpart'} eq 'none' ) {
 524
 525     my $svcdb;
 526     my $svcpart = '';
 527     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 528       $svcpart = $1;
 529       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 530       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 531       $svcdb = $part_svc->svcdb;
 532     } else {
 533       $svcdb = 'svc_acct';
 534     }
 535     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 536
 537     my %fields = (
 538       'svc_acct'     => [ qw( username _password sec_phrase popnum ) ],
 539       'svc_domain'   => [ qw( domain ) ],
 540       'svc_external' => [ qw( id title ) ],
 541     );
 542
 543     my $svc_x = "FS::$svcdb"->new( {
 544       'svcpart'   => $svcpart,
 545       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 546     } );
 547
 548     if ( $svcdb eq 'svc_acct' ) {
 549       my @acct_snarf;
 550       my $snarfnum = 1;
 551       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 552         my $acct_snarf = new FS::acct_snarf ( {
 553           'machine'   => $p->{"snarf_machine$snarfnum"},
 554           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 555           'username'  => $p->{"snarf_username$snarfnum"},
 556           '_password' => $p->{"snarf_password$snarfnum"},
 557         } );
 558         $snarfnum++;
 559         push @acct_snarf, $acct_snarf;
 560       }
 561       $svc_x->child_objects( \@acct_snarf );
 562     }
 563
 564     my $y = $svc_x->setdefault; # arguably should be in new method
 565     return { 'error' => $y } if $y && !ref($y);
 566
 567     $error = $svc_x->check;
 568     return { 'error' => $error } if $error;
 569
 570     push @svc, $svc_x;
 571
 572   }
 573
 574   use Tie::RefHash;
 575   tie my %hash, 'Tie::RefHash';
 576   %hash = ( $cust_pkg => \@svc );
 577   #msgcat
 578   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 579   return { 'error' => $error } if $error;
 580
 581   my $conf = new FS::Conf;
 582   if ( $conf->exists('signup_server-realtime') ) {
 583
 584     my $old_balance = $cust_main->balance;
 585
 586     my $bill_error = $cust_main->bill;
 587     $cust_main->apply_payments;
 588     $cust_main->apply_credits;
 589     $bill_error = $cust_main->collect;
 590
 591     if (    $cust_main->balance > $old_balance
 592          && $cust_main->balance > 0
 593          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 594       #this makes sense.  credit is "un-doing" the invoice
 595       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 596                           'self-service decline' );
 597       $cust_main->apply_credits( 'order' => 'newest' );
 598
 599       $cust_pkg->cancel('quiet'=>1);
 600       return { 'error' => '_decline', 'bill_error' => $bill_error };
 601     } else {
 602       $cust_pkg->reexport;
 603     }
 604
 605   } else {
 606     $cust_pkg->reexport;
 607   }
 608
 609   return { error => '', pkgnum => $cust_pkg->pkgnum };
 610
 611 }
 612
 613 sub cancel_pkg {
 614   my $p = shift;
 615   my $session = _cache->get($p->{'session_id'})
 616     or return { 'error' => "Can't resume session" }; #better error message
 617
 618   my $custnum = $session->{'custnum'};
 619
 620   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 621     or return { 'error' => "unknown custnum $custnum" };
 622
 623   my $pkgnum = $p->{'pkgnum'};
 624
 625   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 626                                         'pkgnum'  => $pkgnum,   } )
 627     or return { 'error' => "unknown pkgnum $pkgnum" };
 628
 629   my $error = $cust_pkg->cancel( 'quiet'=>1 );
 630   return { 'error' => $error };
 631
 632 }
 633
 634 sub provision_acct {
 635   my $p = shift;
 636
 637   return { 'error' => gettext('passwords_dont_match') }
 638     if $p->{'_password'} ne $p->{'_password2'};
 639   return { 'error' => gettext('empty_password') }
 640     unless length($p->{'_password'});
 641
 642   _provision( 'FS::svc_acct',
 643               [qw(username _password)],
 644               [qw(username _password)],
 645               $p,
 646               @_
 647             );
 648 }
 649
 650 sub provision_external {
 651   my $p = shift;
 652   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
 653   _provision( 'FS::svc_external',
 654               [],
 655               [qw(id title)],
 656               $p,
 657               @_
 658             );
 659 }
 660
 661 sub _provision {
 662   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
 663
 664   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 665   return { 'error' => $session } if $context eq 'error';
 666
 667   my $search = { 'custnum' => $custnum };
 668   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 669   my $cust_main = qsearchs('cust_main', $search )
 670     or return { 'error' => "unknown custnum $custnum" };
 671
 672   my $pkgnum = $p->{'pkgnum'};
 673
 674   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 675                                         'pkgnum'  => $pkgnum,
 676                                                                } )
 677     or return { 'error' => "unknown pkgnum $pkgnum" };
 678
 679   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
 680     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
 681
 682   my $svc_x = $class->new( {
 683     'pkgnum'  => $p->{'pkgnum'},
 684     'svcpart' => $p->{'svcpart'},
 685     map { $_ => $p->{$_} } @$fields
 686   } );
 687   my $error = $svc_x->insert;
 688   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
 689     unless $error;
 690
 691   return { 'svc'   => $part_svc->svc,
 692            'error' => $error,
 693            map { $_ => $svc_x->get($_) } @$return_fields
 694          };
 695
 696 }
 697
 698 sub part_svc_info {
 699   my $p = shift;
 700
 701   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 702   return { 'error' => $session } if $context eq 'error';
 703
 704   my $search = { 'custnum' => $custnum };
 705   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 706   my $cust_main = qsearchs('cust_main', $search )
 707     or return { 'error' => "unknown custnum $custnum" };
 708
 709   my $pkgnum = $p->{'pkgnum'};
 710
 711   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 712                                         'pkgnum'  => $pkgnum,
 713                                                                } )
 714     or return { 'error' => "unknown pkgnum $pkgnum" };
 715
 716   my $svcpart = $p->{'svcpart'};
 717
 718   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
 719                                       'svcpart' => $svcpart,           } )
 720     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
 721   my $part_svc = $pkg_svc->part_svc;
 722
 723   my $conf = new FS::Conf;
 724
 725   return {
 726     'svc'     => $part_svc->svc,
 727     'svcdb'   => $part_svc->svcdb,
 728     'pkgnum'  => $pkgnum,
 729     'svcpart' => $svcpart,
 730     'custnum' => $custnum,
 731
 732     'security_phrase' => 0, #XXX !
 733     'svc_acct_pop'    => [], #XXX !
 734     'popnum'          => '',
 735     'init_popstate'   => '',
 736     'popac'           => '',
 737     'acstate'         => '',
 738
 739     'small_custview' =>
 740       small_custview( $cust_main, $conf->config('countrydefault') ),
 741
 742   };
 743
 744 }
 745
 746 sub unprovision_svc {
 747   my $p = shift;
 748
 749   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 750   return { 'error' => $session } if $context eq 'error';
 751
 752   my $search = { 'custnum' => $custnum };
 753   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 754   my $cust_main = qsearchs('cust_main', $search )
 755     or return { 'error' => "unknown custnum $custnum" };
 756
 757   my $svcnum = $p->{'svcnum'};
 758
 759   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
 760     or return { 'error' => "unknown svcnum $svcnum" };
 761
 762   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
 763     unless $cust_svc->cust_pkg->custnum == $custnum;
 764
 765   my $conf = new FS::Conf;
 766
 767   return { 'svc'   => $cust_svc->part_svc->svc,
 768            'error' => $cust_svc->cancel,
 769            'small_custview' =>
 770              small_custview( $cust_main, $conf->config('countrydefault') ),
 771          };
 772
 773 }
 774
 775 #--
 776
 777 sub _custoragent_session_custnum {
 778   my $p = shift;
 779
 780   my($context, $session, $custnum);
 781   if ( $p->{'session_id'} ) {
 782
 783     $context = 'customer';
 784     $session = _cache->get($p->{'session_id'})
 785       or return ( 'error' => "Can't resume session" ); #better error message
 786     $custnum = $session->{'custnum'};
 787
 788   } elsif ( $p->{'agent_session_id'} ) {
 789
 790     $context = 'agent';
 791     my $agent_cache = new FS::ClientAPI_SessionCache( {
 792       'namespace' => 'FS::ClientAPI::Agent',
 793     } );
 794     $session = $agent_cache->get($p->{'agent_session_id'})
 795       or return ( 'error' => "Can't resume session" ); #better error message
 796     $custnum = $p->{'custnum'};
 797
 798   } else {
 799     return ( 'error' => "Can't resume session" ); #better error message
 800   }
 801
 802   ($context, $session, $custnum);
 803
 804 }
 805
 806 1;
 807