1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
|
package FS::did_order;
use base qw( FS::o2m_Common FS::Record );
use strict;
use FS::Record qw( qsearch qsearchs dbh );
=head1 NAME
FS::did_order - Object methods for did_order records
=head1 SYNOPSIS
use FS::did_order;
$record = new FS::did_order \%hash;
$record = new FS::did_order { 'column' => 'value' };
$error = $record->insert;
$error = $new_record->replace($old_record);
$error = $record->delete;
$error = $record->check;
=head1 DESCRIPTION
An FS::did_order object represents a bulk DID order. FS::did_order inherits from
FS::Record. The following fields are currently supported:
=over 4
=item ordernum
primary key
=item vendornum
vendornum
=item vendor_order_id
vendor_order_id
=item submitted
submitted
=item confirmed
confirmed
=item received
received
=back
=head1 METHODS
=over 4
=item new HASHREF
Creates a new bulk DID order. To add it to the database, see L<"insert">.
Note that this stores the hash reference, not a distinct copy of the hash it
points to. You can ask the object for a copy with the I<hash> method.
=cut
# the new method can be inherited from FS::Record, if a table method is defined
sub table { 'did_order'; }
=item insert
Adds this record to the database. If there is an error, returns the error,
otherwise returns false.
=cut
# the insert method can be inherited from FS::Record
=item delete
Delete this record from the database.
=cut
sub delete {
my $self = shift;
return "Can't delete a DID order which has DIDs received"
if qsearch( 'phone_avail', { 'ordernum' => $self->ordernum } );
local $SIG{HUP} = 'IGNORE';
local $SIG{INT} = 'IGNORE';
local $SIG{QUIT} = 'IGNORE';
local $SIG{TERM} = 'IGNORE';
local $SIG{TSTP} = 'IGNORE';
local $SIG{PIPE} = 'IGNORE';
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my @did_order_item = $self->did_order_item;
foreach my $did_order_item ( @did_order_item ) {
my $error = $did_order_item->delete;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return "can't delete DID order item "
. $did_order_item->orderitemnum . ": $error";
}
}
my $error = $self->SUPER::delete(@_);
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
$dbh->commit or die $dbh->errstr if $oldAutoCommit;
'';
}
=item merge SOURCE_ORDER
Merges the DID order given by SOURCE_ORDER into THIS order.
The following fields from the source order are transferred, only if they aren't
set in this order:
-vendor order #
-confirmed
-customer
DID order items are transferred into this order. Per-order customer is cleared
if any order items are assigned to a customer.
The source order is deleted.
The operation fails if:
-either order has a received time; or
-the DID vendors do not match between the orders
=cut
sub merge {
my $self = shift;
my $src = shift;
return "invalid source order" unless $src;
return "DIDs received for either order"
if $src->received || $self->received;
return "DID vendors do not match"
if $src->vendornum != $self->vendornum;
local $SIG{HUP} = 'IGNORE';
local $SIG{INT} = 'IGNORE';
local $SIG{QUIT} = 'IGNORE';
local $SIG{TERM} = 'IGNORE';
local $SIG{TSTP} = 'IGNORE';
local $SIG{PIPE} = 'IGNORE';
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my @move_if_unset = qw( vendor_order_id confirmed custnum );
foreach my $f ( @move_if_unset ) {
$self->$f($src->$f) if !$self->$f;
}
my $error = '';
my $item_has_cust = 0;
my @did_order_item = $src->did_order_item;
foreach my $did_order_item ( @did_order_item ) {
$did_order_item->ordernum($self->ordernum);
$item_has_cust = 1 if $did_order_item->custnum;
$error = $did_order_item->replace;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return "can't replace did order item "
. $did_order_item->orderitemnum . ": $error";
}
}
@did_order_item = $self->did_order_item;
foreach my $did_order_item ( @did_order_item ) {
$item_has_cust = 1 if $did_order_item->custnum;
}
$self->custnum('') if $item_has_cust;
$error = $src->delete;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return "can't delete source order: $error";
}
$error = $self->replace;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return "can't replace target order: $error";
}
$dbh->commit or die $dbh->errstr if $oldAutoCommit;
'';
}
=item replace OLD_RECORD
Replaces the OLD_RECORD with this one in the database. If there is an error,
returns the error, otherwise returns false.
=cut
# the replace method can be inherited from FS::Record
=item check
Checks all fields to make sure this is a valid bulk DID order. If there is
an error, returns the error, otherwise returns false. Called by the insert
and replace methods.
=cut
# the check method should currently be supplied - FS::Record contains some
# data checking routines
sub check {
my $self = shift;
my $error =
$self->ut_numbern('ordernum')
|| $self->ut_foreign_key('vendornum', 'did_vendor', 'vendornum' )
|| $self->ut_textn('vendor_order_id')
|| $self->ut_number('submitted')
|| $self->ut_numbern('confirmed')
|| $self->ut_numbern('received')
;
return $error if $error;
$self->SUPER::check;
}
=item did_order_item
Returns the did_order_items (see L<FS::did_order_item>) associated with this bulk DID order.
=item cust_main
Returns all cust_main (see L<FS::cust_main>), if any, associated with this
bulk DID order.
=cut
sub cust_main {
my $self = shift;
my @did_order_item = $self->did_order_item;
my @custnums;
push @custnums, $self->custnum if $self->custnum;
foreach my $did_order_item ( @did_order_item ) {
push @custnums, $did_order_item->custnum if $did_order_item->custnum;
}
my @cust_main;
foreach my $custnum ( @custnums ) {
push @cust_main, qsearchs('cust_main', { 'custnum' => $custnum } );
}
@cust_main;
}
=item has_stock
Returns true if and only if the order has any stock order items.
=cut
sub has_stock {
my $self = shift;
my $items_with_custnum = 0;
my @did_order_item = $self->did_order_item;
foreach my $did_order_item ( @did_order_item ) {
$items_with_custnum++ if $did_order_item->custnum;
}
return 0 if ($items_with_custnum == scalar(@did_order_item)
&& $items_with_custnum != 0 && !$self->custnum)
|| $self->custnum;
1;
}
=item provisioned
Returns the provisioned DIDs, if any, as phone_avail (see L<FS::phone_avail>) objects.
=cut
sub provisioned {
my $self = shift;
qsearch({ table => 'phone_avail',
hashref => { 'ordernum' => $self->ordernum, },
select => 'phone_avail.*',
extra_sql => ' and svcnum is not null ',
});
}
=back
=head1 SEE ALSO
L<FS::Record>, schema.html from the base documentation.
=cut
1;
|