1 files changed, 155 insertions, 0 deletions
diff --git a/FS/FS/part_export/artera_turbo.pm b/FS/FS/part_export/artera_turbo.pm
new file mode 100644
index 0000000..af4c790
--- /dev/null
+++ b/FS/FS/part_export/artera_turbo.pm
@@ -0,0 +1,155 @@
+package FS::part_export::artera_turbo;
+
+use vars qw(@ISA %info);
+use Tie::IxHash;
+use FS::Record qw(qsearch);
+use FS::part_export;
+use FS::cust_svc;
+use FS::svc_external;
+
+@ISA = qw(FS::part_export);
+
+tie my %options, 'Tie::IxHash',
+  'rid'        => { 'label' => 'Reseller ID (RID)' },
+  'username'   => { 'label' => 'Reseller username', },
+  'password'   => { 'label' => 'Reseller password', },
+  'pid'        => { 'label' => 'Artera Product ID', },
+  'priceid'    => { 'label' => 'Artera Price ID', },
+  'agent_aid'  => { 'label' => 'Export agentnum values to Artera AID',
+                    'type'  => 'checkbox',
+                  },
+  'aid'        => { 'label' => 'Artera Agent ID to use if not using agentnum values', },
+  'production' => { 'label' => 'Production mode (leave unchecked for staging)',
+                    'type'  => 'checkbox',
+                  },
+  'debug'      => { 'label' => 'Enable debug logging',
+                    'type'  => 'checkbox',
+                  },
+;
+
+%info = (
+  'svc'      => 'svc_external',
+  #'svc'      => [qw( svc_acct svc_forward )],
+  'desc'     =>
+    'Real-time export to Artera Turbo Reseller API',
+  'options'  => \%options,
+  #'nodomain' => 'Y',
+  'notes'    => <<'END'
+Real-time export to <a href="http://www.arteraturbo.com/">Artera Turbo</a>
+Reseller API.  Requires installation of
+<a href="http://search.cpan.org/dist/Net-Artera">Net::Artera</a>
+from CPAN.  You probably also want to:
+<UL>
+  <LI>In the configuraiton UI section: set the <B>svc_external-skip_manual</B> and <B>svc_external-display_type</B> configuration values.
+  <LI>In the message catalog: set <B>svc_external-id</B> to <I>Artera Serial Number</I> and set <B>svc_external-title</B> to <I>Artera Key Code</I>.
+</UL>
+END
+);
+
+sub rebless { shift; }
+
+sub _new_Artera {
+  my $self = shift;
+
+  my $artera = new Net::Artera (
+    map { $_ => $self->option($_) }
+        qw( rid username password production )
+  );
+}
+
+
+sub _export_insert {
+  my($self, $svc_external) = (shift, shift);
+
+  # want the ASN (serial) and AKC (key code) right away
+
+  eval "use Net::Artera;";
+  return $@ if $@;
+  $Net::Artera::DEBUG = 1 if $self->option('debug');
+  my $artera = $self->_new_Artera;
+
+  my $cust_pkg = $svc_external->cust_svc->cust_pkg;
+  my $part_pkg = $cust_pkg->part_pkg;
+  my @svc_acct = grep { $_->table eq 'svc_acct' }
+                 map { $_->svc_x }
+                 sort { my $svcpart = $part_pkg->svcpart('svc_acct');
+                        ($b->svcpart==$svcpart) cmp ($a->svcpart==$svcpart); }
+                 qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
+  my $email = scalar(@svc_acct) ? $svc_acct[0]->email : '';
+  
+  my $cust_main = $cust_pkg->cust_main;
+
+  my $result = $artera->newOrder(
+    'pid'     => $self->option('pid'),
+    'priceid' => $self->option('priceid'),
+    'email'   => $email,
+    'cname'   => $cust_main->name,
+    'ref'     => $svc_external->svcnum,
+    'aid'     => ( $self->option('agent_aid')
+                     ? $cust_main->agentnum
+                     : $self->option('aid')   ),
+    'add1'    => $cust_main->address1,
+    'add2'    => $cust_main->address2,
+    'add3'    => $cust_main->city,
+    'add4'    => $cust_main->state,
+    'zip'     => $cust_main->zip,
+    'cid'     => $cust_main->country,
+    'phone'   => $cust_main->daytime || $cust_main->night,
+    'fax'     => $cust_main->fax,
+  );
+
+  if ( $result->{'id'} == 1 ) {
+    my $new = new FS::svc_external { $svc_external->hash };
+    $new->id($result->{'ASN'});
+    $new->title($result->{'AKC'});
+    $new->replace($svc_external);
+  } else {
+    $result->{'message'} || 'No response from Artera';
+  }
+}
+
+sub _export_replace {
+  my( $self, $new, $old ) = (shift, shift, shift);
+  return "can't change serial number with Artera"
+    if $old->id != $new->id && $old->id;
+  return "can't change key code with Artera"
+    if $old->title ne $new->title && $old->title;
+  '';
+}
+
+sub _export_delete {
+  my( $self, $svc_external ) = (shift, shift);
+  $self->statusChange(17, $svc_external);
+}
+
+sub _export_suspend {
+  my( $self, $svc_external ) = (shift, shift);
+  $self->statusChange(16, $svc_external);
+}
+
+sub _export_unsuspend {
+  my( $self, $svc_external ) = (shift, shift);
+  $self->statusChange(15, $svc_external);
+}
+
+sub statusChange {
+  my( $self, $status, $svc_external ) = @_;
+
+  eval "use Net::Artera;";
+  return $@ if $@;
+  $Net::Artera::DEBUG = 1 if $self->option('debug');
+  my $artera = $self->_new_Artera;
+
+  my $result = $artera->statusChange(
+    'asn'      => sprintf('%010d', $svc_external->id),
+    'akc'      => $svc_external->title,
+    'statusid' => $status,
+  );
+
+  $result->{'id'} == 1
+    ? ''
+    : $result->{'message'};
+}
+
+1;
+