+=item sms_cdr_carrier
+
+Returns the L<FS::cdr_carrier> assigned as the SMS carrier for this phone.
+
+=cut
+
+sub sms_cdr_carrier {
+ my $self = shift;
+ return '' unless $self->sms_carrierid;
+ qsearchs('cdr_carrier', { 'carrierid' => $self->sms_carrierid } );
+}
+
+=item sms_carriername
+
+Returns the name of the SMS carrier, or an empty string if there isn't one.
+
+=cut
+
+sub sms_carriername {
+ my $self = shift;
+ my $cdr_carrier = $self->sms_cdr_carrier or return '';
+ $cdr_carrier->carriername;
+}
+
+=item svc_circuit
+
+Returns the L<FS::svc_circuit> assigned as the trunk for this phone line.
+
+=item circuit_label
+
+Returns the label of the circuit (the part_svc label followed by the
+circuit ID), or an empty string if there isn't one.
+
+=cut
+
+sub svc_circuit {
+ my $self = shift;
+ my $svcnum = $self->get('circuit_svcnum') or return '';
+ return FS::svc_circuit->by_key($svcnum);
+}
+
+sub circuit_label {
+ my $self = shift;
+ my $svc_circuit = $self->svc_circuit or return '';
+ return join(' ', $svc_circuit->part_svc->svc, $svc_circuit->circuit_id);
+}
+
+=item phone_device
+
+Returns any FS::phone_device records associated with this service.
+
+=cut
+
+#override location_Mixin version cause we want to try the cust_pkg location
+#in between us and cust_main
+# XXX what to do in the unlinked case??? return a pseudo-object that returns
+# empty fields?
+sub cust_location_or_main {
+ my $self = shift;
+ return $self->cust_location if $self->locationnum;
+ my $cust_pkg = $self->cust_svc->cust_pkg;
+ $cust_pkg ? $cust_pkg->cust_location_or_main : '';
+}
+
+=item phone_name_or_cust
+
+Returns the C<phone_name> field if it has a value, or the package contact
+name if there is one, or the customer contact name.
+
+=cut
+
+sub phone_name_or_cust {
+ my $self = shift;
+ if ( $self->phone_name ) {
+ return $self->phone_name;
+ }
+ my $cust_pkg = $self->cust_svc->cust_pkg or return '';
+ if ( $cust_pkg->contactnum ) {
+ return $cust_pkg->contact->firstlast;
+ } else {
+ return $cust_pkg->cust_main->name_short;
+ }
+}
+
+=item psearch_cdrs OPTIONS
+
+Returns a paged search (L<FS::PagedSearch>) for Call Detail Records
+associated with this service. By default, "associated with" means that
+either the "src" or the "charged_party" field of the CDR matches the
+"phonenum" field of the service. To access the CDRs themselves, call
+"->fetch" on the resulting object.
+
+=over 2
+
+Accepts the following options:
+
+=item for_update => 1: SELECT the CDRs "FOR UPDATE".
+
+=item status => "" (or "processing-tiered", "done"): Return only CDRs with that processing status.
+
+=item inbound => 1: Return CDRs for inbound calls (that is, those that match
+on 'dst'). With "status", will filter on inbound processing status.
+
+=item default_prefix => "XXX": Also accept the phone number of the service prepended
+with the chosen prefix.
+
+=item begin, end: Start and end of a date range, as unix timestamp.
+
+=item cdrtypenum: Only return CDRs with this type.
+
+=item calltypenum: Only return CDRs with this call type.
+
+=item disable_src => 1: Only match on 'charged_party', not 'src'.
+
+=item disable_charged_party => 1: Only match on 'src', not 'charged_party'.
+
+=item nonzero: Only return CDRs where duration > 0.
+
+=item by_svcnum: not supported for svc_phone
+
+=item billsec_sum: Instead of returning all of the CDRs, return a single
+record (as an L<FS::cdr> object) with the sum of the 'billsec' field over
+the entire result set.
+
+=back
+
+=cut
+
+sub psearch_cdrs {
+ my($self, %options) = @_;
+
+ unless ( $options{'billsec_sum'} ) {
+ #fixes a weird sequential scan of the whole cdr table on startdate, but only
+ # for a few charged_party values here and there.
+ # Pg 9.1 only? need to retest on 9.4, 9.6
+ dbh->do('SET enable_indexscan TO OFF');
+ }
+
+ my @fields;
+ my %hash;
+ my @where;
+
+ if ( $options{'inbound'} ) {
+
+ @fields = ( 'dst' );
+ if ( exists($options{'status'}) ) {
+ my $status = $options{'status'};
+ if ( $status ) {
+ push @where, 'EXISTS ( SELECT 1 FROM cdr_termination '.
+ 'WHERE cdr.acctid = cdr_termination.acctid '.
+ "AND cdr_termination.status = '$status' ". #quoting kludge
+ 'AND cdr_termination.termpart = 1 )';
+ } else {
+ push @where, 'NOT EXISTS ( SELECT 1 FROM cdr_termination '.
+ 'WHERE cdr.acctid = cdr_termination.acctid '.
+ 'AND cdr_termination.termpart = 1 )';
+ }
+ }
+
+ } else {
+
+ push @fields, 'charged_party' unless $options{'disable_charged_party'};
+ push @fields, 'src' unless $options{'disable_src'};
+ $hash{'freesidestatus'} = $options{'status'}
+ if exists($options{'status'});
+ }
+
+ if ($options{'cdrtypenum'}) {
+ $hash{'cdrtypenum'} = $options{'cdrtypenum'};
+ }
+ if ($options{'calltypenum'}) {
+ $hash{'calltypenum'} = $options{'calltypenum'};
+ }
+
+ my $for_update = $options{'for_update'} ? 'FOR UPDATE' : '';
+
+ my $number = $self->phonenum;
+
+ my $prefix = $options{'default_prefix'};
+
+ my @orwhere = map " $_ = '$number' ", @fields;
+ push @orwhere, map " $_ = '$prefix$number' ", @fields
+ if defined($prefix) && length($prefix);
+ if ( $prefix && $prefix =~ /^\+(\d+)$/ ) {
+ push @orwhere, map " $_ = '$1$number' ", @fields
+ }
+
+ push @where, ' ( '. join(' OR ', @orwhere ). ' ) ';
+
+ if ( $options{'begin'} ) {
+ push @where, 'startdate >= '. $options{'begin'};
+ }
+ if ( $options{'end'} ) {
+ push @where, 'startdate < '. $options{'end'};
+ }
+ if ( $options{'nonzero'} ) {
+ push @where, 'duration > 0';
+ }
+
+ my $extra_sql = ( keys(%hash) ? ' AND ' : ' WHERE ' ). join(' AND ', @where );
+
+ psearch( {
+ 'table' => 'cdr',
+ 'hashref' => \%hash,
+ 'extra_sql' => $extra_sql,
+ 'order_by' => $options{'billsec_sum'} ? '' : "ORDER BY startdate $for_update",
+ 'select' => $options{'billsec_sum'} ? 'sum(billsec) as billsec_sum' : '*',
+ } );
+}
+
+=item get_cdrs (DEPRECATED)
+
+Like psearch_cdrs, but returns all the L<FS::cdr> objects at once, in a
+single list. Arguments are the same as for psearch_cdrs. This can take
+an unreasonably large amount of memory and is best avoided.
+
+=cut
+
+sub get_cdrs {
+ my $self = shift;
+ my $psearch = $self->psearch_cdrs(@_);
+ qsearch ( $psearch->{query} )
+}
+
+=item sum_cdrs
+
+Takes the same options as psearch_cdrs, but returns a single row containing
+"count" (the number of CDRs) and the sums of the following fields: duration,
+billsec, rated_price, rated_seconds, rated_minutes.
+
+Note that if any calls are not rated, their rated_* fields will be null.
+If you want to use those fields, pass the 'status' option to limit to
+calls that have been rated. This is intentional; please don't "fix" it.
+
+=cut
+
+sub sum_cdrs {
+ my $self = shift;
+ my $psearch = $self->psearch_cdrs(@_);
+ $psearch->{query}->{'select'} = join(',',
+ 'COUNT(*) AS count',
+ map { "SUM($_) AS $_" }
+ qw(duration billsec rated_price rated_seconds rated_minutes)
+ );
+ # hack
+ $psearch->{query}->{'extra_sql'} =~ s/ ORDER BY.*$//;
+ qsearchs ( $psearch->{query} );
+}
+
+=back
+
+=head1 CLASS METHODS
+
+=over 4
+
+=item e911_classes
+
+Returns a hashref of allowed values and descriptions for the C<e911_class>
+field.
+
+=item e911_types
+
+Returns a hashref of allowed values and descriptions for the C<e911_type>
+field.
+
+=cut
+
+sub e911_classes {
+ tie my %x, 'Tie::IxHash', (
+ 1 => 'Residence',
+ 2 => 'Business',
+ 3 => 'Residence PBX',
+ 4 => 'Business PBX',
+ 5 => 'Centrex',
+ 6 => 'Coin 1 Way out',
+ 7 => 'Coin 2 Way',
+ 8 => 'Mobile',
+ 9 => 'Residence OPX',
+ 0 => 'Business OPX',
+ A => 'Customer Operated Coin Telephone',
+ #B => not available
+ G => 'Wireless Phase I',
+ H => 'Wireless Phase II',
+ I => 'Wireless Phase II with Phase I information',
+ V => 'VoIP Services Default',
+ C => 'VoIP Residence',
+ D => 'VoIP Business',
+ E => 'VoIP Coin/Pay Phone',
+ F => 'VoIP Wireless',
+ J => 'VoIP Nomadic',
+ K => 'VoIP Enterprise Services',
+ T => 'Telematics',
+ );
+ \%x;
+}
+
+sub e911_types {
+ tie my %x, 'Tie::IxHash', (
+ 0 => 'Not FX nor Non-Published',
+ 1 => 'FX in 911 serving area',
+ 2 => 'FX outside 911 serving area',
+ 3 => 'Non-Published',
+ 4 => 'Non-Published FX in serving area',
+ 5 => 'Non-Published FX outside serving area',
+ 6 => 'Local Ported Number',
+ 7 => 'Interim Ported Number',
+ );
+ \%x;
+}
+