+use vars qw( $myaccount_cache );
+sub _myaccount_cache {
+ $myaccount_cache ||= new FS::ClientAPI_SessionCache( {
+ 'namespace' => 'FS::ClientAPI::MyAccount',
+ } );
+}
+
+sub capture_payment {
+ my $packet = shift;
+
+ warn "$me capture_payment called on $packet\n" if $DEBUG;
+
+ ###
+ # identify processor/gateway from called back URL
+ ###
+
+ my $conf = new FS::Conf;
+
+ my $payment_gateway;
+ if ( my $gwnum = $conf->config('selfservice-payment_gateway') ) {
+ $payment_gateway = qsearchs('payment_gateway', { 'gatewaynum' => $gwnum })
+ or die "configured gatewaynum $gwnum not found!";
+ }
+ else {
+ my $url = $packet->{url};
+
+ $payment_gateway = qsearchs('payment_gateway',
+ { 'gateway_callback_url' => popurl(0, $url) }
+ );
+ if (!$payment_gateway) {
+
+ my ( $processor, $login, $password, $action, @bop_options ) =
+ $conf->config('business-onlinepayment');
+ $action ||= 'normal authorization';
+ pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
+ die "No real-time processor is enabled - ".
+ "did you set the business-onlinepayment configuration value?\n"
+ unless $processor;
+
+ $payment_gateway = new FS::payment_gateway( {
+ gateway_namespace => $conf->config('business-onlinepayment-namespace'),
+ gateway_module => $processor,
+ gateway_username => $login,
+ gateway_password => $password,
+ gateway_action => $action,
+ options => [ ( @bop_options ) ],
+ });
+ }
+ }
+
+ die "No real-time third party processor is enabled - ".
+ "did you set the business-onlinepayment configuration value?\n*"
+ unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
+
+ ###
+ # locate pending transaction
+ ###
+
+ eval "use Business::OnlineThirdPartyPayment";
+ die $@ if $@;
+
+ my $transaction =
+ new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
+ @{ [ $payment_gateway->options ] },
+ );
+
+ my $paypendingnum = $transaction->reference($packet->{data});
+
+ my $cust_pay_pending =
+ qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
+
+ unless ($cust_pay_pending) {
+ my $bill_error = "No payment is being processed with id $paypendingnum".
+ "; Transaction aborted.";
+ return { error => '_decline', bill_error => $bill_error };
+ }
+
+ if ($cust_pay_pending->status ne 'thirdparty') {
+ my $bill_error = "Payment with id $paypendingnum is not thirdparty, but ".
+ $cust_pay_pending->status. "; Transaction aborted.";
+ return { error => '_decline', bill_error => $bill_error };
+ }
+
+ my $cust_main = $cust_pay_pending->cust_main;
+ if ( $packet->{cancel} ) {
+ # the user has chosen not to make this payment
+ # (probably should be a separate API call, but I don't want to duplicate
+ # all of the above...which should eventually go away)
+ my $error = $cust_pay_pending->delete;
+ # don't show any errors related to this; they're not meaningful
+ warn "error canceling pending payment $paypendingnum: $error\n" if $error;
+ return { 'error' => '_cancel',
+ 'session_id' => $cust_pay_pending->session_id };
+ } else {
+ # create the payment
+ my $bill_error =
+ $cust_main->realtime_botpp_capture( $cust_pay_pending,
+ %{$packet->{data}},
+ apply => 1,
+ );
+
+ return { 'error' => ( $bill_error->{bill_error} ? '_decline' : '' ),
+ %$bill_error,
+ };
+ }
+
+}
+
+=item get_agentnum PACKET
+
+Given a PACKET from the signup server, looks up the agentnum to use for signing
+up a customer. This will use 'session_id' if the agent is authenticated,
+otherwise 'agentnum', otherwise the 'signup_server-default_agentnum' config. If
+the agent can't be found, returns an error packet.
+
+=cut
+
+sub get_agentnum {
+ my $packet = shift;
+ my $conf = new FS::Conf;
+ my $agentnum;
+ if ( exists $packet->{'session_id'} ) {
+ my $cache = new FS::ClientAPI_SessionCache( {
+ 'namespace' => 'FS::ClientAPI::Agent',
+ } );
+ my $session = $cache->get($packet->{'session_id'});
+ if ( $session ) {
+ $agentnum = $session->{'agentnum'};
+ } else {
+ return { 'error' => "Can't resume session" }; #better error message
+ }
+ } else {
+ $agentnum = $packet->{agentnum}
+ || $conf->config('signup_server-default_agentnum');
+ }
+ if ( $agentnum and FS::agent->count('agentnum = ?', $agentnum) ) {
+ return $agentnum;
+ }
+ return { 'error' => 'Signup is not configured' };
+}
+
+=item new_prospect PACKET
+
+Creates a new L<FS::prospect_main> entry. PACKET must contain:
+
+- either agentnum or session_id; if not, signup_server-default_agentnum will
+be used and must not be empty
+
+- either refnum or referral_title; if not, signup_server-default_refnum will
+be used and must not be empty
+
+- last and first (names), and optionally company and title
+
+- address1, city, state, country, zip, and optionally address2
+
+- emailaddress
+
+and can also contain:
+
+- one or more of phone_daytime, phone_night, phone_mobile, and phone_fax
+
+- a 'comment' (will be attached to the contact)
+
+State and country will be normalized to Freeside state/country codes if
+necessary.
+
+=cut
+
+sub new_prospect {
+
+ my $packet = shift;
+ warn "$me new_prospect called\n".Dumper($packet) if $DEBUG;
+
+ my $oldAutoCommit = $FS::UID::AutoCommit;
+ local $FS::UID::AutoCommit = 0;
+ my $dbh = dbh;
+ my $conf = FS::Conf->new;
+
+ my $error;
+
+ my $agentnum = get_agentnum($packet);
+ return $agentnum if ref $agentnum;
+ my $refnum;
+ if ( my $title = $packet->{referral_title} ) {
+ my $part_referral = qsearchs('part_referral', {
+ 'agentnum' => $agentnum,
+ 'title' => $title,
+ });
+ $part_referral ||= qsearchs('part_referral', {
+ 'agentnum' => '',
+ 'title' => $title,
+ });
+ if (!$part_referral) {
+ return { error => "Unknown referral type: '$title'" };
+ }
+ $refnum = $part_referral->refnum;
+ } elsif ( $packet->{refnum} ) {
+ $refnum = $packet->{refnum};
+ }
+ $refnum ||= $conf->config('signup_server-default_refnum');
+ return { error => "Signup referral type is not configured" } if !$refnum;
+
+ my $prospect = FS::prospect_main->new({
+ 'agentnum' => $agentnum,
+ 'refnum' => $refnum,
+ 'company' => $packet->{company},
+ });
+
+ my $location = FS::cust_location->new;
+ foreach ( qw(address1 address2 city county zip ) ) {
+ $location->set($_, $packet->{$_});
+ }
+ # normalize country and state if they're not already ISO codes
+ # easier than doing it on the client side--we already have the tables here
+ my $country = $packet->{country};
+ my $state = $packet->{state};
+ if (length($country) > 2) {
+ # it likes title case
+ $country = join(' ', map ucfirst, split(/\s+/, $country));
+ my $lsc = Locale::SubCountry->new($country);
+ if ($lsc) {
+ $country = uc($lsc->country_code);
+
+ if ($lsc->has_sub_countries) {
+ if ( $lsc->full_name($state) eq 'unknown' ) {
+ # then we were probably given a full name, so resolve it
+ $state = $lsc->code($state);
+ if ( $state eq 'unknown' ) {
+ # doesn't resolve as a full name either, return an error
+ $error = "Unknown state: ".$packet->{state};
+ } else {
+ $state = uc($state);
+ }
+ }
+ } # else state doesn't matter
+ } else {
+ # couldn't find the country in LSC
+ $error = "Unknown country: $country";
+ }
+ }
+ $location->set('country', $country);
+ $location->set('state', $state);
+ $prospect->set('cust_location', $location);
+
+ $error ||= $prospect->insert; # also does location
+ return { error => $error } if $error;
+
+ my $contact = FS::contact->new({
+ prospectnum => $prospect->prospectnum,
+ locationnum => $location->locationnum,
+ invoice_dest => 'Y',
+ });
+ # use emailaddress pseudo-field behavior here
+ foreach (qw(last first title emailaddress comment)) {
+ $contact->set($_, $packet->{$_});
+ }
+ $error = $contact->insert;
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return { error => $error };
+ }
+
+ foreach my $phone_type (qsearch('phone_type', {})) {
+ my $key = 'phone_' . lc($phone_type->typename);
+ my $phonenum = $packet->{$key};
+ if ( $phonenum ) {
+ # just to not have to supply country code from the other end
+ my $number = Number::Phone->new($location->country, $phonenum);
+ if (!$number) {
+ $error = 'invalid phone number';
+ } else {
+ my $phone = FS::contact_phone->new({
+ contactnum => $contact->contactnum,
+ phonenum => $phonenum,
+ countrycode => $number->country_code,
+ phonetypenum => $phone_type->phonetypenum,
+ });
+ $error = $phone->insert;
+ }
+ if ( $error ) {
+ $dbh->rollback if $oldAutoCommit;
+ return { error => $phone_type->typename . ' phone: ' . $error };
+ }
+ }
+ } # foreach $phone_type
+
+ $dbh->commit if $oldAutoCommit;
+ return { prospectnum => $prospect->prospectnum };
+}
+