summaryrefslogtreecommitdiff
path: root/FS/FS/svc_cable.pm
blob: daaf680c59150a5409f5484b079e40ad773b88f7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
package FS::svc_cable;
use base qw( FS::MAC_Mixin
             FS::svc_Common
           ); #FS::device_Common

use strict;
use Tie::IxHash;

=head1 NAME

FS::svc_cable - Object methods for svc_cable records

=head1 SYNOPSIS

  use FS::svc_cable;

  $record = new FS::svc_cable \%hash;
  $record = new FS::svc_cable { 'column' => 'value' };

  $error = $record->insert;

  $error = $new_record->replace($old_record);

  $error = $record->delete;

  $error = $record->check;

=head1 DESCRIPTION

An FS::svc_cable object represents a cable subscriber.  FS::svc_cable inherits
from FS::Record.  The following fields are currently supported:

=over 4

=item svcnum

primary key

=item providernum

Provider (see L<FS::cable_provider>)

=item ordernum

Provider order number

=item modelnum

Cable device model (see L<FS::cable_model>)

=item serialnum

Cable device serial number

=item mac_addr

Cable device MAC address

=back

=head1 METHODS

=over 4

=item new HASHREF

Creates a new record.  To add the record to the database, see L<"insert">.

Note that this stores the hash reference, not a distinct copy of the hash it
points to.  You can ask the object for a copy with the I<hash> method.

=cut

sub table { 'svc_cable'; }

sub table_dupcheck_fields { ( 'serialnum', 'mac_addr' ); }

sub search_sql {
  my( $class, $string ) = @_;
  if ( $string =~ /^([A-F0-9]{12})$/i ) {
    $class->search_sql_field('mac_addr', uc($string));
  } elsif ( $string =~ /^(([A-F0-9]{2}:){5}([A-F0-9]{2}))$/i ) {
    $string =~ s/://g;
    $class->search_sql_field('mac_addr', uc($string) );
  } elsif ( $string =~ /^(\w+)$/ ) {
    $class->search_sql_field('serialnum', $1);
  } else {
    '1 = 0'; #false
  }
}

sub table_info {

  tie my %fields, 'Tie::IxHash',
    'svcnum'      => 'Service',
    'providernum' => { label             => 'Provider',
                       type              => 'select-cable_provider',
                       disable_inventory => 1,
                       disable_select    => 1,
                       value_callback    => sub {
                                              my $svc = shift;
                                              my $p = $svc->cable_provider;
                                              $p ? $p->provider : '';
                                            },
                     },
    'ordernum'    => 'Order number', #XXX "Circuit ID/Order number"
    'modelnum'    => { label             => 'Model',
                       type              => 'select-cable_model',
                       disable_inventory => 1,
                       disable_select    => 1,
                       value_callback    => sub {
                                              my $svc = shift;
                                              $svc->cable_model->model_name;
                                            },
                     },
    'serialnum'   => 'Serial number',
    'mac_addr'    => { label          => 'MAC address',
                       type           => 'input-mac_addr',
                       value_callback => sub {
                                           my $svc = shift;
                                           $svc->mac_addr_formatted('U',':');
                                         },
                     },
  ;

  {
    'name'            => 'Cable Subscriber',
    #'name_plural'     => '', #optional,
    #'longname_plural' => '', #optional
    'fields'          => \%fields,
    'sorts'           => [ 'svcnum', 'serialnum', 'mac_addr', ],
    'display_weight'  => 54,
    'cancel_weight'   => 70, #?  no deps, so
  };
}

=item label

Returns the MAC address and serial number.

=cut

sub label {
  my $self = shift;
  my $part_svc = $self->cust_svc->part_svc;
  my @label = ();
  push @label, 'MAC:'. $self->mac_addr_pretty
    if $self->mac_addr;
  if ( $self->serialnum ) {
    my $serialnum_label = $part_svc->part_svc_column('serialnum');
    push @label,
      ($serialnum_label && $serialnum_label->columnlabel || 'Serial#').
      $self->serialnum;
  }
  return join(', ', @label);
}

=item insert

Adds this record to the database.  If there is an error, returns the error,
otherwise returns false.

=item delete

Delete this record from the database.

=item replace OLD_RECORD

Replaces the OLD_RECORD with this one in the database.  If there is an error,
returns the error, otherwise returns false.

=item check

Checks all fields to make sure this is a valid record.  If there is
an error, returns the error, otherwise returns false.  Called by the insert
and replace methods.

=cut

sub check {
  my $self = shift;

  my $error = 
       $self->ut_numbern('svcnum')
    || $self->ut_foreign_keyn('providernum', 'cable_provider', 'providernum')
    || $self->ut_alphan('ordernum')
    || $self->ut_foreign_key('modelnum', 'cable_model', 'modelnum')
    || $self->ut_alphan('serialnum')
    || $self->ut_mac_addrn('mac_addr')
  ;
  return $error if $error;

  $self->SUPER::check;
}

sub _check_duplicate {
  my $self = shift;

  # Not reliable checks because the table isn't locked, but that's why we have
  # unique indices.  These are just to give friendlier error messages.

  if ( $self->mac_addr ) {
    my @dup_mac;
    @dup_mac = $self->find_duplicates('global', 'mac_addr');
    if ( @dup_mac ) {
      return "MAC address in use (svcnum ".$dup_mac[0]->svcnum.")";
    }
  }

  if ( $self->serialnum ) {
    my @dup_serial;
    @dup_serial = $self->find_duplicates('global', 'modelnum', 'serialnum');
    if ( @dup_serial ) {
      return "Serial number in use (svcnum ".$dup_serial[0]->svcnum.")";
    }
  }

  '';
}

=item cable_provider

Returns the cable_provider object for this record.

=item cable_model

Returns the cable_model object for this record.

=back

=head1 BUGS

=head1 SEE ALSO

L<FS::Record>, schema.html from the base documentation.

=cut

1;