RT#7046: inbound rate for rate plan billing

8 files changed, 514 insertions, 73 deletions

diff --git a/FS/FS/ClientAPI/MyAccount.pm b/FS/FS/ClientAPI/MyAccount.pm
index 50dc89c..71fe752 100644
--- a/FS/FS/ClientAPI/MyAccount.pm
+++ b/FS/FS/ClientAPI/MyAccount.pm
@@ -1052,7 +1052,7 @@ sub list_support_usage {
 sub _list_cdr_usage {
   my($svc_phone, $begin, $end) = @_;
   map [ $_->downstream_csv('format' => 'default') ], #XXX config for format
-      $svc_phone->cust_svc->get_cdrs( 'begin'=>$begin, 'end'=>$end, );
+      $svc_phone->get_cdrs( 'begin'=>$begin, 'end'=>$end, );
 }
 
 sub list_cdr_usage {
diff --git a/FS/FS/Schema.pm b/FS/FS/Schema.pm
index 28f8264..dcd618d 100644
--- a/FS/FS/Schema.pm
+++ b/FS/FS/Schema.pm
@@ -2524,6 +2524,7 @@ sub tables_hashref {
         'termpart',         'int',     '',      '', '', '',#future use see below
         'rated_price',  'decimal', 'NULL',  '10,4', '', '',
         'status',       'varchar', 'NULL',      32, '', '',
+        'svcnum',           'int', 'NULL',      '', '', '',
       ],
       'primary_key' => 'cdrtermnum',
       'unique'      => [ [ 'acctid', 'termpart' ] ],
diff --git a/FS/FS/cdr.pm b/FS/FS/cdr.pm
index b9a4e41..36797b7 100644
--- a/FS/FS/cdr.pm
+++ b/FS/FS/cdr.pm
@@ -14,6 +14,7 @@ use FS::cdr_type;
 use FS::cdr_calltype;
 use FS::cdr_carrier;
 use FS::cdr_batch;
+use FS::cdr_termination;
 
 @ISA = qw(FS::Record);
 @EXPORT_OK = qw( _cdr_date_parser_maker _cdr_min_parser_maker );
@@ -386,11 +387,33 @@ error, otherwise returns false.
 =cut
 
 sub set_status_and_rated_price {
-  my($self, $status, $rated_price, $svcnum) = @_;
-  $self->freesidestatus($status);
-  $self->rated_price($rated_price);
-  $self->svcnum($svcnum) if $svcnum;
-  $self->replace();
+  my($self, $status, $rated_price, $svcnum, %opt) = @_;
+  if($opt{'inbound'}) {
+    my $term = qsearchs('cdr_termination', {
+        acctid   => $self->acctid, 
+        termpart => 1 # inbound
+    });
+    my $error;
+    if($term) {
+      warn "replacing existing cdr status (".$self->acctid.")\n" if $term;
+      $error = $term->delete;
+      return $error if $error;
+    }
+    $term = FS::cdr_termination->new({
+        acctid      => $self->acctid,
+        termpart    => 1,
+        rated_price => $rated_price,
+        status      => $status,
+        svcnum      => $svcnum,
+    });
+    return $term->insert;
+  }
+  else {
+    $self->freesidestatus($status);
+    $self->rated_price($rated_price);
+    $self->svcnum($svcnum) if $svcnum;
+    return $self->replace();
+  }
 }
 
 =item calldate_unix 
diff --git a/FS/FS/cdr_termination.pm b/FS/FS/cdr_termination.pm
index e0cde6e..5e30805 100644
--- a/FS/FS/cdr_termination.pm
+++ b/FS/FS/cdr_termination.pm
@@ -51,6 +51,9 @@ rated_price
 
 status
 
+=item svcnum
+
+svc_phone record associated with this transaction, if there is one.
 
 =back
 
diff --git a/FS/FS/cust_svc.pm b/FS/FS/cust_svc.pm
index 3ce1314..c0766e5 100644
--- a/FS/FS/cust_svc.pm
+++ b/FS/FS/cust_svc.pm
@@ -709,72 +709,6 @@ sub get_session_history {
 
 }
 
-=item get_cdrs_for_update
-
-Returns (and SELECTs "FOR UPDATE") all unprocessed (freesidestatus NULL) CDR
-objects (see L<FS::cdr>) associated with this service.
-
-CDRs are associated with svc_phone services via svc_phone.phonenum
-
-=cut
-
-sub get_cdrs_for_update {
-  my $self = shift;
-  $self->get_cdrs( 'freesidestatus' => '',
-                   'for_update'     => 1,
-                   @_,
-                 );
-}
-
-sub get_cdrs {
-  my($self, %options) = @_;
-
-  my @fields = ( 'charged_party' );
-  push @fields, 'src' unless $options{'disable_src'};
-
-  my $for_update = $options{'for_update'} ? 'FOR UPDATE' : '';
-
-  my %hash = ();
-  $hash{'freesidestatus'} = $options{'freesidestatus'}
-    if exists($options{'freesidestatus'});
-
-  #CDRs are associated with svc_phone services via svc_phone.phonenum
-
-  #return () unless $self->svc_x->isa('FS::svc_phone');
-  return () unless $self->part_svc->svcdb eq 'svc_phone';
-  my $number = $self->svc_x->phonenum;
-
-  my $prefix = $options{'default_prefix'};
-
-  my @orwhere =  map " $_ = '$number'        ", @fields;
-  push @orwhere, map " $_ = '$prefix$number' ", @fields
-    if length($prefix);
-  if ( $prefix =~ /^\+(\d+)$/ ) {
-    push @orwhere, map " $_ = '$1$number' ", @fields
-  }
-
-  my @where = ( ' ( '. join(' OR ', @orwhere ). ' ) ' );
-
-  if ( $options{'begin'} ) {
-    push @where, 'startdate >= '. $options{'begin'};
-  }
-  if ( $options{'end'} ) {
-    push @where, 'startdate < '.  $options{'end'};
-  }
-
-  my $extra_sql = ( keys(%hash) ? ' AND ' : ' WHERE ' ). join(' AND ', @where );
-
-  my @cdrs =
-    qsearch( {
-      'table'      => 'cdr',
-      'hashref'    => \%hash,
-      'extra_sql'  => $extra_sql,
-      'order_by'   => "ORDER BY startdate $for_update",
-    } );
-
-  @cdrs;
-}
-
 =back
 
 =head1 BUGS
diff --git a/FS/FS/part_pkg/voip_cdr.pm b/FS/FS/part_pkg/voip_cdr.pm
index 38e5941..7134ccc 100644
--- a/FS/FS/part_pkg/voip_cdr.pm
+++ b/FS/FS/part_pkg/voip_cdr.pm
@@ -309,10 +309,13 @@ sub calc_usage {
     grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc
   ) {
 
+    my $svc_phone = $cust_svc->svc_x;
     foreach my $cdr (
-      $cust_svc->get_cdrs_for_update(
+      $svc_phone->get_cdrs(
         'disable_src'    => $self->option('disable_src'),
         'default_prefix' => $self->option('default_prefix'),
+        'status'         => '',
+        'for_update'     => 1,
       )  # $last_bill, $$sdate )
     ) {
       if ( $DEBUG > 1 ) {
diff --git a/FS/FS/part_pkg/voip_inbound.pm b/FS/FS/part_pkg/voip_inbound.pm
new file mode 100644
index 0000000..6e9b172
--- /dev/null
+++ b/FS/FS/part_pkg/voip_inbound.pm
@@ -0,0 +1,384 @@
+package FS::part_pkg::voip_inbound;
+
+use strict;
+use vars qw(@ISA $DEBUG %info);
+use Date::Format;
+use Tie::IxHash;
+use FS::Conf;
+use FS::Record qw(qsearchs qsearch);
+use FS::part_pkg::recur_Common;
+use FS::cdr;
+use FS::part_pkg::recur_Common;
+
+@ISA = qw(FS::part_pkg::recur_Common);
+
+$DEBUG = 0;
+
+tie my %temporalities, 'Tie::IxHash',
+  'upcoming'  => "Upcoming (future)",
+  'preceding' => "Preceding (past)",
+;
+
+tie my %granularity, 'Tie::IxHash', FS::rate_detail::granularities();
+
+%info = (
+  'name' => 'VoIP flat rate pricing of CDRs for inbound calls',
+  'shortname' => 'VoIP/telco CDR rating (inbound)',
+  'fields' => {
+    'setup_fee'     => { 'name' => 'Setup fee for this package',
+                         'default' => 0,
+                       },
+    'recur_fee'     => { 'name' => 'Base recurring fee for this package',
+                         'default' => 0,
+                       },
+
+    #false laziness w/flat.pm
+    'recur_temporality' => { 'name' => 'Charge recurring fee for period',
+                             'type' => 'select',
+                             'select_options' => \%temporalities,
+                           },
+
+    'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
+                                   ' of service at cancellation',
+                         'type' => 'checkbox',
+                       },
+
+    'cutoff_day'    => { 'name' => 'Billing Day (1 - 28) for prorating or '.
+                                   'subscription',
+                         'default' => '1',
+                       },
+
+    'recur_method'  => { 'name' => 'Recurring fee method',
+                         'type' => 'select',
+                         'select_options' => \%FS::part_pkg::recur_Common::recur_method,
+                       },
+
+    'min_charge' => { 'name' => 'Charge per minute',
+                    },
+
+    'sec_granularity' => { 'name' => 'Granularity',
+                           'type' => 'select',
+                           'select_options' => \%granularity,
+                         },
+
+    'default_prefix' => { 'name'    => 'Default prefix optionally prepended to customer DID numbers when searching for CDR records',
+                          'default' => '+1',
+                        },
+
+    'disable_tollfree' => { 'name' => 'Disable automatic toll-free processing',
+                            'type' => 'checkbox',
+                          },
+
+    'use_amaflags' => { 'name' => 'Do not charge for CDRs where the amaflags field is not set to "2" ("BILL"/"BILLING").',
+                        'type' => 'checkbox',
+                      },
+
+    'use_disposition' => { 'name' => 'Do not charge for CDRs where the disposition flag is not set to "ANSWERED".',
+                           'type' => 'checkbox',
+                         },
+
+    'use_disposition_taqua' => { 'name' => 'Do not charge for CDRs where the disposition is not set to "100" (Taqua).',
+                                 'type' => 'checkbox',
+                               },
+
+    'use_carrierid' => { 'name' => 'Do not charge for CDRs where the Carrier ID is not set to: ',
+                         },
+
+    'use_cdrtypenum' => { 'name' => 'Do not charge for CDRs where the CDR Type is not set to: ',
+                         },
+
+    'skip_dcontext' => { 'name' => 'Do not charge for CDRs where the dcontext is set to any of these (comma-separated) values:',
+                       },
+
+    'skip_dstchannel_prefix' => { 'name' => 'Do not charge for CDRs where the dstchannel starts with:',
+                                },
+
+    'skip_dst_length_less' => { 'name' => 'Do not charge for CDRs where the destination is less than this many digits:',
+                              },
+
+    'skip_lastapp' => { 'name' => 'Do not charge for CDRs where the lastapp matches this value',
+                      },
+
+    'use_duration'   => { 'name' => 'Calculate usage based on the duration field instead of the billsec field',
+                          'type' => 'checkbox',
+                        },
+
+    #false laziness w/cdr_termination.pm
+    'output_format' => { 'name' => 'CDR invoice display format',
+                         'type' => 'select',
+                         'select_options' => { FS::cdr::invoice_formats() },
+                         'default'        => 'default', #XXX test
+                       },
+
+    'usage_section' => { 'name' => 'Section in which to place usage charges (whether separated or not)',
+                       },
+
+    'summarize_usage' => { 'name' => 'Include usage summary with recurring charges when usage is in separate section',
+                          'type' => 'checkbox',
+                        },
+
+    'usage_mandate' => { 'name' => 'Always put usage details in separate section',
+                          'type' => 'checkbox',
+                       },
+    #eofalse
+
+    'bill_every_call' => { 'name' => 'Generate an invoice immediately for every call.  Useful for prepaid.',
+                           'type' => 'checkbox',
+                         },
+
+    #XXX also have option for an external db
+#    'cdr_location' => { 'name' => 'CDR database location'
+#                        'type' => 'select',
+#                        'select_options' => \%cdr_location,
+#                        'select_callback' => {
+#                          'external' => {
+#                            'enable' => [ 'datasrc', 'username', 'password' ],
+#                          },
+#                          'internal' => {
+#                            'disable' => [ 'datasrc', 'username', 'password' ],
+#                          }
+#                        },
+#                      },
+#    'datasrc' => { 'name' => 'DBI data source for external CDR table',
+#                   'disabled' => 'Y',
+#                 },
+#    'username' => { 'name' => 'External database username',
+#                    'disabled' => 'Y',
+#                  },
+#    'password' => { 'name' => 'External database password',
+#                    'disabled' => 'Y',
+#                  },
+
+  },
+  'fieldorder' => [qw(
+                       setup_fee recur_fee recur_temporality unused_credit
+                       recur_method cutoff_day
+                       min_charge sec_granularity
+                       ignore_unrateable
+                       default_prefix
+                       disable_src
+                       disable_tollfree
+                       use_amaflags use_disposition
+                       use_disposition_taqua use_carrierid use_cdrtypenum
+                       skip_dcontext skip_dstchannel_prefix
+                       skip_dst_length_less skip_lastapp
+                       use_duration
+                       output_format usage_mandate summarize_usage usage_section
+                       bill_every_call
+                       count_available_phones
+                     )
+                  ],
+  'weight' => 40,
+);
+
+sub calc_setup {
+  my($self, $cust_pkg ) = @_;
+  $self->option('setup_fee');
+}
+
+sub calc_recur {
+  my $self = shift;
+  my($cust_pkg, $sdate, $details, $param ) = @_;
+
+  my $charges = 0;
+
+  $charges += $self->calc_usage(@_);
+  $charges += $self->calc_recur_Common(@_);
+
+  $charges;
+
+}
+
+sub calc_cancel {
+  my $self = shift;
+  my($cust_pkg, $sdate, $details, $param ) = @_;
+
+  $self->calc_usage(@_);
+}
+
+#false laziness w/voip_sqlradacct calc_recur resolve it if that one ever gets used again
+
+sub calc_usage {
+  my $self = shift;
+  my($cust_pkg, $sdate, $details, $param ) = @_;
+
+  #my $last_bill = $cust_pkg->last_bill;
+  my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
+
+  return 0
+    if $self->option('recur_temporality', 1) eq 'preceding'
+    && ( $last_bill eq '' || $last_bill == 0 );
+
+  my $spool_cdr = $cust_pkg->cust_main->spool_cdr;
+
+  my %included_min = ();
+
+  my $charges = 0;
+
+#  my $downstream_cdr = '';
+
+  my $disable_tollfree  = $self->option('disable_tollfree');
+  my $ignore_unrateable = $self->option('ignore_unrateable', 'Hush!');
+  my $use_duration      = $self->option('use_duration');
+
+  my $output_format     = $self->option('output_format', 'Hush!') || 'default';
+
+  #for check_chargable, so we don't keep looking up options inside the loop
+  my %opt_cache = ();
+
+  eval "use Text::CSV_XS;";
+  die $@ if $@;
+  my $csv = new Text::CSV_XS;
+
+  foreach my $cust_svc (
+    grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc
+  ) {
+    my $svc_phone = $cust_svc->svc_x;
+
+    foreach my $cdr ( $svc_phone->get_cdrs(
+      'for_update'     => 1,
+      'status'         => '', # unprocessed only
+      'default_prefix' => $self->option('default_prefix'),
+      'inbound'        => 1,
+      )
+    ) {
+      if ( $DEBUG > 1 ) {
+        warn "rating inbound CDR $cdr\n".
+             join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
+      }
+      my $granularity = length($self->option('sec_granularity'))
+                          ? $self->option('sec_granularity')
+                          : 60;
+
+      my $seconds = $use_duration ? $cdr->duration : $cdr->billsec;
+
+      $seconds += $granularity - ( $seconds % $granularity )
+        if $seconds      # don't granular-ize 0 billsec calls (bills them)
+        && $granularity; # 0 is per call
+      my $minutes = sprintf("%.1f",$seconds / 60); 
+      $minutes =~ s/\.0$// if $granularity == 60; # count whole minutes, convert to integer
+      $minutes = 1 unless $granularity; # per call
+      my $charge = sprintf('%.2f', ( $self->option('min_charge') * $minutes )
+                                + 0.00000001 ); #so 1.00005 rounds to 1.0001
+      next if !$charge;
+      $charges += $charge;
+      my @call_details = ($cdr->downstream_csv( 'format' => $output_format,
+                                             'charge'  => $charge,
+                                             'minutes' => $minutes,
+                                             'granularity' => $granularity,
+                                           )
+                        );
+      push @$details,
+        [ 'C',
+          $call_details[0],
+          $charge,
+          $cdr->calltypenum, #classnum
+          $self->phonenum,
+          $seconds,
+          '', #regionname, not set for inbound calls
+        ];
+
+    my $error = $cdr->set_status_and_rated_price( 'done',
+                                                  $charge,
+                                                  $cust_svc->svcnum,
+                                                  'inbound' => 1 );
+    die $error if $error;
+
+    } #$cdr
+  } # $cust_svc
+  unshift @$details, [ 'C',
+                       FS::cdr::invoice_header($output_format),
+                       '',
+                       '',
+                       '',
+                       '',
+                       '',
+                     ]
+    if @$details;
+
+  $charges;
+}
+
+#returns a reason why not to rate this CDR, or false if the CDR is chargeable
+sub check_chargable {
+  my( $self, $cdr, %flags ) = @_;
+
+  #should have some better way of checking these options from a hash
+  #or something
+
+  my @opt = qw(
+    use_amaflags
+    use_disposition
+    use_disposition_taqua
+    use_carrierid
+    use_cdrtypenum
+    skip_dcontext
+    skip_dstchannel_prefix
+    skip_dst_length_less
+    skip_lastapp
+  );
+  foreach my $opt (grep !exists($flags{option_cache}->{$_}), @opt ) {
+    $flags{option_cache}->{$opt} = $self->option($opt, 1);
+  }
+  my %opt = %{ $flags{option_cache} };
+
+  return 'amaflags != 2'
+    if $opt{'use_amaflags'} && $cdr->amaflags != 2;
+
+  return 'disposition != ANSWERED'
+    if $opt{'use_disposition'} && $cdr->disposition ne 'ANSWERED';
+
+  return "disposition != 100"
+    if $opt{'use_disposition_taqua'} && $cdr->disposition != 100;
+
+  return "carrierid != $opt{'use_carrierid'}"
+    if length($opt{'use_carrierid'})
+    && $cdr->carrierid ne $opt{'use_carrierid'} #ne otherwise 0 matches ''
+    && ! $flags{'da_rewrote'};
+
+  return "cdrtypenum != $opt{'use_cdrtypenum'}"
+    if length($opt{'use_cdrtypenum'})
+    && $cdr->cdrtypenum ne $opt{'use_cdrtypenum'}; #ne otherwise 0 matches ''
+
+  return "dcontext IN ( $opt{'skip_dcontext'} )"
+    if $opt{'skip_dcontext'} =~ /\S/
+    && grep { $cdr->dcontext eq $_ } split(/\s*,\s*/, $opt{'skip_dcontext'});
+
+  my $len_prefix = length($opt{'skip_dstchannel_prefix'});
+  return "dstchannel starts with $opt{'skip_dstchannel_prefix'}"
+    if $len_prefix
+    && substr($cdr->dstchannel,0,$len_prefix) eq $opt{'skip_dstchannel_prefix'};
+
+  my $dst_length = $opt{'skip_dst_length_less'};
+  return "destination less than $dst_length digits"
+    if $dst_length && length($cdr->dst) < $dst_length;
+
+  return "lastapp is $opt{'skip_lastapp'}"
+    if length($opt{'skip_lastapp'}) && $cdr->lastapp eq $opt{'skip_lastapp'};
+
+  #all right then, rate it
+  '';
+}
+
+sub is_free {
+  0;
+}
+
+#  This equates svc_phone records; perhaps svc_phone should have a field
+#  to indicate it represents a line
+sub calc_units {    
+  my($self, $cust_pkg ) = @_;
+  my $count = 0;
+  if ( $self->option('count_available_phones', 1)) {
+    map { $count += ( $_->quantity || 0 ) }
+      grep { $_->part_svc->svcdb eq 'svc_phone' }
+      $cust_pkg->part_pkg->pkg_svc;
+  } else {
+    $count = 
+      scalar(grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc);
+  }
+  $count;
+}
+
+1;
+
diff --git a/FS/FS/svc_phone.pm b/FS/FS/svc_phone.pm
index 30572ec..a0a2c3e 100644
--- a/FS/FS/svc_phone.pm
+++ b/FS/FS/svc_phone.pm
@@ -525,6 +525,99 @@ sub cust_location_or_main {
   $cust_pkg ? $cust_pkg->cust_location_or_main : '';
 }
 
+=item get_cdrs
+
+Returns a set of Call Detail Records (see L<FS::cdr>) associated with this 
+service.  By default, "associated with" means that either the "src" or the 
+"charged_party" field of the CDR matches the "phonenum" field of the service.
+
+=over 2
+
+Accepts the following options:
+
+=item for_update => 1: SELECT the CDRs "FOR UPDATE".
+
+=item status => "" (or "done"): Return only CDRs with that processing status.
+
+=item inbound => 1: Return CDRs for inbound calls.  With "status", will filter 
+on inbound processing status.
+
+=item default_prefix => "XXX": Also accept the phone number of the service prepended 
+with the chosen prefix.
+
+=item disable_src => 1: Only match on "charged_party", not "src".
+
+=back
+
+=cut
+
+sub get_cdrs {
+  my($self, %options) = @_;
+  my @fields;
+  my %hash;
+  my @where;
+
+  if ( $options{'inbound'} ) {
+    @fields = ( 'dst' );
+    if ( exists($options{'status'}) ) {
+      # must be 'done' or ''
+      my $sq = 'EXISTS ( SELECT 1 FROM cdr_termination '.
+        'WHERE cdr.acctid = cdr_termination.acctid '.
+        'AND cdr_termination.status = \'done\' '.
+        'AND cdr_termination.termpart = 1 )';
+      if ( $options{'status'} eq 'done' ) {
+        push @where, $sq;
+      }
+      elsif ($options{'status'} eq '' ) {
+        push @where, "NOT $sq";
+      }
+      else {
+        warn "invalid status: $options{'status'} (ignored)\n";
+      }
+    }
+  }
+  else {
+    @fields = ( 'charged_party' );
+    push @fields, 'src' if !$options{'disable_src'};
+    $hash{'freesidestatus'} = $options{'status'}
+      if exists($options{'status'});
+  }
+  
+  my $for_update = $options{'for_update'} ? 'FOR UPDATE' : '';
+
+  my $number = $self->phonenum;
+
+  my $prefix = $options{'default_prefix'};
+
+  my @orwhere =  map " $_ = '$number'        ", @fields;
+  push @orwhere, map " $_ = '$prefix$number' ", @fields
+    if length($prefix);
+  if ( $prefix =~ /^\+(\d+)$/ ) {
+    push @orwhere, map " $_ = '$1$number' ", @fields
+  }
+
+  push @where, ' ( '. join(' OR ', @orwhere ). ' ) ';
+
+  if ( $options{'begin'} ) {
+    push @where, 'startdate >= '. $options{'begin'};
+  }
+  if ( $options{'end'} ) {
+    push @where, 'startdate < '.  $options{'end'};
+  }
+
+  my $extra_sql = ( keys(%hash) ? ' AND ' : ' WHERE ' ). join(' AND ', @where );
+
+  my @cdrs =
+    qsearch( {
+      'table'      => 'cdr',
+      'hashref'    => \%hash,
+      'extra_sql'  => $extra_sql,
+      'order_by'   => "ORDER BY startdate $for_update",
+    } );
+
+  @cdrs;
+}
+
 =back
 
 =head1 BUGS