1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
|
package FS::router;
use base qw( FS::m2m_Common FS::Record );
use strict;
use FS::Record qw( qsearchs qsearch dbh );
use FS::addr_block;
=head1 NAME
FS::router - Object methods for router records
=head1 SYNOPSIS
use FS::router;
$record = new FS::router \%hash;
$record = new FS::router { 'column' => 'value' };
$error = $record->insert;
$error = $new_record->replace($old_record);
$error = $record->delete;
$error = $record->check;
=head1 DESCRIPTION
An FS::router record describes a broadband router, such as a DSLAM or a wireless
access point. FS::router inherits from FS::Record. The following
fields are currently supported:
=over 4
=item routernum - primary key
=item routername - descriptive name for the router
=item svcnum - svcnum of the owning FS::svc_broadband, if appropriate
=item manual_addr - set to 'Y' to allow services linked to this router
to have any IP address, rather than one in an address block belonging
to the router.
=back
=head1 METHODS
=over 4
=item new HASHREF
Create a new record. To add the record to the database, see "insert".
=cut
sub table { 'router'; }
=item insert
Adds this record to the database. If there is an error, returns the error,
otherwise returns false.
If the pseudo-field 'blocknum' is set to an L<FS::addr_block> number, then
that address block will be assigned to this router. Currently only one
block can be assigned this way.
=cut
sub insert {
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my $self = shift;
my $error = $self->SUPER::insert(@_);
return $error if $error;
if ( $self->blocknum ) {
my $block = FS::addr_block->by_key($self->blocknum);
if ($block) {
if ($block->routernum) {
$error = "block ".$block->cidr." is already assigned to a router";
} else {
$block->set('routernum', $self->routernum);
$block->set('manual_flag', 'Y');
$error = $block->replace;
}
} else {
$error = "blocknum ".$self->blocknum." not found";
}
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
}
$dbh->commit if $oldAutoCommit;
return $error;
}
=item replace OLD_RECORD
Replaces OLD_RECORD with this one in the database. If there is an error,
returns the error, otherwise returns false.
=cut
sub replace {
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my $self = shift;
my $old = shift || $self->replace_old;
my $error = $self->SUPER::replace($old, @_);
return $error if $error;
if ( defined($self->blocknum) ) {
#warn "FS::router::replace: blocknum = ".$self->blocknum."\n";
# then release any blocks we're already holding
foreach my $block ($self->addr_block) {
$block->set('routernum', 0);
$block->set('manual_flag', '');
$error ||= $block->replace;
}
if ( !$error and $self->blocknum > 0 ) {
# and, if the new blocknum is a real blocknum, assign it
my $block = FS::addr_block->by_key($self->blocknum);
if ( $block ) {
$block->set('routernum', $self->routernum);
$block->set('manual_flag', '');
$error ||= $block->replace;
} else {
$error = "blocknum ".$self->blocknum." not found";
}
}
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
}
$dbh->commit if $oldAutoCommit;
return $error;
}
=item check
Checks all fields to make sure this is a valid record. If there is an error,
returns the error, otherwise returns false. Called by the insert and replace
methods.
=cut
sub check {
my $self = shift;
my $error =
$self->ut_numbern('routernum')
|| $self->ut_text('routername')
|| $self->ut_enum('manual_addr', [ '', 'Y' ])
|| $self->ut_agentnum_acl('agentnum', 'Broadband global configuration')
|| $self->ut_foreign_keyn('svcnum', 'cust_svc', 'svcnum')
;
return $error if $error;
$self->SUPER::check;
}
=item delete
Deallocate all address blocks from this router and delete it.
=cut
sub delete {
my $self = shift;
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my $error;
foreach my $block ($self->addr_block) {
$block->set('manual_flag', '');
$block->set('routernum', 0);
$error ||= $block->replace;
}
$error ||= $self->SUPER::delete;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
$dbh->commit or die $dbh->errstr if $oldAutoCommit;
'';
}
=item addr_block
Returns a list of FS::addr_block objects (address blocks) associated
with this object.
=item auto_addr_block
Returns a list of address blocks on which auto-assignment of IP addresses
is enabled.
=cut
sub auto_addr_block {
my $self = shift;
return () if $self->manual_addr;
return qsearch('addr_block', { routernum => $self->routernum,
manual_flag => '' });
}
=item part_svc_router
Returns a list of FS::part_svc_router objects associated with this
object. This is unlikely to be useful for any purpose other than retrieving
the associated FS::part_svc objects. See below.
=item part_svc
Returns a list of FS::part_svc objects associated with this object.
=cut
sub part_svc {
my $self = shift;
return map { qsearchs('part_svc', { svcpart => $_->svcpart }) }
$self->part_svc_router;
}
=item agent
Returns the agent associated with this router, if any.
=item cust_svc
Returns the cust_svc associated with this router, if any. This should be
the service that I<provides connectivity to the router>, not any service
connected I<through> the router.
=back
=head1 SEE ALSO
FS::svc_broadband, FS::router, FS::addr_block, FS::part_svc,
schema.html from the base documentation.
=cut
1;
|