FS/FS/ClientAPI/Agent.pm

   1 package FS::ClientAPI::Agent;
   2
   3 #some false laziness w/MyAccount
   4
   5 use strict;
   6 use vars qw($cache);
   7 use Digest::MD5 qw(md5_hex);
   8 use Cache::SharedMemoryCache; #store in db?
   9 use FS::Record qw(qsearchs); # qsearch dbdef dbh);
  10 use FS::agent;
  11 use FS::cust_main qw(smart_search);
  12
  13 use FS::ClientAPI;
  14 FS::ClientAPI->register_handlers(
  15   'Agent/agent_login'          => \&agent_login,
  16   'Agent/agent_logout'         => \&agent_logout,
  17   'Agent/agent_info'           => \&agent_info,
  18   'Agent/agent_list_customers' => \&agent_list_customers,
  19 );
  20
  21 #store in db?
  22 my $cache = new Cache::SharedMemoryCache( {
  23    'namespace' => 'FS::ClientAPI::Agent',
  24 } );
  25
  26 sub agent_login {
  27   my $p = shift;
  28
  29   #don't allow a blank login to first unconfigured agent with no user/pass
  30   return { error => 'Must specify your reseller username and password.' }
  31     unless length($p->{'username'}) && length($p->{'password'});
  32
  33   my $agent = qsearchs( 'agent', {
  34     'username'  => $p->{'username'},
  35     '_password' => $p->{'password'},
  36   } );
  37
  38   unless ( $agent ) { return { error => 'Incorrect password.' } }
  39
  40   my $session = {
  41     'agentnum' => $agent->agentnum,
  42     'agent'    => $agent->agent,
  43   };
  44
  45   my $session_id;
  46   do {
  47     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  48   } until ( ! defined $cache->get($session_id) ); #just in case
  49
  50   $cache->set( $session_id, $session, '1 hour' );
  51
  52   { 'error'      => '',
  53     'session_id' => $session_id,
  54   };
  55 }
  56
  57 sub agent_logout {
  58   my $p = shift;
  59   if ( $p->{'session_id'} ) {
  60     $cache->remove($p->{'session_id'});
  61     return { 'error' => '' };
  62   } else {
  63     return { 'error' => "Can't resume session" }; #better error message
  64   }
  65 }
  66
  67 sub agent_info {
  68   my $p = shift;
  69
  70   my $session = $cache->get($p->{'session_id'})
  71     or return { 'error' => "Can't resume session" }; #better error message
  72
  73   #my %return;
  74
  75   my $agentnum = $session->{'agentnum'};
  76
  77   my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } )
  78     or return { 'error' => "unknown agentnum $agentnum" };
  79
  80   { 'error'        => '',
  81     'agentnum'     => $agentnum,
  82     'agent'        => $agent->agent,
  83     'num_prospect' => $agent->num_prospect_cust_main,
  84     'num_active'   => $agent->num_active_cust_main,
  85     'num_susp'     => $agent->num_susp_cust_main,
  86     'num_cancel'   => $agent->num_cancel_cust_main,
  87     #%return,
  88   };
  89
  90 }
  91
  92 sub agent_list_customers {
  93   my $p = shift;
  94
  95   my $session = $cache->get($p->{'session_id'})
  96     or return { 'error' => "Can't resume session" }; #better error message
  97
  98   #my %return;
  99
 100   my $agentnum = $session->{'agentnum'};
 101
 102   my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } )
 103     or return { 'error' => "unknown agentnum $agentnum" };
 104
 105   my @cust_main = smart_search( 'search'   => $p->{'search'},
 106                                 'agentnum' => $agentnum,
 107                               );
 108
 109   #aggregate searches
 110   push @cust_main,
 111     map $agent->$_(), map $_.'_cust_main',
 112       grep $p->{$_}, qw( prospect active susp cancel );
 113
 114   #eliminate dups?
 115   my %saw = ();
 116   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 117
 118   { customers => [ map {
 119                          my $cust_main = $_;
 120                          my $hashref = $cust_main->hashref;
 121                          $hashref->{$_} = $cust_main->$_()
 122                            foreach qw(name status statuscolor);
 123                          delete $hashref->{$_} foreach qw( payinfo paycvv );
 124                          $hashref;
 125                    } @cust_main
 126                  ],
 127   }
 128
 129 }
 130