FS/FS/ClientAPI/MasonComponent.pm

   1 package FS::ClientAPI::MasonComponent;
   2
   3 use strict;
   4 use vars qw( $cache $DEBUG $me );
   5 use subs qw( _cache );
   6 use FS::Mason qw( mason_interps );
   7 use FS::Conf;
   8 use FS::ClientAPI_SessionCache;
   9 use FS::Record qw( qsearch qsearchs );
  10 use FS::cust_main;
  11 use FS::part_pkg;
  12
  13 $DEBUG = 0;
  14 $me = '[FS::ClientAPI::MasonComponent]';
  15
  16 my %allowed_comps = map { $_=>1 } qw(
  17   /elements/select-did.html
  18   /misc/areacodes.cgi
  19   /misc/exchanges.cgi
  20   /misc/phonenums.cgi
  21   /misc/states.cgi
  22   /misc/counties.cgi
  23   /misc/svc_acct-domains.cgi
  24   /misc/part_svc-columns.cgi
  25 );
  26
  27 my %session_comps = map { $_=>1 } qw(
  28   /elements/location.html
  29   /edit/cust_main/first_pkg/select-part_pkg.html
  30 );
  31
  32 my %session_callbacks = (
  33
  34   '/elements/location.html' => sub {
  35     my( $custnum, $argsref ) = @_;
  36     my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
  37       or return "unknown custnum $custnum";
  38     my %args = @$argsref;
  39     $args{object} = $cust_main->bill_location;
  40     @$argsref = ( %args );
  41     return ''; #no error
  42   },
  43
  44   '/edit/cust_main/first_pkg/select-part_pkg.html' => sub {
  45     my( $custnum, $argsref ) = @_;
  46     my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
  47       or return "unknown custnum $custnum";
  48
  49     my $pkgpart = $cust_main->agent->pkgpart_hashref;
  50
  51     #false laziness w/ edit/cust_main/first_pkg.html
  52     my @first_svc = ( 'svc_acct', 'svc_phone' );
  53
  54     my @part_pkg =
  55       grep { $_->svcpart(\@first_svc)
  56              && ( $pkgpart->{ $_->pkgpart }
  57                   || ( $_->agentnum && $_->agentnum == $cust_main->agentnum )
  58                 )
  59            }
  60       qsearch( 'part_pkg', { 'disabled' => '' }, '', 'ORDER BY pkg' ); # case?
  61
  62     my $conf = new FS::Conf;
  63     if ( $conf->exists('pkg-addon_classnum') ) {
  64
  65       my %classnum = map  { ( $_->addon_classnum => 1 ) }
  66                      grep { $_->freq !~ /^0/ }
  67                      map  { $_->part_pkg }
  68                           $cust_main->ncancelled_pkgs;
  69
  70       unless ( $classnum{''} || ! keys %classnum ) {
  71         @part_pkg = grep $classnum{ $_->classnum }, @part_pkg;
  72       }
  73     }
  74
  75     my %args = @$argsref;
  76     $args{part_pkg} = \@part_pkg;
  77     $args{first_svc} = \@first_svc;
  78     @$argsref = ( %args );
  79     return ''; #no error
  80
  81   },
  82
  83 );
  84
  85 my $outbuf;
  86 my( $fs_interp, $rt_interp ) = mason_interps('standalone', 'outbuf'=>\$outbuf);
  87
  88 sub mason_comp {
  89   my $packet = shift;
  90
  91   warn "$me mason_comp called on $packet\n" if $DEBUG;
  92
  93   my $comp = $packet->{'comp'};
  94   unless ( $allowed_comps{$comp} || $session_comps{$comp} ) {
  95     return { 'error' => 'Illegal component' };
  96   }
  97
  98   my @args = $packet->{'args'} ? @{ $packet->{'args'} } : ();
  99
 100   if ( $session_comps{$comp} ) {
 101
 102     my $session = _cache->get($packet->{'session_id'})
 103       or return ( 'error' => "Can't resume session" ); #better error message
 104     my $custnum = $session->{'custnum'};
 105
 106     my $error = &{ $session_callbacks{$comp} }( $custnum, \@args );
 107     return { 'error' => $error } if $error;
 108
 109   }
 110
 111   my $conf = new FS::Conf;
 112   $FS::Mason::Request::FSURL = $conf->config('selfservice_server-base_url');
 113   $FS::Mason::Request::FSURL .= '/' unless $FS::Mason::Request::FSURL =~ /\/$/;
 114   $FS::Mason::Request::QUERY_STRING = $packet->{'query_string'} || '';
 115
 116   $outbuf = '';
 117   $fs_interp->exec($comp, @args); #only FS for now alas...
 118
 119   #errors? (turn off in-line error reporting?)
 120
 121   return { 'output' => $outbuf };
 122
 123 }
 124
 125 #hmm
 126 sub _cache {
 127   $cache ||= new FS::ClientAPI_SessionCache( {
 128                'namespace' => 'FS::ClientAPI::MyAccount',
 129              } );
 130 }
 131
 132 1;